Module header tidyup, phase 1
[ghc.git] / compiler / cmm / CmmLex.x
1 -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow, 2004-2006
4 --
5 -- Lexer for concrete Cmm.  We try to stay close to the C-- spec, but there
6 -- are a few minor differences:
7 --
8 --   * extra keywords for our macros, and float32/float64 types
9 --   * global registers (Sp,Hp, etc.)
10 --
11 -----------------------------------------------------------------------------
12
13 {
14 module CmmLex (
15    CmmToken(..), cmmlex,
16   ) where
17
18 #include "HsVersions.h"
19
20 import Cmm
21 import Lexer
22
23 import SrcLoc
24 import UniqFM
25 import StringBuffer
26 import FastString
27 import Ctype
28 import Util
29 --import TRACE
30 }
31
32 $whitechar   = [\ \t\n\r\f\v\xa0]
33 $white_no_nl = $whitechar # \n
34
35 $ascdigit  = 0-9
36 $unidigit  = \x01
37 $digit     = [$ascdigit $unidigit]
38 $octit     = 0-7
39 $hexit     = [$digit A-F a-f]
40
41 $unilarge  = \x03
42 $asclarge  = [A-Z \xc0-\xd6 \xd8-\xde]
43 $large     = [$asclarge $unilarge]
44
45 $unismall  = \x04
46 $ascsmall  = [a-z \xdf-\xf6 \xf8-\xff]
47 $small     = [$ascsmall $unismall \_]
48
49 $namebegin = [$large $small \_ \. \$ \@]
50 $namechar  = [$namebegin $digit]
51
52 @decimal     = $digit+
53 @octal       = $octit+
54 @hexadecimal = $hexit+
55 @exponent    = [eE] [\-\+]? @decimal
56
57 @floating_point = @decimal \. @decimal @exponent? | @decimal @exponent
58
59 @escape      = \\ ([abfnrt\\\'\"\?] | x @hexadecimal | @octal)
60 @strchar     = ($printable # [\"\\]) | @escape
61
62 cmm :-
63
64 $white_no_nl+           ;
65 ^\# pragma .* \n        ; -- Apple GCC 3.3 CPP generates pragmas in its output
66
67 ^\# (line)?             { begin line_prag }
68
69 -- single-line line pragmas, of the form
70 --    # <line> "<file>" <extra-stuff> \n
71 <line_prag> $digit+                     { setLine line_prag1 }
72 <line_prag1> \" ($printable # \")* \"   { setFile line_prag2 }
73 <line_prag2> .*                         { pop }
74
75 <0> {
76   \n                    ;
77
78   [\:\;\{\}\[\]\(\)\=\`\~\/\*\%\-\+\&\^\|\>\<\,\!]      { special_char }
79   
80   ".."                  { kw CmmT_DotDot }
81   "::"                  { kw CmmT_DoubleColon }
82   ">>"                  { kw CmmT_Shr }
83   "<<"                  { kw CmmT_Shl }
84   ">="                  { kw CmmT_Ge }
85   "<="                  { kw CmmT_Le }
86   "=="                  { kw CmmT_Eq }
87   "!="                  { kw CmmT_Ne }
88   "&&"                  { kw CmmT_BoolAnd }
89   "||"                  { kw CmmT_BoolOr }
90   
91   R@decimal             { global_regN VanillaReg }
92   F@decimal             { global_regN FloatReg }
93   D@decimal             { global_regN DoubleReg }
94   L@decimal             { global_regN LongReg }
95   Sp                    { global_reg Sp }
96   SpLim                 { global_reg SpLim }
97   Hp                    { global_reg Hp }
98   HpLim                 { global_reg HpLim }
99   CurrentTSO            { global_reg CurrentTSO }
100   CurrentNursery        { global_reg CurrentNursery }
101   HpAlloc               { global_reg HpAlloc }
102   BaseReg               { global_reg BaseReg }
103   
104   $namebegin $namechar* { name }
105   
106   0 @octal              { tok_octal }
107   @decimal              { tok_decimal }
108   0[xX] @hexadecimal    { tok_hexadecimal }
109   @floating_point       { strtoken tok_float }
110   
111   \" @strchar* \"       { strtoken tok_string }
112 }
113
114 {
115 data CmmToken
116   = CmmT_SpecChar  Char
117   | CmmT_DotDot
118   | CmmT_DoubleColon
119   | CmmT_Shr
120   | CmmT_Shl
121   | CmmT_Ge
122   | CmmT_Le
123   | CmmT_Eq
124   | CmmT_Ne
125   | CmmT_BoolAnd
126   | CmmT_BoolOr
127   | CmmT_CLOSURE
128   | CmmT_INFO_TABLE
129   | CmmT_INFO_TABLE_RET
130   | CmmT_INFO_TABLE_FUN
131   | CmmT_INFO_TABLE_CONSTR
132   | CmmT_INFO_TABLE_SELECTOR
133   | CmmT_else
134   | CmmT_export
135   | CmmT_section
136   | CmmT_align
137   | CmmT_goto
138   | CmmT_if
139   | CmmT_jump
140   | CmmT_foreign
141   | CmmT_prim
142   | CmmT_import
143   | CmmT_switch
144   | CmmT_case
145   | CmmT_default
146   | CmmT_bits8
147   | CmmT_bits16
148   | CmmT_bits32
149   | CmmT_bits64
150   | CmmT_float32
151   | CmmT_float64
152   | CmmT_GlobalReg GlobalReg
153   | CmmT_Name      FastString
154   | CmmT_String    String
155   | CmmT_Int       Integer
156   | CmmT_Float     Rational
157   | CmmT_EOF
158 #ifdef DEBUG
159   deriving (Show)
160 #endif
161
162 -- -----------------------------------------------------------------------------
163 -- Lexer actions
164
165 type Action = SrcSpan -> StringBuffer -> Int -> P (Located CmmToken)
166
167 begin :: Int -> Action
168 begin code _span _str _len = do pushLexState code; lexToken
169
170 pop :: Action
171 pop _span _buf _len = do popLexState; lexToken
172
173 special_char :: Action
174 special_char span buf len = return (L span (CmmT_SpecChar (currentChar buf)))
175
176 kw :: CmmToken -> Action
177 kw tok span buf len = return (L span tok)
178
179 global_regN :: (Int -> GlobalReg) -> Action
180 global_regN con span buf len 
181   = return (L span (CmmT_GlobalReg (con (fromIntegral n))))
182   where buf' = stepOn buf
183         n = parseInteger buf' (len-1) 10 octDecDigit
184
185 global_reg :: GlobalReg -> Action
186 global_reg r span buf len = return (L span (CmmT_GlobalReg r))
187
188 strtoken :: (String -> CmmToken) -> Action
189 strtoken f span buf len = 
190   return (L span $! (f $! lexemeToString buf len))
191
192 name :: Action
193 name span buf len = 
194   case lookupUFM reservedWordsFM fs of
195         Just tok -> return (L span tok)
196         Nothing  -> return (L span (CmmT_Name fs))
197   where
198         fs = lexemeToFastString buf len
199
200 reservedWordsFM = listToUFM $
201         map (\(x, y) -> (mkFastString x, y)) [
202         ( "CLOSURE",            CmmT_CLOSURE ),
203         ( "INFO_TABLE",         CmmT_INFO_TABLE ),
204         ( "INFO_TABLE_RET",     CmmT_INFO_TABLE_RET ),
205         ( "INFO_TABLE_FUN",     CmmT_INFO_TABLE_FUN ),
206         ( "INFO_TABLE_CONSTR",  CmmT_INFO_TABLE_CONSTR ),
207         ( "INFO_TABLE_SELECTOR",CmmT_INFO_TABLE_SELECTOR ),
208         ( "else",               CmmT_else ),
209         ( "export",             CmmT_export ),
210         ( "section",            CmmT_section ),
211         ( "align",              CmmT_align ),
212         ( "goto",               CmmT_goto ),
213         ( "if",                 CmmT_if ),
214         ( "jump",               CmmT_jump ),
215         ( "foreign",            CmmT_foreign ),
216         ( "prim",               CmmT_prim ),
217         ( "import",             CmmT_import ),
218         ( "switch",             CmmT_switch ),
219         ( "case",               CmmT_case ),
220         ( "default",            CmmT_default ),
221         ( "bits8",              CmmT_bits8 ),
222         ( "bits16",             CmmT_bits16 ),
223         ( "bits32",             CmmT_bits32 ),
224         ( "bits64",             CmmT_bits64 ),
225         ( "float32",            CmmT_float32 ),
226         ( "float64",            CmmT_float64 )
227         ]
228
229 tok_decimal span buf len 
230   = return (L span (CmmT_Int  $! parseInteger buf len 10 octDecDigit))
231
232 tok_octal span buf len 
233   = return (L span (CmmT_Int  $! parseInteger (offsetBytes 1 buf) (len-1) 8 octDecDigit))
234
235 tok_hexadecimal span buf len 
236   = return (L span (CmmT_Int  $! parseInteger (offsetBytes 2 buf) (len-2) 16 hexDigit))
237
238 tok_float str = CmmT_Float $! readRational str
239
240 tok_string str = CmmT_String (read str)
241                  -- urk, not quite right, but it'll do for now
242
243 -- -----------------------------------------------------------------------------
244 -- Line pragmas
245
246 setLine :: Int -> Action
247 setLine code span buf len = do
248   let line = parseInteger buf len 10 octDecDigit
249   setSrcLoc (mkSrcLoc (srcSpanFile span) (fromIntegral line - 1) 0)
250         -- subtract one: the line number refers to the *following* line
251   -- trace ("setLine "  ++ show line) $ do
252   popLexState
253   pushLexState code
254   lexToken
255
256 setFile :: Int -> Action
257 setFile code span buf len = do
258   let file = lexemeToFastString (stepOn buf) (len-2)
259   setSrcLoc (mkSrcLoc file (srcSpanEndLine span) (srcSpanEndCol span))
260   popLexState
261   pushLexState code
262   lexToken
263
264 -- -----------------------------------------------------------------------------
265 -- This is the top-level function: called from the parser each time a
266 -- new token is to be read from the input.
267
268 cmmlex :: (Located CmmToken -> P a) -> P a
269 cmmlex cont = do
270   tok@(L _ tok__) <- lexToken
271   --trace ("token: " ++ show tok__) $ do
272   cont tok
273
274 lexToken :: P (Located CmmToken)
275 lexToken = do
276   inp@(loc1,buf) <- getInput
277   sc <- getLexState
278   case alexScan inp sc of
279     AlexEOF -> do let span = mkSrcSpan loc1 loc1
280                   setLastToken span 0 0
281                   return (L span CmmT_EOF)
282     AlexError (loc2,_) -> do failLocMsgP loc1 loc2 "lexical error"
283     AlexSkip inp2 _ -> do
284         setInput inp2
285         lexToken
286     AlexToken inp2@(end,buf2) len t -> do
287         setInput inp2
288         let span = mkSrcSpan loc1 end
289         span `seq` setLastToken span len len
290         t span buf len
291
292 -- -----------------------------------------------------------------------------
293 -- Monad stuff
294
295 -- Stuff that Alex needs to know about our input type:
296 type AlexInput = (SrcLoc,StringBuffer)
297
298 alexInputPrevChar :: AlexInput -> Char
299 alexInputPrevChar (_,s) = prevChar s '\n'
300
301 alexGetChar :: AlexInput -> Maybe (Char,AlexInput)
302 alexGetChar (loc,s) 
303   | atEnd s   = Nothing
304   | otherwise = c `seq` loc' `seq` s' `seq` Just (c, (loc', s'))
305   where c = currentChar s
306         loc' = advanceSrcLoc loc c
307         s'   = stepOn s
308
309 getInput :: P AlexInput
310 getInput = P $ \s@PState{ loc=l, buffer=b } -> POk s (l,b)
311
312 setInput :: AlexInput -> P ()
313 setInput (l,b) = P $ \s -> POk s{ loc=l, buffer=b } ()
314 }