Eliminate all uses of IF_ARCH_i386, and remove the definition
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 -- 
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 module AsmCodeGen ( nativeCodeGen ) where
11
12 #include "HsVersions.h"
13 #include "nativeGen/NCG.h"
14
15
16 import qualified X86.CodeGen
17 import qualified X86.Regs
18 import qualified X86.Instr
19 import qualified X86.Ppr
20
21 import qualified SPARC.CodeGen
22 import qualified SPARC.Regs
23 import qualified SPARC.Instr
24 import qualified SPARC.Ppr
25 import qualified SPARC.ShortcutJump
26 import qualified SPARC.CodeGen.Expand
27
28 import qualified PPC.CodeGen
29 import qualified PPC.Cond
30 import qualified PPC.Regs
31 import qualified PPC.RegInfo
32 import qualified PPC.Instr
33 import qualified PPC.Ppr
34
35 import RegAlloc.Liveness
36 import qualified RegAlloc.Linear.Main           as Linear
37
38 import qualified GraphColor                     as Color
39 import qualified RegAlloc.Graph.Main            as Color
40 import qualified RegAlloc.Graph.Stats           as Color
41 import qualified RegAlloc.Graph.TrivColorable   as Color
42
43 import TargetReg
44 import Platform
45 import Config
46 import Instruction
47 import PIC
48 import Reg
49 import NCGMonad
50
51 import BlockId
52 import CgUtils          ( fixStgRegisters )
53 import OldCmm
54 import CmmOpt           ( cmmEliminateDeadBlocks, cmmMiniInline, cmmMachOpFold )
55 import OldPprCmm
56 import CLabel
57
58 import UniqFM
59 import Unique           ( Unique, getUnique )
60 import UniqSupply
61 import DynFlags
62 import StaticFlags
63 import Util
64
65 import BasicTypes       ( Alignment )
66 import Digraph
67 import Pretty (Doc)
68 import qualified Pretty
69 import BufWrite
70 import Outputable
71 import FastString
72 import UniqSet
73 import ErrUtils
74 import Module
75
76 -- DEBUGGING ONLY
77 --import OrdList
78
79 import Data.List
80 import Data.Maybe
81 import Control.Monad
82 import System.IO
83
84 {-
85 The native-code generator has machine-independent and
86 machine-dependent modules.
87
88 This module ("AsmCodeGen") is the top-level machine-independent
89 module.  Before entering machine-dependent land, we do some
90 machine-independent optimisations (defined below) on the
91 'CmmStmts's.
92
93 We convert to the machine-specific 'Instr' datatype with
94 'cmmCodeGen', assuming an infinite supply of registers.  We then use
95 a machine-independent register allocator ('regAlloc') to rejoin
96 reality.  Obviously, 'regAlloc' has machine-specific helper
97 functions (see about "RegAllocInfo" below).
98
99 Finally, we order the basic blocks of the function so as to minimise
100 the number of jumps between blocks, by utilising fallthrough wherever
101 possible.
102
103 The machine-dependent bits break down as follows:
104
105   * ["MachRegs"]  Everything about the target platform's machine
106     registers (and immediate operands, and addresses, which tend to
107     intermingle/interact with registers).
108
109   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
110     have a module of its own), plus a miscellany of other things
111     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
112
113   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
114     machine instructions.
115
116   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
117     a 'Doc').
118
119   * ["RegAllocInfo"] In the register allocator, we manipulate
120     'MRegsState's, which are 'BitSet's, one bit per machine register.
121     When we want to say something about a specific machine register
122     (e.g., ``it gets clobbered by this instruction''), we set/unset
123     its bit.  Obviously, we do this 'BitSet' thing for efficiency
124     reasons.
125
126     The 'RegAllocInfo' module collects together the machine-specific
127     info needed to do register allocation.
128
129    * ["RegisterAlloc"] The (machine-independent) register allocator.
130 -}
131
132 -- -----------------------------------------------------------------------------
133 -- Top-level of the native codegen
134
135 data NcgImpl statics instr jumpDest = NcgImpl {
136     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
137     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
138     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
139     canShortcut               :: instr -> Maybe jumpDest,
140     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
141     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
142     pprNatCmmDecl              :: Platform -> NatCmmDecl statics instr -> Doc,
143     maxSpillSlots             :: Int,
144     allocatableRegs           :: [RealReg],
145     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
146     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
147     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
148     }
149
150 --------------------
151 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
152 nativeCodeGen dflags h us cmms
153  = let platform = targetPlatform dflags
154        nCG' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
155        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
156        x86NcgImpl = NcgImpl {
157                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
158                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr
159                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
160                         ,canShortcut               = X86.Instr.canShortcut
161                         ,shortcutStatics           = X86.Instr.shortcutStatics
162                         ,shortcutJump              = X86.Instr.shortcutJump
163                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
164                         ,maxSpillSlots             = X86.Instr.maxSpillSlots (target32Bit platform)
165                         ,allocatableRegs           = X86.Regs.allocatableRegs
166                         ,ncg_x86fp_kludge          = id
167                         ,ncgExpandTop              = id
168                         ,ncgMakeFarBranches        = id
169                     }
170    in case platformArch platform of
171                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
172                  ArchX86_64 -> nCG' x86NcgImpl
173                  ArchPPC ->
174                      nCG' $ NcgImpl {
175                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
176                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr
177                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
178                          ,canShortcut               = PPC.RegInfo.canShortcut
179                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
180                          ,shortcutJump              = PPC.RegInfo.shortcutJump
181                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
182                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots
183                          ,allocatableRegs           = PPC.Regs.allocatableRegs
184                          ,ncg_x86fp_kludge          = id
185                          ,ncgExpandTop              = id
186                          ,ncgMakeFarBranches        = makeFarBranches
187                      }
188                  ArchSPARC ->
189                      nCG' $ NcgImpl {
190                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
191                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr
192                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
193                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
194                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
195                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
196                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
197                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots
198                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
199                          ,ncg_x86fp_kludge          = id
200                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
201                          ,ncgMakeFarBranches        = id
202                      }
203                  ArchARM _ _ ->
204                      panic "nativeCodeGen: No NCG for ARM"
205                  ArchPPC_64 ->
206                      panic "nativeCodeGen: No NCG for PPC 64"
207                  ArchAlpha ->
208                      panic "nativeCodeGen: No NCG for Alpha"
209                  ArchMipseb ->
210                      panic "nativeCodeGen: No NCG for mipseb"
211                  ArchMipsel ->
212                      panic "nativeCodeGen: No NCG for mipsel"
213                  ArchUnknown ->
214                      panic "nativeCodeGen: No NCG for unknown arch"
215
216 nativeCodeGen' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
217                => DynFlags
218                -> NcgImpl statics instr jumpDest
219                -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
220 nativeCodeGen' dflags ncgImpl h us cmms
221  = do
222         let platform = targetPlatform dflags
223             split_cmms  = concat $ map add_split cmms
224         -- BufHandle is a performance hack.  We could hide it inside
225         -- Pretty if it weren't for the fact that we do lots of little
226         -- printDocs here (in order to do codegen in constant space).
227         bufh <- newBufHandle h
228         (imports, prof) <- cmmNativeGens dflags ncgImpl bufh us split_cmms [] [] 0
229         bFlush bufh
230
231         let (native, colorStats, linearStats)
232                 = unzip3 prof
233
234         -- dump native code
235         dumpIfSet_dyn dflags
236                 Opt_D_dump_asm "Asm code"
237                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) $ concat native)
238
239         -- dump global NCG stats for graph coloring allocator
240         (case concat $ catMaybes colorStats of
241           []    -> return ()
242           stats -> do   
243                 -- build the global register conflict graph
244                 let graphGlobal 
245                         = foldl Color.union Color.initGraph
246                         $ [ Color.raGraph stat
247                                 | stat@Color.RegAllocStatsStart{} <- stats]
248            
249                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
250                         $ Color.pprStats stats graphGlobal
251
252                 dumpIfSet_dyn dflags
253                         Opt_D_dump_asm_conflicts "Register conflict graph"
254                         $ Color.dotGraph 
255                                 (targetRegDotColor platform)
256                                 (Color.trivColorable platform
257                                         (targetVirtualRegSqueeze platform)
258                                         (targetRealRegSqueeze platform))
259                         $ graphGlobal)
260
261
262         -- dump global NCG stats for linear allocator
263         (case concat $ catMaybes linearStats of
264                 []      -> return ()
265                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
266                                 $ Linear.pprStats (concat native) stats)
267
268         -- write out the imports
269         Pretty.printDoc Pretty.LeftMode h
270                 $ makeImportsDoc dflags (concat imports)
271
272         return  ()
273
274  where  add_split tops
275                 | dopt Opt_SplitObjs dflags = split_marker : tops
276                 | otherwise                 = tops
277
278         split_marker = CmmProc Nothing mkSplitMarkerLabel (ListGraph [])
279
280
281 -- | Do native code generation on all these cmms.
282 --
283 cmmNativeGens :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
284               => DynFlags
285               -> NcgImpl statics instr jumpDest
286               -> BufHandle
287               -> UniqSupply
288               -> [RawCmmDecl]
289               -> [[CLabel]]
290               -> [ ([NatCmmDecl statics instr],
291                    Maybe [Color.RegAllocStats statics instr],
292                    Maybe [Linear.RegAllocStats]) ]
293               -> Int
294               -> IO ( [[CLabel]],
295                       [([NatCmmDecl statics instr],
296                       Maybe [Color.RegAllocStats statics instr],
297                       Maybe [Linear.RegAllocStats])] )
298
299 cmmNativeGens _ _ _ _ [] impAcc profAcc _
300         = return (reverse impAcc, reverse profAcc)
301
302 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
303  = do
304         let platform = targetPlatform dflags
305
306         (us', native, imports, colorStats, linearStats)
307                 <- cmmNativeGen dflags ncgImpl us cmm count
308
309         Pretty.bufLeftRender h
310                 $ {-# SCC "pprNativeCode" #-} Pretty.vcat $ map (pprNatCmmDecl ncgImpl platform) native
311
312            -- carefully evaluate this strictly.  Binding it with 'let'
313            -- and then using 'seq' doesn't work, because the let
314            -- apparently gets inlined first.
315         lsPprNative <- return $!
316                 if  dopt Opt_D_dump_asm       dflags
317                  || dopt Opt_D_dump_asm_stats dflags
318                         then native
319                         else []
320
321         count' <- return $! count + 1;
322
323         -- force evaulation all this stuff to avoid space leaks
324         seqString (showSDoc $ vcat $ map (pprPlatform platform) imports) `seq` return ()
325
326         cmmNativeGens dflags ncgImpl
327             h us' cmms
328                         (imports : impAcc)
329                         ((lsPprNative, colorStats, linearStats) : profAcc)
330                         count'
331
332  where  seqString []            = ()
333         seqString (x:xs)        = x `seq` seqString xs `seq` ()
334
335
336 -- | Complete native code generation phase for a single top-level chunk of Cmm.
337 --      Dumping the output of each stage along the way.
338 --      Global conflict graph and NGC stats
339 cmmNativeGen
340         :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
341     => DynFlags
342     -> NcgImpl statics instr jumpDest
343         -> UniqSupply
344         -> RawCmmDecl                                   -- ^ the cmm to generate code for
345         -> Int                                          -- ^ sequence number of this top thing
346         -> IO   ( UniqSupply
347                 , [NatCmmDecl statics instr]                -- native code
348                 , [CLabel]                                  -- things imported by this cmm
349                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
350                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
351
352 cmmNativeGen dflags ncgImpl us cmm count
353  = do
354         let platform = targetPlatform dflags
355
356         -- rewrite assignments to global regs
357         let fixed_cmm =
358                 {-# SCC "fixStgRegisters" #-}
359                 fixStgRegisters cmm
360
361         -- cmm to cmm optimisations
362         let (opt_cmm, imports) =
363                 {-# SCC "cmmToCmm" #-}
364                 cmmToCmm dflags fixed_cmm
365
366         dumpIfSet_dyn dflags
367                 Opt_D_dump_opt_cmm "Optimised Cmm"
368                 (pprCmmGroup platform [opt_cmm])
369
370         -- generate native code from cmm
371         let ((native, lastMinuteImports), usGen) =
372                 {-# SCC "genMachCode" #-}
373                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
374
375         dumpIfSet_dyn dflags
376                 Opt_D_dump_asm_native "Native code"
377                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) native)
378
379         -- tag instructions with register liveness information
380         let (withLiveness, usLive) =
381                 {-# SCC "regLiveness" #-}
382                 initUs usGen 
383                         $ mapUs (regLiveness platform)
384                         $ map natCmmTopToLive native
385
386         dumpIfSet_dyn dflags
387                 Opt_D_dump_asm_liveness "Liveness annotations added"
388                 (vcat $ map (pprPlatform platform) withLiveness)
389                 
390         -- allocate registers
391         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
392          if ( dopt Opt_RegsGraph dflags
393            || dopt Opt_RegsIterative dflags)
394           then do
395                 -- the regs usable for allocation
396                 let (alloc_regs :: UniqFM (UniqSet RealReg))
397                         = foldr (\r -> plusUFM_C unionUniqSets
398                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
399                                 emptyUFM
400                         $ allocatableRegs ncgImpl
401
402                 -- do the graph coloring register allocation
403                 let ((alloced, regAllocStats), usAlloc)
404                         = {-# SCC "RegAlloc" #-}
405                           initUs usLive
406                           $ Color.regAlloc
407                                 dflags
408                                 alloc_regs
409                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
410                                 withLiveness
411
412                 -- dump out what happened during register allocation
413                 dumpIfSet_dyn dflags
414                         Opt_D_dump_asm_regalloc "Registers allocated"
415                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
416
417                 dumpIfSet_dyn dflags
418                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
419                         (vcat   $ map (\(stage, stats)
420                                         -> text "# --------------------------"
421                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
422                                         $$ pprPlatform platform stats)
423                                 $ zip [0..] regAllocStats)
424
425                 let mPprStats =
426                         if dopt Opt_D_dump_asm_stats dflags
427                          then Just regAllocStats else Nothing
428
429                 -- force evaluation of the Maybe to avoid space leak
430                 mPprStats `seq` return ()
431
432                 return  ( alloced, usAlloc
433                         , mPprStats
434                         , Nothing)
435
436           else do
437                 -- do linear register allocation
438                 let ((alloced, regAllocStats), usAlloc) 
439                         = {-# SCC "RegAlloc" #-}
440                           initUs usLive
441                           $ liftM unzip
442                           $ mapUs (Linear.regAlloc dflags) withLiveness
443
444                 dumpIfSet_dyn dflags
445                         Opt_D_dump_asm_regalloc "Registers allocated"
446                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
447
448                 let mPprStats =
449                         if dopt Opt_D_dump_asm_stats dflags
450                          then Just (catMaybes regAllocStats) else Nothing
451
452                 -- force evaluation of the Maybe to avoid space leak
453                 mPprStats `seq` return ()
454
455                 return  ( alloced, usAlloc
456                         , Nothing
457                         , mPprStats)
458
459         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
460         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
461         ---- is clear, and library functions can return odd results if it
462         ---- isn't.
463         ----
464         ---- NB. must happen before shortcutBranches, because that
465         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
466         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
467
468         ---- generate jump tables
469         let tabled      =
470                 {-# SCC "generateJumpTables" #-}
471                 generateJumpTables ncgImpl kludged
472
473         ---- shortcut branches
474         let shorted     =
475                 {-# SCC "shortcutBranches" #-}
476                 shortcutBranches dflags ncgImpl tabled
477
478         ---- sequence blocks
479         let sequenced   =
480                 {-# SCC "sequenceBlocks" #-}
481                 map (sequenceTop ncgImpl) shorted
482
483         ---- expansion of SPARC synthetic instrs
484         let expanded = 
485                 {-# SCC "sparc_expand" #-}
486                 ncgExpandTop ncgImpl sequenced
487
488         dumpIfSet_dyn dflags
489                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
490                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) expanded)
491
492         return  ( usAlloc
493                 , expanded
494                 , lastMinuteImports ++ imports
495                 , ppr_raStatsColor
496                 , ppr_raStatsLinear)
497
498
499 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
500 x86fp_kludge top@(CmmData _ _) = top
501 x86fp_kludge (CmmProc info lbl (ListGraph code)) = 
502         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
503
504
505 -- | Build a doc for all the imports.
506 --
507 makeImportsDoc :: DynFlags -> [CLabel] -> Pretty.Doc
508 makeImportsDoc dflags imports
509  = dyld_stubs imports
510             Pretty.$$
511             -- On recent versions of Darwin, the linker supports
512             -- dead-stripping of code and data on a per-symbol basis.
513             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
514             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
515              then Pretty.text ".subsections_via_symbols"
516              else Pretty.empty)
517             Pretty.$$ 
518                 -- On recent GNU ELF systems one can mark an object file
519                 -- as not requiring an executable stack. If all objects
520                 -- linked into a program have this note then the program
521                 -- will not use an executable stack, which is good for
522                 -- security. GHC generated code does not need an executable
523                 -- stack so add the note in:
524             (if platformHasGnuNonexecStack (targetPlatform dflags)
525              then Pretty.text ".section .note.GNU-stack,\"\",@progbits"
526              else Pretty.empty)
527                 -- And just because every other compiler does, lets stick in
528                 -- an identifier directive: .ident "GHC x.y.z"
529             Pretty.$$ let compilerIdent = Pretty.text "GHC" Pretty.<+>
530                                           Pretty.text cProjectVersion
531                        in Pretty.text ".ident" Pretty.<+>
532                           Pretty.doubleQuotes compilerIdent
533
534  where
535         -- Generate "symbol stubs" for all external symbols that might
536         -- come from a dynamic library.
537         dyld_stubs :: [CLabel] -> Pretty.Doc
538 {-      dyld_stubs imps = Pretty.vcat $ map pprDyldSymbolStub $
539                                     map head $ group $ sort imps-}
540
541         platform = targetPlatform dflags
542         arch = platformArch platform
543         os   = platformOS   platform
544         
545         -- (Hack) sometimes two Labels pretty-print the same, but have
546         -- different uniques; so we compare their text versions...
547         dyld_stubs imps
548                 | needImportedSymbols arch os
549                 = Pretty.vcat $
550                         (pprGotDeclaration arch os :) $
551                         map ( pprImportedSymbol platform . fst . head) $
552                         groupBy (\(_,a) (_,b) -> a == b) $
553                         sortBy (\(_,a) (_,b) -> compare a b) $
554                         map doPpr $
555                         imps
556                 | otherwise
557                 = Pretty.empty
558
559         doPpr lbl = (lbl, renderWithStyle (pprCLabel platform lbl) astyle)
560         astyle = mkCodeStyle AsmStyle
561
562
563 -- -----------------------------------------------------------------------------
564 -- Sequencing the basic blocks
565
566 -- Cmm BasicBlocks are self-contained entities: they always end in a
567 -- jump, either non-local or to another basic block in the same proc.
568 -- In this phase, we attempt to place the basic blocks in a sequence
569 -- such that as many of the local jumps as possible turn into
570 -- fallthroughs.
571
572 sequenceTop 
573         :: Instruction instr
574     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
575
576 sequenceTop _       top@(CmmData _ _) = top
577 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) = 
578   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks blocks)
579
580 -- The algorithm is very simple (and stupid): we make a graph out of
581 -- the blocks where there is an edge from one block to another iff the
582 -- first block ends by jumping to the second.  Then we topologically
583 -- sort this graph.  Then traverse the list: for each block, we first
584 -- output the block, then if it has an out edge, we move the
585 -- destination of the out edge to the front of the list, and continue.
586
587 -- FYI, the classic layout for basic blocks uses postorder DFS; this
588 -- algorithm is implemented in Hoopl.
589
590 sequenceBlocks 
591         :: Instruction instr
592         => [NatBasicBlock instr] 
593         -> [NatBasicBlock instr]
594
595 sequenceBlocks [] = []
596 sequenceBlocks (entry:blocks) = 
597   seqBlocks (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
598   -- the first block is the entry point ==> it must remain at the start.
599
600
601 sccBlocks 
602         :: Instruction instr
603         => [NatBasicBlock instr] 
604         -> [SCC ( NatBasicBlock instr
605                 , Unique
606                 , [Unique])]
607
608 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
609
610 -- we're only interested in the last instruction of
611 -- the block, and only if it has a single destination.
612 getOutEdges 
613         :: Instruction instr
614         => [instr] -> [Unique]
615
616 getOutEdges instrs 
617         = case jumpDestsOfInstr (last instrs) of
618                 [one] -> [getUnique one]
619                 _many -> []
620
621 mkNode :: (Instruction t)
622        => GenBasicBlock t
623        -> (GenBasicBlock t, Unique, [Unique])
624 mkNode block@(BasicBlock id instrs) = (block, getUnique id, getOutEdges instrs)
625
626 seqBlocks :: (Eq t) => [(GenBasicBlock t1, t, [t])] -> [GenBasicBlock t1]
627 seqBlocks [] = []
628 seqBlocks ((block,_,[]) : rest)
629   = block : seqBlocks rest
630 seqBlocks ((block@(BasicBlock id instrs),_,[next]) : rest)
631   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks rest'
632   | otherwise       = block : seqBlocks rest'
633   where
634         (can_fallthrough, rest') = reorder next [] rest
635           -- TODO: we should do a better job for cycles; try to maximise the
636           -- fallthroughs within a loop.
637 seqBlocks _ = panic "AsmCodegen:seqBlocks"
638
639 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
640 reorder  _ accum [] = (False, reverse accum)
641 reorder id accum (b@(block,id',out) : rest)
642   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
643   | otherwise  = reorder id (b:accum) rest
644
645
646 -- -----------------------------------------------------------------------------
647 -- Making far branches
648
649 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
650 -- big, we have to work around this limitation.
651
652 makeFarBranches
653         :: [NatBasicBlock PPC.Instr.Instr] 
654         -> [NatBasicBlock PPC.Instr.Instr]
655 makeFarBranches blocks
656     | last blockAddresses < nearLimit = blocks
657     | otherwise = zipWith handleBlock blockAddresses blocks
658     where
659         blockAddresses = scanl (+) 0 $ map blockLen blocks
660         blockLen (BasicBlock _ instrs) = length instrs
661         
662         handleBlock addr (BasicBlock id instrs)
663                 = BasicBlock id (zipWith makeFar [addr..] instrs)
664         
665         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
666         makeFar addr (PPC.Instr.BCC cond tgt)
667             | abs (addr - targetAddr) >= nearLimit
668             = PPC.Instr.BCCFAR cond tgt
669             | otherwise
670             = PPC.Instr.BCC cond tgt
671             where Just targetAddr = lookupUFM blockAddressMap tgt
672         makeFar _ other            = other
673         
674         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
675                          -- distance, as we have a few pseudo-insns that are
676                          -- pretty-printed as multiple instructions,
677                          -- and it's just not worth the effort to calculate
678                          -- things exactly
679         
680         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
681
682 -- -----------------------------------------------------------------------------
683 -- Generate jump tables
684
685 -- Analyzes all native code and generates data sections for all jump
686 -- table instructions.
687 generateJumpTables
688         :: NcgImpl statics instr jumpDest
689     -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
690 generateJumpTables ncgImpl xs = concatMap f xs
691     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
692           f p = [p]
693           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
694
695 -- -----------------------------------------------------------------------------
696 -- Shortcut branches
697
698 shortcutBranches
699         :: DynFlags
700     -> NcgImpl statics instr jumpDest
701         -> [NatCmmDecl statics instr] 
702         -> [NatCmmDecl statics instr]
703
704 shortcutBranches dflags ncgImpl tops
705   | optLevel dflags < 1 = tops    -- only with -O or higher
706   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
707   where
708     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
709     mapping = foldr plusUFM emptyUFM mappings
710
711 build_mapping :: NcgImpl statics instr jumpDest
712               -> GenCmmDecl d t (ListGraph instr)
713               -> (GenCmmDecl d t (ListGraph instr), UniqFM jumpDest)
714 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
715 build_mapping _ (CmmProc info lbl (ListGraph []))
716   = (CmmProc info lbl (ListGraph []), emptyUFM)
717 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
718   = (CmmProc info lbl (ListGraph (head:others)), mapping)
719         -- drop the shorted blocks, but don't ever drop the first one,
720         -- because it is pointed to by a global label.
721   where
722     -- find all the blocks that just consist of a jump that can be
723     -- shorted.
724     -- Don't completely eliminate loops here -- that can leave a dangling jump!
725     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
726     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
727         | Just jd <- canShortcut ncgImpl insn,
728           Just dest <- getJumpDestBlockId ncgImpl jd,
729           (setMember dest s) || dest == id -- loop checks
730         = (s, shortcut_blocks, b : others)
731     split (s, shortcut_blocks, others) (BasicBlock id [insn])
732         | Just dest <- canShortcut ncgImpl insn
733         = (setInsert id s, (id,dest) : shortcut_blocks, others)
734     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
735
736
737     -- build a mapping from BlockId to JumpDest for shorting branches
738     mapping = foldl add emptyUFM shortcut_blocks
739     add ufm (id,dest) = addToUFM ufm id dest
740     
741 apply_mapping :: NcgImpl statics instr jumpDest
742               -> UniqFM jumpDest
743               -> GenCmmDecl statics h (ListGraph instr)
744               -> GenCmmDecl statics h (ListGraph instr)
745 apply_mapping ncgImpl ufm (CmmData sec statics)
746   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
747 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
748   = CmmProc info lbl (ListGraph $ map short_bb blocks)
749   where
750     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
751     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
752                  -- shortcutJump should apply the mapping repeatedly,
753                  -- just in case we can short multiple branches.
754
755 -- -----------------------------------------------------------------------------
756 -- Instruction selection
757
758 -- Native code instruction selection for a chunk of stix code.  For
759 -- this part of the computation, we switch from the UniqSM monad to
760 -- the NatM monad.  The latter carries not only a Unique, but also an
761 -- Int denoting the current C stack pointer offset in the generated
762 -- code; this is needed for creating correct spill offsets on
763 -- architectures which don't offer, or for which it would be
764 -- prohibitively expensive to employ, a frame pointer register.  Viz,
765 -- x86.
766
767 -- The offset is measured in bytes, and indicates the difference
768 -- between the current (simulated) C stack-ptr and the value it was at
769 -- the beginning of the block.  For stacks which grow down, this value
770 -- should be either zero or negative.
771
772 -- Switching between the two monads whilst carrying along the same
773 -- Unique supply breaks abstraction.  Is that bad?
774
775 genMachCode 
776         :: DynFlags 
777         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
778         -> RawCmmDecl 
779         -> UniqSM 
780                 ( [NatCmmDecl statics instr]
781                 , [CLabel])
782
783 genMachCode dflags cmmTopCodeGen cmm_top
784   = do  { initial_us <- getUs
785         ; let initial_st           = mkNatM_State initial_us 0 dflags
786               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
787               final_delta          = natm_delta final_st
788               final_imports        = natm_imports final_st
789         ; if   final_delta == 0
790           then return (new_tops, final_imports)
791           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
792     }
793
794 -- -----------------------------------------------------------------------------
795 -- Generic Cmm optimiser
796
797 {-
798 Here we do:
799
800   (a) Constant folding
801   (b) Simple inlining: a temporary which is assigned to and then
802       used, once, can be shorted.
803   (c) Position independent code and dynamic linking
804         (i)  introduce the appropriate indirections
805              and position independent refs
806         (ii) compile a list of imported symbols
807   (d) Some arch-specific optimizations
808
809 (a) and (b) will be moving to the new Hoopl pipeline, however, (c) and
810 (d) are only needed by the native backend and will continue to live
811 here.
812
813 Ideas for other things we could do (put these in Hoopl please!):
814
815   - shortcut jumps-to-jumps
816   - simple CSE: if an expr is assigned to a temp, then replace later occs of
817     that expr with the temp, until the expr is no longer valid (can push through
818     temp assignments, and certain assigns to mem...)
819 -}
820
821 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
822 cmmToCmm _ top@(CmmData _ _) = (top, [])
823 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
824   blocks' <- mapM cmmBlockConFold (cmmMiniInline (cmmEliminateDeadBlocks blocks))
825   return $ CmmProc info lbl (ListGraph blocks')
826
827 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
828
829 instance Monad CmmOptM where
830   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
831   (CmmOptM f) >>= g =
832     CmmOptM $ \(imports, dflags) ->
833                 case f (imports, dflags) of
834                   (# x, imports' #) ->
835                     case g x of
836                       CmmOptM g' -> g' (imports', dflags)
837
838 addImportCmmOpt :: CLabel -> CmmOptM ()
839 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
840
841 getDynFlagsCmmOpt :: CmmOptM DynFlags
842 getDynFlagsCmmOpt = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
843
844 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
845 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
846                         (# result, imports #) -> (result, imports)
847
848 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
849 cmmBlockConFold (BasicBlock id stmts) = do
850   stmts' <- mapM cmmStmtConFold stmts
851   return $ BasicBlock id stmts'
852
853 -- This does three optimizations, but they're very quick to check, so we don't
854 -- bother turning them off even when the Hoopl code is active.  Since
855 -- this is on the old Cmm representation, we can't reuse the code either:
856 --  * reg = reg      --> nop
857 --  * if 0 then jump --> nop
858 --  * if 1 then jump --> jump
859 -- We might be tempted to skip this step entirely of not opt_PIC, but
860 -- there is some PowerPC code for the non-PIC case, which would also
861 -- have to be separated.
862 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
863 cmmStmtConFold stmt
864    = case stmt of
865         CmmAssign reg src
866            -> do src' <- cmmExprConFold DataReference src
867                  return $ case src' of
868                    CmmReg reg' | reg == reg' -> CmmNop
869                    new_src -> CmmAssign reg new_src
870
871         CmmStore addr src
872            -> do addr' <- cmmExprConFold DataReference addr
873                  src'  <- cmmExprConFold DataReference src
874                  return $ CmmStore addr' src'
875
876         CmmJump addr regs
877            -> do addr' <- cmmExprConFold JumpReference addr
878                  return $ CmmJump addr' regs
879
880         CmmCall target regs args srt returns
881            -> do target' <- case target of
882                               CmmCallee e conv -> do
883                                 e' <- cmmExprConFold CallReference e
884                                 return $ CmmCallee e' conv
885                               other -> return other
886                  args' <- mapM (\(CmmHinted arg hint) -> do
887                                   arg' <- cmmExprConFold DataReference arg
888                                   return (CmmHinted arg' hint)) args
889                  return $ CmmCall target' regs args' srt returns
890
891         CmmCondBranch test dest
892            -> do test' <- cmmExprConFold DataReference test
893                  dflags <- getDynFlagsCmmOpt
894                  let platform = targetPlatform dflags
895                  return $ case test' of
896                    CmmLit (CmmInt 0 _) -> 
897                      CmmComment (mkFastString ("deleted: " ++ 
898                                         showSDoc (pprStmt platform stmt)))
899
900                    CmmLit (CmmInt _ _) -> CmmBranch dest
901                    _other -> CmmCondBranch test' dest
902
903         CmmSwitch expr ids
904            -> do expr' <- cmmExprConFold DataReference expr
905                  return $ CmmSwitch expr' ids
906
907         other
908            -> return other
909
910 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
911 cmmExprConFold referenceKind expr = do
912     dflags <- getDynFlagsCmmOpt
913     -- Skip constant folding if new code generator is running
914     -- (this optimization is done in Hoopl)
915     let expr' = if dopt Opt_TryNewCodeGen dflags
916                     then expr
917                     else cmmExprCon expr
918     cmmExprNative referenceKind expr'
919
920 cmmExprCon :: CmmExpr -> CmmExpr
921 cmmExprCon (CmmLoad addr rep) = CmmLoad (cmmExprCon addr) rep
922 cmmExprCon (CmmMachOp mop args) = cmmMachOpFold mop (map cmmExprCon args)
923 cmmExprCon other = other
924
925 -- handles both PIC and non-PIC cases... a very strange mixture
926 -- of things to do.
927 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
928 cmmExprNative referenceKind expr = do
929      dflags <- getDynFlagsCmmOpt
930      let arch = platformArch (targetPlatform dflags)
931      case expr of
932         CmmLoad addr rep
933            -> do addr' <- cmmExprNative DataReference addr
934                  return $ CmmLoad addr' rep
935
936         CmmMachOp mop args
937            -> do args' <- mapM (cmmExprNative DataReference) args
938                  return $ CmmMachOp mop args'
939
940         CmmLit (CmmLabel lbl)
941            -> do
942                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
943         CmmLit (CmmLabelOff lbl off)
944            -> do
945                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
946                  -- need to optimize here, since it's late
947                  return $ cmmMachOpFold (MO_Add wordWidth) [
948                      dynRef,
949                      (CmmLit $ CmmInt (fromIntegral off) wordWidth)
950                    ]
951
952         -- On powerpc (non-PIC), it's easier to jump directly to a label than
953         -- to use the register table, so we replace these registers
954         -- with the corresponding labels:
955         CmmReg (CmmGlobal EagerBlackholeInfo)
956           | arch == ArchPPC && not opt_PIC
957           -> cmmExprNative referenceKind $
958              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
959         CmmReg (CmmGlobal GCEnter1)
960           | arch == ArchPPC && not opt_PIC
961           -> cmmExprNative referenceKind $
962              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1"))) 
963         CmmReg (CmmGlobal GCFun)
964           | arch == ArchPPC && not opt_PIC
965           -> cmmExprNative referenceKind $
966              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
967
968         other
969            -> return other
970
971 \end{code}
972