Update transformers submodule
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.0],
162     [AC_MSG_ERROR([GHC version 8.0 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
180                     SUPPORTS_THIS_UNIT_ID=NO,
181                     SUPPORTS_THIS_UNIT_ID=YES)
182 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
183
184 # GHC is passed to Cabal, so we need a native path
185 if test "${WithGhc}" != ""
186 then
187     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
188
189     if test "$ghc_host_os" = "mingw32"
190     then
191         if test "${OSTYPE}" = "msys"
192         then
193             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
194         else
195             # Canonicalise to <drive>:/path/to/ghc
196             WithGhc=`cygpath -m "${WithGhc}"`
197         fi
198         echo "GHC path canonicalised to: ${WithGhc}"
199     fi
200 fi
201 AC_SUBST([WithGhc])
202
203 dnl ** Without optimization some INLINE trickery fails for GHCi
204 SRC_CC_OPTS="-O"
205
206 dnl--------------------------------------------------------------------
207 dnl * Choose host(/target/build) platform
208 dnl--------------------------------------------------------------------
209 dnl If we aren't explicitly told what values to use with configure flags,
210 dnl we ask the bootstrapping compiler what platform it is for
211
212 if test "${WithGhc}" != ""
213 then
214         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
215         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         if test "$bootstrap_host" != "$bootstrap_target"
217         then
218                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
219         fi
220 fi
221
222 # We have to run these unconditionally, but we may discard their
223 # results in the following code
224 AC_CANONICAL_BUILD
225 AC_CANONICAL_HOST
226 AC_CANONICAL_TARGET
227
228 FPTOOLS_SET_PLATFORM_VARS
229
230 # Verify that the installed (bootstrap) GHC is capable of generating
231 # code for the requested build platform.
232 if test "$BuildPlatform" != "$bootstrap_target"
233 then
234     echo "This GHC (${WithGhc}) does not generate code for the build platform"
235     echo "   GHC target platform    : $bootstrap_target"
236     echo "   Desired build platform : $BuildPlatform"
237     exit 1
238 fi
239
240 # Testing if we shall enable shared libs support on Solaris.
241 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
242
243 SOLARIS_BROKEN_SHLD=NO
244
245 case $host in
246      i386-*-solaris2)
247      # here we go with the test
248      MINOR=`uname -r|cut -d '.' -f 2-`
249      if test "$MINOR" -lt "11"; then
250          SOLARIS_BROKEN_SHLD=YES
251      fi
252      ;;
253 esac
254
255 AC_SUBST(SOLARIS_BROKEN_SHLD)
256
257 dnl ** Do an unregisterised build?
258 dnl --------------------------------------------------------------
259 case "$TargetArch" in
260     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
261         UnregisterisedDefault=NO
262         ;;
263     *)
264         UnregisterisedDefault=YES
265         ;;
266 esac
267 AC_ARG_ENABLE(unregisterised,
268 [AC_HELP_STRING([--enable-unregisterised],
269 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
270 [ if test x"$enableval" = x"yes"; then
271         Unregisterised=YES
272   else
273         Unregisterised=NO
274   fi
275 ],
276 [Unregisterised="$UnregisterisedDefault"]
277 )
278 AC_SUBST(Unregisterised)
279
280 dnl ** Does target have runtime linker support?
281 dnl --------------------------------------------------------------
282 case "$target" in
283     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
284         HaskellHaveRTSLinker=NO
285         ;;
286     *)
287         HaskellHaveRTSLinker=YES
288         ;;
289 esac
290 AC_SUBST(HaskellHaveRTSLinker)
291
292 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
293 FP_FIND_ROOT
294
295 fail() {
296     echo >&2
297     echo "$1" >&2
298     exit 1
299 }
300
301
302 if test "$HostOS" = "mingw32"
303 then
304     # Find the mingw-w64 7z file to extract.
305     # NB. If you update the tarballs to a new version of gcc, don't
306     # forget to tweak the paths in driver/gcc/gcc.c.
307     if test "$HostArch" = "i386"
308     then
309         mingw_arch="i686"
310         tarball_dest_dir="mingw-w64/x86"
311         tarball_mingw_dir="mingw32"
312     else
313         mingw_arch="x86_64"
314         tarball_dest_dir="mingw-w64/x86_64"
315         tarball_mingw_dir="mingw64"
316     fi
317 fi
318
319 set_up_tarballs() {
320     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
321     local action
322     if test "$TarballsAutodownload" = "NO"
323     then
324         action="verify"
325     else
326         action="download"
327     fi
328     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
329     case $? in
330         0)
331            rm missing-win32-tarballs
332            ;;
333         2)
334            echo
335            echo "Error:"
336            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
337            echo
338            echo "  * run configure with the --enable-tarballs-autodownload option"
339            echo
340            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
341            echo
342            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
343            echo "    them in the ghc-tarballs directory."
344            echo
345            exit 1
346            ;;
347         *)
348            echo
349            echo "Error fetching msys2 tarballs; see errors above."
350            exit 1
351            ;;
352     esac
353
354     # Extract all the tarballs in one go
355     if ! test -d inplace/mingw
356     then
357         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
358         rm -rf inplace/mingw
359         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
360         ( cd inplace &&
361         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
362         rm ".MTREE" &&
363         rm ".PKGINFO" &&
364         cd .. ) || fail "Error: Could not extract Windows toolchains."
365
366         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
367         touch inplace/mingw
368
369         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
370         # make a wrapper around it to give it the proper paths
371         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
372         PATH=`pwd`/inplace/mingw/bin:$PATH
373         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
374
375         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
376     fi
377 }
378
379 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
380 then
381     test -d inplace || mkdir inplace
382
383     # NB. Download and extract the MingW-w64 distribution if required
384     set_up_tarballs
385
386     mingwbin="$hardtop/inplace/mingw/bin/"
387     CC="${mingwbin}gcc.exe"
388     LD="${mingwbin}ld.exe"
389     NM="${mingwbin}nm.exe"
390     RANLIB="${mingwbin}ranlib.exe"
391     OBJDUMP="${mingwbin}objdump.exe"
392     fp_prog_ar="${mingwbin}ar.exe"
393
394     AC_PATH_PROG([Genlib],[genlib])
395
396     # NB. Download the perl binaries if required
397     if ! test -d inplace/perl ||
398          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
399     then
400         AC_MSG_NOTICE([Making in-tree perl tree])
401         rm -rf inplace/perl
402         mkdir inplace/perl
403         (
404             cd inplace/perl &&
405             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
406         )
407         AC_MSG_NOTICE([In-tree perl tree created])
408     fi
409 fi
410
411 # We don't want to bundle a MinGW-w64 toolchain
412 # So we have to find these individual tools.
413 if test "$EnableDistroToolchain" = "YES"
414 then
415     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
416     # are screwed up. Configure doesn't think they're ever equal and
417     # so never tried without the prefix.
418     AC_PATH_PROG([CC],[gcc], [clang])
419     AC_PATH_PROG([NM],[nm])
420     AC_PATH_PROG([AR],[ar])
421     AC_PATH_PROG([RANLIB],[ranlib])
422     AC_PATH_PROG([OBJDUMP],[objdump])
423     AC_PATH_PROG([DllWrap],[dllwrap])
424     AC_PATH_PROG([Windres],[windres])
425     AC_PATH_PROG([Genlib],[genlib])
426 fi
427
428 DllWrapCmd="$DllWrap"
429 WindresCmd="$Windres"
430
431 HAVE_GENLIB=False
432 if test "$HostOS" = "mingw32"
433 then
434     if test "$Genlib" != ""; then
435         GenlibCmd="$(cygpath -m $Genlib)"
436         HAVE_GENLIB=True
437     fi
438 fi
439
440 AC_SUBST([DllWrapCmd])
441 AC_SUBST([WindresCmd])
442 AC_SUBST([GenlibCmd])
443 AC_SUBST([HAVE_GENLIB])
444
445 FP_ICONV
446 FP_GMP
447 FP_CURSES
448
449 XCODE_VERSION()
450
451
452 dnl ** Building a cross compiler?
453 dnl --------------------------------------------------------------
454 CrossCompiling=NO
455 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
456 if test "$TargetPlatform" != "$HostPlatform" ; then
457     CrossCompiling=YES
458     cross_compiling=yes   # This tells configure that it can accept just 'target',
459                           # otherwise you get
460                           #   configure: error: cannot run C compiled programs.
461                           #   If you meant to cross compile, use `--host'.
462 fi
463 if test "$BuildPlatform" != "$HostPlatform" ; then
464    AC_MSG_ERROR([
465 You've selected:
466
467   BUILD:  $BuildPlatform   (the architecture we're building on)
468   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
469   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
470
471 BUILD must equal HOST; that is, we do not support building GHC itself
472 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
473 1 will be a cross-compiler, and stage 2 will be the cross-compiled
474 GHC.
475 ])
476 fi
477 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
478 # in calls to subproject configure scripts and thus must be set to the autoconf
479 # triple, not the normalized GHC triple that TargetPlatform is set to.
480 #
481 # We use the non-canonicalized triple, target_alias, here since the subproject
482 # configure scripts will use this triple to construct the names of the toolchain
483 # executables. If we instead passed down the triple produced by
484 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
485 # name (this is a known problem in the case of the Android NDK, which has
486 # slightly odd triples).
487 #
488 # It may be better to just do away with the GHC triples altogether. This would
489 # all be taken care of for us if we configured the subprojects using
490 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
491 # configuration.
492 #
493 # We also use non-canonicalized triple when install stage1 crosscompiler
494 if test -z "${target_alias}"
495 then
496   # --target wasn't given; use result from AC_CANONICAL_TARGET
497   TargetPlatformFull="${target}"
498 else
499   TargetPlatformFull="${target_alias}"
500 fi
501 if test "$CrossCompiling" = "YES"
502 then
503   # Use value passed by user from --target=
504   CrossCompilePrefix="${TargetPlatformFull}-"
505 else
506   CrossCompilePrefix=""
507 fi
508 AC_SUBST(CrossCompiling)
509 AC_SUBST(CrossCompilePrefix)
510 AC_SUBST(TargetPlatformFull)
511 AC_SUBST(EnableDistroToolchain)
512
513 dnl ** Which gcc to use?
514 dnl --------------------------------------------------------------
515
516 AC_ARG_WITH([gcc],
517         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
518         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
519
520 AC_ARG_WITH([clang],
521         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
522         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
523
524 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
525 dnl later CC is copied to CC_STAGE{1,2,3}
526 AC_PROG_CC([gcc clang])
527
528 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
529
530 dnl make extensions visible to allow feature-tests to detect them lateron
531 AC_USE_SYSTEM_EXTENSIONS
532
533 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
534 AC_PROG_CPP
535
536 # --with-hs-cpp/--with-hs-cpp-flags
537 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
538 AC_SUBST([HaskellCPPCmd])
539 AC_SUBST([HaskellCPPArgs])
540
541 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
542 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
543 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
544 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
545
546 dnl ** Choose a linker
547 dnl --------------------------------------------------------------
548 FIND_LD([$target],[GccUseLdOpt])
549 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
550 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
551 LdCmd="$LD"
552 CFLAGS="$CFLAGS $GccUseLdOpt"
553 AC_SUBST([LdCmd])
554
555 dnl ** Which nm to use?
556 dnl --------------------------------------------------------------
557 if test "$HostOS" != "mingw32"; then
558     AC_CHECK_TARGET_TOOL([NM], [nm])
559     if test "$NM" = ":"; then
560         AC_MSG_ERROR([cannot find nm in your PATH])
561     fi
562 fi
563 NmCmd="$NM"
564 AC_SUBST([NmCmd])
565
566 if test "$TargetOS_CPP" = "darwin"
567 then
568     AC_MSG_CHECKING(whether nm program is broken)
569     # Some versions of XCode ship a broken version of `nm`. Detect and work
570     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
571     nmver=$(${NM} --version | grep version | sed 's/ //g')
572     case "$nmver" in
573         LLVMversion7.3.0|LLVMversion7.3.1)
574             AC_MSG_RESULT(yes)
575             echo "The detected nm program is broken."
576             echo
577             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
578             echo
579             echo "Try re-running configure with:"
580             echo
581             echo '   NM=$(xcrun --find nm-classic) ./configure'
582             echo
583             exit 1
584             ;;
585         *)
586             AC_MSG_RESULT(no)
587             ;;
588         esac
589 fi
590
591 dnl ** Which objdump to use?
592 dnl --------------------------------------------------------------
593 dnl Note: we may not have objdump on OS X, and we only need it on
594 dnl Windows (for DLL checks), OpenBSD, and AIX
595 case $HostOS_CPP in
596   cygwin32|mingw32|openbsd|aix)
597     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
598     ;;
599 esac
600
601 ObjdumpCmd="$OBJDUMP"
602 AC_SUBST([ObjdumpCmd])
603
604 dnl ** Which ranlib to use?
605 dnl --------------------------------------------------------------
606 AC_PROG_RANLIB
607 if test "$RANLIB" = ":"; then
608     AC_MSG_ERROR([cannot find ranlib in your PATH])
609 fi
610 RanlibCmd="$RANLIB"
611 RANLIB="$RanlibCmd"
612
613 dnl ** which libtool to use?
614 dnl --------------------------------------------------------------
615 # The host normalization on Windows breaks autoconf, it no longer
616 # thinks that target == host so it never checks the unqualified
617 # tools for Windows. I don't know why we do this whole normalization thing
618 # as it just breaks everything.. but for now, just check the unqualified one
619 # if on Windows.
620 if test "$HostOS" = "mingw32"
621 then
622     AC_PATH_PROG([LIBTOOL],[libtool])
623     LibtoolCmd="$(cygpath -m $LIBTOOL)"
624 else
625     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
626     LibtoolCmd="$LIBTOOL"
627     LIBTOOL="$LibtoolCmd"
628 fi
629 AC_SUBST([LibtoolCmd])
630
631 # Here is where we re-target which specific version of the LLVM
632 # tools we are looking for. In the past, GHC supported a number of
633 # versions of LLVM simultaneously, but that stopped working around
634 # 3.5/3.6 release of LLVM.
635 LlvmVersion=4.0
636 AC_SUBST([LlvmVersion])
637 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
638 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
639
640 dnl ** Which LLVM llc to use?
641 dnl --------------------------------------------------------------
642 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
643 LlcCmd="$LLC"
644 AC_SUBST([LlcCmd])
645
646 dnl ** Which LLVM opt to use?
647 dnl --------------------------------------------------------------
648 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
649 OptCmd="$OPT"
650 AC_SUBST([OptCmd])
651
652 dnl --------------------------------------------------------------
653 dnl End of configure script option section
654 dnl --------------------------------------------------------------
655
656
657 dnl --------------------------------------------------------------
658 dnl ** Can the unix package be built?
659 dnl --------------------------------------------------------------
660
661 if test "$TargetOS" = "mingw32"
662 then
663     GhcLibsWithUnix=NO
664 else
665     GhcLibsWithUnix=YES
666 fi
667 AC_SUBST([GhcLibsWithUnix])
668
669 dnl ** does #! work?
670 AC_SYS_INTERPRETER()
671
672 # Check for split-objs
673 SplitObjsBroken=NO
674 dnl ** look for `perl'
675 case $HostOS_CPP in
676 cygwin32|mingw32)
677   if test "$EnableDistroToolchain" = "NO"; then
678     PerlCmd=$hardtop/inplace/perl/perl
679   else
680     AC_PATH_PROG([PerlCmd],[perl])
681   fi
682   ;;
683 *)
684     AC_PATH_PROG([PerlCmd],[perl])
685     if test -z "$PerlCmd"
686     then
687         AC_MSG_WARN([No Perl on PATH, disabling split object support])
688         SplitObjsBroken=YES
689     else
690         FPTOOLS_CHECK_PERL_VERSION
691     fi
692     ;;
693 esac
694 AC_SUBST([SplitObjsBroken])
695
696 dnl ** look for GCC and find out which version
697 dnl     Figure out which C compiler to use.  Gcc is preferred.
698 dnl     If gcc, make sure it's at least 3.0
699 dnl
700 FP_GCC_VERSION
701
702 dnl ** See whether gcc supports -no-pie
703 FP_GCC_SUPPORTS_NO_PIE
704
705 dnl ** look to see if we have a C compiler using an llvm back end.
706 dnl
707 FP_CC_LLVM_BACKEND
708
709 FP_PROG_LD_IS_GNU
710 FP_PROG_LD_BUILD_ID
711 FP_PROG_LD_NO_COMPACT_UNWIND
712 FP_PROG_LD_FILELIST
713
714 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
715 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
716 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
717 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
718 # Stage 3 won't be supported by cross-compilation
719
720 FP_GCC_EXTRA_FLAGS
721
722 # See rules/distdir-way-opts.mk for details.
723 # Flags passed to the C compiler
724 AC_SUBST(CONF_CC_OPTS_STAGE0)
725 AC_SUBST(CONF_CC_OPTS_STAGE1)
726 AC_SUBST(CONF_CC_OPTS_STAGE2)
727 # Flags passed to the C compiler when we ask it to link
728 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
729 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
730 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
731 # Flags passed to the linker when we ask it to link
732 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
733 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
734 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
735 # Flags passed to the C preprocessor
736 AC_SUBST(CONF_CPP_OPTS_STAGE0)
737 AC_SUBST(CONF_CPP_OPTS_STAGE1)
738 AC_SUBST(CONF_CPP_OPTS_STAGE2)
739 # Flags passed to the Haskell compiler
740 AC_SUBST(CONF_HC_OPTS_STAGE0)
741 AC_SUBST(CONF_HC_OPTS_STAGE1)
742 AC_SUBST(CONF_HC_OPTS_STAGE2)
743
744 dnl ** Set up the variables for the platform in the settings file.
745 dnl May need to use gcc to find platform details.
746 dnl --------------------------------------------------------------
747 FPTOOLS_SET_HASKELL_PLATFORM_VARS
748
749 dnl ** figure out how to do context diffs
750 FP_PROG_CONTEXT_DIFF
751
752 dnl Let's make sure install-sh is executable here.  If we got it from
753 dnl a darcs repo, it might not be (see bug #978).
754 chmod +x install-sh
755 dnl ** figure out how to do a BSD-ish install
756 AC_PROG_INSTALL
757
758 dnl ** how to invoke `ar' and `ranlib'
759 FP_PROG_AR_SUPPORTS_ATFILE
760 FP_PROG_AR_NEEDS_RANLIB
761
762 dnl ** Check to see whether ln -s works
763 AC_PROG_LN_S
764
765 FP_SETTINGS
766
767 dnl ** Find the path to sed
768 AC_PATH_PROGS(SedCmd,gsed sed,sed)
769
770
771 dnl ** check for time command
772 AC_PATH_PROG(TimeCmd,time)
773
774 dnl ** check for tar
775 dnl   if GNU tar is named gtar, look for it first.
776 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
777
778 dnl ** check for compressors
779 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
780 AC_PATH_PROGS(GzipCmd,gzip, gzip)
781 AC_PATH_PROGS(XzCmd,pxz xz, xz)
782
783 dnl ** check for patch
784 dnl if GNU patch is named gpatch, look for it first
785 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
786
787 dnl ** check for dtrace (currently only implemented for Mac OS X)
788 HaveDtrace=NO
789 AC_PATH_PROG(DtraceCmd,dtrace)
790 if test -n "$DtraceCmd"; then
791   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
792     HaveDtrace=YES
793   fi
794 fi
795 AC_SUBST(HaveDtrace)
796
797 AC_PATH_PROG(HSCOLOUR,HsColour)
798 # HsColour is passed to Cabal, so we need a native path
799 if test "$HostOS"      = "mingw32" && \
800    test "${OSTYPE}"   != "msys"    && \
801    test "${HSCOLOUR}" != ""
802 then
803     # Canonicalise to <drive>:/path/to/gcc
804     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
805 fi
806
807 dnl ** check for Sphinx toolchain
808 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
809 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
810 changequote(, )dnl
811 [if test -n "$SPHINXBUILD"; then
812   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
813 fi;
814 changequote([, ])dnl
815 ])
816 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
817     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
818
819 dnl ** check for xelatex
820 AC_PATH_PROG(XELATEX,xelatex)
821
822 dnl ** check for ghc-pkg command
823 FP_PROG_GHC_PKG
824
825 dnl ** check for installed happy binary + version
826 FPTOOLS_HAPPY
827
828 dnl ** check for installed alex binary + version
829 FPTOOLS_ALEX
830
831 dnl --------------------------------------------------
832 dnl ### program checking section ends here ###
833 dnl --------------------------------------------------
834
835 dnl --------------------------------------------------
836 dnl * Platform header file and syscall feature tests
837 dnl ### checking the state of the local header files and syscalls ###
838
839 dnl ** check for full ANSI header (.h) files
840 AC_HEADER_STDC
841
842 dnl ** Enable large file support.  NB. do this before testing the type of
843 dnl    off_t, because it will affect the result of that test.
844 AC_SYS_LARGEFILE
845
846 dnl ** check for specific header (.h) files that we are interested in
847 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
848
849 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
850 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
851 [[#if HAVE_SYS_PARAM_H
852 # include <sys/param.h>
853 #endif
854 ]])
855
856 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
857 AC_HEADER_TIME
858
859 dnl ** do we have long longs?
860 AC_CHECK_TYPES([long long])
861
862 dnl ** what are the sizes of various types
863 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
864 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
865 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
866 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
867 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
868 if test "$ac_cv_type_long_long" = yes; then
869 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
870 fi
871 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
872 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
873 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
874 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
875 if test "$ac_cv_type_long_long" = yes; then
876 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
877 fi
878 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
879 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
880
881 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
882 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
883 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
884 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
885 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
886 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
887 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
888 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
889
890
891 dnl for use in settings.in
892 TargetWordSize=$ac_cv_sizeof_void_p
893 AC_SUBST(TargetWordSize)
894 FP_CHECK_FUNC([WinExec],
895   [@%:@include <windows.h>], [WinExec("",0)])
896
897 FP_CHECK_FUNC([GetModuleFileName],
898   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
899
900 dnl ** check for more functions
901 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
902 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
903
904 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
905 dnl ** _POSIX_C_SOURCE is defined
906 AC_CHECK_DECLS([ctime_r], , ,
907 [#define _POSIX_SOURCE 1
908 #define _POSIX_C_SOURCE 199506L
909 #include <time.h>])
910
911 dnl ** check for mingwex library
912 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
913 AC_SUBST(HaveLibMingwEx)
914
915 if test $HaveLibMingwEx = YES ; then
916   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
917 fi
918
919 dnl ** check for math library
920 dnl    Keep that check as early as possible.
921 dnl    as we need to know whether we need libm
922 dnl    for math functions or not
923 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
924 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
925 if test $HaveLibM = YES
926 then
927   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
928 fi
929
930 FP_BFD_SUPPORT
931
932 dnl ################################################################
933 dnl Check for libraries
934 dnl ################################################################
935
936 # system libffi
937
938 AC_ARG_WITH([system-libffi],
939 [AC_HELP_STRING([--with-system-libffi],
940   [Use system provided libffi for RTS [default=no]])
941 ])
942
943 AS_IF([test "x$with_system_libffi" = "xyes"],
944   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
945 )
946
947
948 AC_SUBST(UseSystemLibFFI)
949
950 AC_ARG_WITH([ffi-includes],
951 [AC_HELP_STRING([--with-ffi-includes=ARG],
952   [Find includes for libffi in ARG [default=system default]])
953 ],
954 [
955  if test "x$UseSystemLibFFI" != "xYES"; then
956     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
957  else
958     FFIIncludeDir="$withval"
959     LIBFFI_CFLAGS="-I$withval"
960  fi
961 ])
962
963 AC_SUBST(FFIIncludeDir)
964
965 AC_ARG_WITH([ffi-libraries],
966 [AC_HELP_STRING([--with-ffi-libraries=ARG],
967   [Find libffi in ARG [default=system default]])
968 ],
969 [
970  if test "x$UseSystemLibFFI" != "xYES"; then
971     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
972  else
973     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
974  fi
975 ])
976
977 AC_SUBST(FFILibDir)
978
979 AS_IF([test "$UseSystemLibFFI" = "YES"], [
980  CFLAGS2="$CFLAGS"
981  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
982  LDFLAGS2="$LDFLAGS"
983  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
984  if test "$HostOS" = "openbsd";
985  then
986    # OpenBSD's libffi is not directly linked to the libpthread but
987    # still requires pthread functionality. This means that any client
988    # binary which links with libffi also needs to link with
989    # libpthread. If it does not, then linking fails with unresolved
990    # symbols.
991    LDFLAGS="$LDFLAGS -lpthread"
992  fi
993  AC_CHECK_LIB(ffi, ffi_call,
994   [AC_CHECK_HEADERS([ffi.h], [break], [])
995    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
996   [AC_MSG_ERROR([Cannot find system libffi])])
997  CFLAGS="$CFLAGS2"
998  LDFLAGS="$LDFLAGS2"
999 ])
1000
1001 dnl ** check whether we need -ldl to get dlopen()
1002 AC_CHECK_LIB(dl, dlopen)
1003
1004 dnl --------------------------------------------------
1005 dnl * Miscellaneous feature tests
1006 dnl --------------------------------------------------
1007
1008 dnl ** can we get alloca?
1009 AC_FUNC_ALLOCA
1010
1011 dnl ** working vfork?
1012 AC_FUNC_FORK
1013
1014 dnl ** determine whether or not const works
1015 AC_C_CONST
1016
1017 dnl ** are we big endian?
1018 AC_C_BIGENDIAN
1019 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1020
1021 dnl ** check for leading underscores in symbol names
1022 FP_LEADING_UNDERSCORE
1023
1024 FP_VISIBILITY_HIDDEN
1025
1026 dnl ** check for librt
1027 AC_CHECK_LIB(rt, clock_gettime)
1028 AC_CHECK_FUNCS(clock_gettime timer_settime)
1029 FP_CHECK_TIMER_CREATE
1030
1031 dnl ** check for Apple's "interesting" long double compatibility scheme
1032 AC_MSG_CHECKING(for printf\$LDBLStub)
1033 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1034     [
1035         AC_MSG_RESULT(yes)
1036         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1037             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1038     ],
1039     [
1040         AC_MSG_RESULT(no)
1041         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1042             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1043     ])
1044
1045 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1046 dnl without linking against libpthread. Check whether -lpthread is necessary
1047 dnl to use pthreads.
1048 dnl
1049 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1050 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1051 AC_CHECK_FUNC(pthread_create,
1052     [
1053         AC_MSG_RESULT(no)
1054         need_lpthread=0
1055     ],
1056     [
1057         AC_CHECK_LIB(pthread, pthread_create,
1058             [
1059                 AC_MSG_RESULT(yes)
1060                 need_lpthread=1
1061             ],
1062             [
1063                 AC_MSG_RESULT([no pthreads support found.])
1064                 need_lpthread=0
1065             ])
1066     ])
1067 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1068     [Define 1 if we need to link code using pthreads with -lpthread])
1069
1070 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1071 dnl    a different single-argument version.
1072 AC_CHECK_LIB(pthread, pthread_setname_np)
1073 AC_MSG_CHECKING(for pthread_setname_np)
1074 AC_TRY_LINK(
1075 [
1076 #define _GNU_SOURCE
1077 #include <pthread.h>
1078 ],
1079 [pthread_setname_np(pthread_self(), "name");],
1080     AC_MSG_RESULT(yes)
1081     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1082       [Define to 1 if you have the glibc version of pthread_setname_np]),
1083     AC_MSG_RESULT(no)
1084 )
1085
1086 dnl ** check for eventfd which is needed by the I/O manager
1087 AC_CHECK_HEADERS([sys/eventfd.h])
1088 AC_CHECK_FUNCS([eventfd])
1089
1090 dnl ** Check for __thread support in the compiler
1091 AC_MSG_CHECKING(for __thread support)
1092 AC_COMPILE_IFELSE(
1093   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1094   [
1095    AC_MSG_RESULT(yes)
1096    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1097   ],
1098   [
1099    AC_MSG_RESULT(no)
1100    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1101   ])
1102
1103 dnl large address space support (see includes/rts/storage/MBlock.h)
1104 dnl
1105 dnl Darwin has vm_allocate/vm_protect
1106 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1107 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1108 dnl (They also have MADV_DONTNEED, but it means something else!)
1109 dnl
1110 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1111 dnl it counts page-table space as committed memory, and so quickly
1112 dnl runs out of paging file when we have multiple processes reserving
1113 dnl 1TB of address space, we get the following error:
1114 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1115 dnl
1116
1117 AC_ARG_ENABLE(large-address-space,
1118     [AC_HELP_STRING([--enable-large-address-space],
1119         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1120     EnableLargeAddressSpace=$enableval,
1121     EnableLargeAddressSpace=yes
1122 )
1123
1124 use_large_address_space=no
1125 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1126     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1127         if test "$ghc_host_os" = "darwin" ; then
1128             use_large_address_space=yes
1129         elif test "$ghc_host_os" = "openbsd" ; then
1130             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1131             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1132             # but is completely ignored by OS mmap
1133             use_large_address_space=no
1134         else
1135             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1136                 [
1137                 #include <unistd.h>
1138                 #include <sys/types.h>
1139                 #include <sys/mman.h>
1140                 #include <fcntl.h>
1141             ])
1142             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1143                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1144                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1145                     use_large_address_space=yes
1146             fi
1147         fi
1148     fi
1149 fi
1150 if test "$use_large_address_space" = "yes" ; then
1151    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1152 fi
1153
1154 dnl ** Use MMAP in the runtime linker?
1155 dnl --------------------------------------------------------------
1156
1157 case ${TargetOS} in
1158     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1159         RtsLinkerUseMmap=1
1160         ;;
1161     darwin|ios)
1162         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1163         # reallocating. Reallocating is needed to allocate jump islands just
1164         # after each object image. Jumps to these jump islands use relative
1165         # branches which are limited to offsets that can be represented in
1166         # 24-bits.
1167         if test "$TargetArch" != "powerpc" ; then
1168             RtsLinkerUseMmap=1
1169         else
1170             RtsLinkerUseMmap=0
1171         fi
1172         ;;
1173     *)
1174         # Windows (which doesn't have mmap) and everything else.
1175         RtsLinkerUseMmap=0
1176         ;;
1177     esac
1178
1179 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1180                    [Use mmap in the runtime linker])
1181
1182 dnl ** Have libdw?
1183 dnl --------------------------------------------------------------
1184 UseLibdw=NO
1185 USE_LIBDW=0
1186 AC_ARG_ENABLE(dwarf-unwind,
1187     [AC_HELP_STRING([--enable-dwarf-unwind],
1188         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1189     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1190     [UseLibdw=NO]
1191 )
1192 AC_SUBST(UseLibdw)
1193 if test $UseLibdw = "YES" ; then
1194         USE_LIBDW=1
1195 fi
1196 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1197
1198 dnl ** Have libnuma?
1199 dnl --------------------------------------------------------------
1200 HaveLibNuma=0
1201 AC_CHECK_HEADERS([numa.h numaif.h])
1202
1203 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1204     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1205 fi
1206 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1207
1208 dnl ** Documentation
1209 dnl --------------------------------------------------------------
1210 if test -n "$SPHINXBUILD"; then
1211     BUILD_MAN=YES
1212     BUILD_SPHINX_HTML=YES
1213     if test -n "$XELATEX"; then
1214         BUILD_SPHINX_PDF=YES
1215     else
1216         BUILD_SPHINX_PDF=NO
1217     fi
1218 else
1219     BUILD_MAN=NO
1220     BUILD_SPHINX_HTML=NO
1221     BUILD_SPHINX_PDF=NO
1222 fi
1223 AC_SUBST(BUILD_MAN)
1224 AC_SUBST(BUILD_SPHINX_HTML)
1225 AC_SUBST(BUILD_SPHINX_PDF)
1226
1227 LIBRARY_VERSION(base)
1228 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1229 LIBRARY_VERSION(ghc-prim)
1230 LIBRARY_VERSION(ghc-compact)
1231 LIBRARY_ghc_VERSION="$ProjectVersion"
1232 AC_SUBST(LIBRARY_ghc_VERSION)
1233
1234 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1235    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1236 fi
1237
1238 # Create the configuration for the Hadrian build system if it is present
1239 if test -e hadrian/cfg/system.config.in; then
1240     AC_CONFIG_FILES([hadrian/cfg/system.config])
1241 fi
1242
1243 # We got caught by
1244 #     http://savannah.gnu.org/bugs/index.php?1516
1245 #     $(eval ...) inside conditionals causes errors
1246 # with make 3.80, so warn the user if it looks like they're about to
1247 # try to use it.
1248 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1249 print_make_warning=""
1250 checkMake380() {
1251     make_ver=`$1 --version 2>&1 | head -1`
1252     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1253     then
1254         print_make_warning="true"
1255     fi
1256     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1257     then
1258         MakeCmd=$1
1259         AC_SUBST(MakeCmd)
1260     fi
1261 }
1262
1263 checkMake380 make
1264 checkMake380 gmake
1265
1266 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1267 AC_OUTPUT
1268 [
1269 if test "$print_make_warning" = "true"; then
1270    echo
1271    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1272    echo "This version cannot be used to build GHC."
1273    echo "Please use GNU make >= 3.81."
1274 fi
1275
1276 echo "
1277 ----------------------------------------------------------------------
1278 Configure completed successfully.
1279
1280    Building GHC version  : $ProjectVersion
1281           Git commit id  : $ProjectGitCommitId
1282
1283    Build platform        : $BuildPlatform
1284    Host platform         : $HostPlatform
1285    Target platform       : $TargetPlatform
1286 "
1287
1288 echo "\
1289    Bootstrapping using   : $WithGhc
1290       which is version   : $GhcVersion
1291 "
1292
1293 if test "x$CC_LLVM_BACKEND" = "x1"; then
1294     if test "x$CC_CLANG_BACKEND" = "x1"; then
1295         CompilerName="clang        "
1296     else
1297         CompilerName="llvm-gcc     "
1298     fi
1299 else
1300     CompilerName="gcc          "
1301 fi
1302
1303 echo "\
1304    Using (for bootstrapping) : $CC_STAGE0
1305    Using $CompilerName       : $CC
1306       which is version       : $GccVersion
1307    Building a cross compiler : $CrossCompiling
1308    Unregisterised            : $Unregisterised
1309    hs-cpp       : $HaskellCPPCmd
1310    hs-cpp-flags : $HaskellCPPArgs
1311    ar           : $ArCmd
1312    ld           : $LdCmd
1313    nm           : $NmCmd
1314    libtool      : $LibtoolCmd
1315    objdump      : $ObjdumpCmd
1316    ranlib       : $RanlibCmd
1317    windres      : $WindresCmd
1318    dllwrap      : $DllWrapCmd
1319    genlib       : $GenlibCmd
1320    Happy        : $HappyCmd ($HappyVersion)
1321    Alex         : $AlexCmd ($AlexVersion)
1322    Perl         : $PerlCmd
1323    sphinx-build : $SPHINXBUILD
1324    xelatex      : $XELATEX
1325
1326    Using LLVM tools
1327       llc   : $LlcCmd
1328       opt   : $OptCmd"
1329
1330 if test "$HSCOLOUR" = ""; then
1331 echo "
1332    HsColour was not found; documentation will not contain source links
1333 "
1334 else
1335 echo "\
1336    HsColour : $HSCOLOUR
1337 "
1338 fi
1339
1340 echo "\
1341    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1342    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1343
1344 echo "----------------------------------------------------------------------
1345 "
1346
1347 echo "\
1348 For a standard build of GHC (fully optimised with profiling), type (g)make.
1349
1350 To make changes to the default build configuration, copy the file
1351 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1352
1353 For more information on how to configure your GHC build, see
1354    http://ghc.haskell.org/trac/ghc/wiki/Building
1355 "]