Hurrah! This major commit adds support for scoped kind variables,
[ghc.git] / compiler / parser / Parser.y.pp
1 --                                                              -*-haskell-*-
2 -- ---------------------------------------------------------------------------
3 -- (c) The University of Glasgow 1997-2003
4 ---
5 -- The GHC grammar.
6 --
7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
8 -- ---------------------------------------------------------------------------
9
10 {
11 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
12 {-# OPTIONS -Wwarn -w #-}
13 -- The above warning supression flag is a temporary kludge.
14 -- While working on this module you are encouraged to remove it and fix
15 -- any warnings in the module. See
16 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
17 -- for details
18
19 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
20 {-
21 Careful optimisation of the parser: we don't want to throw everything
22 at it, because that takes too long and doesn't buy much, but we do want
23 to inline certain key external functions, so we instruct GHC not to
24 throw away inlinings as it would normally do in -O0 mode.
25 -}
26
27 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
28                 parseHeader ) where
29
30 import HsSyn
31 import RdrHsSyn
32 import HscTypes         ( IsBootInterface, WarningTxt(..) )
33 import Lexer
34 import RdrName
35 import TcEvidence       ( emptyTcEvBinds )
36 import TysPrim          ( liftedTypeKindTyConName, eqPrimTyCon )
37 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
38                           unboxedUnitTyCon, unboxedUnitDataCon,
39                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR, eqTyCon_RDR )
40 import Type             ( funTyCon )
41 import ForeignCall
42 import OccName          ( varName, dataName, tcClsName, tvName )
43 import DataCon          ( DataCon, dataConName )
44 import SrcLoc
45 import Module
46 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
47 import Kind             ( Kind, liftedTypeKind, unliftedTypeKind, mkArrowKind )
48 import Class            ( FunDep )
49 import BasicTypes
50 import DynFlags
51 import OrdList
52 import HaddockUtils
53
54 import FastString
55 import Maybes           ( orElse )
56 import Outputable
57
58 import Control.Monad    ( unless )
59 import GHC.Exts
60 import Data.Char
61 import Control.Monad    ( mplus )
62 }
63
64 {-
65 -----------------------------------------------------------------------------
66 24 Februar 2006
67
68 Conflicts: 33 shift/reduce
69            1 reduce/reduce
70
71 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
72 would think the two should never occur in the same context.
73
74   -=chak
75
76 -----------------------------------------------------------------------------
77 31 December 2006
78
79 Conflicts: 34 shift/reduce
80            1 reduce/reduce
81
82 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
83 would think the two should never occur in the same context.
84
85   -=chak
86
87 -----------------------------------------------------------------------------
88 6 December 2006
89
90 Conflicts: 32 shift/reduce
91            1 reduce/reduce
92
93 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
94 would think the two should never occur in the same context.
95
96   -=chak
97
98 -----------------------------------------------------------------------------
99 26 July 2006
100
101 Conflicts: 37 shift/reduce
102            1 reduce/reduce
103
104 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
105 would think the two should never occur in the same context.
106
107   -=chak
108
109 -----------------------------------------------------------------------------
110 Conflicts: 38 shift/reduce (1.25)
111
112 10 for abiguity in 'if x then y else z + 1'             [State 178]
113         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
114         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
115
116 1 for ambiguity in 'if x then y else z :: T'            [State 178]
117         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
118
119 4 for ambiguity in 'if x then y else z -< e'            [State 178]
120         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
121         There are four such operators: -<, >-, -<<, >>-
122
123
124 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
125         Which of these two is intended?
126           case v of
127             (x::T) -> T         -- Rhs is T
128     or
129           case v of
130             (x::T -> T) -> ..   -- Rhs is ...
131
132 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
133         (e::a) `b` c, or 
134         (e :: (a `b` c))
135     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
136     Same duplication between states 11 and 253 as the previous case
137
138 1 for ambiguity in 'let ?x ...'                         [State 329]
139         the parser can't tell whether the ?x is the lhs of a normal binding or
140         an implicit binding.  Fortunately resolving as shift gives it the only
141         sensible meaning, namely the lhs of an implicit binding.
142
143 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
144         we don't know whether the '[' starts the activation or not: it
145         might be the start of the declaration with the activation being
146         empty.  --SDM 1/4/2002
147
148 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
149         since 'forall' is a valid variable name, we don't know whether
150         to treat a forall on the input as the beginning of a quantifier
151         or the beginning of the rule itself.  Resolving to shift means
152         it's always treated as a quantifier, hence the above is disallowed.
153         This saves explicitly defining a grammar for the rule lhs that
154         doesn't include 'forall'.
155
156 1 for ambiguity when the source file starts with "-- | doc". We need another
157   token of lookahead to determine if a top declaration or the 'module' keyword
158   follows. Shift parses as if the 'module' keyword follows.   
159
160 -- ---------------------------------------------------------------------------
161 -- Adding location info
162
163 This is done in a stylised way using the three macros below, L0, L1
164 and LL.  Each of these macros can be thought of as having type
165
166    L0, L1, LL :: a -> Located a
167
168 They each add a SrcSpan to their argument.
169
170    L0   adds 'noSrcSpan', used for empty productions
171      -- This doesn't seem to work anymore -=chak
172
173    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
174         from that token.
175
176    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
177         the first and last tokens.
178
179 These suffice for the majority of cases.  However, we must be
180 especially careful with empty productions: LL won't work if the first
181 or last token on the lhs can represent an empty span.  In these cases,
182 we have to calculate the span using more of the tokens from the lhs, eg.
183
184         | 'newtype' tycl_hdr '=' newconstr deriving
185                 { L (comb3 $1 $4 $5)
186                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
187
188 We provide comb3 and comb4 functions which are useful in such cases.
189
190 Be careful: there's no checking that you actually got this right, the
191 only symptom will be that the SrcSpans of your syntax will be
192 incorrect.
193
194 /*
195  * We must expand these macros *before* running Happy, which is why this file is
196  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
197  */
198 #define L0   L noSrcSpan
199 #define L1   sL (getLoc $1)
200 #define LL   sL (comb2 $1 $>)
201
202 -- -----------------------------------------------------------------------------
203
204 -}
205
206 %token
207  '_'            { L _ ITunderscore }            -- Haskell keywords
208  'as'           { L _ ITas }
209  'case'         { L _ ITcase }          
210  'class'        { L _ ITclass } 
211  'data'         { L _ ITdata } 
212  'default'      { L _ ITdefault }
213  'deriving'     { L _ ITderiving }
214  'do'           { L _ ITdo }
215  'else'         { L _ ITelse }
216  'hiding'       { L _ IThiding }
217  'if'           { L _ ITif }
218  'import'       { L _ ITimport }
219  'in'           { L _ ITin }
220  'infix'        { L _ ITinfix }
221  'infixl'       { L _ ITinfixl }
222  'infixr'       { L _ ITinfixr }
223  'instance'     { L _ ITinstance }
224  'let'          { L _ ITlet }
225  'module'       { L _ ITmodule }
226  'newtype'      { L _ ITnewtype }
227  'of'           { L _ ITof }
228  'qualified'    { L _ ITqualified }
229  'then'         { L _ ITthen }
230  'type'         { L _ ITtype }
231  'where'        { L _ ITwhere }
232  '_scc_'        { L _ ITscc }         -- ToDo: remove
233
234  'forall'       { L _ ITforall }                -- GHC extension keywords
235  'foreign'      { L _ ITforeign }
236  'export'       { L _ ITexport }
237  'label'        { L _ ITlabel } 
238  'dynamic'      { L _ ITdynamic }
239  'safe'         { L _ ITsafe }
240  'interruptible' { L _ ITinterruptible }
241  'unsafe'       { L _ ITunsafe }
242  'mdo'          { L _ ITmdo }
243  'family'       { L _ ITfamily }
244  'stdcall'      { L _ ITstdcallconv }
245  'ccall'        { L _ ITccallconv }
246  'capi'         { L _ ITcapiconv }
247  'prim'         { L _ ITprimcallconv }
248  'proc'         { L _ ITproc }          -- for arrow notation extension
249  'rec'          { L _ ITrec }           -- for arrow notation extension
250  'group'    { L _ ITgroup }     -- for list transform extension
251  'by'       { L _ ITby }        -- for list transform extension
252  'using'    { L _ ITusing }     -- for list transform extension
253
254  '{-# INLINE'             { L _ (ITinline_prag _ _) }
255  '{-# SPECIALISE'         { L _ ITspec_prag }
256  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
257  '{-# SOURCE'                                   { L _ ITsource_prag }
258  '{-# RULES'                                    { L _ ITrules_prag }
259  '{-# CORE'                                     { L _ ITcore_prag }              -- hdaume: annotated core
260  '{-# SCC'                { L _ ITscc_prag }
261  '{-# GENERATED'          { L _ ITgenerated_prag }
262  '{-# DEPRECATED'         { L _ ITdeprecated_prag }
263  '{-# WARNING'            { L _ ITwarning_prag }
264  '{-# UNPACK'             { L _ ITunpack_prag }
265  '{-# NOUNPACK'           { L _ ITnounpack_prag }
266  '{-# ANN'                { L _ ITann_prag }
267  '{-# VECTORISE'          { L _ ITvect_prag }
268  '{-# VECTORISE_SCALAR'   { L _ ITvect_scalar_prag }
269  '{-# NOVECTORISE'        { L _ ITnovect_prag }
270  '{-# CTYPE'              { L _ ITctype }
271  '#-}'                                          { L _ ITclose_prag }
272
273  '..'           { L _ ITdotdot }                        -- reserved symbols
274  ':'            { L _ ITcolon }
275  '::'           { L _ ITdcolon }
276  '='            { L _ ITequal }
277  '\\'           { L _ ITlam }
278  '|'            { L _ ITvbar }
279  '<-'           { L _ ITlarrow }
280  '->'           { L _ ITrarrow }
281  '@'            { L _ ITat }
282  '~'            { L _ ITtilde }
283  '~#'           { L _ ITtildehsh }
284  '=>'           { L _ ITdarrow }
285  '-'            { L _ ITminus }
286  '!'            { L _ ITbang }
287  '*'            { L _ ITstar }
288  '-<'           { L _ ITlarrowtail }            -- for arrow notation
289  '>-'           { L _ ITrarrowtail }            -- for arrow notation
290  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
291  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
292  '.'            { L _ ITdot }
293
294  '{'            { L _ ITocurly }                        -- special symbols
295  '}'            { L _ ITccurly }
296  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
297  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
298  '['            { L _ ITobrack }
299  ']'            { L _ ITcbrack }
300  '[:'           { L _ ITopabrack }
301  ':]'           { L _ ITcpabrack }
302  '('            { L _ IToparen }
303  ')'            { L _ ITcparen }
304  '(#'           { L _ IToubxparen }
305  '#)'           { L _ ITcubxparen }
306  '(|'           { L _ IToparenbar }
307  '|)'           { L _ ITcparenbar }
308  ';'            { L _ ITsemi }
309  ','            { L _ ITcomma }
310  '`'            { L _ ITbackquote }
311  SIMPLEQUOTE    { L _ ITsimpleQuote      }     -- 'x
312
313  VARID          { L _ (ITvarid    _) }          -- identifiers
314  CONID          { L _ (ITconid    _) }
315  VARSYM         { L _ (ITvarsym   _) }
316  CONSYM         { L _ (ITconsym   _) }
317  QVARID         { L _ (ITqvarid   _) }
318  QCONID         { L _ (ITqconid   _) }
319  QVARSYM        { L _ (ITqvarsym  _) }
320  QCONSYM        { L _ (ITqconsym  _) }
321  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
322  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
323
324  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
325
326  CHAR           { L _ (ITchar     _) }
327  STRING         { L _ (ITstring   _) }
328  INTEGER        { L _ (ITinteger  _) }
329  RATIONAL       { L _ (ITrational _) }
330                     
331  PRIMCHAR       { L _ (ITprimchar   _) }
332  PRIMSTRING     { L _ (ITprimstring _) }
333  PRIMINTEGER    { L _ (ITprimint    _) }
334  PRIMWORD       { L _ (ITprimword  _) }
335  PRIMFLOAT      { L _ (ITprimfloat  _) }
336  PRIMDOUBLE     { L _ (ITprimdouble _) }
337
338  DOCNEXT        { L _ (ITdocCommentNext _) }
339  DOCPREV        { L _ (ITdocCommentPrev _) }
340  DOCNAMED       { L _ (ITdocCommentNamed _) }
341  DOCSECTION     { L _ (ITdocSection _ _) }
342
343 -- Template Haskell 
344 '[|'            { L _ ITopenExpQuote  }       
345 '[p|'           { L _ ITopenPatQuote  }      
346 '[t|'           { L _ ITopenTypQuote  }      
347 '[d|'           { L _ ITopenDecQuote  }      
348 '|]'            { L _ ITcloseQuote    }
349 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
350 '$('            { L _ ITparenEscape   }     -- $( exp )
351 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
352 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
353
354 %monad { P } { >>= } { return }
355 %lexer { lexer } { L _ ITeof }
356 %name parseModule module
357 %name parseStmt   maybe_stmt
358 %name parseIdentifier  identifier
359 %name parseType ctype
360 %partial parseHeader header
361 %tokentype { (Located Token) }
362 %%
363
364 -----------------------------------------------------------------------------
365 -- Identifiers; one of the entry points
366 identifier :: { Located RdrName }
367         : qvar                          { $1 }
368         | qcon                          { $1 }
369         | qvarop                        { $1 }
370         | qconop                        { $1 }
371     | '(' '->' ')'      { LL $ getRdrName funTyCon }
372
373 -----------------------------------------------------------------------------
374 -- Module Header
375
376 -- The place for module deprecation is really too restrictive, but if it
377 -- was allowed at its natural place just before 'module', we get an ugly
378 -- s/r conflict with the second alternative. Another solution would be the
379 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
380 -- either, and DEPRECATED is only expected to be used by people who really
381 -- know what they are doing. :-)
382
383 module  :: { Located (HsModule RdrName) }
384         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
385                 {% fileSrcSpan >>= \ loc ->
386                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
387                           ) )}
388         | body2
389                 {% fileSrcSpan >>= \ loc ->
390                    return (L loc (HsModule Nothing Nothing
391                           (fst $1) (snd $1) Nothing Nothing
392                           )) }
393
394 maybedocheader :: { Maybe LHsDocString }
395         : moduleheader            { $1 }
396         | {- empty -}             { Nothing }
397
398 missing_module_keyword :: { () }
399         : {- empty -}                           {% pushCurrentContext }
400
401 maybemodwarning :: { Maybe WarningTxt }
402     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
403     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
404     |  {- empty -}                  { Nothing }
405
406 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
407         :  '{'            top '}'               { $2 }
408         |      vocurly    top close             { $2 }
409
410 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
411         :  '{' top '}'                          { $2 }
412         |  missing_module_keyword top close     { $2 }
413
414 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
415         : importdecls                           { (reverse $1,[]) }
416         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
417         | cvtopdecls                            { ([],$1) }
418
419 cvtopdecls :: { [LHsDecl RdrName] }
420         : topdecls                              { cvTopDecls $1 }
421
422 -----------------------------------------------------------------------------
423 -- Module declaration & imports only
424
425 header  :: { Located (HsModule RdrName) }
426         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
427                 {% fileSrcSpan >>= \ loc ->
428                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
429                           ))}
430         | header_body2
431                 {% fileSrcSpan >>= \ loc ->
432                    return (L loc (HsModule Nothing Nothing $1 [] Nothing
433                           Nothing)) }
434
435 header_body :: { [LImportDecl RdrName] }
436         :  '{'            importdecls           { $2 }
437         |      vocurly    importdecls           { $2 }
438
439 header_body2 :: { [LImportDecl RdrName] }
440         :  '{' importdecls                      { $2 }
441         |  missing_module_keyword importdecls   { $2 }
442
443 -----------------------------------------------------------------------------
444 -- The Export List
445
446 maybeexports :: { Maybe [LIE RdrName] }
447         :  '(' exportlist ')'                   { Just $2 }
448         |  {- empty -}                          { Nothing }
449
450 exportlist :: { [LIE RdrName] }
451         : expdoclist ',' expdoclist             { $1 ++ $3 }
452         | exportlist1                           { $1 }
453
454 exportlist1 :: { [LIE RdrName] }
455         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
456         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
457         | expdoclist                                   { $1 }
458
459 expdoclist :: { [LIE RdrName] }
460         : exp_doc expdoclist                           { $1 : $2 }
461         | {- empty -}                                  { [] }
462
463 exp_doc :: { LIE RdrName }                                                   
464         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
465         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
466         | docnext       { L1 (IEDoc (unLoc $1)) }       
467                        
468    -- No longer allow things like [] and (,,,) to be exported
469    -- They are built in syntax, always available
470 export  :: { LIE RdrName }
471         :  qvar                         { L1 (IEVar (unLoc $1)) }
472         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
473         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
474         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
475         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
476         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
477
478 qcnames :: { [RdrName] }
479         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
480         |  qcname_ext                   { [unLoc $1]  }
481
482 qcname_ext :: { Located RdrName }       -- Variable or data constructor
483                                         -- or tagged type constructor
484         :  qcname                       { $1 }
485         |  'type' qcon                  { sL (comb2 $1 $2) 
486                                              (setRdrNameSpace (unLoc $2) 
487                                                               tcClsName)  }
488
489 -- Cannot pull into qcname_ext, as qcname is also used in expression.
490 qcname  :: { Located RdrName }  -- Variable or data constructor
491         :  qvar                         { $1 }
492         |  qcon                         { $1 }
493
494 -----------------------------------------------------------------------------
495 -- Import Declarations
496
497 -- import decls can be *empty*, or even just a string of semicolons
498 -- whereas topdecls must contain at least one topdecl.
499
500 importdecls :: { [LImportDecl RdrName] }
501         : importdecls ';' importdecl            { $3 : $1 }
502         | importdecls ';'                       { $1 }
503         | importdecl                            { [ $1 ] }
504         | {- empty -}                           { [] }
505
506 importdecl :: { LImportDecl RdrName }
507         : 'import' maybe_src maybe_safe optqualified maybe_pkg modid maybeas maybeimpspec 
508                 { L (comb4 $1 $6 $7 $8) $
509                   ImportDecl { ideclName = $6, ideclPkgQual = $5
510                              , ideclSource = $2, ideclSafe = $3
511                              , ideclQualified = $4, ideclImplicit = False
512                              , ideclAs = unLoc $7, ideclHiding = unLoc $8 } }
513
514 maybe_src :: { IsBootInterface }
515         : '{-# SOURCE' '#-}'                    { True }
516         | {- empty -}                           { False }
517
518 maybe_safe :: { Bool }
519         : 'safe'                                { True }
520         | {- empty -}                           { False }
521
522 maybe_pkg :: { Maybe FastString }
523         : STRING                                { Just (getSTRING $1) }
524         | {- empty -}                           { Nothing }
525
526 optqualified :: { Bool }
527         : 'qualified'                           { True  }
528         | {- empty -}                           { False }
529
530 maybeas :: { Located (Maybe ModuleName) }
531         : 'as' modid                            { LL (Just (unLoc $2)) }
532         | {- empty -}                           { noLoc Nothing }
533
534 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
535         : impspec                               { L1 (Just (unLoc $1)) }
536         | {- empty -}                           { noLoc Nothing }
537
538 impspec :: { Located (Bool, [LIE RdrName]) }
539         :  '(' exportlist ')'                   { LL (False, $2) }
540         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
541
542 -----------------------------------------------------------------------------
543 -- Fixity Declarations
544
545 prec    :: { Int }
546         : {- empty -}           { 9 }
547         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
548
549 infix   :: { Located FixityDirection }
550         : 'infix'                               { L1 InfixN  }
551         | 'infixl'                              { L1 InfixL  }
552         | 'infixr'                              { L1 InfixR }
553
554 ops     :: { Located [Located RdrName] }
555         : ops ',' op                            { LL ($3 : unLoc $1) }
556         | op                                    { L1 [$1] }
557
558 -----------------------------------------------------------------------------
559 -- Top-Level Declarations
560
561 topdecls :: { OrdList (LHsDecl RdrName) }
562         : topdecls ';' topdecl                  { $1 `appOL` $3 }
563         | topdecls ';'                          { $1 }
564         | topdecl                               { $1 }
565
566 topdecl :: { OrdList (LHsDecl RdrName) }
567         : cl_decl                               { unitOL (L1 (TyClD (unLoc $1))) }
568         | ty_decl                               { unitOL (L1 (TyClD (unLoc $1))) }
569         | inst_decl                             { unitOL (L1 (InstD (unLoc $1))) }
570         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
571         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
572         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
573         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
574         | '{-# WARNING' warnings '#-}'          { $2 }
575         | '{-# RULES' rules '#-}'               { $2 }
576         | '{-# VECTORISE_SCALAR' qvar '#-}'     { unitOL $ LL $ VectD (HsVect       $2 Nothing) }
577         | '{-# VECTORISE' qvar '=' exp '#-}'    { unitOL $ LL $ VectD (HsVect       $2 (Just $4)) }
578         | '{-# NOVECTORISE' qvar '#-}'          { unitOL $ LL $ VectD (HsNoVect     $2) }
579         | '{-# VECTORISE' 'type' gtycon '#-}'     
580                                                 { unitOL $ LL $ 
581                                                     VectD (HsVectTypeIn False $3 Nothing) }
582         | '{-# VECTORISE_SCALAR' 'type' gtycon '#-}'     
583                                                 { unitOL $ LL $ 
584                                                     VectD (HsVectTypeIn True $3 Nothing) }
585         | '{-# VECTORISE' 'type' gtycon '=' gtycon '#-}'     
586                                                 { unitOL $ LL $ 
587                                                     VectD (HsVectTypeIn False $3 (Just $5)) }
588         | '{-# VECTORISE_SCALAR' 'type' gtycon '=' gtycon '#-}'     
589                                                 { unitOL $ LL $ 
590                                                     VectD (HsVectTypeIn True $3 (Just $5)) }
591         | '{-# VECTORISE' 'class' gtycon '#-}'  { unitOL $ LL $ VectD (HsVectClassIn $3) }
592         | '{-# VECTORISE_SCALAR' 'instance' type '#-}'     
593                                                 { unitOL $ LL $ VectD (HsVectInstIn $3) }
594         | annotation { unitOL $1 }
595         | decl                                  { unLoc $1 }
596
597         -- Template Haskell Extension
598         -- The $(..) form is one possible form of infixexp
599         -- but we treat an arbitrary expression just as if 
600         -- it had a $(..) wrapped around it
601         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) } 
602
603 -- Type classes
604 --
605 cl_decl :: { LTyClDecl RdrName }
606         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
607
608 -- Type declarations (toplevel)
609 --
610 ty_decl :: { LTyClDecl RdrName }
611            -- ordinary type synonyms
612         : 'type' type '=' ctypedoc
613                 -- Note ctype, not sigtype, on the right of '='
614                 -- We allow an explicit for-all but we don't insert one
615                 -- in   type Foo a = (b,b)
616                 -- Instead we just say b is out of scope
617                 --
618                 -- Note the use of type for the head; this allows
619                 -- infix type constructors to be declared 
620                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
621
622            -- type family declarations
623         | 'type' 'family' type opt_kind_sig 
624                 -- Note the use of type for the head; this allows
625                 -- infix type constructors to be declared
626                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
627
628           -- ordinary data type or newtype declaration
629         | data_or_newtype capi_ctype tycl_hdr constrs deriving
630                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) False $2 $3 
631                             Nothing (reverse (unLoc $4)) (unLoc $5) }
632                                    -- We need the location on tycl_hdr in case 
633                                    -- constrs and deriving are both empty
634
635           -- ordinary GADT declaration
636         | data_or_newtype capi_ctype tycl_hdr opt_kind_sig 
637                  gadt_constrlist
638                  deriving
639                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) False $2 $3 
640                             (unLoc $4) (unLoc $5) (unLoc $6) }
641                                    -- We need the location on tycl_hdr in case 
642                                    -- constrs and deriving are both empty
643
644           -- data/newtype family
645         | 'data' 'family' type opt_kind_sig
646                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
647
648 inst_decl :: { LInstDecl RdrName }
649         : 'instance' inst_type where_inst
650                  { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
651                    in L (comb3 $1 $2 $3) (ClsInstDecl $2 binds sigs ats) }
652
653            -- type instance declarations
654         | 'type' 'instance' type '=' ctype
655                 -- Note the use of type for the head; this allows
656                 -- infix type constructors and type patterns
657                 {% do { L loc d <- mkTySynonym (comb2 $1 $5) True $3 $5
658                       ; return (L loc (FamInstDecl d)) } }
659
660           -- data/newtype instance declaration
661         | data_or_newtype 'instance' tycl_hdr constrs deriving
662                 {% do { L loc d <- mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True Nothing $3
663                                       Nothing (reverse (unLoc $4)) (unLoc $5)
664                       ; return (L loc (FamInstDecl d)) } }
665
666           -- GADT instance declaration
667         | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
668                  gadt_constrlist
669                  deriving
670                 {% do { L loc d <- mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True Nothing $3
671                                             (unLoc $4) (unLoc $5) (unLoc $6)
672                       ; return (L loc (FamInstDecl d)) } }
673         
674 -- Associated type family declarations
675 --
676 -- * They have a different syntax than on the toplevel (no family special
677 --   identifier).
678 --
679 -- * They also need to be separate from instances; otherwise, data family
680 --   declarations without a kind signature cause parsing conflicts with empty
681 --   data declarations. 
682 --
683 at_decl_cls :: { LTyClDecl RdrName }
684            -- type family declarations
685         : 'type' type opt_kind_sig
686                 -- Note the use of type for the head; this allows
687                 -- infix type constructors to be declared.
688                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
689
690            -- default type instance
691         | 'type' type '=' ctype
692                 -- Note the use of type for the head; this allows
693                 -- infix type constructors and type patterns
694                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
695
696           -- data/newtype family declaration
697         | 'data' type opt_kind_sig
698                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
699
700 -- Associated type instances
701 --
702 at_decl_inst :: { LTyClDecl RdrName }
703            -- type instance declarations
704         : 'type' type '=' ctype
705                 -- Note the use of type for the head; this allows
706                 -- infix type constructors and type patterns
707                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
708
709         -- data/newtype instance declaration
710         | data_or_newtype capi_ctype tycl_hdr constrs deriving
711                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $2 $3 
712                             Nothing (reverse (unLoc $4)) (unLoc $5) }
713
714         -- GADT instance declaration
715         | data_or_newtype capi_ctype tycl_hdr opt_kind_sig 
716                  gadt_constrlist
717                  deriving
718                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $2 $3 
719                             (unLoc $4) (unLoc $5) (unLoc $6) }
720
721 data_or_newtype :: { Located NewOrData }
722         : 'data'        { L1 DataType }
723         | 'newtype'     { L1 NewType }
724
725 opt_kind_sig :: { Located (Maybe (LHsKind RdrName)) }
726         :                               { noLoc Nothing }
727         | '::' kind                     { LL (Just $2) }
728
729 -- tycl_hdr parses the header of a class or data type decl,
730 -- which takes the form
731 --      T a b
732 --      Eq a => T a
733 --      (Eq a, Ord b) => T a b
734 --      T Int [a]                       -- for associated types
735 -- Rather a lot of inlining here, else we get reduce/reduce errors
736 tycl_hdr :: { Located (Maybe (LHsContext RdrName), LHsType RdrName) }
737         : context '=>' type             { LL (Just $1, $3) }
738         | type                          { L1 (Nothing, $1) }
739
740 capi_ctype :: { Maybe CType }
741 capi_ctype : '{-# CTYPE' STRING STRING '#-}' { Just (CType (Just (Header (getSTRING $2))) (getSTRING $3)) }
742            | '{-# CTYPE'        STRING '#-}' { Just (CType Nothing                        (getSTRING $2)) }
743            |                                 { Nothing }
744
745 -----------------------------------------------------------------------------
746 -- Stand-alone deriving
747
748 -- Glasgow extension: stand-alone deriving declarations
749 stand_alone_deriving :: { LDerivDecl RdrName }
750         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
751
752 -----------------------------------------------------------------------------
753 -- Nested declarations
754
755 -- Declaration in class bodies
756 --
757 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
758 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
759           | decl                        { $1 }
760
761           -- A 'default' signature used with the generic-programming extension
762           | 'default' infixexp '::' sigtypedoc
763                     {% do { (TypeSig l ty) <- checkValSig $2 $4
764                           ; return (LL $ unitOL (LL $ SigD (GenericSig l ty))) } }
765
766 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
767           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
768           | decls_cls ';'               { LL (unLoc $1) }
769           | decl_cls                    { $1 }
770           | {- empty -}                 { noLoc nilOL }
771
772
773 decllist_cls
774         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
775         : '{'         decls_cls '}'     { LL (unLoc $2) }
776         |     vocurly decls_cls close   { $2 }
777
778 -- Class body
779 --
780 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
781                                 -- No implicit parameters
782                                 -- May have type declarations
783         : 'where' decllist_cls          { LL (unLoc $2) }
784         | {- empty -}                   { noLoc nilOL }
785
786 -- Declarations in instance bodies
787 --
788 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
789 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
790            | decl                       { $1 }
791
792 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
793            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
794            | decls_inst ';'             { LL (unLoc $1) }
795            | decl_inst                  { $1 }
796            | {- empty -}                { noLoc nilOL }
797
798 decllist_inst 
799         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
800         : '{'         decls_inst '}'    { LL (unLoc $2) }
801         |     vocurly decls_inst close  { $2 }
802
803 -- Instance body
804 --
805 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
806                                 -- No implicit parameters
807                                 -- May have type declarations
808         : 'where' decllist_inst         { LL (unLoc $2) }
809         | {- empty -}                   { noLoc nilOL }
810
811 -- Declarations in binding groups other than classes and instances
812 --
813 decls   :: { Located (OrdList (LHsDecl RdrName)) }      
814         : decls ';' decl                { let { this = unLoc $3;
815                                     rest = unLoc $1;
816                                     these = rest `appOL` this }
817                               in rest `seq` this `seq` these `seq`
818                                     LL these }
819         | decls ';'                     { LL (unLoc $1) }
820         | decl                          { $1 }
821         | {- empty -}                   { noLoc nilOL }
822
823 decllist :: { Located (OrdList (LHsDecl RdrName)) }
824         : '{'            decls '}'      { LL (unLoc $2) }
825         |     vocurly    decls close    { $2 }
826
827 -- Binding groups other than those of class and instance declarations
828 --
829 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
830                                                 -- No type declarations
831         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
832         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
833         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
834
835 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
836                                                 -- No type declarations
837         : 'where' binds                 { LL (unLoc $2) }
838         | {- empty -}                   { noLoc emptyLocalBinds }
839
840
841 -----------------------------------------------------------------------------
842 -- Transformation Rules
843
844 rules   :: { OrdList (LHsDecl RdrName) }
845         :  rules ';' rule                       { $1 `snocOL` $3 }
846         |  rules ';'                            { $1 }
847         |  rule                                 { unitOL $1 }
848         |  {- empty -}                          { nilOL }
849
850 rule    :: { LHsDecl RdrName }
851         : STRING activation rule_forall infixexp '=' exp
852              { LL $ RuleD (HsRule (getSTRING $1) 
853                                   ($2 `orElse` AlwaysActive) 
854                                   $3 $4 placeHolderNames $6 placeHolderNames) }
855
856 activation :: { Maybe Activation } 
857         : {- empty -}                           { Nothing }
858         | explicit_activation                   { Just $1 }
859
860 explicit_activation :: { Activation }  -- In brackets
861         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
862         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
863
864 rule_forall :: { [RuleBndr RdrName] }
865         : 'forall' rule_var_list '.'            { $2 }
866         | {- empty -}                           { [] }
867
868 rule_var_list :: { [RuleBndr RdrName] }
869         : rule_var                              { [$1] }
870         | rule_var rule_var_list                { $1 : $2 }
871
872 rule_var :: { RuleBndr RdrName }
873         : varid                                 { RuleBndr $1 }
874         | '(' varid '::' ctype ')'              { RuleBndrSig $2 (HsBSig $4 placeHolderBndrs) }
875
876 -----------------------------------------------------------------------------
877 -- Warnings and deprecations (c.f. rules)
878
879 warnings :: { OrdList (LHsDecl RdrName) }
880         : warnings ';' warning          { $1 `appOL` $3 }
881         | warnings ';'                  { $1 }
882         | warning                               { $1 }
883         | {- empty -}                           { nilOL }
884
885 -- SUP: TEMPORARY HACK, not checking for `module Foo'
886 warning :: { OrdList (LHsDecl RdrName) }
887         : namelist strings
888                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
889                        | n <- unLoc $1 ] }
890
891 deprecations :: { OrdList (LHsDecl RdrName) }
892         : deprecations ';' deprecation          { $1 `appOL` $3 }
893         | deprecations ';'                      { $1 }
894         | deprecation                           { $1 }
895         | {- empty -}                           { nilOL }
896
897 -- SUP: TEMPORARY HACK, not checking for `module Foo'
898 deprecation :: { OrdList (LHsDecl RdrName) }
899         : namelist strings
900                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
901                        | n <- unLoc $1 ] }
902
903 strings :: { Located [FastString] }
904     : STRING { L1 [getSTRING $1] }
905     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
906
907 stringlist :: { Located (OrdList FastString) }
908     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
909     | STRING                { LL (unitOL (getSTRING $1)) }
910
911 -----------------------------------------------------------------------------
912 -- Annotations
913 annotation :: { LHsDecl RdrName }
914     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
915     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
916     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
917
918
919 -----------------------------------------------------------------------------
920 -- Foreign import and export declarations
921
922 fdecl :: { LHsDecl RdrName }
923 fdecl : 'import' callconv safety fspec
924                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
925       | 'import' callconv        fspec          
926                 {% do { d <- mkImport $2 PlaySafe (unLoc $3);
927                         return (LL d) } }
928       | 'export' callconv fspec
929                 {% mkExport $2 (unLoc $3) >>= return.LL }
930
931 callconv :: { CCallConv }
932           : 'stdcall'                   { StdCallConv }
933           | 'ccall'                     { CCallConv   }
934           | 'capi'                      { CApiConv    }
935           | 'prim'                      { PrimCallConv}
936
937 safety :: { Safety }
938         : 'unsafe'                      { PlayRisky }
939         | 'safe'                        { PlaySafe }
940         | 'interruptible'               { PlayInterruptible }
941
942 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
943        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
944        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
945          -- if the entity string is missing, it defaults to the empty string;
946          -- the meaning of an empty entity string depends on the calling
947          -- convention
948
949 -----------------------------------------------------------------------------
950 -- Type signatures
951
952 opt_sig :: { Maybe (LHsType RdrName) }
953         : {- empty -}                   { Nothing }
954         | '::' sigtype                  { Just $2 }
955
956 opt_asig :: { Maybe (LHsType RdrName) }
957         : {- empty -}                   { Nothing }
958         | '::' atype                    { Just $2 }
959
960 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
961                                         -- to tell the renamer where to generalise
962         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
963         -- Wrap an Implicit forall if there isn't one there already
964
965 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
966         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
967         -- Wrap an Implicit forall if there isn't one there already
968
969 sig_vars :: { Located [Located RdrName] }
970          : sig_vars ',' var             { LL ($3 : unLoc $1) }
971          | var                          { L1 [$1] }
972
973 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
974         : sigtype                       { [ $1 ] }
975         | sigtype ',' sigtypes1         { $1 : $3 }
976
977 -----------------------------------------------------------------------------
978 -- Types
979
980 infixtype :: { LHsType RdrName }
981         : btype qtyconop type         { LL $ mkHsOpTy $1 $2 $3 }
982         | btype tyvarop  type    { LL $ mkHsOpTy $1 $2 $3 }
983
984 strict_mark :: { Located HsBang }
985         : '!'                           { L1 HsStrict }
986         | '{-# UNPACK' '#-}' '!'        { LL HsUnpack }
987         | '{-# NOUNPACK' '#-}' '!'      { LL HsNoUnpack }
988
989 -- A ctype is a for-all type
990 ctype   :: { LHsType RdrName }
991         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
992         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
993         -- A type of form (context => type) is an *implicit* HsForAllTy
994         | ipvar '::' type               { LL (HsIParamTy (unLoc $1) $3) }
995         | type                          { $1 }
996
997 ----------------------
998 -- Notes for 'ctypedoc'
999 -- It would have been nice to simplify the grammar by unifying `ctype` and 
1000 -- ctypedoc` into one production, allowing comments on types everywhere (and
1001 -- rejecting them after parsing, where necessary).  This is however not possible
1002 -- since it leads to ambiguity. The reason is the support for comments on record
1003 -- fields: 
1004 --         data R = R { field :: Int -- ^ comment on the field }
1005 -- If we allow comments on types here, it's not clear if the comment applies
1006 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
1007
1008 ctypedoc :: { LHsType RdrName }
1009         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
1010         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
1011         -- A type of form (context => type) is an *implicit* HsForAllTy
1012         | ipvar '::' type               { LL (HsIParamTy (unLoc $1) $3) }
1013         | typedoc                       { $1 }
1014
1015 ----------------------
1016 -- Notes for 'context'
1017 -- We parse a context as a btype so that we don't get reduce/reduce
1018 -- errors in ctype.  The basic problem is that
1019 --      (Eq a, Ord a)
1020 -- looks so much like a tuple type.  We can't tell until we find the =>
1021
1022 -- We have the t1 ~ t2 form both in 'context' and in type, 
1023 -- to permit an individual equational constraint without parenthesis.
1024 -- Thus for some reason we allow    f :: a~b => blah
1025 -- but not                          f :: ?x::Int => blah
1026 context :: { LHsContext RdrName }
1027         : btype '~'      btype          {% checkContext
1028                                              (LL $ HsEqTy $1 $3) }
1029         | btype                         {% checkContext $1 }
1030
1031 type :: { LHsType RdrName }
1032         : btype                         { $1 }
1033         | btype qtyconop type           { LL $ mkHsOpTy $1 $2 $3 }
1034         | btype tyvarop  type           { LL $ mkHsOpTy $1 $2 $3 }
1035         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
1036         | btype '~'      btype          { LL $ HsEqTy $1 $3 }
1037                                         -- see Note [Promotion]
1038         | btype SIMPLEQUOTE qconop type     { LL $ mkHsOpTy $1 $3 $4 }
1039         | btype SIMPLEQUOTE varop  type     { LL $ mkHsOpTy $1 $3 $4 }
1040
1041 typedoc :: { LHsType RdrName }
1042         : btype                          { $1 }
1043         | btype docprev                  { LL $ HsDocTy $1 $2 }
1044         | btype qtyconop type            { LL $ mkHsOpTy $1 $2 $3 }
1045         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (mkHsOpTy $1 $2 $3)) $4 }
1046         | btype tyvarop  type            { LL $ mkHsOpTy $1 $2 $3 }
1047         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (mkHsOpTy $1 $2 $3)) $4 }
1048         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
1049         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
1050         | btype '~'      btype           { LL $ HsEqTy $1 $3 }
1051
1052 btype :: { LHsType RdrName }
1053         : btype atype                   { LL $ HsAppTy $1 $2 }
1054         | atype                         { $1 }
1055
1056 atype :: { LHsType RdrName }
1057         : ntgtycon                       { L1 (HsTyVar (unLoc $1)) }      -- Not including unit tuples
1058         | tyvar                          { L1 (HsTyVar (unLoc $1)) }      -- (See Note [Unit tuples])
1059         | strict_mark atype              { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1060         | '{' fielddecls '}'             {% checkRecordSyntax (LL $ HsRecTy $2) } -- Constructor sigs only
1061         | '(' ')'                        { LL $ HsTupleTy HsBoxedOrConstraintTuple []      }
1062         | '(' ctype ',' comma_types1 ')' { LL $ HsTupleTy HsBoxedOrConstraintTuple ($2:$4) }
1063         | '(#' '#)'                      { LL $ HsTupleTy HsUnboxedTuple           []      }       
1064         | '(#' comma_types1 '#)'         { LL $ HsTupleTy HsUnboxedTuple           $2      }
1065         | '[' ctype ']'                  { LL $ HsListTy  $2 }
1066         | '[:' ctype ':]'                { LL $ HsPArrTy  $2 }
1067         | '(' ctype ')'                  { LL $ HsParTy   $2 }
1068         | '(' ctype '::' kind ')'        { LL $ HsKindSig $2 $4 }
1069         | quasiquote                     { L1 (HsQuasiQuoteTy (unLoc $1)) }
1070         | '$(' exp ')'                   { LL $ mkHsSpliceTy $2 }
1071         | TH_ID_SPLICE                   { LL $ mkHsSpliceTy $ L1 $ HsVar $
1072                                            mkUnqual varName (getTH_ID_SPLICE $1) }
1073                                                       -- see Note [Promotion] for the followings
1074         | SIMPLEQUOTE qconid                          { LL $ HsTyVar $ unLoc $2 }
1075         | SIMPLEQUOTE  '(' ')'                        { LL $ HsTyVar $ getRdrName unitDataCon }
1076         | SIMPLEQUOTE  '(' ctype ',' comma_types1 ')' { LL $ HsExplicitTupleTy [] ($3 : $5) }
1077         | SIMPLEQUOTE  '[' comma_types0 ']'           { LL $ HsExplicitListTy placeHolderKind $3 }
1078         | '[' ctype ',' comma_types1 ']'              { LL $ HsExplicitListTy placeHolderKind ($2 : $4) }
1079
1080 -- An inst_type is what occurs in the head of an instance decl
1081 --      e.g.  (Foo a, Gaz b) => Wibble a b
1082 -- It's kept as a single type, with a MonoDictTy at the right
1083 -- hand corner, for convenience.
1084 inst_type :: { LHsType RdrName }
1085         : sigtype                       { $1 }
1086
1087 inst_types1 :: { [LHsType RdrName] }
1088         : inst_type                     { [$1] }
1089         | inst_type ',' inst_types1     { $1 : $3 }
1090
1091 comma_types0  :: { [LHsType RdrName] }
1092         : comma_types1                  { $1 }
1093         | {- empty -}                   { [] }
1094
1095 comma_types1    :: { [LHsType RdrName] }
1096         : ctype                         { [$1] }
1097         | ctype  ',' comma_types1       { $1 : $3 }
1098
1099 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1100          : tv_bndr tv_bndrs             { $1 : $2 }
1101          | {- empty -}                  { [] }
1102
1103 tv_bndr :: { LHsTyVarBndr RdrName }
1104         : tyvar                         { L1 (UserTyVar (unLoc $1) placeHolderKind) }
1105         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) (HsBSig $4 placeHolderBndrs) placeHolderKind) }
1106
1107 fds :: { Located [Located (FunDep RdrName)] }
1108         : {- empty -}                   { noLoc [] }
1109         | '|' fds1                      { LL (reverse (unLoc $2)) }
1110
1111 fds1 :: { Located [Located (FunDep RdrName)] }
1112         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1113         | fd                            { L1 [$1] }
1114
1115 fd :: { Located (FunDep RdrName) }
1116         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1117                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1118
1119 varids0 :: { Located [RdrName] }
1120         : {- empty -}                   { noLoc [] }
1121         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1122
1123 -----------------------------------------------------------------------------
1124 -- Kinds
1125
1126 kind :: { LHsKind RdrName }
1127         : bkind                  { $1 }
1128         | bkind '->' kind        { LL $ HsFunTy $1 $3 }
1129
1130 bkind :: { LHsKind RdrName }
1131         : akind                  { $1 }
1132         | bkind akind            { LL $ HsAppTy $1 $2 }
1133
1134 akind :: { LHsKind RdrName }
1135         : '*'                    { L1 $ HsTyVar (nameRdrName liftedTypeKindTyConName) }
1136         | '(' kind ')'           { LL $ HsParTy $2 }
1137         | pkind                  { $1 }
1138         | tyvar                  { L1 $ HsTyVar (unLoc $1) }
1139
1140 pkind :: { LHsKind RdrName }  -- promoted type, see Note [Promotion]
1141         : qtycon                          { L1 $ HsTyVar $ unLoc $1 }
1142         | '(' ')'                         { LL $ HsTyVar $ getRdrName unitTyCon }
1143         | '(' kind ',' comma_kinds1 ')'   { LL $ HsTupleTy HsBoxedTuple ($2 : $4) }
1144         | '[' kind ']'                    { LL $ HsListTy $2 }
1145
1146 comma_kinds1 :: { [LHsKind RdrName] }
1147         : kind                          { [$1] }
1148         | kind  ',' comma_kinds1        { $1 : $3 }
1149
1150 {- Note [Promotion]
1151    ~~~~~~~~~~~~~~~~
1152
1153 - Syntax of promoted qualified names
1154 We write 'Nat.Zero instead of Nat.'Zero when dealing with qualified
1155 names. Moreover ticks are only allowed in types, not in kinds, for a
1156 few reasons:
1157   1. we don't need quotes since we cannot define names in kinds
1158   2. if one day we merge types and kinds, tick would mean look in DataName
1159   3. we don't have a kind namespace anyway
1160
1161 - Syntax of explicit kind polymorphism  (IA0_TODO: not yet implemented)
1162 Kind abstraction is implicit. We write
1163 > data SList (s :: k -> *) (as :: [k]) where ...
1164 because it looks like what we do in terms
1165 > id (x :: a) = x
1166
1167 - Name resolution
1168 When the user write Zero instead of 'Zero in types, we parse it a
1169 HsTyVar ("Zero", TcClsName) instead of HsTyVar ("Zero", DataName). We
1170 deal with this in the renamer. If a HsTyVar ("Zero", TcClsName) is not
1171 bounded in the type level, then we look for it in the term level (we
1172 change its namespace to DataName, see Note [Demotion] in OccName). And
1173 both become a HsTyVar ("Zero", DataName) after the renamer.
1174
1175 -}
1176
1177
1178 -----------------------------------------------------------------------------
1179 -- Datatype declarations
1180
1181 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1182         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1183         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1184         | {- empty -}                              { noLoc [] }
1185
1186 gadt_constrs :: { Located [LConDecl RdrName] }
1187         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1188         | gadt_constr                   { L (getLoc (head $1)) $1 }
1189         | {- empty -}                   { noLoc [] }
1190
1191 -- We allow the following forms:
1192 --      C :: Eq a => a -> T a
1193 --      C :: forall a. Eq a => !a -> T a
1194 --      D { x,y :: a } :: T a
1195 --      forall a. Eq a => D { x,y :: a } :: T a
1196
1197 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1198         : con_list '::' sigtype
1199                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) } 
1200
1201                 -- Deprecated syntax for GADT record declarations
1202         | oqtycon '{' fielddecls '}' '::' sigtype
1203                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1204                       ; cd' <- checkRecordSyntax cd
1205                       ; return [cd'] } }
1206
1207 constrs :: { Located [LConDecl RdrName] }
1208         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1209
1210 constrs1 :: { Located [LConDecl RdrName] }
1211         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1212         | constr                                          { L1 [$1] }
1213
1214 constr :: { LConDecl RdrName }
1215         : maybe_docnext forall context '=>' constr_stuff maybe_docprev  
1216                 { let (con,details) = unLoc $5 in 
1217                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1218                             ($1 `mplus` $6) }
1219         | maybe_docnext forall constr_stuff maybe_docprev
1220                 { let (con,details) = unLoc $3 in 
1221                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1222                             ($1 `mplus` $4) }
1223
1224 forall :: { Located [LHsTyVarBndr RdrName] }
1225         : 'forall' tv_bndrs '.'         { LL $2 }
1226         | {- empty -}                   { noLoc [] }
1227
1228 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1229 -- We parse the constructor declaration 
1230 --      C t1 t2
1231 -- as a btype (treating C as a type constructor) and then convert C to be
1232 -- a data constructor.  Reason: it might continue like this:
1233 --      C t1 t2 %: D Int
1234 -- in which case C really would be a type constructor.  We can't resolve this
1235 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1236         : btype                         {% splitCon $1 >>= return.LL }
1237         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1238
1239 fielddecls :: { [ConDeclField RdrName] }
1240         : {- empty -}     { [] }
1241         | fielddecls1     { $1 }
1242
1243 fielddecls1 :: { [ConDeclField RdrName] }
1244         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1245                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1246                              -- This adds the doc $4 to each field separately
1247         | fielddecl   { $1 }
1248
1249 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1250         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5) 
1251                                                                  | fld <- reverse (unLoc $2) ] }
1252
1253 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1254 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1255 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1256 -- We don't allow a context, but that's sorted out by the type checker.
1257 deriving :: { Located (Maybe [LHsType RdrName]) }
1258         : {- empty -}                           { noLoc Nothing }
1259         | 'deriving' qtycon                     { let { L loc tv = $2 }
1260                                                   in LL (Just [L loc (HsTyVar tv)]) } 
1261         | 'deriving' '(' ')'                    { LL (Just []) }
1262         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1263              -- Glasgow extension: allow partial 
1264              -- applications in derivings
1265
1266 -----------------------------------------------------------------------------
1267 -- Value definitions
1268
1269 {- Note [Declaration/signature overlap]
1270 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1271 There's an awkward overlap with a type signature.  Consider
1272         f :: Int -> Int = ...rhs...
1273    Then we can't tell whether it's a type signature or a value
1274    definition with a result signature until we see the '='.
1275    So we have to inline enough to postpone reductions until we know.
1276 -}
1277
1278 {-
1279   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1280   instead of qvar, we get another shift/reduce-conflict. Consider the
1281   following programs:
1282   
1283      { (^^) :: Int->Int ; }          Type signature; only var allowed
1284
1285      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1286                                      qvar allowed (because of instance decls)
1287   
1288   We can't tell whether to reduce var to qvar until after we've read the signatures.
1289 -}
1290
1291 docdecl :: { LHsDecl RdrName }
1292         : docdecld { L1 (DocD (unLoc $1)) }
1293
1294 docdecld :: { LDocDecl }
1295         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1296         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1297         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1298         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1299
1300 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1301         : sigdecl               { $1 }
1302
1303         | '!' aexp rhs          {% do { let { e = LL (SectionR (LL (HsVar bang_RDR)) $2) };
1304                                         pat <- checkPattern e;
1305                                         return $ LL $ unitOL $ LL $ ValD $
1306                                                PatBind pat (unLoc $3)
1307                                                        placeHolderType placeHolderNames (Nothing,[]) } }
1308                                 -- Turn it all into an expression so that
1309                                 -- checkPattern can check that bangs are enabled
1310
1311         | infixexp opt_sig rhs  {% do { r <- checkValDef $1 $2 $3;
1312                                         let { l = comb2 $1 $> };
1313                                         return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1314         | docdecl               { LL $ unitOL $1 }
1315
1316 rhs     :: { Located (GRHSs RdrName) }
1317         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1318         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1319
1320 gdrhs :: { Located [LGRHS RdrName] }
1321         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1322         | gdrh                  { L1 [$1] }
1323
1324 gdrh :: { LGRHS RdrName }
1325         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1326
1327 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1328         : 
1329         -- See Note [Declaration/signature overlap] for why we need infixexp here
1330           infixexp '::' sigtypedoc
1331                         {% do s <- checkValSig $1 $3 
1332                         ; return (LL $ unitOL (LL $ SigD s)) }
1333         | var ',' sig_vars '::' sigtypedoc
1334                                 { LL $ toOL [ LL $ SigD (TypeSig ($1 : unLoc $3) $5) ] }
1335         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1336                                              | n <- unLoc $3 ] }
1337         | '{-# INLINE' activation qvar '#-}'        
1338                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma (getINLINE $1) $2))) }
1339         | '{-# SPECIALISE' activation qvar '::' sigtypes1 '#-}'
1340                 { let inl_prag = mkInlinePragma (EmptyInlineSpec, FunLike) $2
1341                   in LL $ toOL [ LL $ SigD (SpecSig $3 t inl_prag) 
1342                                | t <- $5] }
1343         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1344                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma (getSPEC_INLINE $1) $2))
1345                             | t <- $5] }
1346         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1347                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1348
1349 -----------------------------------------------------------------------------
1350 -- Expressions
1351
1352 quasiquote :: { Located (HsQuasiQuote RdrName) }
1353         : TH_QUASIQUOTE   { let { loc = getLoc $1
1354                                 ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1355                                 ; quoterId = mkUnqual varName quoter }
1356                             in L1 (mkHsQuasiQuote quoterId (RealSrcSpan quoteSpan) quote) }
1357
1358 exp   :: { LHsExpr RdrName }
1359         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1360         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1361         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1362         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1363         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1364         | infixexp                      { $1 }
1365
1366 infixexp :: { LHsExpr RdrName }
1367         : exp10                         { $1 }
1368         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1369
1370 exp10 :: { LHsExpr RdrName }
1371         : '\\' apat apats opt_asig '->' exp     
1372                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1373                                                                 (unguardedGRHSs $6)
1374                                                             ]) }
1375         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1376         | 'if' exp optSemi 'then' exp optSemi 'else' exp
1377                                         {% checkDoAndIfThenElse $2 $3 $5 $6 $8 >>
1378                                            return (LL $ mkHsIf $2 $5 $8) }
1379         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1380         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1381
1382         | 'do' stmtlist                 { L (comb2 $1 $2) (mkHsDo DoExpr  (unLoc $2)) }
1383         | 'mdo' stmtlist                { L (comb2 $1 $2) (mkHsDo MDoExpr (unLoc $2)) }
1384
1385         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1386                                                         then HsSCC (unLoc $1) $2
1387                                                         else HsPar $2 }
1388         | hpc_annot exp                         { LL $ if opt_Hpc
1389                                                         then HsTickPragma (unLoc $1) $2
1390                                                         else HsPar $2 }
1391
1392         | 'proc' aexp '->' exp  
1393                         {% checkPattern $2 >>= \ p -> 
1394                            return (LL $ HsProc p (LL $ HsCmdTop $4 [] 
1395                                                    placeHolderType undefined)) }
1396                                                 -- TODO: is LL right here?
1397
1398         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1399                                                     -- hdaume: core annotation
1400         | fexp                                  { $1 }
1401
1402 optSemi :: { Bool }
1403         : ';'         { True }
1404         | {- empty -} { False }
1405
1406 scc_annot :: { Located FastString }
1407         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1408                                    ( do scc <- getSCC $2; return $ LL scc ) }
1409         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1410         | '{-# SCC' VARID  '#-}'                { LL (getVARID $2) }
1411
1412 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1413         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1414                                                 { LL $ (getSTRING $2
1415                                                        ,( fromInteger $ getINTEGER $3
1416                                                         , fromInteger $ getINTEGER $5
1417                                                         )
1418                                                        ,( fromInteger $ getINTEGER $7
1419                                                         , fromInteger $ getINTEGER $9
1420                                                         )
1421                                                        )
1422                                                  }
1423
1424 fexp    :: { LHsExpr RdrName }
1425         : fexp aexp                             { LL $ HsApp $1 $2 }
1426         | aexp                                  { $1 }
1427
1428 aexp    :: { LHsExpr RdrName }
1429         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1430         | '~' aexp                      { LL $ ELazyPat $2 }
1431         | aexp1                 { $1 }
1432
1433 aexp1   :: { LHsExpr RdrName }
1434         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1435                                       ; checkRecordSyntax (LL r) }}
1436         | aexp2                 { $1 }
1437
1438 aexp2   :: { LHsExpr RdrName }
1439         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1440         | qcname                        { L1 (HsVar   $! unLoc $1) }
1441         | literal                       { L1 (HsLit   $! unLoc $1) }
1442 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1443 -- into HsOverLit when -foverloaded-strings is on.
1444 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1445         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1446         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1447
1448         -- N.B.: sections get parsed by these next two productions.
1449         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't
1450         -- correct Haskell (you'd have to write '((+ 3), (4 -))')
1451         -- but the less cluttered version fell out of having texps.
1452         | '(' texp ')'                  { LL (HsPar $2) }
1453         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1454
1455         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1456         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1457
1458         | '[' list ']'                  { LL (unLoc $2) }
1459         | '[:' parr ':]'                { LL (unLoc $2) }
1460         | '_'                           { L1 EWildPat }
1461         
1462         -- Template Haskell Extension
1463         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice 
1464                                         (L1 $ HsVar (mkUnqual varName 
1465                                                         (getTH_ID_SPLICE $1)))) } 
1466         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               
1467
1468
1469         | SIMPLEQUOTE  qvar     { LL $ HsBracket (VarBr True  (unLoc $2)) }
1470         | SIMPLEQUOTE  qcon     { LL $ HsBracket (VarBr True  (unLoc $2)) }
1471         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr False (unLoc $2)) }
1472         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr False (unLoc $2)) }
1473         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }                       
1474         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }                       
1475         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1476                                         return (LL $ HsBracket (PatBr p)) }
1477         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBrL $2) }
1478         | quasiquote            { L1 (HsQuasiQuoteE (unLoc $1)) }
1479
1480         -- arrow notation extension
1481         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1482
1483 cmdargs :: { [LHsCmdTop RdrName] }
1484         : cmdargs acmd                  { $2 : $1 }
1485         | {- empty -}                   { [] }
1486
1487 acmd    :: { LHsCmdTop RdrName }
1488         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1489
1490 cvtopbody :: { [LHsDecl RdrName] }
1491         :  '{'            cvtopdecls0 '}'               { $2 }
1492         |      vocurly    cvtopdecls0 close             { $2 }
1493
1494 cvtopdecls0 :: { [LHsDecl RdrName] }
1495         : {- empty -}           { [] }
1496         | cvtopdecls            { $1 }
1497
1498 -----------------------------------------------------------------------------
1499 -- Tuple expressions
1500
1501 -- "texp" is short for tuple expressions: 
1502 -- things that can appear unparenthesized as long as they're
1503 -- inside parens or delimitted by commas
1504 texp :: { LHsExpr RdrName }
1505         : exp                           { $1 }
1506
1507         -- Note [Parsing sections]
1508         -- ~~~~~~~~~~~~~~~~~~~~~~~
1509         -- We include left and right sections here, which isn't
1510         -- technically right according to the Haskell standard.
1511         -- For example (3 +, True) isn't legal.
1512         -- However, we want to parse bang patterns like
1513         --      (!x, !y)
1514         -- and it's convenient to do so here as a section
1515         -- Then when converting expr to pattern we unravel it again
1516         -- Meanwhile, the renamer checks that real sections appear
1517         -- inside parens.
1518         | infixexp qop        { LL $ SectionL $1 $2 }
1519         | qopm infixexp       { LL $ SectionR $1 $2 }
1520
1521        -- View patterns get parenthesized above
1522         | exp '->' texp   { LL $ EViewPat $1 $3 }
1523
1524 -- Always at least one comma
1525 tup_exprs :: { [HsTupArg RdrName] }
1526            : texp commas_tup_tail  { Present $1 : $2 }
1527            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1528
1529 -- Always starts with commas; always follows an expr
1530 commas_tup_tail :: { [HsTupArg RdrName] }
1531 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1532
1533 -- Always follows a comma
1534 tup_tail :: { [HsTupArg RdrName] }
1535           : texp commas_tup_tail        { Present $1 : $2 }
1536           | texp                        { [Present $1] }
1537           | {- empty -}                 { [missingTupArg] }
1538
1539 -----------------------------------------------------------------------------
1540 -- List expressions
1541
1542 -- The rules below are little bit contorted to keep lexps left-recursive while
1543 -- avoiding another shift/reduce-conflict.
1544
1545 list :: { LHsExpr RdrName }
1546         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1547         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1548         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1549         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1550         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1551         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1552         | texp '|' flattenedpquals      
1553              {% checkMonadComp >>= \ ctxt ->
1554                 return (sL (comb2 $1 $>) $ 
1555                         mkHsComp ctxt (unLoc $3) $1) }
1556
1557 lexps :: { Located [LHsExpr RdrName] }
1558         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1559         | texp ',' texp                 { LL [$3,$1] }
1560
1561 -----------------------------------------------------------------------------
1562 -- List Comprehensions
1563
1564 flattenedpquals :: { Located [LStmt RdrName] }
1565     : pquals   { case (unLoc $1) of
1566                     [qs] -> L1 qs
1567                     -- We just had one thing in our "parallel" list so 
1568                     -- we simply return that thing directly
1569                     
1570                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss] noSyntaxExpr noSyntaxExpr noSyntaxExpr]
1571                     -- We actually found some actual parallel lists so
1572                     -- we wrap them into as a ParStmt
1573                 }
1574
1575 pquals :: { Located [[LStmt RdrName]] }
1576     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1577     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1578
1579 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last 
1580                                         -- one can "grab" the earlier ones
1581     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1582     | squals ',' qual                        { LL ($3 : unLoc $1) }
1583     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1584     | qual                                   { L1 [$1] }
1585 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1586 --  | '{|' pquals '|}'                       { L1 [$2] }
1587
1588
1589 -- It is possible to enable bracketing (associating) qualifier lists
1590 -- by uncommenting the lines with {| |} above. Due to a lack of
1591 -- consensus on the syntax, this feature is not being used until we
1592 -- get user demand.
1593
1594 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1595                         -- Function is applied to a list of stmts *in order*
1596     : 'then' exp                           { LL $ \ss -> (mkTransformStmt    ss $2)    }
1597     | 'then' exp 'by' exp                  { LL $ \ss -> (mkTransformByStmt  ss $2 $4) }
1598     | 'then' 'group' 'using' exp           { LL $ \ss -> (mkGroupUsingStmt   ss $4)    }
1599     | 'then' 'group' 'by' exp 'using' exp  { LL $ \ss -> (mkGroupByUsingStmt ss $4 $6) }
1600
1601 -- Note that 'group' is a special_id, which means that you can enable
1602 -- TransformListComp while still using Data.List.group. However, this
1603 -- introduces a shift/reduce conflict. Happy chooses to resolve the conflict
1604 -- in by choosing the "group by" variant, which is what we want.
1605
1606 -----------------------------------------------------------------------------
1607 -- Parallel array expressions
1608
1609 -- The rules below are little bit contorted; see the list case for details.
1610 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1611 -- Moreover, we allow explicit arrays with no element (represented by the nil
1612 -- constructor in the list case).
1613
1614 parr :: { LHsExpr RdrName }
1615         :                               { noLoc (ExplicitPArr placeHolderType []) }
1616         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1617         | lexps                         { L1 $ ExplicitPArr placeHolderType 
1618                                                        (reverse (unLoc $1)) }
1619         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1620         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1621         | texp '|' flattenedpquals      { LL $ mkHsComp PArrComp (unLoc $3) $1 }
1622
1623 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1624
1625 -----------------------------------------------------------------------------
1626 -- Guards
1627
1628 guardquals :: { Located [LStmt RdrName] }
1629     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1630
1631 guardquals1 :: { Located [LStmt RdrName] }
1632     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1633     | qual                  { L1 [$1] }
1634
1635 -----------------------------------------------------------------------------
1636 -- Case alternatives
1637
1638 altslist :: { Located [LMatch RdrName] }
1639         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1640         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1641
1642 alts    :: { Located [LMatch RdrName] }
1643         : alts1                         { L1 (unLoc $1) }
1644         | ';' alts                      { LL (unLoc $2) }
1645
1646 alts1   :: { Located [LMatch RdrName] }
1647         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1648         | alts1 ';'                     { LL (unLoc $1) }
1649         | alt                           { L1 [$1] }
1650
1651 alt     :: { LMatch RdrName }
1652         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1653
1654 alt_rhs :: { Located (GRHSs RdrName) }
1655         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1656
1657 ralt :: { Located [LGRHS RdrName] }
1658         : '->' exp                      { LL (unguardedRHS $2) }
1659         | gdpats                        { L1 (reverse (unLoc $1)) }
1660
1661 gdpats :: { Located [LGRHS RdrName] }
1662         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1663         | gdpat                         { L1 [$1] }
1664
1665 gdpat   :: { LGRHS RdrName }
1666         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1667
1668 -- 'pat' recognises a pattern, including one with a bang at the top
1669 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1670 -- Bangs inside are parsed as infix operator applications, so that
1671 -- we parse them right when bang-patterns are off
1672 pat     :: { LPat RdrName }
1673 pat     :  exp                  {% checkPattern $1 }
1674         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1675
1676 apat   :: { LPat RdrName }      
1677 apat    : aexp                  {% checkPattern $1 }
1678         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1679
1680 apats  :: { [LPat RdrName] }
1681         : apat apats            { $1 : $2 }
1682         | {- empty -}           { [] }
1683
1684 -----------------------------------------------------------------------------
1685 -- Statement sequences
1686
1687 stmtlist :: { Located [LStmt RdrName] }
1688         : '{'           stmts '}'       { LL (unLoc $2) }
1689         |     vocurly   stmts close     { $2 }
1690
1691 --      do { ;; s ; s ; ; s ;; }
1692 -- The last Stmt should be an expression, but that's hard to enforce
1693 -- here, because we need too much lookahead if we see do { e ; }
1694 -- So we use ExprStmts throughout, and switch the last one over
1695 -- in ParseUtils.checkDo instead
1696 stmts :: { Located [LStmt RdrName] }
1697         : stmt stmts_help               { LL ($1 : unLoc $2) }
1698         | ';' stmts                     { LL (unLoc $2) }
1699         | {- empty -}                   { noLoc [] }
1700
1701 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1702         : ';' stmts                     { LL (unLoc $2) }
1703         | {- empty -}                   { noLoc [] }
1704
1705 -- For typing stmts at the GHCi prompt, where 
1706 -- the input may consist of just comments.
1707 maybe_stmt :: { Maybe (LStmt RdrName) }
1708         : stmt                          { Just $1 }
1709         | {- nothing -}                 { Nothing }
1710
1711 stmt  :: { LStmt RdrName }
1712         : qual                              { $1 }
1713         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1714
1715 qual  :: { LStmt RdrName }
1716     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1717     | exp                                   { L1 $ mkExprStmt $1 }
1718     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1719
1720 -----------------------------------------------------------------------------
1721 -- Record Field Update/Construction
1722
1723 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1724         : fbinds1                       { $1 }
1725         | {- empty -}                   { ([], False) }
1726
1727 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1728         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) } 
1729         | fbind                         { ([$1], False) }
1730         | '..'                          { ([],   True) }
1731   
1732 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1733         : qvar '=' exp  { HsRecField $1 $3                False }
1734         | qvar          { HsRecField $1 placeHolderPunRhs True }
1735                         -- In the punning case, use a place-holder
1736                         -- The renamer fills in the final value
1737
1738 -----------------------------------------------------------------------------
1739 -- Implicit Parameter Bindings
1740
1741 dbinds  :: { Located [LIPBind RdrName] }
1742         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1743                               in rest `seq` this `seq` LL (this : rest) }
1744         | dbinds ';'                    { LL (unLoc $1) }
1745         | dbind                         { let this = $1 in this `seq` L1 [this] }
1746 --      | {- empty -}                   { [] }
1747
1748 dbind   :: { LIPBind RdrName }
1749 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1750
1751 ipvar   :: { Located (IPName RdrName) }
1752         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1753
1754 -----------------------------------------------------------------------------
1755 -- Warnings and deprecations
1756
1757 namelist :: { Located [RdrName] }
1758 namelist : name_var              { L1 [unLoc $1] }
1759          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1760
1761 name_var :: { Located RdrName }
1762 name_var : var { $1 }
1763          | con { $1 }
1764
1765 -----------------------------------------
1766 -- Data constructors
1767 qcon    :: { Located RdrName }
1768         : qconid                { $1 }
1769         | '(' qconsym ')'       { LL (unLoc $2) }
1770         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1771 -- The case of '[:' ':]' is part of the production `parr'
1772
1773 con     :: { Located RdrName }
1774         : conid                 { $1 }
1775         | '(' consym ')'        { LL (unLoc $2) }
1776         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1777
1778 con_list :: { Located [Located RdrName] }
1779 con_list : con                  { L1 [$1] }
1780          | con ',' con_list     { LL ($1 : unLoc $3) }
1781
1782 sysdcon :: { Located DataCon }  -- Wired in data constructors
1783         : '(' ')'               { LL unitDataCon }
1784         | '(' commas ')'        { LL $ tupleCon BoxedTuple ($2 + 1) }
1785         | '(#' '#)'             { LL $ unboxedUnitDataCon }
1786         | '(#' commas '#)'      { LL $ tupleCon UnboxedTuple ($2 + 1) }
1787         | '[' ']'               { LL nilDataCon }
1788
1789 conop :: { Located RdrName }
1790         : consym                { $1 }  
1791         | '`' conid '`'         { LL (unLoc $2) }
1792
1793 qconop :: { Located RdrName }
1794         : qconsym               { $1 }
1795         | '`' qconid '`'        { LL (unLoc $2) }
1796
1797 ----------------------------------------------------------------------------
1798 -- Type constructors
1799
1800
1801 -- See Note [Unit tuples] in HsTypes for the distinction 
1802 -- between gtycon and ntgtycon
1803 gtycon :: { Located RdrName }  -- A "general" qualified tycon, including unit tuples
1804         : ntgtycon                      { $1 }
1805         | '(' ')'                       { LL $ getRdrName unitTyCon }
1806         | '(#' '#)'                     { LL $ getRdrName unboxedUnitTyCon }
1807
1808 ntgtycon :: { Located RdrName }  -- A "general" qualified tycon, excluding unit tuples
1809         : oqtycon                       { $1 }
1810         | '(' commas ')'                { LL $ getRdrName (tupleTyCon BoxedTuple ($2 + 1)) }
1811         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon UnboxedTuple ($2 + 1)) }
1812         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1813         | '[' ']'                       { LL $ listTyCon_RDR }
1814         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1815         | '(' '~#' ')'                  { LL $ getRdrName eqPrimTyCon }
1816
1817 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon;
1818                                 -- These can appear in export lists
1819         : qtycon                        { $1 }
1820         | '(' qtyconsym ')'             { LL (unLoc $2) }
1821         | '(' '~' ')'                   { LL $ eqTyCon_RDR }
1822
1823 qtyconop :: { Located RdrName } -- Qualified or unqualified
1824         : qtyconsym                     { $1 }
1825         | '`' qtycon '`'                { LL (unLoc $2) }
1826
1827 qtycon :: { Located RdrName }   -- Qualified or unqualified
1828         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1829         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1830         | tycon                         { $1 }
1831
1832 tycon   :: { Located RdrName }  -- Unqualified
1833         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1834
1835 qtyconsym :: { Located RdrName }
1836         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1837         | tyconsym                      { $1 }
1838
1839 tyconsym :: { Located RdrName }
1840         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1841
1842 -----------------------------------------------------------------------------
1843 -- Operators
1844
1845 op      :: { Located RdrName }   -- used in infix decls
1846         : varop                 { $1 }
1847         | conop                 { $1 }
1848
1849 varop   :: { Located RdrName }
1850         : varsym                { $1 }
1851         | '`' varid '`'         { LL (unLoc $2) }
1852
1853 qop     :: { LHsExpr RdrName }   -- used in sections
1854         : qvarop                { L1 $ HsVar (unLoc $1) }
1855         | qconop                { L1 $ HsVar (unLoc $1) }
1856
1857 qopm    :: { LHsExpr RdrName }   -- used in sections
1858         : qvaropm               { L1 $ HsVar (unLoc $1) }
1859         | qconop                { L1 $ HsVar (unLoc $1) }
1860
1861 qvarop :: { Located RdrName }
1862         : qvarsym               { $1 }
1863         | '`' qvarid '`'        { LL (unLoc $2) }
1864
1865 qvaropm :: { Located RdrName }
1866         : qvarsym_no_minus      { $1 }
1867         | '`' qvarid '`'        { LL (unLoc $2) }
1868
1869 -----------------------------------------------------------------------------
1870 -- Type variables
1871
1872 tyvar   :: { Located RdrName }
1873 tyvar   : tyvarid               { $1 }
1874         | '(' tyvarsym ')'      { LL (unLoc $2) }
1875
1876 tyvarop :: { Located RdrName }
1877 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1878         | tyvarsym              { $1 }
1879         | '.'                   {% parseErrorSDoc (getLoc $1) 
1880                                       (vcat [ptext (sLit "Illegal symbol '.' in type"), 
1881                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1882                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1883                                 }
1884
1885 tyvarid :: { Located RdrName }
1886         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1887         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1888         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1889         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1890         | 'interruptible'       { L1 $! mkUnqual tvName (fsLit "interruptible") }
1891
1892 tyvarsym :: { Located RdrName }
1893 -- Does not include "!", because that is used for strictness marks
1894 --               or ".", because that separates the quantified type vars from the rest
1895 --               or "*", because that's used for kinds
1896 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1897
1898 -----------------------------------------------------------------------------
1899 -- Variables 
1900
1901 var     :: { Located RdrName }
1902         : varid                 { $1 }
1903         | '(' varsym ')'        { LL (unLoc $2) }
1904
1905 qvar    :: { Located RdrName }
1906         : qvarid                { $1 }
1907         | '(' varsym ')'        { LL (unLoc $2) }
1908         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1909 -- We've inlined qvarsym here so that the decision about
1910 -- whether it's a qvar or a var can be postponed until
1911 -- *after* we see the close paren.
1912
1913 qvarid :: { Located RdrName }
1914         : varid                 { $1 }
1915         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1916         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1917
1918 varid :: { Located RdrName }
1919         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1920         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1921         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1922         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1923         | 'interruptible'       { L1 $! mkUnqual varName (fsLit "interruptible") }
1924         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1925         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1926
1927 qvarsym :: { Located RdrName }
1928         : varsym                { $1 }
1929         | qvarsym1              { $1 }
1930
1931 qvarsym_no_minus :: { Located RdrName }
1932         : varsym_no_minus       { $1 }
1933         | qvarsym1              { $1 }
1934
1935 qvarsym1 :: { Located RdrName }
1936 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1937
1938 varsym :: { Located RdrName }
1939         : varsym_no_minus       { $1 }
1940         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1941
1942 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1943         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1944         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1945
1946
1947 -- These special_ids are treated as keywords in various places, 
1948 -- but as ordinary ids elsewhere.   'special_id' collects all these
1949 -- except 'unsafe', 'interruptible', 'forall', and 'family' whose treatment differs
1950 -- depending on context 
1951 special_id :: { Located FastString }
1952 special_id
1953         : 'as'                  { L1 (fsLit "as") }
1954         | 'qualified'           { L1 (fsLit "qualified") }
1955         | 'hiding'              { L1 (fsLit "hiding") }
1956         | 'export'              { L1 (fsLit "export") }
1957         | 'label'               { L1 (fsLit "label")  }
1958         | 'dynamic'             { L1 (fsLit "dynamic") }
1959         | 'stdcall'             { L1 (fsLit "stdcall") }
1960         | 'ccall'               { L1 (fsLit "ccall") }
1961         | 'capi'                { L1 (fsLit "capi") }
1962         | 'prim'                { L1 (fsLit "prim") }
1963         | 'group'               { L1 (fsLit "group") }
1964
1965 special_sym :: { Located FastString }
1966 special_sym : '!'       { L1 (fsLit "!") }
1967             | '.'       { L1 (fsLit ".") }
1968             | '*'       { L1 (fsLit "*") }
1969
1970 -----------------------------------------------------------------------------
1971 -- Data constructors
1972
1973 qconid :: { Located RdrName }   -- Qualified or unqualified
1974         : conid                 { $1 }
1975         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1976         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1977
1978 conid   :: { Located RdrName }
1979         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1980
1981 qconsym :: { Located RdrName }  -- Qualified or unqualified
1982         : consym                { $1 }
1983         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1984
1985 consym :: { Located RdrName }
1986         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1987
1988         -- ':' means only list cons
1989         | ':'                   { L1 $ consDataCon_RDR }
1990
1991
1992 -----------------------------------------------------------------------------
1993 -- Literals
1994
1995 literal :: { Located HsLit }
1996         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1997         | STRING                { L1 $ HsString     $ getSTRING $1 }
1998         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1999         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
2000         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
2001         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
2002         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
2003         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
2004
2005 -----------------------------------------------------------------------------
2006 -- Layout
2007
2008 close :: { () }
2009         : vccurly               { () } -- context popped in lexer.
2010         | error                 {% popContext }
2011
2012 -----------------------------------------------------------------------------
2013 -- Miscellaneous (mostly renamings)
2014
2015 modid   :: { Located ModuleName }
2016         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
2017         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
2018                                   mkModuleNameFS
2019                                    (mkFastString
2020                                      (unpackFS mod ++ '.':unpackFS c))
2021                                 }
2022
2023 commas :: { Int }
2024         : commas ','                    { $1 + 1 }
2025         | ','                           { 1 }
2026
2027 -----------------------------------------------------------------------------
2028 -- Documentation comments
2029
2030 docnext :: { LHsDocString }
2031   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
2032
2033 docprev :: { LHsDocString }
2034   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
2035
2036 docnamed :: { Located (String, HsDocString) }
2037   : DOCNAMED {%
2038       let string = getDOCNAMED $1 
2039           (name, rest) = break isSpace string
2040       in return (L1 (name, HsDocString (mkFastString rest))) }
2041
2042 docsection :: { Located (Int, HsDocString) }
2043   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
2044         return (L1 (n, HsDocString (mkFastString doc))) }
2045
2046 moduleheader :: { Maybe LHsDocString }
2047         : DOCNEXT {% let string = getDOCNEXT $1 in
2048                      return (Just (L1 (HsDocString (mkFastString string)))) }
2049
2050 maybe_docprev :: { Maybe LHsDocString }
2051         : docprev                       { Just $1 }
2052         | {- empty -}                   { Nothing }
2053
2054 maybe_docnext :: { Maybe LHsDocString }
2055         : docnext                       { Just $1 }
2056         | {- empty -}                   { Nothing }
2057
2058 {
2059 happyError :: P a
2060 happyError = srcParseFail
2061
2062 getVARID        (L _ (ITvarid    x)) = x
2063 getCONID        (L _ (ITconid    x)) = x
2064 getVARSYM       (L _ (ITvarsym   x)) = x
2065 getCONSYM       (L _ (ITconsym   x)) = x
2066 getQVARID       (L _ (ITqvarid   x)) = x
2067 getQCONID       (L _ (ITqconid   x)) = x
2068 getQVARSYM      (L _ (ITqvarsym  x)) = x
2069 getQCONSYM      (L _ (ITqconsym  x)) = x
2070 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
2071 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
2072 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
2073 getCHAR         (L _ (ITchar     x)) = x
2074 getSTRING       (L _ (ITstring   x)) = x
2075 getINTEGER      (L _ (ITinteger  x)) = x
2076 getRATIONAL     (L _ (ITrational x)) = x
2077 getPRIMCHAR     (L _ (ITprimchar   x)) = x
2078 getPRIMSTRING   (L _ (ITprimstring x)) = x
2079 getPRIMINTEGER  (L _ (ITprimint    x)) = x
2080 getPRIMWORD     (L _ (ITprimword x)) = x
2081 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
2082 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
2083 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
2084 getINLINE       (L _ (ITinline_prag inl conl)) = (inl,conl)
2085 getSPEC_INLINE  (L _ (ITspec_inline_prag True))  = (Inline,  FunLike)
2086 getSPEC_INLINE  (L _ (ITspec_inline_prag False)) = (NoInline,FunLike)
2087
2088 getDOCNEXT (L _ (ITdocCommentNext x)) = x
2089 getDOCPREV (L _ (ITdocCommentPrev x)) = x
2090 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
2091 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
2092
2093 getSCC :: Located Token -> P FastString
2094 getSCC lt = do let s = getSTRING lt
2095                    err = "Spaces are not allowed in SCCs"
2096                -- We probably actually want to be more restrictive than this
2097                if ' ' `elem` unpackFS s
2098                    then failSpanMsgP (getLoc lt) (text err)
2099                    else return s
2100
2101 -- Utilities for combining source spans
2102 comb2 :: Located a -> Located b -> SrcSpan
2103 comb2 a b = a `seq` b `seq` combineLocs a b
2104
2105 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2106 comb3 a b c = a `seq` b `seq` c `seq`
2107     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2108
2109 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2110 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2111     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2112                 combineSrcSpans (getLoc c) (getLoc d))
2113
2114 -- strict constructor version:
2115 {-# INLINE sL #-}
2116 sL :: SrcSpan -> a -> Located a
2117 sL span a = span `seq` a `seq` L span a
2118
2119 -- Make a source location for the file.  We're a bit lazy here and just
2120 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2121 -- try to find the span of the whole file (ToDo).
2122 fileSrcSpan :: P SrcSpan
2123 fileSrcSpan = do 
2124   l <- getSrcLoc; 
2125   let loc = mkSrcLoc (srcLocFile l) 1 1;
2126   return (mkSrcSpan loc loc)
2127 }