Add tuple sections as a new feature
[ghc.git] / compiler / hsSyn / HsUtils.lhs
1 %
2 % (c) The University of Glasgow, 1992-2006
3 %
4
5 Here we collect a variety of helper functions that construct or
6 analyse HsSyn.  All these functions deal with generic HsSyn; functions
7 which deal with the intantiated versions are located elsewhere:
8
9    Parameterised by     Module
10    ----------------     -------------
11    RdrName              parser/RdrHsSyn
12    Name                 rename/RnHsSyn
13    Id                   typecheck/TcHsSyn       
14
15 \begin{code}
16 module HsUtils where
17
18 import HsBinds
19 import HsExpr
20 import HsPat
21 import HsTypes  
22 import HsLit
23
24 import RdrName
25 import Var
26 import Coercion
27 import Type
28 import DataCon
29 import Name
30 import BasicTypes
31 import SrcLoc
32 import FastString
33 import Outputable
34 import Util
35 import Bag
36 \end{code}
37
38
39 %************************************************************************
40 %*                                                                      *
41         Some useful helpers for constructing syntax
42 %*                                                                      *
43 %************************************************************************
44
45 These functions attempt to construct a not-completely-useless SrcSpan
46 from their components, compared with the nl* functions below which
47 just attach noSrcSpan to everything.
48
49 \begin{code}
50 mkHsPar :: LHsExpr id -> LHsExpr id
51 mkHsPar e = L (getLoc e) (HsPar e)
52
53 mkSimpleMatch :: [LPat id] -> LHsExpr id -> LMatch id
54 mkSimpleMatch pats rhs 
55   = L loc $
56     Match pats Nothing (unguardedGRHSs rhs)
57   where
58     loc = case pats of
59                 []      -> getLoc rhs
60                 (pat:_) -> combineSrcSpans (getLoc pat) (getLoc rhs)
61
62 unguardedGRHSs :: LHsExpr id -> GRHSs id
63 unguardedGRHSs rhs = GRHSs (unguardedRHS rhs) emptyLocalBinds
64
65 unguardedRHS :: LHsExpr id -> [LGRHS id]
66 unguardedRHS rhs@(L loc _) = [L loc (GRHS [] rhs)]
67
68 mkHsAppTy :: LHsType name -> LHsType name -> LHsType name
69 mkHsAppTy t1 t2 = addCLoc t1 t2 (HsAppTy t1 t2)
70
71 mkHsApp :: LHsExpr name -> LHsExpr name -> LHsExpr name
72 mkHsApp e1 e2 = addCLoc e1 e2 (HsApp e1 e2)
73
74 nlHsTyApp :: name -> [Type] -> LHsExpr name
75 nlHsTyApp fun_id tys = noLoc (HsWrap (mkWpTyApps tys) (HsVar fun_id))
76
77 mkLHsWrap :: HsWrapper -> LHsExpr id -> LHsExpr id
78 mkLHsWrap co_fn (L loc e) = L loc (mkHsWrap co_fn e)
79
80 mkHsWrap :: HsWrapper -> HsExpr id -> HsExpr id
81 mkHsWrap co_fn e | isIdHsWrapper co_fn = e
82                  | otherwise           = HsWrap co_fn e
83
84 mkHsWrapCoI :: CoercionI -> HsExpr id -> HsExpr id
85 mkHsWrapCoI IdCo     e = e
86 mkHsWrapCoI (ACo co) e = mkHsWrap (WpCast co) e
87
88 coiToHsWrapper :: CoercionI -> HsWrapper
89 coiToHsWrapper IdCo     = idHsWrapper
90 coiToHsWrapper (ACo co) = WpCast co
91
92 mkHsLam :: [LPat id] -> LHsExpr id -> LHsExpr id
93 mkHsLam pats body = mkHsPar (L (getLoc body) (HsLam matches))
94         where
95           matches = mkMatchGroup [mkSimpleMatch pats body]
96
97 mkMatchGroup :: [LMatch id] -> MatchGroup id
98 mkMatchGroup matches = MatchGroup matches placeHolderType
99
100 mkHsDictLet :: LHsBinds Id -> LHsExpr Id -> LHsExpr Id
101 -- Used for the dictionary bindings gotten from TcSimplify
102 -- We make them recursive to be on the safe side
103 mkHsDictLet binds expr 
104   | isEmptyLHsBinds binds = expr
105   | otherwise             = L (getLoc expr) (HsLet (HsValBinds val_binds) expr)
106                           where
107                             val_binds = ValBindsOut [(Recursive, binds)] []
108
109 mkHsConApp :: DataCon -> [Type] -> [HsExpr Id] -> LHsExpr Id
110 -- Used for constructing dictionary terms etc, so no locations 
111 mkHsConApp data_con tys args 
112   = foldl mk_app (nlHsTyApp (dataConWrapId data_con) tys) args
113   where
114     mk_app f a = noLoc (HsApp f (noLoc a))
115
116 mkSimpleHsAlt :: LPat id -> LHsExpr id -> LMatch id
117 -- A simple lambda with a single pattern, no binds, no guards; pre-typechecking
118 mkSimpleHsAlt pat expr 
119   = mkSimpleMatch [pat] expr
120
121 -------------------------------
122 -- These are the bits of syntax that contain rebindable names
123 -- See RnEnv.lookupSyntaxName
124
125 mkHsIntegral   :: Integer -> PostTcType -> HsOverLit id
126 mkHsFractional :: Rational -> PostTcType -> HsOverLit id
127 mkHsIsString   :: FastString -> PostTcType -> HsOverLit id
128 mkHsDo         :: HsStmtContext Name -> [LStmt id] -> LHsExpr id -> HsExpr id
129
130 mkNPat      :: HsOverLit id -> Maybe (SyntaxExpr id) -> Pat id
131 mkNPlusKPat :: Located id -> HsOverLit id -> Pat id
132
133 mkTransformStmt   :: [LStmt idL] -> LHsExpr idR                -> StmtLR idL idR
134 mkTransformByStmt :: [LStmt idL] -> LHsExpr idR -> LHsExpr idR -> StmtLR idL idR
135
136 mkGroupUsingStmt   :: [LStmt idL]                -> LHsExpr idR -> StmtLR idL idR
137 mkGroupByStmt      :: [LStmt idL] -> LHsExpr idR                -> StmtLR idL idR
138 mkGroupByUsingStmt :: [LStmt idL] -> LHsExpr idR -> LHsExpr idR -> StmtLR idL idR
139
140 mkExprStmt :: LHsExpr idR -> StmtLR idL idR
141 mkBindStmt :: LPat idL -> LHsExpr idR -> StmtLR idL idR
142 mkRecStmt  :: [LStmtLR idL idR] -> StmtLR idL idR
143
144
145 mkHsIntegral   i       = OverLit (HsIntegral   i)  noRebindableInfo noSyntaxExpr
146 mkHsFractional f       = OverLit (HsFractional f)  noRebindableInfo noSyntaxExpr
147 mkHsIsString   s       = OverLit (HsIsString   s)  noRebindableInfo noSyntaxExpr
148
149 noRebindableInfo :: Bool
150 noRebindableInfo = error "noRebindableInfo"     -- Just another placeholder; 
151
152 mkHsDo ctxt stmts body = HsDo ctxt stmts body placeHolderType
153
154 mkNPat lit neg     = NPat lit neg noSyntaxExpr
155 mkNPlusKPat id lit = NPlusKPat id lit noSyntaxExpr noSyntaxExpr
156
157 mkTransformStmt   stmts usingExpr        = TransformStmt (stmts, []) usingExpr Nothing
158 mkTransformByStmt stmts usingExpr byExpr = TransformStmt (stmts, []) usingExpr (Just byExpr)
159
160 mkGroupUsingStmt   stmts usingExpr        = GroupStmt (stmts, []) (GroupByNothing usingExpr)
161 mkGroupByStmt      stmts byExpr           = GroupStmt (stmts, []) (GroupBySomething (Right noSyntaxExpr) byExpr)
162 mkGroupByUsingStmt stmts byExpr usingExpr = GroupStmt (stmts, []) (GroupBySomething (Left usingExpr) byExpr)
163
164 mkExprStmt expr     = ExprStmt expr noSyntaxExpr placeHolderType
165 mkBindStmt pat expr = BindStmt pat expr noSyntaxExpr noSyntaxExpr
166 mkRecStmt stmts     = RecStmt stmts [] [] [] emptyLHsBinds
167
168 -------------------------------
169 --- A useful function for building @OpApps@.  The operator is always a
170 -- variable, and we don't know the fixity yet.
171 mkHsOpApp :: LHsExpr id -> id -> LHsExpr id -> HsExpr id
172 mkHsOpApp e1 op e2 = OpApp e1 (noLoc (HsVar op)) (error "mkOpApp:fixity") e2
173
174 mkHsSplice :: LHsExpr RdrName -> HsSplice RdrName
175 mkHsSplice e = HsSplice unqualSplice e
176
177 unqualSplice :: RdrName
178 unqualSplice = mkRdrUnqual (mkVarOccFS (fsLit "splice"))
179                 -- A name (uniquified later) to
180                 -- identify the splice
181
182 mkHsQuasiQuote :: RdrName -> SrcSpan -> FastString -> HsQuasiQuote RdrName
183 mkHsQuasiQuote quoter span quote = HsQuasiQuote unqualQuasiQuote quoter span quote
184
185 unqualQuasiQuote :: RdrName
186 unqualQuasiQuote = mkRdrUnqual (mkVarOccFS (fsLit "quasiquote"))
187                 -- A name (uniquified later) to
188                 -- identify the quasi-quote
189
190 mkHsString :: String -> HsLit
191 mkHsString s = HsString (mkFastString s)
192
193 -------------
194 userHsTyVarBndrs :: [Located name] -> [Located (HsTyVarBndr name)]
195 userHsTyVarBndrs bndrs = [ L loc (UserTyVar v) | L loc v <- bndrs ]
196 \end{code}
197
198
199 %************************************************************************
200 %*                                                                      *
201         Constructing syntax with no location info
202 %*                                                                      *
203 %************************************************************************
204
205 \begin{code}
206 nlHsVar :: id -> LHsExpr id
207 nlHsVar n = noLoc (HsVar n)
208
209 nlHsLit :: HsLit -> LHsExpr id
210 nlHsLit n = noLoc (HsLit n)
211
212 nlVarPat :: id -> LPat id
213 nlVarPat n = noLoc (VarPat n)
214
215 nlLitPat :: HsLit -> LPat id
216 nlLitPat l = noLoc (LitPat l)
217
218 nlHsApp :: LHsExpr id -> LHsExpr id -> LHsExpr id
219 nlHsApp f x = noLoc (HsApp f x)
220
221 nlHsIntLit :: Integer -> LHsExpr id
222 nlHsIntLit n = noLoc (HsLit (HsInt n))
223
224 nlHsApps :: id -> [LHsExpr id] -> LHsExpr id
225 nlHsApps f xs = foldl nlHsApp (nlHsVar f) xs
226              
227 nlHsVarApps :: id -> [id] -> LHsExpr id
228 nlHsVarApps f xs = noLoc (foldl mk (HsVar f) (map HsVar xs))
229                  where
230                    mk f a = HsApp (noLoc f) (noLoc a)
231
232 nlConVarPat :: id -> [id] -> LPat id
233 nlConVarPat con vars = nlConPat con (map nlVarPat vars)
234
235 nlInfixConPat :: id -> LPat id -> LPat id -> LPat id
236 nlInfixConPat con l r = noLoc (ConPatIn (noLoc con) (InfixCon l r))
237
238 nlConPat :: id -> [LPat id] -> LPat id
239 nlConPat con pats = noLoc (ConPatIn (noLoc con) (PrefixCon pats))
240
241 nlNullaryConPat :: id -> LPat id
242 nlNullaryConPat con = noLoc (ConPatIn (noLoc con) (PrefixCon []))
243
244 nlWildConPat :: DataCon -> LPat RdrName
245 nlWildConPat con = noLoc (ConPatIn (noLoc (getRdrName con))
246                                    (PrefixCon (nOfThem (dataConSourceArity con) nlWildPat)))
247
248 nlWildPat :: LPat id
249 nlWildPat  = noLoc (WildPat placeHolderType)    -- Pre-typechecking
250
251 nlHsDo :: HsStmtContext Name -> [LStmt id] -> LHsExpr id -> LHsExpr id
252 nlHsDo ctxt stmts body = noLoc (mkHsDo ctxt stmts body)
253
254 nlHsOpApp :: LHsExpr id -> id -> LHsExpr id -> LHsExpr id
255 nlHsOpApp e1 op e2 = noLoc (mkHsOpApp e1 op e2)
256
257 nlHsLam  :: LMatch id -> LHsExpr id
258 nlHsPar  :: LHsExpr id -> LHsExpr id
259 nlHsIf   :: LHsExpr id -> LHsExpr id -> LHsExpr id -> LHsExpr id
260 nlHsCase :: LHsExpr id -> [LMatch id] -> LHsExpr id
261 nlList   :: [LHsExpr id] -> LHsExpr id
262
263 nlHsLam match           = noLoc (HsLam (mkMatchGroup [match]))
264 nlHsPar e               = noLoc (HsPar e)
265 nlHsIf cond true false  = noLoc (HsIf cond true false)
266 nlHsCase expr matches   = noLoc (HsCase expr (mkMatchGroup matches))
267 nlList exprs            = noLoc (ExplicitList placeHolderType exprs)
268
269 nlHsAppTy :: LHsType name -> LHsType name -> LHsType name
270 nlHsTyVar :: name                         -> LHsType name
271 nlHsFunTy :: LHsType name -> LHsType name -> LHsType name
272
273 nlHsAppTy f t           = noLoc (HsAppTy f t)
274 nlHsTyVar x             = noLoc (HsTyVar x)
275 nlHsFunTy a b           = noLoc (HsFunTy a b)
276
277 nlHsTyConApp :: name -> [LHsType name] -> LHsType name
278 nlHsTyConApp tycon tys  = foldl nlHsAppTy (nlHsTyVar tycon) tys
279 \end{code}
280
281 Tuples.  All these functions are *pre-typechecker* because they lack
282 types on the tuple.
283
284 \begin{code}
285 mkLHsTupleExpr :: [LHsExpr a] -> LHsExpr a
286 -- Makes a pre-typechecker boxed tuple, deals with 1 case
287 mkLHsTupleExpr [e] = e
288 mkLHsTupleExpr es  = noLoc $ ExplicitTuple (map Present es) Boxed
289
290 mkLHsVarTuple :: [a] -> LHsExpr a
291 mkLHsVarTuple ids  = mkLHsTupleExpr (map nlHsVar ids)
292
293 nlTuplePat :: [LPat id] -> Boxity -> LPat id
294 nlTuplePat pats box = noLoc (TuplePat pats box placeHolderType)
295
296 missingTupArg :: HsTupArg a
297 missingTupArg = Missing placeHolderType
298 \end{code}
299
300 %************************************************************************
301 %*                                                                      *
302                 Bindings; with a location at the top
303 %*                                                                      *
304 %************************************************************************
305
306 \begin{code}
307 mkFunBind :: Located id -> [LMatch id] -> HsBind id
308 -- Not infix, with place holders for coercion and free vars
309 mkFunBind fn ms = FunBind { fun_id = fn, fun_infix = False, fun_matches = mkMatchGroup ms,
310                             fun_co_fn = idHsWrapper, bind_fvs = placeHolderNames,
311                             fun_tick = Nothing }
312
313
314 mkVarBind :: SrcSpan -> id -> LHsExpr id -> LHsBind id
315 mkVarBind loc var rhs = mk_easy_FunBind loc var [] rhs
316
317 ------------
318 mk_easy_FunBind :: SrcSpan -> id -> [LPat id]
319                 -> LHsExpr id -> LHsBind id
320
321 mk_easy_FunBind loc fun pats expr
322   = L loc $ mkFunBind (L loc fun) [mkMatch pats expr emptyLocalBinds]
323
324 ------------
325 mk_FunBind :: SrcSpan -> id
326            -> [([LPat id], LHsExpr id)]
327            -> LHsBind id
328
329 mk_FunBind _   _   [] = panic "TcGenDeriv:mk_FunBind"
330 mk_FunBind loc fun pats_and_exprs
331   = L loc $ mkFunBind (L loc fun) matches
332   where
333     matches = [mkMatch p e emptyLocalBinds | (p,e) <-pats_and_exprs]
334
335 ------------
336 mkMatch :: [LPat id] -> LHsExpr id -> HsLocalBinds id -> LMatch id
337 mkMatch pats expr binds
338   = noLoc (Match (map paren pats) Nothing 
339                  (GRHSs (unguardedRHS expr) binds))
340   where
341     paren p = case p of
342                 L _ (VarPat _) -> p
343                 L l _          -> L l (ParPat p)
344 \end{code}
345
346
347 %************************************************************************
348 %*                                                                      *
349         Collecting binders from HsBindGroups and HsBinds
350 %*                                                                      *
351 %************************************************************************
352
353 Get all the binders in some HsBindGroups, IN THE ORDER OF APPEARANCE. eg.
354
355 ...
356 where
357   (x, y) = ...
358   f i j  = ...
359   [a, b] = ...
360
361 it should return [x, y, f, a, b] (remember, order important).
362
363 \begin{code}
364 collectLocalBinders :: HsLocalBindsLR idL idR -> [Located idL]
365 collectLocalBinders (HsValBinds val_binds) = collectHsValBinders val_binds
366 collectLocalBinders (HsIPBinds _)   = []
367 collectLocalBinders EmptyLocalBinds = []
368
369 collectHsValBinders :: HsValBindsLR idL idR -> [Located idL]
370 collectHsValBinders (ValBindsIn  binds _) = collectHsBindLocatedBinders binds
371 collectHsValBinders (ValBindsOut binds _) = foldr collect_one [] binds
372   where
373    collect_one (_,binds) acc = foldrBag (collectAcc . unLoc) acc binds
374
375 collectAcc :: HsBindLR idL idR -> [Located idL] -> [Located idL]
376 collectAcc (PatBind { pat_lhs = p }) acc = collectLocatedPatBinders p ++ acc
377 collectAcc (FunBind { fun_id = f })  acc    = f : acc
378 collectAcc (VarBind { var_id = f })  acc    = noLoc f : acc
379 collectAcc (AbsBinds { abs_exports = dbinds, abs_binds = _binds }) acc
380   = [noLoc dp | (_,dp,_,_) <- dbinds] ++ acc
381         -- ++ foldr collectAcc acc binds
382         -- I don't think we want the binders from the nested binds
383         -- The only time we collect binders from a typechecked 
384         -- binding (hence see AbsBinds) is in zonking in TcHsSyn
385
386 collectHsBindBinders :: LHsBindsLR idL idR -> [idL]
387 collectHsBindBinders binds = map unLoc (collectHsBindLocatedBinders binds)
388
389 collectHsBindLocatedBinders :: LHsBindsLR idL idR -> [Located idL]
390 collectHsBindLocatedBinders binds = foldrBag (collectAcc . unLoc) [] binds
391 \end{code}
392
393
394 %************************************************************************
395 %*                                                                      *
396         Getting binders from statements
397 %*                                                                      *
398 %************************************************************************
399
400 \begin{code}
401 collectLStmtsBinders :: [LStmtLR idL idR] -> [Located idL]
402 collectLStmtsBinders = concatMap collectLStmtBinders
403
404 collectStmtsBinders :: [StmtLR idL idR] -> [Located idL]
405 collectStmtsBinders = concatMap collectStmtBinders
406
407 collectLStmtBinders :: LStmtLR idL idR -> [Located idL]
408 collectLStmtBinders = collectStmtBinders . unLoc
409
410 collectStmtBinders :: StmtLR idL idR -> [Located idL]
411   -- Id Binders for a Stmt... [but what about pattern-sig type vars]?
412 collectStmtBinders (BindStmt pat _ _ _) = collectLocatedPatBinders pat
413 collectStmtBinders (LetStmt binds)      = collectLocalBinders binds
414 collectStmtBinders (ExprStmt _ _ _)     = []
415 collectStmtBinders (ParStmt xs)         = collectLStmtsBinders
416                                         $ concatMap fst xs
417 collectStmtBinders (TransformStmt (stmts, _) _ _) = collectLStmtsBinders stmts
418 collectStmtBinders (GroupStmt (stmts, _) _)     = collectLStmtsBinders stmts
419 collectStmtBinders (RecStmt ss _ _ _ _) = collectLStmtsBinders ss
420 \end{code}
421
422
423 %************************************************************************
424 %*                                                                      *
425 %*      Gathering stuff out of patterns
426 %*                                                                      *
427 %************************************************************************
428
429 This function @collectPatBinders@ works with the ``collectBinders''
430 functions for @HsBinds@, etc.  The order in which the binders are
431 collected is important; see @HsBinds.lhs@.
432
433 It collects the bounds *value* variables in renamed patterns; type variables
434 are *not* collected.
435
436 \begin{code}
437 collectPatBinders :: LPat a -> [a]
438 collectPatBinders pat = map unLoc (collectLocatedPatBinders pat)
439
440 collectLocatedPatBinders :: LPat a -> [Located a]
441 collectLocatedPatBinders pat = collectl pat []
442
443 collectPatsBinders :: [LPat a] -> [a]
444 collectPatsBinders pats = map unLoc (collectLocatedPatsBinders pats)
445
446 collectLocatedPatsBinders :: [LPat a] -> [Located a]
447 collectLocatedPatsBinders pats = foldr collectl [] pats
448
449 ---------------------
450 collectl :: LPat name -> [Located name] -> [Located name]
451 collectl (L l pat) bndrs
452   = go pat
453   where
454     go (VarPat var)               = L l var : bndrs
455     go (VarPatOut var bs)         = L l var : collectHsBindLocatedBinders bs 
456                                     ++ bndrs
457     go (WildPat _)                = bndrs
458     go (LazyPat pat)              = collectl pat bndrs
459     go (BangPat pat)              = collectl pat bndrs
460     go (AsPat a pat)              = a : collectl pat bndrs
461     go (ViewPat _ pat _)          = collectl pat bndrs
462     go (ParPat  pat)              = collectl pat bndrs
463                                   
464     go (ListPat pats _)           = foldr collectl bndrs pats
465     go (PArrPat pats _)           = foldr collectl bndrs pats
466     go (TuplePat pats _ _)        = foldr collectl bndrs pats
467                                   
468     go (ConPatIn _ ps)            = foldr collectl bndrs (hsConPatArgs ps)
469     go (ConPatOut {pat_args=ps})  = foldr collectl bndrs (hsConPatArgs ps)
470         -- See Note [Dictionary binders in ConPatOut]
471     go (LitPat _)                 = bndrs
472     go (NPat _ _ _)               = bndrs
473     go (NPlusKPat n _ _ _)        = n : bndrs
474                                   
475     go (SigPatIn pat _)           = collectl pat bndrs
476     go (SigPatOut pat _)          = collectl pat bndrs
477     go (QuasiQuotePat _)          = bndrs
478     go (TypePat _)                = bndrs
479     go (CoPat _ pat _)            = collectl (noLoc pat) bndrs
480 \end{code}
481
482 Note [Dictionary binders in ConPatOut]
483 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
484 Do *not* gather (a) dictionary and (b) dictionary bindings as binders
485 of a ConPatOut pattern.  For most calls it doesn't matter, because
486 it's pre-typechecker and there are no ConPatOuts.  But it does matter
487 more in the desugarer; for example, DsUtils.mkSelectorBinds uses
488 collectPatBinders.  In a lazy pattern, for example f ~(C x y) = ...,
489 we want to generate bindings for x,y but not for dictionaries bound by
490 C.  (The type checker ensures they would not be used.)
491
492 Desugaring of arrow case expressions needs these bindings (see DsArrows
493 and arrowcase1), but SPJ (Jan 2007) says it's safer for it to use its
494 own pat-binder-collector:
495
496 Here's the problem.  Consider
497
498 data T a where
499    C :: Num a => a -> Int -> T a
500
501 f ~(C (n+1) m) = (n,m)
502
503 Here, the pattern (C (n+1)) binds a hidden dictionary (d::Num a),
504 and *also* uses that dictionary to match the (n+1) pattern.  Yet, the
505 variables bound by the lazy pattern are n,m, *not* the dictionary d.
506 So in mkSelectorBinds in DsUtils, we want just m,n as the variables bound.
507
508 \begin{code}
509 collectSigTysFromPats :: [InPat name] -> [LHsType name]
510 collectSigTysFromPats pats = foldr collect_lpat [] pats
511
512 collectSigTysFromPat :: InPat name -> [LHsType name]
513 collectSigTysFromPat pat = collect_lpat pat []
514
515 collect_lpat :: InPat name -> [LHsType name] -> [LHsType name]
516 collect_lpat pat acc = collect_pat (unLoc pat) acc
517
518 collect_pat :: Pat name -> [LHsType name] -> [LHsType name]
519 collect_pat (SigPatIn pat ty)   acc = collect_lpat pat (ty:acc)
520 collect_pat (TypePat ty)        acc = ty:acc
521
522 collect_pat (LazyPat pat)       acc = collect_lpat pat acc
523 collect_pat (BangPat pat)       acc = collect_lpat pat acc
524 collect_pat (AsPat _ pat)       acc = collect_lpat pat acc
525 collect_pat (ParPat  pat)       acc = collect_lpat pat acc
526 collect_pat (ListPat pats _)    acc = foldr collect_lpat acc pats
527 collect_pat (PArrPat pats _)    acc = foldr collect_lpat acc pats
528 collect_pat (TuplePat pats _ _) acc = foldr collect_lpat acc pats
529 collect_pat (ConPatIn _ ps)     acc = foldr collect_lpat acc (hsConPatArgs ps)
530 collect_pat _                   acc = acc       -- Literals, vars, wildcard
531 \end{code}