Add tuple sections as a new feature
[ghc.git] / compiler / typecheck / TcTyClsDecls.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The AQUA Project, Glasgow University, 1996-1998
4 %
5
6 TcTyClsDecls: Typecheck type and class declarations
7
8 \begin{code}
9 module TcTyClsDecls (
10         tcTyAndClassDecls, tcFamInstDecl, mkAuxBinds
11     ) where
12
13 #include "HsVersions.h"
14
15 import HsSyn
16 import HscTypes
17 import BuildTyCl
18 import TcUnify
19 import TcRnMonad
20 import TcEnv
21 import TcTyDecls
22 import TcClassDcl
23 import TcHsType
24 import TcMType
25 import TcType
26 import TysWiredIn       ( unitTy )
27 import Type
28 import Generics
29 import Class
30 import TyCon
31 import DataCon
32 import Id
33 import MkId             ( rEC_SEL_ERROR_ID )
34 import IdInfo
35 import Var
36 import VarSet
37 import Name
38 import Outputable
39 import Maybes
40 import Monad
41 import Unify
42 import Util
43 import SrcLoc
44 import ListSetOps
45 import Digraph
46 import DynFlags
47 import FastString
48 import Unique           ( mkBuiltinUnique )
49 import BasicTypes
50
51 import Bag
52 import Data.List
53 \end{code}
54
55
56 %************************************************************************
57 %*                                                                      *
58 \subsection{Type checking for type and class declarations}
59 %*                                                                      *
60 %************************************************************************
61
62 Dealing with a group
63 ~~~~~~~~~~~~~~~~~~~~
64 Consider a mutually-recursive group, binding 
65 a type constructor T and a class C.
66
67 Step 1:         getInitialKind
68         Construct a KindEnv by binding T and C to a kind variable 
69
70 Step 2:         kcTyClDecl
71         In that environment, do a kind check
72
73 Step 3: Zonk the kinds
74
75 Step 4:         buildTyConOrClass
76         Construct an environment binding T to a TyCon and C to a Class.
77         a) Their kinds comes from zonking the relevant kind variable
78         b) Their arity (for synonyms) comes direct from the decl
79         c) The funcional dependencies come from the decl
80         d) The rest comes a knot-tied binding of T and C, returned from Step 4
81         e) The variances of the tycons in the group is calculated from 
82                 the knot-tied stuff
83
84 Step 5:         tcTyClDecl1
85         In this environment, walk over the decls, constructing the TyCons and Classes.
86         This uses in a strict way items (a)-(c) above, which is why they must
87         be constructed in Step 4. Feed the results back to Step 4.
88         For this step, pass the is-recursive flag as the wimp-out flag
89         to tcTyClDecl1.
90         
91
92 Step 6:         Extend environment
93         We extend the type environment with bindings not only for the TyCons and Classes,
94         but also for their "implicit Ids" like data constructors and class selectors
95
96 Step 7:         checkValidTyCl
97         For a recursive group only, check all the decls again, just
98         to check all the side conditions on validity.  We could not
99         do this before because we were in a mutually recursive knot.
100
101 Identification of recursive TyCons
102 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
103 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
104 @TyThing@s.
105
106 Identifying a TyCon as recursive serves two purposes
107
108 1.  Avoid infinite types.  Non-recursive newtypes are treated as
109 "transparent", like type synonyms, after the type checker.  If we did
110 this for all newtypes, we'd get infinite types.  So we figure out for
111 each newtype whether it is "recursive", and add a coercion if so.  In
112 effect, we are trying to "cut the loops" by identifying a loop-breaker.
113
114 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
115 Suppose we have
116         data T = MkT Int T
117         f (MkT x t) = f t
118 Well, this function diverges, but we don't want the strictness analyser
119 to diverge.  But the strictness analyser will diverge because it looks
120 deeper and deeper into the structure of T.   (I believe there are
121 examples where the function does something sane, and the strictness
122 analyser still diverges, but I can't see one now.)
123
124 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
125 newtypes.  I did this as an experiment, to try to expose cases in which
126 the coercions got in the way of optimisations.  If it turns out that we
127 can indeed always use a coercion, then we don't risk recursive types,
128 and don't need to figure out what the loop breakers are.
129
130 For newtype *families* though, we will always have a coercion, so they
131 are always loop breakers!  So you can easily adjust the current
132 algorithm by simply treating all newtype families as loop breakers (and
133 indeed type families).  I think.
134
135 \begin{code}
136 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
137                    -> TcM (TcGblEnv,         -- Input env extended by types and classes 
138                                              -- and their implicit Ids,DataCons
139                            HsValBinds Name)  -- Renamed bindings for record selectors
140 -- Fails if there are any errors
141
142 tcTyAndClassDecls boot_details allDecls
143   = checkNoErrs $       -- The code recovers internally, but if anything gave rise to
144                         -- an error we'd better stop now, to avoid a cascade
145     do  {       -- Omit instances of type families; they are handled together
146                 -- with the *heads* of class instances
147         ; let decls = filter (not . isFamInstDecl . unLoc) allDecls
148
149                 -- First check for cyclic type synonysm or classes
150                 -- See notes with checkCycleErrs
151         ; checkCycleErrs decls
152         ; mod <- getModule
153         ; traceTc (text "tcTyAndCl" <+> ppr mod)
154         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(_rec_syn_tycons, rec_alg_tyclss) ->
155           do    { let { -- Seperate ordinary synonyms from all other type and
156                         -- class declarations and add all associated type
157                         -- declarations from type classes.  The latter is
158                         -- required so that the temporary environment for the
159                         -- knot includes all associated family declarations.
160                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
161                                                    decls
162                       ; alg_at_decls           = concatMap addATs alg_decls
163                       }
164                         -- Extend the global env with the knot-tied results
165                         -- for data types and classes
166                         -- 
167                         -- We must populate the environment with the loop-tied
168                         -- T's right away, because the kind checker may "fault
169                         -- in" some type  constructors that recursively
170                         -- mention T
171                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
172                 ; tcExtendRecEnv gbl_things $ do
173
174                         -- Kind-check the declarations
175                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
176
177                 ; let { -- Calculate rec-flag
178                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
179                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
180
181                         -- Type-check the type synonyms, and extend the envt
182                 ; syn_tycons <- tcSynDecls kc_syn_decls
183                 ; tcExtendGlobalEnv syn_tycons $ do
184
185                         -- Type-check the data types and classes
186                 { alg_tyclss <- mapM tc_decl kc_alg_decls
187                 ; return (syn_tycons, concat alg_tyclss)
188             }}})
189         -- Finished with knot-tying now
190         -- Extend the environment with the finished things
191         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
192
193         -- Perform the validity check
194         { traceTc (text "ready for validity check")
195         ; mapM_ (addLocM checkValidTyCl) decls
196         ; traceTc (text "done")
197    
198         -- Add the implicit things;
199         -- we want them in the environment because 
200         -- they may be mentioned in interface files
201         -- NB: All associated types and their implicit things will be added a
202         --     second time here.  This doesn't matter as the definitions are
203         --     the same.
204         ; let { implicit_things = concatMap implicitTyThings alg_tyclss
205               ; aux_binds       = mkAuxBinds alg_tyclss }
206         ; traceTc ((text "Adding" <+> ppr alg_tyclss) 
207                    $$ (text "and" <+> ppr implicit_things))
208         ; env <- tcExtendGlobalEnv implicit_things getGblEnv
209         ; return (env, aux_binds) }
210     }
211   where
212     -- Pull associated types out of class declarations, to tie them into the
213     -- knot above.  
214     -- NB: We put them in the same place in the list as `tcTyClDecl' will
215     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
216     --     the two argument lists of `mkGlobalThings' don't match up.
217     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
218     addATs decl                                  = [decl]
219
220 mkGlobalThings :: [LTyClDecl Name]      -- The decls
221                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
222                -> [(Name,TyThing)]
223 -- Driven by the Decls, and treating the TyThings lazily
224 -- make a TypeEnv for the new things
225 mkGlobalThings decls things
226   = map mk_thing (decls `zipLazy` things)
227   where
228     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
229          = (name, AClass cl)
230     mk_thing (L _ decl, ~(ATyCon tc))
231          = (tcdName decl, ATyCon tc)
232 \end{code}
233
234
235 %************************************************************************
236 %*                                                                      *
237                Type checking family instances
238 %*                                                                      *
239 %************************************************************************
240
241 Family instances are somewhat of a hybrid.  They are processed together with
242 class instance heads, but can contain data constructors and hence they share a
243 lot of kinding and type checking code with ordinary algebraic data types (and
244 GADTs).
245
246 \begin{code}
247 tcFamInstDecl :: LTyClDecl Name -> TcM TyThing
248 tcFamInstDecl (L loc decl)
249   =     -- Prime error recovery, set source location
250     setSrcSpan loc                              $
251     tcAddDeclCtxt decl                          $
252     do { -- type families require -XTypeFamilies and can't be in an
253          -- hs-boot file
254        ; type_families <- doptM Opt_TypeFamilies
255        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
256        ; checkTc type_families $ badFamInstDecl (tcdLName decl)
257        ; checkTc (not is_boot) $ badBootFamInstDeclErr
258
259          -- Perform kind and type checking
260        ; tc <- tcFamInstDecl1 decl
261        ; checkValidTyCon tc     -- Remember to check validity;
262                                 -- no recursion to worry about here
263        ; return (ATyCon tc) }
264
265 tcFamInstDecl1 :: TyClDecl Name -> TcM TyCon
266
267   -- "type instance"
268 tcFamInstDecl1 (decl@TySynonym {tcdLName = L loc tc_name})
269   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
270     do { -- check that the family declaration is for a synonym
271          checkTc (isOpenTyCon family) (notFamily family)
272        ; checkTc (isSynTyCon family) (wrongKindOfFamily family)
273
274        ; -- (1) kind check the right-hand side of the type equation
275        ; k_rhs <- kcCheckLHsType (tcdSynRhs decl) (EK resKind EkUnk)
276                   -- ToDo: the ExpKind could be better
277
278          -- we need the exact same number of type parameters as the family
279          -- declaration 
280        ; let famArity = tyConArity family
281        ; checkTc (length k_typats == famArity) $ 
282            wrongNumberOfParmsErr famArity
283
284          -- (2) type check type equation
285        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
286        ; t_typats <- mapM tcHsKindedType k_typats
287        ; t_rhs    <- tcHsKindedType k_rhs
288
289          -- (3) check the well-formedness of the instance
290        ; checkValidTypeInst t_typats t_rhs
291
292          -- (4) construct representation tycon
293        ; rep_tc_name <- newFamInstTyConName tc_name t_typats loc
294        ; buildSynTyCon rep_tc_name t_tvs (SynonymTyCon t_rhs) 
295                        (typeKind t_rhs) (Just (family, t_typats))
296        }}
297
298   -- "newtype instance" and "data instance"
299 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
300                              tcdCons = cons})
301   = kcIdxTyPats decl $ \k_tvs k_typats resKind fam_tycon ->
302     do { -- check that the family declaration is for the right kind
303          checkTc (isOpenTyCon fam_tycon) (notFamily fam_tycon)
304        ; checkTc (isAlgTyCon fam_tycon) (wrongKindOfFamily fam_tycon)
305
306        ; -- (1) kind check the data declaration as usual
307        ; k_decl <- kcDataDecl decl k_tvs
308        ; let k_ctxt = tcdCtxt k_decl
309              k_cons = tcdCons k_decl
310
311          -- result kind must be '*' (otherwise, we have too few patterns)
312        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr (tyConArity fam_tycon)
313
314          -- (2) type check indexed data type declaration
315        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
316        ; unbox_strict <- doptM Opt_UnboxStrictFields
317
318          -- kind check the type indexes and the context
319        ; t_typats     <- mapM tcHsKindedType k_typats
320        ; stupid_theta <- tcHsKindedContext k_ctxt
321
322          -- (3) Check that
323          --     (a) left-hand side contains no type family applications
324          --         (vanilla synonyms are fine, though, and we checked for
325          --         foralls earlier)
326        ; mapM_ checkTyFamFreeness t_typats
327
328          -- Check that we don't use GADT syntax in H98 world
329        ; gadt_ok <- doptM Opt_GADTs
330        ; checkTc (gadt_ok || consUseH98Syntax cons) (badGadtDecl tc_name)
331
332          --     (b) a newtype has exactly one constructor
333        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
334                  newtypeConError tc_name (length k_cons)
335
336          -- (4) construct representation tycon
337        ; rep_tc_name <- newFamInstTyConName tc_name t_typats loc
338        ; let ex_ok = True       -- Existentials ok for type families!
339        ; fixM (\ rep_tycon -> do 
340              { let orig_res_ty = mkTyConApp fam_tycon t_typats
341              ; data_cons <- tcConDecls unbox_strict ex_ok rep_tycon
342                                        (t_tvs, orig_res_ty) k_cons
343              ; tc_rhs <-
344                  case new_or_data of
345                    DataType -> return (mkDataTyConRhs data_cons)
346                    NewType  -> ASSERT( not (null data_cons) )
347                                mkNewTyConRhs rep_tc_name rep_tycon (head data_cons)
348              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
349                              False h98_syntax (Just (fam_tycon, t_typats))
350                  -- We always assume that indexed types are recursive.  Why?
351                  -- (1) Due to their open nature, we can never be sure that a
352                  -- further instance might not introduce a new recursive
353                  -- dependency.  (2) They are always valid loop breakers as
354                  -- they involve a coercion.
355              })
356        }}
357        where
358          h98_syntax = case cons of      -- All constructors have same shape
359                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
360                         _ -> True
361
362 tcFamInstDecl1 d = pprPanic "tcFamInstDecl1" (ppr d)
363
364 -- Kind checking of indexed types
365 -- -
366
367 -- Kind check type patterns and kind annotate the embedded type variables.
368 --
369 -- * Here we check that a type instance matches its kind signature, but we do
370 --   not check whether there is a pattern for each type index; the latter
371 --   check is only required for type synonym instances.
372
373 kcIdxTyPats :: TyClDecl Name
374             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
375                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
376             -> TcM a
377 kcIdxTyPats decl thing_inside
378   = kcHsTyVars (tcdTyVars decl) $ \tvs -> 
379     do { let tc_name = tcdLName decl
380        ; fam_tycon <- tcLookupLocatedTyCon tc_name
381        ; let { (kinds, resKind) = splitKindFunTys (tyConKind fam_tycon)
382              ; hs_typats        = fromJust $ tcdTyPats decl }
383
384          -- we may not have more parameters than the kind indicates
385        ; checkTc (length kinds >= length hs_typats) $
386            tooManyParmsErr (tcdLName decl)
387
388          -- type functions can have a higher-kinded result
389        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
390        ; typats <- zipWithM kcCheckLHsType hs_typats 
391                             [ EK kind (EkArg (ppr tc_name) n) 
392                             | (kind,n) <- kinds `zip` [1..]]
393        ; thing_inside tvs typats resultKind fam_tycon
394        }
395 \end{code}
396
397
398 %************************************************************************
399 %*                                                                      *
400                 Kind checking
401 %*                                                                      *
402 %************************************************************************
403
404 We need to kind check all types in the mutually recursive group
405 before we know the kind of the type variables.  For example:
406
407 class C a where
408    op :: D b => a -> b -> b
409
410 class D c where
411    bop :: (Monad c) => ...
412
413 Here, the kind of the locally-polymorphic type variable "b"
414 depends on *all the uses of class D*.  For example, the use of
415 Monad c in bop's type signature means that D must have kind Type->Type.
416
417 However type synonyms work differently.  They can have kinds which don't
418 just involve (->) and *:
419         type R = Int#           -- Kind #
420         type S a = Array# a     -- Kind * -> #
421         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
422 So we must infer their kinds from their right-hand sides *first* and then
423 use them, whereas for the mutually recursive data types D we bring into
424 scope kind bindings D -> k, where k is a kind variable, and do inference.
425
426 Type families
427 ~~~~~~~~~~~~~
428 This treatment of type synonyms only applies to Haskell 98-style synonyms.
429 General type functions can be recursive, and hence, appear in `alg_decls'.
430
431 The kind of a type family is solely determinded by its kind signature;
432 hence, only kind signatures participate in the construction of the initial
433 kind environment (as constructed by `getInitialKind').  In fact, we ignore
434 instances of families altogether in the following.  However, we need to
435 include the kinds of associated families into the construction of the
436 initial kind environment.  (This is handled by `allDecls').
437
438 \begin{code}
439 kcTyClDecls :: [LTyClDecl Name] -> [Located (TyClDecl Name)]
440             -> TcM ([LTyClDecl Name], [Located (TyClDecl Name)])
441 kcTyClDecls syn_decls alg_decls
442   = do  {       -- First extend the kind env with each data type, class, and
443                 -- indexed type, mapping them to a type variable
444           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
445         ; alg_kinds <- mapM getInitialKind initialKindDecls
446         ; tcExtendKindEnv alg_kinds $ do
447
448                 -- Now kind-check the type synonyms, in dependency order
449                 -- We do these differently to data type and classes,
450                 -- because a type synonym can be an unboxed type
451                 --      type Foo = Int#
452                 -- and a kind variable can't unify with UnboxedTypeKind
453                 -- So we infer their kinds in dependency order
454         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
455         ; tcExtendKindEnv syn_kinds $  do
456
457                 -- Now kind-check the data type, class, and kind signatures,
458                 -- returning kind-annotated decls; we don't kind-check
459                 -- instances of indexed types yet, but leave this to
460                 -- `tcInstDecls1'
461         { kc_alg_decls <- mapM (wrapLocM kcTyClDecl)
462                             (filter (not . isFamInstDecl . unLoc) alg_decls)
463
464         ; return (kc_syn_decls, kc_alg_decls) }}}
465   where
466     -- get all declarations relevant for determining the initial kind
467     -- environment
468     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at 
469                                                       | L _ at <- ats
470                                                       , isFamilyDecl at]
471     allDecls decl | isFamInstDecl decl = []
472                   | otherwise          = [decl]
473
474 ------------------------------------------------------------------------
475 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
476 -- Only for data type, class, and indexed type declarations
477 -- Get as much info as possible from the data, class, or indexed type decl,
478 -- so as to maximise usefulness of error messages
479 getInitialKind decl
480   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
481         ; res_kind  <- mk_res_kind decl
482         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
483   where
484     mk_arg_kind (UserTyVar _)        = newKindVar
485     mk_arg_kind (KindedTyVar _ kind) = return kind
486
487     mk_res_kind (TyFamily { tcdKind    = Just kind }) = return kind
488     mk_res_kind (TyData   { tcdKindSig = Just kind }) = return kind
489         -- On GADT-style declarations we allow a kind signature
490         --      data T :: *->* where { ... }
491     mk_res_kind _ = return liftedTypeKind
492
493
494 ----------------
495 kcSynDecls :: [SCC (LTyClDecl Name)] 
496            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
497                    [(Name,TcKind)])     -- Kind bindings
498 kcSynDecls []
499   = return ([], [])
500 kcSynDecls (group : groups)
501   = do  { (decl,  nk)  <- kcSynDecl group
502         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
503         ; return (decl:decls, nk:nks) }
504                         
505 ----------------
506 kcSynDecl :: SCC (LTyClDecl Name) 
507            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
508                    (Name,TcKind))       -- Kind bindings
509 kcSynDecl (AcyclicSCC (L loc decl))
510   = tcAddDeclCtxt decl  $
511     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
512     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl)) 
513                         <+> brackets (ppr k_tvs))
514        ; (k_rhs, rhs_kind) <- kcLHsType (tcdSynRhs decl)
515        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
516        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
517        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
518                  (unLoc (tcdLName decl), tc_kind)) })
519
520 kcSynDecl (CyclicSCC decls)
521   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
522                                         -- of out-of-scope tycons
523
524 kindedTyVarKind :: LHsTyVarBndr Name -> Kind
525 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
526 kindedTyVarKind x = pprPanic "kindedTyVarKind" (ppr x)
527
528 ------------------------------------------------------------------------
529 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
530         -- Not used for type synonyms (see kcSynDecl)
531
532 kcTyClDecl decl@(TyData {})
533   = ASSERT( not . isFamInstDecl $ decl )   -- must not be a family instance
534     kcTyClDeclBody decl $
535       kcDataDecl decl
536
537 kcTyClDecl decl@(TyFamily {})
538   = kcFamilyDecl [] decl      -- the empty list signals a toplevel decl      
539
540 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
541   = kcTyClDeclBody decl $ \ tvs' ->
542     do  { ctxt' <- kcHsContext ctxt     
543         ; ats'  <- mapM (wrapLocM (kcFamilyDecl tvs')) ats
544         ; sigs' <- mapM (wrapLocM kc_sig) sigs
545         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
546                         tcdATs = ats'}) }
547   where
548     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
549                                    ; return (TypeSig nm op_ty') }
550     kc_sig other_sig          = return other_sig
551
552 kcTyClDecl decl@(ForeignType {})
553   = return decl
554
555 kcTyClDecl (TySynonym {}) = panic "kcTyClDecl TySynonym"
556
557 kcTyClDeclBody :: TyClDecl Name
558                -> ([LHsTyVarBndr Name] -> TcM a)
559                -> TcM a
560 -- getInitialKind has made a suitably-shaped kind for the type or class
561 -- Unpack it, and attribute those kinds to the type variables
562 -- Extend the env with bindings for the tyvars, taken from
563 -- the kind of the tycon/class.  Give it to the thing inside, and 
564 -- check the result kind matches
565 kcTyClDeclBody decl thing_inside
566   = tcAddDeclCtxt decl          $
567     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
568         ; let tc_kind    = case tc_ty_thing of
569                            AThing k -> k
570                            _ -> pprPanic "kcTyClDeclBody" (ppr tc_ty_thing)
571               (kinds, _) = splitKindFunTys tc_kind
572               hs_tvs     = tcdTyVars decl
573               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
574                            [ L loc (KindedTyVar (hsTyVarName tv) k)
575                            | (L loc tv, k) <- zip hs_tvs kinds]
576         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
577
578 -- Kind check a data declaration, assuming that we already extended the
579 -- kind environment with the type variables of the left-hand side (these
580 -- kinded type variables are also passed as the second parameter).
581 --
582 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
583 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
584            tvs
585   = do  { ctxt' <- kcHsContext ctxt     
586         ; cons' <- mapM (wrapLocM kc_con_decl) cons
587         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
588   where
589     -- doc comments are typechecked to Nothing here
590     kc_con_decl con_decl@(ConDecl { con_name = name, con_qvars = ex_tvs
591                                   , con_cxt = ex_ctxt, con_details = details, con_res = res })
592       = addErrCtxt (dataConCtxt name)   $ 
593         kcHsTyVars ex_tvs $ \ex_tvs' -> do
594         do { ex_ctxt' <- kcHsContext ex_ctxt
595            ; details' <- kc_con_details details 
596            ; res'     <- case res of
597                 ResTyH98 -> return ResTyH98
598                 ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
599            ; return (con_decl { con_qvars = ex_tvs', con_cxt = ex_ctxt'
600                               , con_details = details', con_res = res' }) }
601
602     kc_con_details (PrefixCon btys) 
603         = do { btys' <- mapM kc_larg_ty btys 
604              ; return (PrefixCon btys') }
605     kc_con_details (InfixCon bty1 bty2) 
606         = do { bty1' <- kc_larg_ty bty1
607              ; bty2' <- kc_larg_ty bty2
608              ; return (InfixCon bty1' bty2') }
609     kc_con_details (RecCon fields) 
610         = do { fields' <- mapM kc_field fields
611              ; return (RecCon fields') }
612
613     kc_field (ConDeclField fld bty d) = do { bty' <- kc_larg_ty bty
614                                            ; return (ConDeclField fld bty' d) }
615
616     kc_larg_ty bty = case new_or_data of
617                         DataType -> kcHsSigType bty
618                         NewType  -> kcHsLiftedSigType bty
619         -- Can't allow an unlifted type for newtypes, because we're effectively
620         -- going to remove the constructor while coercing it to a lifted type.
621         -- And newtypes can't be bang'd
622 kcDataDecl d _ = pprPanic "kcDataDecl" (ppr d)
623
624 -- Kind check a family declaration or type family default declaration.
625 --
626 kcFamilyDecl :: [LHsTyVarBndr Name]  -- tyvars of enclosing class decl if any
627              -> TyClDecl Name -> TcM (TyClDecl Name)
628 kcFamilyDecl classTvs decl@(TyFamily {tcdKind = kind})
629   = kcTyClDeclBody decl $ \tvs' ->
630     do { mapM_ unifyClassParmKinds tvs'
631        ; return (decl {tcdTyVars = tvs', 
632                        tcdKind = kind `mplus` Just liftedTypeKind})
633                        -- default result kind is '*'
634        }
635   where
636     unifyClassParmKinds (L _ (KindedTyVar n k))
637       | Just classParmKind <- lookup n classTyKinds = unifyKind k classParmKind
638       | otherwise                                   = return ()
639     unifyClassParmKinds x = pprPanic "kcFamilyDecl/unifyClassParmKinds" (ppr x)
640     classTyKinds = [(n, k) | L _ (KindedTyVar n k) <- classTvs]
641 kcFamilyDecl _ (TySynonym {})              -- type family defaults
642   = panic "TcTyClsDecls.kcFamilyDecl: not implemented yet"
643 kcFamilyDecl _ d = pprPanic "kcFamilyDecl" (ppr d)
644 \end{code}
645
646
647 %************************************************************************
648 %*                                                                      *
649 \subsection{Type checking}
650 %*                                                                      *
651 %************************************************************************
652
653 \begin{code}
654 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
655 tcSynDecls [] = return []
656 tcSynDecls (decl : decls) 
657   = do { syn_tc <- addLocM tcSynDecl decl
658        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
659        ; return (syn_tc : syn_tcs) }
660
661   -- "type"
662 tcSynDecl :: TyClDecl Name -> TcM TyThing
663 tcSynDecl
664   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
665   = tcTyVarBndrs tvs            $ \ tvs' -> do 
666     { traceTc (text "tcd1" <+> ppr tc_name) 
667     ; rhs_ty' <- tcHsKindedType rhs_ty
668     ; tycon <- buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty') 
669                              (typeKind rhs_ty') Nothing
670     ; return (ATyCon tycon) 
671     }
672 tcSynDecl d = pprPanic "tcSynDecl" (ppr d)
673
674 --------------------
675 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
676
677 tcTyClDecl calc_isrec decl
678   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
679
680   -- "type family" declarations
681 tcTyClDecl1 :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
682 tcTyClDecl1 _calc_isrec 
683   (TyFamily {tcdFlavour = TypeFamily, 
684              tcdLName = L _ tc_name, tcdTyVars = tvs,
685              tcdKind = Just kind}) -- NB: kind at latest added during kind checking
686   = tcTyVarBndrs tvs  $ \ tvs' -> do 
687   { traceTc (text "type family: " <+> ppr tc_name) 
688
689         -- Check that we don't use families without -XTypeFamilies
690   ; idx_tys <- doptM Opt_TypeFamilies
691   ; checkTc idx_tys $ badFamInstDecl tc_name
692
693   ; tycon <- buildSynTyCon tc_name tvs' (OpenSynTyCon kind Nothing) kind Nothing
694   ; return [ATyCon tycon]
695   }
696
697   -- "data family" declaration
698 tcTyClDecl1 _calc_isrec 
699   (TyFamily {tcdFlavour = DataFamily, 
700              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = mb_kind})
701   = tcTyVarBndrs tvs  $ \ tvs' -> do 
702   { traceTc (text "data family: " <+> ppr tc_name) 
703   ; extra_tvs <- tcDataKindSig mb_kind
704   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
705
706
707         -- Check that we don't use families without -XTypeFamilies
708   ; idx_tys <- doptM Opt_TypeFamilies
709   ; checkTc idx_tys $ badFamInstDecl tc_name
710
711   ; tycon <- buildAlgTyCon tc_name final_tvs [] 
712                mkOpenDataTyConRhs Recursive False True Nothing
713   ; return [ATyCon tycon]
714   }
715
716   -- "newtype" and "data"
717   -- NB: not used for newtype/data instances (whether associated or not)
718 tcTyClDecl1 calc_isrec
719   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
720            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
721   = tcTyVarBndrs tvs    $ \ tvs' -> do 
722   { extra_tvs <- tcDataKindSig mb_ksig
723   ; let final_tvs = tvs' ++ extra_tvs
724   ; stupid_theta <- tcHsKindedContext ctxt
725   ; want_generic <- doptM Opt_Generics
726   ; unbox_strict <- doptM Opt_UnboxStrictFields
727   ; empty_data_decls <- doptM Opt_EmptyDataDecls
728   ; kind_signatures <- doptM Opt_KindSignatures
729   ; existential_ok <- doptM Opt_ExistentialQuantification
730   ; gadt_ok      <- doptM Opt_GADTs
731   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
732   ; let ex_ok = existential_ok || gadt_ok       -- Data cons can have existential context
733
734         -- Check that we don't use GADT syntax in H98 world
735   ; checkTc (gadt_ok || h98_syntax) (badGadtDecl tc_name)
736
737         -- Check that we don't use kind signatures without Glasgow extensions
738   ; checkTc (kind_signatures || isNothing mb_ksig) (badSigTyDecl tc_name)
739
740         -- Check that the stupid theta is empty for a GADT-style declaration
741   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
742
743         -- Check that a newtype has exactly one constructor
744         -- Do this before checking for empty data decls, so that
745         -- we don't suggest -XEmptyDataDecls for newtypes
746   ; checkTc (new_or_data == DataType || isSingleton cons) 
747             (newtypeConError tc_name (length cons))
748
749         -- Check that there's at least one condecl,
750         -- or else we're reading an hs-boot file, or -XEmptyDataDecls
751   ; checkTc (not (null cons) || empty_data_decls || is_boot)
752             (emptyConDeclsErr tc_name)
753     
754   ; tycon <- fixM (\ tycon -> do 
755         { let res_ty = mkTyConApp tycon (mkTyVarTys final_tvs)
756         ; data_cons <- tcConDecls unbox_strict ex_ok 
757                                   tycon (final_tvs, res_ty) cons
758         ; tc_rhs <-
759             if null cons && is_boot     -- In a hs-boot file, empty cons means
760             then return AbstractTyCon   -- "don't know"; hence Abstract
761             else case new_or_data of
762                    DataType -> return (mkDataTyConRhs data_cons)
763                    NewType  -> ASSERT( not (null data_cons) )
764                                mkNewTyConRhs tc_name tycon (head data_cons)
765         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
766             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
767         })
768   ; return [ATyCon tycon]
769   }
770   where
771     is_rec   = calc_isrec tc_name
772     h98_syntax = consUseH98Syntax cons
773
774 tcTyClDecl1 calc_isrec 
775   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs, 
776               tcdCtxt = ctxt, tcdMeths = meths,
777               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
778   = tcTyVarBndrs tvs            $ \ tvs' -> do 
779   { ctxt' <- tcHsKindedContext ctxt
780   ; fds' <- mapM (addLocM tc_fundep) fundeps
781   ; atss <- mapM (addLocM (tcTyClDecl1 (const Recursive))) ats
782             -- NB: 'ats' only contains "type family" and "data family"
783             --     declarations as well as type family defaults
784   ; let ats' = map (setAssocFamilyPermutation tvs') (concat atss)
785   ; sig_stuff <- tcClassSigs class_name sigs meths
786   ; clas <- fixM (\ clas ->
787                 let     -- This little knot is just so we can get
788                         -- hold of the name of the class TyCon, which we
789                         -- need to look up its recursiveness
790                     tycon_name = tyConName (classTyCon clas)
791                     tc_isrec = calc_isrec tycon_name
792                 in
793                 buildClass False {- Must include unfoldings for selectors -}
794                            class_name tvs' ctxt' fds' ats'
795                            sig_stuff tc_isrec)
796   ; return (AClass clas : ats')
797       -- NB: Order is important due to the call to `mkGlobalThings' when
798       --     tying the the type and class declaration type checking knot.
799   }
800   where
801     tc_fundep (tvs1, tvs2) = do { tvs1' <- mapM tcLookupTyVar tvs1 ;
802                                 ; tvs2' <- mapM tcLookupTyVar tvs2 ;
803                                 ; return (tvs1', tvs2') }
804
805 tcTyClDecl1 _
806   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
807   = return [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
808
809 tcTyClDecl1 _ d = pprPanic "tcTyClDecl1" (ppr d)
810
811 -----------------------------------
812 tcConDecls :: Bool -> Bool -> TyCon -> ([TyVar], Type)
813            -> [LConDecl Name] -> TcM [DataCon]
814 tcConDecls unbox ex_ok rep_tycon res_tmpl cons
815   = mapM (addLocM (tcConDecl unbox ex_ok rep_tycon res_tmpl)) cons
816
817 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
818           -> Bool               -- True <=> -XExistentialQuantificaton or -XGADTs
819           -> TyCon              -- Representation tycon
820           -> ([TyVar], Type)    -- Return type template (with its template tyvars)
821           -> ConDecl Name 
822           -> TcM DataCon
823
824 tcConDecl unbox_strict existential_ok rep_tycon res_tmpl        -- Data types
825           (ConDecl {con_name =name, con_qvars = tvs, con_cxt = ctxt
826                    , con_details = details, con_res = res_ty })
827   = addErrCtxt (dataConCtxt name)       $ 
828     tcTyVarBndrs tvs                    $ \ tvs' -> do 
829     { ctxt' <- tcHsKindedContext ctxt
830     ; checkTc (existential_ok || (null tvs && null (unLoc ctxt)))
831               (badExistential name)
832     ; (univ_tvs, ex_tvs, eq_preds, res_ty') <- tcResultType res_tmpl tvs' res_ty
833     ; let 
834         tc_datacon is_infix field_lbls btys
835           = do { (arg_tys, stricts) <- mapAndUnzipM (tcConArg unbox_strict) btys
836                ; buildDataCon (unLoc name) is_infix
837                     stricts field_lbls
838                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
839                     res_ty' rep_tycon }
840                 -- NB:  we put data_tc, the type constructor gotten from the
841                 --      constructor type signature into the data constructor;
842                 --      that way checkValidDataCon can complain if it's wrong.
843
844     ; case details of
845         PrefixCon btys     -> tc_datacon False [] btys
846         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
847         RecCon fields      -> tc_datacon False field_names btys
848                            where
849                               field_names = map (unLoc . cd_fld_name) fields
850                               btys        = map cd_fld_type fields
851     }
852
853 -- Example
854 --   data instance T (b,c) where 
855 --      TI :: forall e. e -> T (e,e)
856 --
857 -- The representation tycon looks like this:
858 --   data :R7T b c where 
859 --      TI :: forall b1 c1. (b1 ~ c1) => b1 -> :R7T b1 c1
860 -- In this case orig_res_ty = T (e,e)
861
862 tcResultType :: ([TyVar], Type) -- Template for result type; e.g.
863                                 -- data instance T [a] b c = ...  
864                                 --      gives template ([a,b,c], T [a] b c)
865              -> [TyVar]         -- where MkT :: forall x y z. ...
866              -> ResType Name
867              -> TcM ([TyVar],           -- Universal
868                      [TyVar],           -- Existential (distinct OccNames from univs)
869                      [(TyVar,Type)],    -- Equality predicates
870                      Type)              -- Typechecked return type
871         -- We don't check that the TyCon given in the ResTy is
872         -- the same as the parent tycon, becuase we are in the middle
873         -- of a recursive knot; so it's postponed until checkValidDataCon
874
875 tcResultType (tmpl_tvs, res_ty) dc_tvs ResTyH98
876   = return (tmpl_tvs, dc_tvs, [], res_ty)
877         -- In H98 syntax the dc_tvs are the existential ones
878         --      data T a b c = forall d e. MkT ...
879         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
880
881 tcResultType (tmpl_tvs, res_tmpl) dc_tvs (ResTyGADT res_ty)
882         -- E.g.  data T [a] b c where
883         --         MkT :: forall x y z. T [(x,y)] z z
884         -- Then we generate
885         --      Univ tyvars     Eq-spec
886         --          a              a~(x,y)
887         --          b              b~z
888         --          z              
889         -- Existentials are the leftover type vars: [x,y]
890         -- So we return ([a,b,z], [x,y], [a~(x,y),b~z], T [(x,y)] z z)
891   = do  { res_ty' <- tcHsKindedType res_ty
892         ; let Just subst = tcMatchTy (mkVarSet tmpl_tvs) res_tmpl res_ty'
893
894                 -- /Lazily/ figure out the univ_tvs etc
895                 -- Each univ_tv is either a dc_tv or a tmpl_tv
896               (univ_tvs, eq_spec) = foldr choose ([], []) tidy_tmpl_tvs
897               choose tmpl (univs, eqs)
898                 | Just ty <- lookupTyVar subst tmpl 
899                 = case tcGetTyVar_maybe ty of
900                     Just tv | not (tv `elem` univs)
901                             -> (tv:univs,   eqs)
902                     _other  -> (tmpl:univs, (tmpl,ty):eqs)
903                 | otherwise = pprPanic "tcResultType" (ppr res_ty)
904               ex_tvs = dc_tvs `minusList` univ_tvs
905
906         ; return (univ_tvs, ex_tvs, eq_spec, res_ty') }
907   where
908         -- NB: tmpl_tvs and dc_tvs are distinct, but
909         -- we want them to be *visibly* distinct, both for
910         -- interface files and general confusion.  So rename
911         -- the tc_tvs, since they are not used yet (no 
912         -- consequential renaming needed)
913     (_, tidy_tmpl_tvs) = mapAccumL tidy_one init_occ_env tmpl_tvs
914     init_occ_env       = initTidyOccEnv (map getOccName dc_tvs)
915     tidy_one env tv    = (env', setTyVarName tv (tidyNameOcc name occ'))
916               where
917                  name = tyVarName tv
918                  (env', occ') = tidyOccName env (getOccName name) 
919
920 consUseH98Syntax :: [LConDecl a] -> Bool
921 consUseH98Syntax (L _ (ConDecl { con_res = ResTyGADT _ }) : _) = False
922 consUseH98Syntax _                                             = True
923                  -- All constructors have same shape
924
925 -------------------
926 tcConArg :: Bool                -- True <=> -funbox-strict_fields
927            -> LHsType Name
928            -> TcM (TcType, StrictnessMark)
929 tcConArg unbox_strict bty
930   = do  { arg_ty <- tcHsBangType bty
931         ; let bang = getBangStrictness bty
932         ; return (arg_ty, chooseBoxingStrategy unbox_strict arg_ty bang) }
933
934 -- We attempt to unbox/unpack a strict field when either:
935 --   (i)  The field is marked '!!', or
936 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
937 --
938 -- We have turned off unboxing of newtypes because coercions make unboxing 
939 -- and reboxing more complicated
940 chooseBoxingStrategy :: Bool -> TcType -> HsBang -> StrictnessMark
941 chooseBoxingStrategy unbox_strict_fields arg_ty bang
942   = case bang of
943         HsNoBang                                    -> NotMarkedStrict
944         HsStrict | unbox_strict_fields 
945                    && can_unbox arg_ty              -> MarkedUnboxed
946         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
947         _                                           -> MarkedStrict
948   where
949     -- we can unbox if the type is a chain of newtypes with a product tycon
950     -- at the end
951     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
952                    Nothing                      -> False
953                    Just (arg_tycon, tycon_args) -> 
954                        not (isRecursiveTyCon arg_tycon) &&      -- Note [Recusive unboxing]
955                        isProductTyCon arg_tycon &&
956                        (if isNewTyCon arg_tycon then 
957                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
958                         else True)
959 \end{code}
960
961 Note [Recursive unboxing]
962 ~~~~~~~~~~~~~~~~~~~~~~~~~
963 Be careful not to try to unbox this!
964         data T = MkT !T Int
965 But it's the *argument* type that matters. This is fine:
966         data S = MkS S !Int
967 because Int is non-recursive.
968
969
970 %************************************************************************
971 %*                                                                      *
972                 Validity checking
973 %*                                                                      *
974 %************************************************************************
975
976 Validity checking is done once the mutually-recursive knot has been
977 tied, so we can look at things freely.
978
979 \begin{code}
980 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
981 checkCycleErrs tyclss
982   | null cls_cycles
983   = return ()
984   | otherwise
985   = do  { mapM_ recClsErr cls_cycles
986         ; failM }       -- Give up now, because later checkValidTyCl
987                         -- will loop if the synonym is recursive
988   where
989     cls_cycles = calcClassCycles tyclss
990
991 checkValidTyCl :: TyClDecl Name -> TcM ()
992 -- We do the validity check over declarations, rather than TyThings
993 -- only so that we can add a nice context with tcAddDeclCtxt
994 checkValidTyCl decl
995   = tcAddDeclCtxt decl $
996     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
997         ; traceTc (text "Validity of" <+> ppr thing)    
998         ; case thing of
999             ATyCon tc -> checkValidTyCon tc
1000             AClass cl -> checkValidClass cl 
1001             _ -> panic "checkValidTyCl"
1002         ; traceTc (text "Done validity of" <+> ppr thing)       
1003         }
1004
1005 -------------------------
1006 -- For data types declared with record syntax, we require
1007 -- that each constructor that has a field 'f' 
1008 --      (a) has the same result type
1009 --      (b) has the same type for 'f'
1010 -- module alpha conversion of the quantified type variables
1011 -- of the constructor.
1012 --
1013 -- Note that we allow existentials to match becuase the
1014 -- fields can never meet. E.g
1015 --      data T where
1016 --        T1 { f1 :: b, f2 :: a, f3 ::Int } :: T
1017 --        T2 { f1 :: c, f2 :: c, f3 ::Int } :: T  
1018 -- Here we do not complain about f1,f2 because they are existential
1019
1020 checkValidTyCon :: TyCon -> TcM ()
1021 checkValidTyCon tc 
1022   | isSynTyCon tc 
1023   = case synTyConRhs tc of
1024       OpenSynTyCon _ _ -> return ()
1025       SynonymTyCon ty  -> checkValidType syn_ctxt ty
1026   | otherwise
1027   = do  -- Check the context on the data decl
1028     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)
1029         
1030         -- Check arg types of data constructors
1031     mapM_ (checkValidDataCon tc) data_cons
1032
1033         -- Check that fields with the same name share a type
1034     mapM_ check_fields groups
1035
1036   where
1037     syn_ctxt  = TySynCtxt name
1038     name      = tyConName tc
1039     data_cons = tyConDataCons tc
1040
1041     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
1042     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
1043     get_fields con = dataConFieldLabels con `zip` repeat con
1044         -- dataConFieldLabels may return the empty list, which is fine
1045
1046     -- See Note [GADT record selectors] in MkId.lhs
1047     -- We must check (a) that the named field has the same 
1048     --                   type in each constructor
1049     --               (b) that those constructors have the same result type
1050     --
1051     -- However, the constructors may have differently named type variable
1052     -- and (worse) we don't know how the correspond to each other.  E.g.
1053     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
1054     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
1055     -- 
1056     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
1057     -- result type against other candidates' types BOTH WAYS ROUND.
1058     -- If they magically agrees, take the substitution and
1059     -- apply them to the latter ones, and see if they match perfectly.
1060     check_fields ((label, con1) : other_fields)
1061         -- These fields all have the same name, but are from
1062         -- different constructors in the data type
1063         = recoverM (return ()) $ mapM_ checkOne other_fields
1064                 -- Check that all the fields in the group have the same type
1065                 -- NB: this check assumes that all the constructors of a given
1066                 -- data type use the same type variables
1067         where
1068         (tvs1, _, _, res1) = dataConSig con1
1069         ts1 = mkVarSet tvs1
1070         fty1 = dataConFieldType con1 label
1071
1072         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
1073             = do { checkFieldCompat label con1 con2 ts1 res1 res2 fty1 fty2
1074                  ; checkFieldCompat label con2 con1 ts2 res2 res1 fty2 fty1 }
1075             where        
1076                 (tvs2, _, _, res2) = dataConSig con2
1077                 ts2 = mkVarSet tvs2
1078                 fty2 = dataConFieldType con2 label
1079     check_fields [] = panic "checkValidTyCon/check_fields []"
1080
1081 checkFieldCompat :: Name -> DataCon -> DataCon -> TyVarSet
1082                  -> Type -> Type -> Type -> Type -> TcM ()
1083 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1084   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1085         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1086   where
1087     mb_subst1 = tcMatchTy tvs1 res1 res2
1088     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1089
1090 -------------------------------
1091 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1092 checkValidDataCon tc con
1093   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1094     addErrCtxt (dataConCtxt con)                $ 
1095     do  { traceTc (ptext (sLit "Validity of data con") <+> ppr con)
1096         ; let tc_tvs = tyConTyVars tc
1097               res_ty_tmpl = mkFamilyTyConApp tc (mkTyVarTys tc_tvs)
1098               actual_res_ty = dataConOrigResTy con
1099         ; checkTc (isJust (tcMatchTy (mkVarSet tc_tvs)
1100                                 res_ty_tmpl
1101                                 actual_res_ty))
1102                   (badDataConTyCon con res_ty_tmpl actual_res_ty)
1103         ; checkValidMonoType (dataConOrigResTy con)
1104                 -- Disallow MkT :: T (forall a. a->a)
1105                 -- Reason: it's really the argument of an equality constraint
1106         ; checkValidType ctxt (dataConUserType con)
1107         ; when (isNewTyCon tc) (checkNewDataCon con)
1108     }
1109   where
1110     ctxt = ConArgCtxt (dataConName con) 
1111
1112 -------------------------------
1113 checkNewDataCon :: DataCon -> TcM ()
1114 -- Checks for the data constructor of a newtype
1115 checkNewDataCon con
1116   = do  { checkTc (isSingleton arg_tys) (newtypeFieldErr con (length arg_tys))
1117                 -- One argument
1118         ; checkTc (null eq_spec) (newtypePredError con)
1119                 -- Return type is (T a b c)
1120         ; checkTc (null ex_tvs && null eq_theta && null dict_theta) (newtypeExError con)
1121                 -- No existentials
1122         ; checkTc (not (any isMarkedStrict (dataConStrictMarks con))) 
1123                   (newtypeStrictError con)
1124                 -- No strictness
1125     }
1126   where
1127     (_univ_tvs, ex_tvs, eq_spec, eq_theta, dict_theta, arg_tys, _res_ty) = dataConFullSig con
1128
1129 -------------------------------
1130 checkValidClass :: Class -> TcM ()
1131 checkValidClass cls
1132   = do  { constrained_class_methods <- doptM Opt_ConstrainedClassMethods
1133         ; multi_param_type_classes <- doptM Opt_MultiParamTypeClasses
1134         ; fundep_classes <- doptM Opt_FunctionalDependencies
1135
1136         -- Check that the class is unary, unless GlaExs
1137         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1138         ; checkTc (multi_param_type_classes || unary) (classArityErr cls)
1139         ; checkTc (fundep_classes || null fundeps) (classFunDepsErr cls)
1140
1141         -- Check the super-classes
1142         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1143
1144         -- Check the class operations
1145         ; mapM_ (check_op constrained_class_methods) op_stuff
1146
1147         -- Check that if the class has generic methods, then the
1148         -- class has only one parameter.  We can't do generic
1149         -- multi-parameter type classes!
1150         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1151         }
1152   where
1153     (tyvars, fundeps, theta, _, _, op_stuff) = classExtraBigSig cls
1154     unary       = isSingleton tyvars
1155     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1156
1157     check_op constrained_class_methods (sel_id, dm) 
1158       = addErrCtxt (classOpCtxt sel_id tau) $ do
1159         { checkValidTheta SigmaCtxt (tail theta)
1160                 -- The 'tail' removes the initial (C a) from the
1161                 -- class itself, leaving just the method type
1162
1163         ; traceTc (text "class op type" <+> ppr op_ty <+> ppr tau)
1164         ; checkValidType (FunSigCtxt op_name) tau
1165
1166                 -- Check that the type mentions at least one of
1167                 -- the class type variables...or at least one reachable
1168                 -- from one of the class variables.  Example: tc223
1169                 --   class Error e => Game b mv e | b -> mv e where
1170                 --      newBoard :: MonadState b m => m ()
1171                 -- Here, MonadState has a fundep m->b, so newBoard is fine
1172         ; let grown_tyvars = growThetaTyVars theta (mkVarSet tyvars)
1173         ; checkTc (tyVarsOfType tau `intersectsVarSet` grown_tyvars)
1174                   (noClassTyVarErr cls sel_id)
1175
1176                 -- Check that for a generic method, the type of 
1177                 -- the method is sufficiently simple
1178         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1179                   (badGenericMethodType op_name op_ty)
1180         }
1181         where
1182           op_name = idName sel_id
1183           op_ty   = idType sel_id
1184           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1185           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1186           (theta,tau) | constrained_class_methods = (theta1 ++ theta2, tau2)
1187                       | otherwise = (theta1, mkPhiTy (tail theta1) tau1)
1188                 -- Ugh!  The function might have a type like
1189                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1190                 -- With -XConstrainedClassMethods, we want to allow this, even though the inner 
1191                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint 
1192                 -- in the context of a for-all must mention at least one quantified
1193                 -- type variable.  What a mess!
1194 \end{code}
1195
1196
1197 %************************************************************************
1198 %*                                                                      *
1199                 Building record selectors
1200 %*                                                                      *
1201 %************************************************************************
1202
1203 \begin{code}
1204 mkAuxBinds :: [TyThing] -> HsValBinds Name
1205 -- NB We produce *un-typechecked* bindings, rather like 'deriving'
1206 --    This makes life easier, because the later type checking will add
1207 --    all necessary type abstractions and applications
1208 mkAuxBinds ty_things
1209   = ValBindsOut [(NonRecursive, b) | b <- binds] sigs
1210   where
1211     (sigs, binds) = unzip rec_sels
1212     rec_sels = map mkRecSelBind [ (tc,fld) 
1213                                 | ATyCon tc <- ty_things 
1214                                 , fld <- tyConFields tc ]
1215
1216 mkRecSelBind :: (TyCon, FieldLabel) -> (LSig Name, LHsBinds Name)
1217 mkRecSelBind (tycon, sel_name)
1218   = (L loc (IdSig sel_id), unitBag (L loc sel_bind))
1219   where
1220     loc         = getSrcSpan tycon    
1221     sel_id      = Var.mkLocalVar rec_details sel_name sel_ty vanillaIdInfo
1222     rec_details = RecSelId { sel_tycon = tycon, sel_naughty = is_naughty }
1223
1224     -- Find a representative constructor, con1
1225     all_cons     = tyConDataCons tycon 
1226     cons_w_field = [ con | con <- all_cons
1227                    , sel_name `elem` dataConFieldLabels con ] 
1228     con1 = ASSERT( not (null cons_w_field) ) head cons_w_field
1229
1230     -- Selector type; Note [Polymorphic selectors]
1231     field_ty   = dataConFieldType con1 sel_name
1232     data_ty    = dataConOrigResTy con1
1233     data_tvs   = tyVarsOfType data_ty
1234     is_naughty = not (tyVarsOfType field_ty `subVarSet` data_tvs)  
1235     (field_tvs, field_theta, field_tau) = tcSplitSigmaTy field_ty
1236     sel_ty | is_naughty = unitTy  -- See Note [Naughty record selectors]
1237            | otherwise  = mkForAllTys (varSetElems data_tvs ++ field_tvs) $ 
1238                           mkPhiTy (dataConStupidTheta con1) $   -- Urgh!
1239                           mkPhiTy field_theta               $   -- Urgh!
1240                           mkFunTy data_ty field_tau
1241
1242     -- Make the binding: sel (C2 { fld = x }) = x
1243     --                   sel (C7 { fld = x }) = x
1244     --    where cons_w_field = [C2,C7]
1245     sel_bind | is_naughty = mkFunBind sel_lname [mkSimpleMatch [] unit_rhs]
1246              | otherwise  = mkFunBind sel_lname (map mk_match cons_w_field ++ deflt)
1247     mk_match con = mkSimpleMatch [L loc (mk_sel_pat con)] 
1248                                  (L loc (HsVar field_var))
1249     mk_sel_pat con = ConPatIn (L loc (getName con)) (RecCon rec_fields)
1250     rec_fields = HsRecFields { rec_flds = [rec_field], rec_dotdot = Nothing }
1251     rec_field  = HsRecField { hsRecFieldId = sel_lname
1252                             , hsRecFieldArg = nlVarPat field_var
1253                             , hsRecPun = False }
1254     sel_lname = L loc sel_name
1255     field_var = mkInternalName (mkBuiltinUnique 1) (getOccName sel_name) loc
1256
1257     -- Add catch-all default case unless the case is exhaustive
1258     -- We do this explicitly so that we get a nice error message that
1259     -- mentions this particular record selector
1260     deflt | not (any is_unused all_cons) = []
1261           | otherwise = [mkSimpleMatch [nlWildPat] 
1262                             (nlHsApp (nlHsVar (getName rEC_SEL_ERROR_ID))
1263                                      (nlHsLit msg_lit))]
1264
1265         -- Do not add a default case unless there are unmatched
1266         -- constructors.  We must take account of GADTs, else we
1267         -- get overlap warning messages from the pattern-match checker
1268     is_unused con = not (con `elem` cons_w_field 
1269                          || dataConCannotMatch inst_tys con)
1270     inst_tys = tyConAppArgs data_ty
1271
1272     unit_rhs = mkLHsTupleExpr []
1273     msg_lit = HsStringPrim $ mkFastString $ 
1274               occNameString (getOccName sel_name)
1275
1276 ---------------
1277 tyConFields :: TyCon -> [FieldLabel]
1278 tyConFields tc 
1279   | isAlgTyCon tc = nub (concatMap dataConFieldLabels (tyConDataCons tc))
1280   | otherwise     = []
1281 \end{code}
1282
1283 Note [Polymorphic selectors]
1284 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1285 When a record has a polymorphic field, we pull the foralls out to the front.
1286    data T = MkT { f :: forall a. [a] -> a }
1287 Then f :: forall a. T -> [a] -> a
1288 NOT  f :: T -> forall a. [a] -> a
1289
1290 This is horrid.  It's only needed in deeply obscure cases, which I hate.
1291 The only case I know is test tc163, which is worth looking at.  It's far
1292 from clear that this test should succeed at all!
1293
1294 Note [Naughty record selectors]
1295 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1296 A "naughty" field is one for which we can't define a record 
1297 selector, because an existential type variable would escape.  For example:
1298         data T = forall a. MkT { x,y::a }
1299 We obviously can't define       
1300         x (MkT v _) = v
1301 Nevertheless we *do* put a RecSelId into the type environment
1302 so that if the user tries to use 'x' as a selector we can bleat
1303 helpfully, rather than saying unhelpfully that 'x' is not in scope.
1304 Hence the sel_naughty flag, to identify record selectors that don't really exist.
1305
1306 In general, a field is "naughty" if its type mentions a type variable that
1307 isn't in the result type of the constructor.  Note that this *allows*
1308 GADT record selectors (Note [GADT record selectors]) whose types may look 
1309 like     sel :: T [a] -> a
1310
1311 For naughty selectors we make a dummy binding 
1312    sel = ()
1313 for naughty selectors, so that the later type-check will add them to the
1314 environment, and they'll be exported.  The function is never called, because
1315 the tyepchecker spots the sel_naughty field.
1316
1317 Note [GADT record selectors]
1318 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1319 For GADTs, we require that all constructors with a common field 'f' have the same
1320 result type (modulo alpha conversion).  [Checked in TcTyClsDecls.checkValidTyCon]
1321 E.g. 
1322         data T where
1323           T1 { f :: Maybe a } :: T [a]
1324           T2 { f :: Maybe a, y :: b  } :: T [a]
1325
1326 and now the selector takes that result type as its argument:
1327    f :: forall a. T [a] -> Maybe a
1328
1329 Details: the "real" types of T1,T2 are:
1330    T1 :: forall r a.   (r~[a]) => a -> T r
1331    T2 :: forall r a b. (r~[a]) => a -> b -> T r
1332
1333 So the selector loooks like this:
1334    f :: forall a. T [a] -> Maybe a
1335    f (a:*) (t:T [a])
1336      = case t of
1337          T1 c   (g:[a]~[c]) (v:Maybe c)       -> v `cast` Maybe (right (sym g))
1338          T2 c d (g:[a]~[c]) (v:Maybe c) (w:d) -> v `cast` Maybe (right (sym g))
1339
1340 Note the forall'd tyvars of the selector are just the free tyvars
1341 of the result type; there may be other tyvars in the constructor's
1342 type (e.g. 'b' in T2).
1343
1344 Note the need for casts in the result!
1345
1346 Note [Selector running example]
1347 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1348 It's OK to combine GADTs and type families.  Here's a running example:
1349
1350         data instance T [a] where 
1351           T1 { fld :: b } :: T [Maybe b]
1352
1353 The representation type looks like this
1354         data :R7T a where
1355           T1 { fld :: b } :: :R7T (Maybe b)
1356
1357 and there's coercion from the family type to the representation type
1358         :CoR7T a :: T [a] ~ :R7T a
1359
1360 The selector we want for fld looks like this:
1361
1362         fld :: forall b. T [Maybe b] -> b
1363         fld = /\b. \(d::T [Maybe b]).
1364               case d `cast` :CoR7T (Maybe b) of 
1365                 T1 (x::b) -> x
1366
1367 The scrutinee of the case has type :R7T (Maybe b), which can be
1368 gotten by appying the eq_spec to the univ_tvs of the data con.
1369
1370 %************************************************************************
1371 %*                                                                      *
1372                 Error messages
1373 %*                                                                      *
1374 %************************************************************************
1375
1376 \begin{code}
1377 resultTypeMisMatch :: Name -> DataCon -> DataCon -> SDoc
1378 resultTypeMisMatch field_name con1 con2
1379   = vcat [sep [ptext (sLit "Constructors") <+> ppr con1 <+> ptext (sLit "and") <+> ppr con2, 
1380                 ptext (sLit "have a common field") <+> quotes (ppr field_name) <> comma],
1381           nest 2 $ ptext (sLit "but have different result types")]
1382
1383 fieldTypeMisMatch :: Name -> DataCon -> DataCon -> SDoc
1384 fieldTypeMisMatch field_name con1 con2
1385   = sep [ptext (sLit "Constructors") <+> ppr con1 <+> ptext (sLit "and") <+> ppr con2, 
1386          ptext (sLit "give different types for field"), quotes (ppr field_name)]
1387
1388 dataConCtxt :: Outputable a => a -> SDoc
1389 dataConCtxt con = ptext (sLit "In the definition of data constructor") <+> quotes (ppr con)
1390
1391 classOpCtxt :: Var -> Type -> SDoc
1392 classOpCtxt sel_id tau = sep [ptext (sLit "When checking the class method:"),
1393                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1394
1395 nullaryClassErr :: Class -> SDoc
1396 nullaryClassErr cls
1397   = ptext (sLit "No parameters for class")  <+> quotes (ppr cls)
1398
1399 classArityErr :: Class -> SDoc
1400 classArityErr cls
1401   = vcat [ptext (sLit "Too many parameters for class") <+> quotes (ppr cls),
1402           parens (ptext (sLit "Use -XMultiParamTypeClasses to allow multi-parameter classes"))]
1403
1404 classFunDepsErr :: Class -> SDoc
1405 classFunDepsErr cls
1406   = vcat [ptext (sLit "Fundeps in class") <+> quotes (ppr cls),
1407           parens (ptext (sLit "Use -XFunctionalDependencies to allow fundeps"))]
1408
1409 noClassTyVarErr :: Class -> Var -> SDoc
1410 noClassTyVarErr clas op
1411   = sep [ptext (sLit "The class method") <+> quotes (ppr op),
1412          ptext (sLit "mentions none of the type variables of the class") <+> 
1413                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1414
1415 genericMultiParamErr :: Class -> SDoc
1416 genericMultiParamErr clas
1417   = ptext (sLit "The multi-parameter class") <+> quotes (ppr clas) <+> 
1418     ptext (sLit "cannot have generic methods")
1419
1420 badGenericMethodType :: Name -> Kind -> SDoc
1421 badGenericMethodType op op_ty
1422   = hang (ptext (sLit "Generic method type is too complex"))
1423        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1424                 ptext (sLit "You can only use type variables, arrows, lists, and tuples")])
1425
1426 recSynErr :: [LTyClDecl Name] -> TcRn ()
1427 recSynErr syn_decls
1428   = setSrcSpan (getLoc (head sorted_decls)) $
1429     addErr (sep [ptext (sLit "Cycle in type synonym declarations:"),
1430                  nest 2 (vcat (map ppr_decl sorted_decls))])
1431   where
1432     sorted_decls = sortLocated syn_decls
1433     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1434
1435 recClsErr :: [Located (TyClDecl Name)] -> TcRn ()
1436 recClsErr cls_decls
1437   = setSrcSpan (getLoc (head sorted_decls)) $
1438     addErr (sep [ptext (sLit "Cycle in class declarations (via superclasses):"),
1439                  nest 2 (vcat (map ppr_decl sorted_decls))])
1440   where
1441     sorted_decls = sortLocated cls_decls
1442     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1443
1444 sortLocated :: [Located a] -> [Located a]
1445 sortLocated things = sortLe le things
1446   where
1447     le (L l1 _) (L l2 _) = l1 <= l2
1448
1449 badDataConTyCon :: DataCon -> Type -> Type -> SDoc
1450 badDataConTyCon data_con res_ty_tmpl actual_res_ty
1451   = hang (ptext (sLit "Data constructor") <+> quotes (ppr data_con) <+>
1452                 ptext (sLit "returns type") <+> quotes (ppr actual_res_ty))
1453        2 (ptext (sLit "instead of an instance of its parent type") <+> quotes (ppr res_ty_tmpl))
1454
1455 badGadtDecl :: Name -> SDoc
1456 badGadtDecl tc_name
1457   = vcat [ ptext (sLit "Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1458          , nest 2 (parens $ ptext (sLit "Use -XGADTs to allow GADTs")) ]
1459
1460 badExistential :: Located Name -> SDoc
1461 badExistential con_name
1462   = hang (ptext (sLit "Data constructor") <+> quotes (ppr con_name) <+>
1463                 ptext (sLit "has existential type variables, or a context"))
1464        2 (parens $ ptext (sLit "Use -XExistentialQuantification or -XGADTs to allow this"))
1465
1466 badStupidTheta :: Name -> SDoc
1467 badStupidTheta tc_name
1468   = ptext (sLit "A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1469
1470 newtypeConError :: Name -> Int -> SDoc
1471 newtypeConError tycon n
1472   = sep [ptext (sLit "A newtype must have exactly one constructor,"),
1473          nest 2 $ ptext (sLit "but") <+> quotes (ppr tycon) <+> ptext (sLit "has") <+> speakN n ]
1474
1475 newtypeExError :: DataCon -> SDoc
1476 newtypeExError con
1477   = sep [ptext (sLit "A newtype constructor cannot have an existential context,"),
1478          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does")]
1479
1480 newtypeStrictError :: DataCon -> SDoc
1481 newtypeStrictError con
1482   = sep [ptext (sLit "A newtype constructor cannot have a strictness annotation,"),
1483          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does")]
1484
1485 newtypePredError :: DataCon -> SDoc
1486 newtypePredError con
1487   = sep [ptext (sLit "A newtype constructor must have a return type of form T a1 ... an"),
1488          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does not")]
1489
1490 newtypeFieldErr :: DataCon -> Int -> SDoc
1491 newtypeFieldErr con_name n_flds
1492   = sep [ptext (sLit "The constructor of a newtype must have exactly one field"), 
1493          nest 2 $ ptext (sLit "but") <+> quotes (ppr con_name) <+> ptext (sLit "has") <+> speakN n_flds]
1494
1495 badSigTyDecl :: Name -> SDoc
1496 badSigTyDecl tc_name
1497   = vcat [ ptext (sLit "Illegal kind signature") <+>
1498            quotes (ppr tc_name)
1499          , nest 2 (parens $ ptext (sLit "Use -XKindSignatures to allow kind signatures")) ]
1500
1501 badFamInstDecl :: Outputable a => a -> SDoc
1502 badFamInstDecl tc_name
1503   = vcat [ ptext (sLit "Illegal family instance for") <+>
1504            quotes (ppr tc_name)
1505          , nest 2 (parens $ ptext (sLit "Use -XTypeFamilies to allow indexed type families")) ]
1506
1507 tooManyParmsErr :: Located Name -> SDoc
1508 tooManyParmsErr tc_name
1509   = ptext (sLit "Family instance has too many parameters:") <+> 
1510     quotes (ppr tc_name)
1511
1512 tooFewParmsErr :: Arity -> SDoc
1513 tooFewParmsErr arity
1514   = ptext (sLit "Family instance has too few parameters; expected") <+> 
1515     ppr arity
1516
1517 wrongNumberOfParmsErr :: Arity -> SDoc
1518 wrongNumberOfParmsErr exp_arity
1519   = ptext (sLit "Number of parameters must match family declaration; expected")
1520     <+> ppr exp_arity
1521
1522 badBootFamInstDeclErr :: SDoc
1523 badBootFamInstDeclErr
1524   = ptext (sLit "Illegal family instance in hs-boot file")
1525
1526 notFamily :: TyCon -> SDoc
1527 notFamily tycon
1528   = vcat [ ptext (sLit "Illegal family instance for") <+> quotes (ppr tycon)
1529          , nest 2 $ parens (ppr tycon <+> ptext (sLit "is not an indexed type family"))]
1530   
1531 wrongKindOfFamily :: TyCon -> SDoc
1532 wrongKindOfFamily family
1533   = ptext (sLit "Wrong category of family instance; declaration was for a")
1534     <+> kindOfFamily
1535   where
1536     kindOfFamily | isSynTyCon family = ptext (sLit "type synonym")
1537                  | isAlgTyCon family = ptext (sLit "data type")
1538                  | otherwise = pprPanic "wrongKindOfFamily" (ppr family)
1539
1540 emptyConDeclsErr :: Name -> SDoc
1541 emptyConDeclsErr tycon
1542   = sep [quotes (ppr tycon) <+> ptext (sLit "has no constructors"),
1543          nest 2 $ ptext (sLit "(-XEmptyDataDecls permits this)")]
1544 \end{code}