3b39320381af9acb81d422b538d0a3b1247ca182
[ghc.git] / compiler / coreSyn / CoreSubst.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 Utility functions on @Core@ syntax
7
8 \begin{code}
9 {-# OPTIONS -fno-warn-tabs #-}
10 -- The above warning supression flag is a temporary kludge.
11 -- While working on this module you are encouraged to remove it and
12 -- detab the module (please do the detabbing in a separate patch). See
13 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
14 -- for details
15
16 module CoreSubst (
17         -- * Main data types
18         Subst(..), -- Implementation exported for supercompiler's Renaming.hs only
19         TvSubstEnv, IdSubstEnv, InScopeSet,
20
21         -- ** Substituting into expressions and related types
22         deShadowBinds, substSpec, substRulesForImportedIds,
23         substTy, substCo, substExpr, substExprSC, substBind, substBindSC,
24         substUnfolding, substUnfoldingSC,
25         lookupIdSubst, lookupTvSubst, lookupCvSubst, substIdOcc,
26         substTickish,
27
28         -- ** Operations on substitutions
29         emptySubst, mkEmptySubst, mkSubst, mkOpenSubst, substInScope, isEmptySubst, 
30         extendIdSubst, extendIdSubstList, extendTvSubst, extendTvSubstList,
31         extendCvSubst, extendCvSubstList,
32         extendSubst, extendSubstList, extendSubstWithVar, zapSubstEnv,
33         addInScopeSet, extendInScope, extendInScopeList, extendInScopeIds,
34         isInScope, setInScope,
35         delBndr, delBndrs,
36
37         -- ** Substituting and cloning binders
38         substBndr, substBndrs, substRecBndrs,
39         cloneBndr, cloneBndrs, cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs,
40
41         -- ** Simple expression optimiser
42         simpleOptPgm, simpleOptExpr, simpleOptExprWith,
43         exprIsConApp_maybe, exprIsLiteral_maybe
44     ) where
45
46 #include "HsVersions.h"
47
48 import CoreSyn
49 import CoreFVs
50 import CoreUtils
51 import Literal  ( Literal )
52 import OccurAnal( occurAnalyseExpr, occurAnalysePgm )
53
54 import qualified Type
55 import qualified Coercion
56
57         -- We are defining local versions
58 import Type     hiding ( substTy, extendTvSubst, extendTvSubstList
59                        , isInScope, substTyVarBndr, cloneTyVarBndr )
60 import Coercion hiding ( substTy, substCo, extendTvSubst, substTyVarBndr, substCoVarBndr )
61
62 import TyCon       ( tyConArity )
63 import DataCon
64 import PrelNames   ( eqBoxDataConKey )
65 import OptCoercion ( optCoercion )
66 import PprCore     ( pprCoreBindings, pprRules )
67 import Module      ( Module )
68 import VarSet
69 import VarEnv
70 import Id
71 import Name     ( Name )
72 import Var
73 import IdInfo
74 import Unique
75 import UniqSupply
76 import Maybes
77 import ErrUtils
78 import DynFlags
79 import BasicTypes ( isAlwaysActive )
80 import Util
81 import Pair
82 import Outputable
83 import PprCore          ()              -- Instances
84 import FastString
85
86 import Data.List
87 \end{code}
88
89
90 %************************************************************************
91 %*                                                                      *
92 \subsection{Substitutions}
93 %*                                                                      *
94 %************************************************************************
95
96 \begin{code}
97 -- | A substitution environment, containing both 'Id' and 'TyVar' substitutions.
98 --
99 -- Some invariants apply to how you use the substitution:
100 --
101 -- 1. #in_scope_invariant# The in-scope set contains at least those 'Id's and 'TyVar's that will be in scope /after/
102 -- applying the substitution to a term. Precisely, the in-scope set must be a superset of the free vars of the
103 -- substitution range that might possibly clash with locally-bound variables in the thing being substituted in.
104 --
105 -- 2. #apply_once# You may apply the substitution only /once/
106 --
107 -- There are various ways of setting up the in-scope set such that the first of these invariants hold:
108 --
109 -- * Arrange that the in-scope set really is all the things in scope
110 --
111 -- * Arrange that it's the free vars of the range of the substitution
112 --
113 -- * Make it empty, if you know that all the free vars of the substitution are fresh, and hence can't possibly clash
114 data Subst 
115   = Subst InScopeSet  -- Variables in in scope (both Ids and TyVars) /after/
116                       -- applying the substitution
117           IdSubstEnv  -- Substitution for Ids
118           TvSubstEnv  -- Substitution from TyVars to Types
119           CvSubstEnv  -- Substitution from CoVars to Coercions
120
121         -- INVARIANT 1: See #in_scope_invariant#
122         -- This is what lets us deal with name capture properly
123         -- It's a hard invariant to check...
124         --
125         -- INVARIANT 2: The substitution is apply-once; see Note [Apply once] with
126         --              Types.TvSubstEnv
127         --
128         -- INVARIANT 3: See Note [Extending the Subst]
129 \end{code}
130
131 Note [Extending the Subst]
132 ~~~~~~~~~~~~~~~~~~~~~~~~~~
133 For a core Subst, which binds Ids as well, we make a different choice for Ids
134 than we do for TyVars.  
135
136 For TyVars, see Note [Extending the TvSubst] with Type.TvSubstEnv
137
138 For Ids, we have a different invariant
139         The IdSubstEnv is extended *only* when the Unique on an Id changes
140         Otherwise, we just extend the InScopeSet
141
142 In consequence:
143
144 * If the TvSubstEnv and IdSubstEnv are both empty, substExpr would be a
145   no-op, so substExprSC ("short cut") does nothing.
146
147   However, substExpr still goes ahead and substitutes.  Reason: we may
148   want to replace existing Ids with new ones from the in-scope set, to
149   avoid space leaks.
150
151 * In substIdBndr, we extend the IdSubstEnv only when the unique changes
152
153 * If the CvSubstEnv, TvSubstEnv and IdSubstEnv are all empty,
154   substExpr does nothing (Note that the above rule for substIdBndr
155   maintains this property.  If the incoming envts are both empty, then
156   substituting the type and IdInfo can't change anything.)
157
158 * In lookupIdSubst, we *must* look up the Id in the in-scope set, because
159   it may contain non-trivial changes.  Example:
160         (/\a. \x:a. ...x...) Int
161   We extend the TvSubstEnv with [a |-> Int]; but x's unique does not change
162   so we only extend the in-scope set.  Then we must look up in the in-scope
163   set when we find the occurrence of x.
164
165 * The requirement to look up the Id in the in-scope set means that we
166   must NOT take no-op short cut when the IdSubst is empty.
167   We must still look up every Id in the in-scope set.
168
169 * (However, we don't need to do so for expressions found in the IdSubst
170   itself, whose range is assumed to be correct wrt the in-scope set.)
171
172 Why do we make a different choice for the IdSubstEnv than the
173 TvSubstEnv and CvSubstEnv?
174
175 * For Ids, we change the IdInfo all the time (e.g. deleting the
176   unfolding), and adding it back later, so using the TyVar convention
177   would entail extending the substitution almost all the time
178
179 * The simplifier wants to look up in the in-scope set anyway, in case it 
180   can see a better unfolding from an enclosing case expression
181
182 * For TyVars, only coercion variables can possibly change, and they are 
183   easy to spot
184
185 \begin{code}
186 -- | An environment for substituting for 'Id's
187 type IdSubstEnv = IdEnv CoreExpr
188
189 ----------------------------
190 isEmptySubst :: Subst -> Bool
191 isEmptySubst (Subst _ id_env tv_env cv_env) 
192   = isEmptyVarEnv id_env && isEmptyVarEnv tv_env && isEmptyVarEnv cv_env
193
194 emptySubst :: Subst
195 emptySubst = Subst emptyInScopeSet emptyVarEnv emptyVarEnv emptyVarEnv
196
197 mkEmptySubst :: InScopeSet -> Subst
198 mkEmptySubst in_scope = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
199
200 mkSubst :: InScopeSet -> TvSubstEnv -> CvSubstEnv -> IdSubstEnv -> Subst
201 mkSubst in_scope tvs cvs ids = Subst in_scope ids tvs cvs
202
203 -- | Find the in-scope set: see "CoreSubst#in_scope_invariant"
204 substInScope :: Subst -> InScopeSet
205 substInScope (Subst in_scope _ _ _) = in_scope
206
207 -- | Remove all substitutions for 'Id's and 'Var's that might have been built up
208 -- while preserving the in-scope set
209 zapSubstEnv :: Subst -> Subst
210 zapSubstEnv (Subst in_scope _ _ _) = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
211
212 -- | Add a substitution for an 'Id' to the 'Subst': you must ensure that the in-scope set is
213 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
214 extendIdSubst :: Subst -> Id -> CoreExpr -> Subst
215 -- ToDo: add an ASSERT that fvs(subst-result) is already in the in-scope set
216 extendIdSubst (Subst in_scope ids tvs cvs) v r = Subst in_scope (extendVarEnv ids v r) tvs cvs
217
218 -- | Adds multiple 'Id' substitutions to the 'Subst': see also 'extendIdSubst'
219 extendIdSubstList :: Subst -> [(Id, CoreExpr)] -> Subst
220 extendIdSubstList (Subst in_scope ids tvs cvs) prs = Subst in_scope (extendVarEnvList ids prs) tvs cvs
221
222 -- | Add a substitution for a 'TyVar' to the 'Subst': you must ensure that the in-scope set is
223 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
224 extendTvSubst :: Subst -> TyVar -> Type -> Subst
225 extendTvSubst (Subst in_scope ids tvs cvs) v r = Subst in_scope ids (extendVarEnv tvs v r) cvs
226
227 -- | Adds multiple 'TyVar' substitutions to the 'Subst': see also 'extendTvSubst'
228 extendTvSubstList :: Subst -> [(TyVar,Type)] -> Subst
229 extendTvSubstList (Subst in_scope ids tvs cvs) prs = Subst in_scope ids (extendVarEnvList tvs prs) cvs
230
231 -- | Add a substitution from a 'CoVar' to a 'Coercion' to the 'Subst': you must ensure that the in-scope set is
232 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
233 extendCvSubst :: Subst -> CoVar -> Coercion -> Subst
234 extendCvSubst (Subst in_scope ids tvs cvs) v r = Subst in_scope ids tvs (extendVarEnv cvs v r)
235
236 -- | Adds multiple 'CoVar' -> 'Coercion' substitutions to the
237 -- 'Subst': see also 'extendCvSubst'
238 extendCvSubstList :: Subst -> [(CoVar,Coercion)] -> Subst
239 extendCvSubstList (Subst in_scope ids tvs cvs) prs = Subst in_scope ids tvs (extendVarEnvList cvs prs)
240
241 -- | Add a substitution appropriate to the thing being substituted
242 --   (whether an expression, type, or coercion). See also
243 --   'extendIdSubst', 'extendTvSubst', and 'extendCvSubst'.
244 extendSubst :: Subst -> Var -> CoreArg -> Subst
245 extendSubst subst var arg
246   = case arg of
247       Type ty     -> ASSERT( isTyVar var ) extendTvSubst subst var ty
248       Coercion co -> ASSERT( isCoVar var ) extendCvSubst subst var co
249       _           -> ASSERT( isId    var ) extendIdSubst subst var arg
250
251 extendSubstWithVar :: Subst -> Var -> Var -> Subst
252 extendSubstWithVar subst v1 v2
253   | isTyVar v1 = ASSERT( isTyVar v2 ) extendTvSubst subst v1 (mkTyVarTy v2)
254   | isCoVar v1 = ASSERT( isCoVar v2 ) extendCvSubst subst v1 (mkCoVarCo v2)
255   | otherwise  = ASSERT( isId    v2 ) extendIdSubst subst v1 (Var v2)
256
257 -- | Add a substitution as appropriate to each of the terms being
258 --   substituted (whether expressions, types, or coercions). See also
259 --   'extendSubst'.
260 extendSubstList :: Subst -> [(Var,CoreArg)] -> Subst
261 extendSubstList subst []              = subst
262 extendSubstList subst ((var,rhs):prs) = extendSubstList (extendSubst subst var rhs) prs
263
264 -- | Find the substitution for an 'Id' in the 'Subst'
265 lookupIdSubst :: SDoc -> Subst -> Id -> CoreExpr
266 lookupIdSubst doc (Subst in_scope ids _ _) v
267   | not (isLocalId v) = Var v
268   | Just e  <- lookupVarEnv ids       v = e
269   | Just v' <- lookupInScope in_scope v = Var v'
270         -- Vital! See Note [Extending the Subst]
271   | otherwise = WARN( True, ptext (sLit "CoreSubst.lookupIdSubst") <+> doc <+> ppr v 
272                             $$ ppr in_scope) 
273                 Var v
274
275 -- | Find the substitution for a 'TyVar' in the 'Subst'
276 lookupTvSubst :: Subst -> TyVar -> Type
277 lookupTvSubst (Subst _ _ tvs _) v = ASSERT( isTyVar v) lookupVarEnv tvs v `orElse` Type.mkTyVarTy v
278
279 -- | Find the coercion substitution for a 'CoVar' in the 'Subst'
280 lookupCvSubst :: Subst -> CoVar -> Coercion
281 lookupCvSubst (Subst _ _ _ cvs) v = ASSERT( isCoVar v ) lookupVarEnv cvs v `orElse` mkCoVarCo v
282
283 delBndr :: Subst -> Var -> Subst
284 delBndr (Subst in_scope ids tvs cvs) v
285   | isCoVar v = Subst in_scope ids tvs (delVarEnv cvs v)
286   | isTyVar v = Subst in_scope ids (delVarEnv tvs v) cvs
287   | otherwise = Subst in_scope (delVarEnv ids v) tvs cvs
288
289 delBndrs :: Subst -> [Var] -> Subst
290 delBndrs (Subst in_scope ids tvs cvs) vs
291   = Subst in_scope (delVarEnvList ids vs) (delVarEnvList tvs vs) (delVarEnvList cvs vs)
292       -- Easiest thing is just delete all from all!
293
294 -- | Simultaneously substitute for a bunch of variables
295 --   No left-right shadowing
296 --   ie the substitution for   (\x \y. e) a1 a2
297 --      so neither x nor y scope over a1 a2
298 mkOpenSubst :: InScopeSet -> [(Var,CoreArg)] -> Subst
299 mkOpenSubst in_scope pairs = Subst in_scope
300                                    (mkVarEnv [(id,e)  | (id, e) <- pairs, isId id])
301                                    (mkVarEnv [(tv,ty) | (tv, Type ty) <- pairs])
302                                    (mkVarEnv [(v,co)  | (v, Coercion co) <- pairs])
303
304 ------------------------------
305 isInScope :: Var -> Subst -> Bool
306 isInScope v (Subst in_scope _ _ _) = v `elemInScopeSet` in_scope
307
308 -- | Add the 'Var' to the in-scope set, but do not remove
309 -- any existing substitutions for it
310 addInScopeSet :: Subst -> VarSet -> Subst
311 addInScopeSet (Subst in_scope ids tvs cvs) vs
312   = Subst (in_scope `extendInScopeSetSet` vs) ids tvs cvs
313
314 -- | Add the 'Var' to the in-scope set: as a side effect,
315 -- and remove any existing substitutions for it
316 extendInScope :: Subst -> Var -> Subst
317 extendInScope (Subst in_scope ids tvs cvs) v
318   = Subst (in_scope `extendInScopeSet` v) 
319           (ids `delVarEnv` v) (tvs `delVarEnv` v) (cvs `delVarEnv` v)
320
321 -- | Add the 'Var's to the in-scope set: see also 'extendInScope'
322 extendInScopeList :: Subst -> [Var] -> Subst
323 extendInScopeList (Subst in_scope ids tvs cvs) vs
324   = Subst (in_scope `extendInScopeSetList` vs) 
325           (ids `delVarEnvList` vs) (tvs `delVarEnvList` vs) (cvs `delVarEnvList` vs)
326
327 -- | Optimized version of 'extendInScopeList' that can be used if you are certain 
328 -- all the things being added are 'Id's and hence none are 'TyVar's or 'CoVar's
329 extendInScopeIds :: Subst -> [Id] -> Subst
330 extendInScopeIds (Subst in_scope ids tvs cvs) vs 
331   = Subst (in_scope `extendInScopeSetList` vs) 
332           (ids `delVarEnvList` vs) tvs cvs
333
334 setInScope :: Subst -> InScopeSet -> Subst
335 setInScope (Subst _ ids tvs cvs) in_scope = Subst in_scope ids tvs cvs
336 \end{code}
337
338 Pretty printing, for debugging only
339
340 \begin{code}
341 instance Outputable Subst where
342   ppr (Subst in_scope ids tvs cvs) 
343         =  ptext (sLit "<InScope =") <+> braces (fsep (map ppr (varEnvElts (getInScopeVars in_scope))))
344         $$ ptext (sLit " IdSubst   =") <+> ppr ids
345         $$ ptext (sLit " TvSubst   =") <+> ppr tvs
346         $$ ptext (sLit " CvSubst   =") <+> ppr cvs   
347          <> char '>'
348 \end{code}
349
350
351 %************************************************************************
352 %*                                                                      *
353         Substituting expressions
354 %*                                                                      *
355 %************************************************************************
356
357 \begin{code}
358 -- | Apply a substititon to an entire 'CoreExpr'. Rememeber, you may only 
359 -- apply the substitution /once/: see "CoreSubst#apply_once"
360 --
361 -- Do *not* attempt to short-cut in the case of an empty substitution!
362 -- See Note [Extending the Subst]
363 substExprSC :: SDoc -> Subst -> CoreExpr -> CoreExpr
364 substExprSC _doc subst orig_expr
365   | isEmptySubst subst = orig_expr
366   | otherwise          = -- pprTrace "enter subst-expr" (doc $$ ppr orig_expr) $
367                          subst_expr subst orig_expr
368
369 substExpr :: SDoc -> Subst -> CoreExpr -> CoreExpr
370 substExpr _doc subst orig_expr = subst_expr subst orig_expr
371
372 subst_expr :: Subst -> CoreExpr -> CoreExpr
373 subst_expr subst expr
374   = go expr
375   where
376     go (Var v)         = lookupIdSubst (text "subst_expr") subst v 
377     go (Type ty)       = Type (substTy subst ty)
378     go (Coercion co)   = Coercion (substCo subst co)
379     go (Lit lit)       = Lit lit
380     go (App fun arg)   = App (go fun) (go arg)
381     go (Tick tickish e) = Tick (substTickish subst tickish) (go e)
382     go (Cast e co)     = Cast (go e) (substCo subst co)
383        -- Do not optimise even identity coercions
384        -- Reason: substitution applies to the LHS of RULES, and
385        --         if you "optimise" an identity coercion, you may
386        --         lose a binder. We optimise the LHS of rules at
387        --         construction time
388
389     go (Lam bndr body) = Lam bndr' (subst_expr subst' body)
390                        where
391                          (subst', bndr') = substBndr subst bndr
392
393     go (Let bind body) = Let bind' (subst_expr subst' body)
394                        where
395                          (subst', bind') = substBind subst bind
396
397     go (Case scrut bndr ty alts) = Case (go scrut) bndr' (substTy subst ty) (map (go_alt subst') alts)
398                                  where
399                                  (subst', bndr') = substBndr subst bndr
400
401     go_alt subst (con, bndrs, rhs) = (con, bndrs', subst_expr subst' rhs)
402                                  where
403                                    (subst', bndrs') = substBndrs subst bndrs
404
405 -- | Apply a substititon to an entire 'CoreBind', additionally returning an updated 'Subst'
406 -- that should be used by subsequent substitutons.
407 substBind, substBindSC :: Subst -> CoreBind -> (Subst, CoreBind)
408
409 substBindSC subst bind    -- Short-cut if the substitution is empty
410   | not (isEmptySubst subst)
411   = substBind subst bind
412   | otherwise
413   = case bind of
414        NonRec bndr rhs -> (subst', NonRec bndr' rhs)
415           where
416             (subst', bndr') = substBndr subst bndr
417        Rec pairs -> (subst', Rec (bndrs' `zip` rhss'))
418           where
419             (bndrs, rhss)    = unzip pairs
420             (subst', bndrs') = substRecBndrs subst bndrs
421             rhss' | isEmptySubst subst' = rhss
422                   | otherwise           = map (subst_expr subst') rhss
423
424 substBind subst (NonRec bndr rhs) = (subst', NonRec bndr' (subst_expr subst rhs))
425                                   where
426                                     (subst', bndr') = substBndr subst bndr
427
428 substBind subst (Rec pairs) = (subst', Rec (bndrs' `zip` rhss'))
429                             where
430                                 (bndrs, rhss)    = unzip pairs
431                                 (subst', bndrs') = substRecBndrs subst bndrs
432                                 rhss' = map (subst_expr subst') rhss
433 \end{code}
434
435 \begin{code}
436 -- | De-shadowing the program is sometimes a useful pre-pass. It can be done simply
437 -- by running over the bindings with an empty substitution, because substitution
438 -- returns a result that has no-shadowing guaranteed.
439 --
440 -- (Actually, within a single /type/ there might still be shadowing, because 
441 -- 'substTy' is a no-op for the empty substitution, but that's probably OK.)
442 --
443 -- [Aug 09] This function is not used in GHC at the moment, but seems so 
444 --          short and simple that I'm going to leave it here
445 deShadowBinds :: CoreProgram -> CoreProgram
446 deShadowBinds binds = snd (mapAccumL substBind emptySubst binds)
447 \end{code}
448
449
450 %************************************************************************
451 %*                                                                      *
452         Substituting binders
453 %*                                                                      *
454 %************************************************************************
455
456 Remember that substBndr and friends are used when doing expression
457 substitution only.  Their only business is substitution, so they
458 preserve all IdInfo (suitably substituted).  For example, we *want* to
459 preserve occ info in rules.
460
461 \begin{code}
462 -- | Substitutes a 'Var' for another one according to the 'Subst' given, returning
463 -- the result and an updated 'Subst' that should be used by subsequent substitutons.
464 -- 'IdInfo' is preserved by this process, although it is substituted into appropriately.
465 substBndr :: Subst -> Var -> (Subst, Var)
466 substBndr subst bndr
467   | isTyVar bndr  = substTyVarBndr subst bndr
468   | isCoVar bndr  = substCoVarBndr subst bndr
469   | otherwise     = substIdBndr (text "var-bndr") subst subst bndr
470
471 -- | Applies 'substBndr' to a number of 'Var's, accumulating a new 'Subst' left-to-right
472 substBndrs :: Subst -> [Var] -> (Subst, [Var])
473 substBndrs subst bndrs = mapAccumL substBndr subst bndrs
474
475 -- | Substitute in a mutually recursive group of 'Id's
476 substRecBndrs :: Subst -> [Id] -> (Subst, [Id])
477 substRecBndrs subst bndrs 
478   = (new_subst, new_bndrs)
479   where         -- Here's the reason we need to pass rec_subst to subst_id
480     (new_subst, new_bndrs) = mapAccumL (substIdBndr (text "rec-bndr") new_subst) subst bndrs
481 \end{code}
482
483
484 \begin{code}
485 substIdBndr :: SDoc 
486             -> Subst            -- ^ Substitution to use for the IdInfo
487             -> Subst -> Id      -- ^ Substitition and Id to transform
488             -> (Subst, Id)      -- ^ Transformed pair
489                                 -- NB: unfolding may be zapped
490
491 substIdBndr _doc rec_subst subst@(Subst in_scope env tvs cvs) old_id
492   = -- pprTrace "substIdBndr" (doc $$ ppr old_id $$ ppr in_scope) $
493     (Subst (in_scope `extendInScopeSet` new_id) new_env tvs cvs, new_id)
494   where
495     id1 = uniqAway in_scope old_id      -- id1 is cloned if necessary
496     id2 | no_type_change = id1
497         | otherwise      = setIdType id1 (substTy subst old_ty)
498
499     old_ty = idType old_id
500     no_type_change = isEmptyVarEnv tvs || 
501                      isEmptyVarSet (Type.tyVarsOfType old_ty)
502
503         -- new_id has the right IdInfo
504         -- The lazy-set is because we're in a loop here, with 
505         -- rec_subst, when dealing with a mutually-recursive group
506     new_id = maybeModifyIdInfo mb_new_info id2
507     mb_new_info = substIdInfo rec_subst id2 (idInfo id2)
508         -- NB: unfolding info may be zapped
509
510         -- Extend the substitution if the unique has changed
511         -- See the notes with substTyVarBndr for the delVarEnv
512     new_env | no_change = delVarEnv env old_id
513             | otherwise = extendVarEnv env old_id (Var new_id)
514
515     no_change = id1 == old_id
516         -- See Note [Extending the Subst]
517         -- it's /not/ necessary to check mb_new_info and no_type_change
518 \end{code}
519
520 Now a variant that unconditionally allocates a new unique.
521 It also unconditionally zaps the OccInfo.
522
523 \begin{code}
524 -- | Very similar to 'substBndr', but it always allocates a new 'Unique' for
525 -- each variable in its output.  It substitutes the IdInfo though.
526 cloneIdBndr :: Subst -> UniqSupply -> Id -> (Subst, Id)
527 cloneIdBndr subst us old_id
528   = clone_id subst subst (old_id, uniqFromSupply us)
529
530 -- | Applies 'cloneIdBndr' to a number of 'Id's, accumulating a final
531 -- substitution from left to right
532 cloneIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
533 cloneIdBndrs subst us ids
534   = mapAccumL (clone_id subst) subst (ids `zip` uniqsFromSupply us)
535
536 cloneBndrs :: Subst -> UniqSupply -> [Var] -> (Subst, [Var])
537 -- Works for all kinds of variables (typically case binders)
538 -- not just Ids
539 cloneBndrs subst us vs
540   = mapAccumL (\subst (v, u) -> cloneBndr subst u v) subst (vs `zip` uniqsFromSupply us)
541
542 cloneBndr :: Subst -> Unique -> Var -> (Subst, Var)
543 cloneBndr subst uniq v
544       | isTyVar v = cloneTyVarBndr subst v uniq
545       | otherwise = clone_id subst subst (v,uniq)  -- Works for coercion variables too
546
547 -- | Clone a mutually recursive group of 'Id's
548 cloneRecIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
549 cloneRecIdBndrs subst us ids
550   = (subst', ids')
551   where
552     (subst', ids') = mapAccumL (clone_id subst') subst
553                                (ids `zip` uniqsFromSupply us)
554
555 -- Just like substIdBndr, except that it always makes a new unique
556 -- It is given the unique to use
557 clone_id    :: Subst                    -- Substitution for the IdInfo
558             -> Subst -> (Id, Unique)    -- Substitition and Id to transform
559             -> (Subst, Id)              -- Transformed pair
560
561 clone_id rec_subst subst@(Subst in_scope idvs tvs cvs) (old_id, uniq)
562   = (Subst (in_scope `extendInScopeSet` new_id) new_idvs tvs new_cvs, new_id)
563   where
564     id1     = setVarUnique old_id uniq
565     id2     = substIdType subst id1
566     new_id  = maybeModifyIdInfo (substIdInfo rec_subst id2 (idInfo old_id)) id2
567     (new_idvs, new_cvs) | isCoVar old_id = (idvs, extendVarEnv cvs old_id (mkCoVarCo new_id))
568                         | otherwise      = (extendVarEnv idvs old_id (Var new_id), cvs)
569 \end{code}
570
571
572 %************************************************************************
573 %*                                                                      *
574                 Types and Coercions
575 %*                                                                      *
576 %************************************************************************
577
578 For types and coercions we just call the corresponding functions in
579 Type and Coercion, but we have to repackage the substitution, from a
580 Subst to a TvSubst.
581
582 \begin{code}
583 substTyVarBndr :: Subst -> TyVar -> (Subst, TyVar)
584 substTyVarBndr (Subst in_scope id_env tv_env cv_env) tv
585   = case Type.substTyVarBndr (TvSubst in_scope tv_env) tv of
586         (TvSubst in_scope' tv_env', tv') 
587            -> (Subst in_scope' id_env tv_env' cv_env, tv')
588
589 cloneTyVarBndr :: Subst -> TyVar -> Unique -> (Subst, TyVar)
590 cloneTyVarBndr (Subst in_scope id_env tv_env cv_env) tv uniq
591   = case Type.cloneTyVarBndr (TvSubst in_scope tv_env) tv uniq of
592         (TvSubst in_scope' tv_env', tv') 
593            -> (Subst in_scope' id_env tv_env' cv_env, tv')
594
595 substCoVarBndr :: Subst -> TyVar -> (Subst, TyVar)
596 substCoVarBndr (Subst in_scope id_env tv_env cv_env) cv
597   = case Coercion.substCoVarBndr (CvSubst in_scope tv_env cv_env) cv of
598         (CvSubst in_scope' tv_env' cv_env', cv') 
599            -> (Subst in_scope' id_env tv_env' cv_env', cv')
600
601 -- | See 'Type.substTy'
602 substTy :: Subst -> Type -> Type 
603 substTy subst ty = Type.substTy (getTvSubst subst) ty
604
605 getTvSubst :: Subst -> TvSubst
606 getTvSubst (Subst in_scope _ tenv _) = TvSubst in_scope tenv
607
608 getCvSubst :: Subst -> CvSubst
609 getCvSubst (Subst in_scope _ tenv cenv) = CvSubst in_scope tenv cenv
610
611 -- | See 'Coercion.substCo'
612 substCo :: Subst -> Coercion -> Coercion
613 substCo subst co = Coercion.substCo (getCvSubst subst) co
614 \end{code}
615
616
617 %************************************************************************
618 %*                                                                      *
619 \section{IdInfo substitution}
620 %*                                                                      *
621 %************************************************************************
622
623 \begin{code}
624 substIdType :: Subst -> Id -> Id
625 substIdType subst@(Subst _ _ tv_env cv_env) id
626   | (isEmptyVarEnv tv_env && isEmptyVarEnv cv_env) || isEmptyVarSet (Type.tyVarsOfType old_ty) = id
627   | otherwise   = setIdType id (substTy subst old_ty)
628                 -- The tyVarsOfType is cheaper than it looks
629                 -- because we cache the free tyvars of the type
630                 -- in a Note in the id's type itself
631   where
632     old_ty = idType id
633
634 ------------------
635 -- | Substitute into some 'IdInfo' with regard to the supplied new 'Id'.
636 substIdInfo :: Subst -> Id -> IdInfo -> Maybe IdInfo
637 substIdInfo subst new_id info
638   | nothing_to_do = Nothing
639   | otherwise     = Just (info `setSpecInfo`      substSpec subst new_id old_rules
640                                `setUnfoldingInfo` substUnfolding subst old_unf)
641   where
642     old_rules     = specInfo info
643     old_unf       = unfoldingInfo info
644     nothing_to_do = isEmptySpecInfo old_rules && isClosedUnfolding old_unf
645     
646
647 ------------------
648 -- | Substitutes for the 'Id's within an unfolding
649 substUnfolding, substUnfoldingSC :: Subst -> Unfolding -> Unfolding
650         -- Seq'ing on the returned Unfolding is enough to cause
651         -- all the substitutions to happen completely
652
653 substUnfoldingSC subst unf       -- Short-cut version
654   | isEmptySubst subst = unf
655   | otherwise          = substUnfolding subst unf
656
657 substUnfolding subst df@(DFunUnfolding { df_bndrs = bndrs, df_args = args })
658   = df { df_bndrs = bndrs', df_args = args' }
659   where
660     (subst',bndrs') = substBndrs subst bndrs
661     args'           = map (substExpr (text "subst-unf:dfun") subst') args
662
663 substUnfolding subst unf@(CoreUnfolding { uf_tmpl = tmpl, uf_src = src })
664         -- Retain an InlineRule!
665   | not (isStableSource src)  -- Zap an unstable unfolding, to save substitution work
666   = NoUnfolding
667   | otherwise                 -- But keep a stable one!
668   = seqExpr new_tmpl `seq`
669     unf { uf_tmpl = new_tmpl }
670   where
671     new_tmpl = substExpr (text "subst-unf") subst tmpl
672
673 substUnfolding _ unf = unf      -- NoUnfolding, OtherCon
674
675 ------------------
676 substIdOcc :: Subst -> Id -> Id
677 -- These Ids should not be substituted to non-Ids
678 substIdOcc subst v = case lookupIdSubst (text "substIdOcc") subst v of
679                         Var v' -> v'
680                         other  -> pprPanic "substIdOcc" (vcat [ppr v <+> ppr other, ppr subst])
681
682 ------------------
683 -- | Substitutes for the 'Id's within the 'WorkerInfo' given the new function 'Id'
684 substSpec :: Subst -> Id -> SpecInfo -> SpecInfo
685 substSpec subst new_id (SpecInfo rules rhs_fvs)
686   = seqSpecInfo new_spec `seq` new_spec
687   where
688     subst_ru_fn = const (idName new_id)
689     new_spec = SpecInfo (map (substRule subst subst_ru_fn) rules)
690                         (substVarSet subst rhs_fvs)
691
692 ------------------
693 substRulesForImportedIds :: Subst -> [CoreRule] -> [CoreRule]
694 substRulesForImportedIds subst rules 
695   = map (substRule subst not_needed) rules
696   where
697     not_needed name = pprPanic "substRulesForImportedIds" (ppr name)
698
699 ------------------
700 substRule :: Subst -> (Name -> Name) -> CoreRule -> CoreRule
701
702 -- The subst_ru_fn argument is applied to substitute the ru_fn field
703 -- of the rule:
704 --    - Rules for *imported* Ids never change ru_fn
705 --    - Rules for *local* Ids are in the IdInfo for that Id,
706 --      and the ru_fn field is simply replaced by the new name 
707 --      of the Id
708 substRule _ _ rule@(BuiltinRule {}) = rule
709 substRule subst subst_ru_fn rule@(Rule { ru_bndrs = bndrs, ru_args = args
710                                        , ru_fn = fn_name, ru_rhs = rhs
711                                        , ru_local = is_local })
712   = rule { ru_bndrs = bndrs', 
713            ru_fn    = if is_local 
714                         then subst_ru_fn fn_name 
715                         else fn_name,
716            ru_args  = map (substExpr (text "subst-rule" <+> ppr fn_name) subst') args,
717            ru_rhs   = simpleOptExprWith subst' rhs }
718            -- Do simple optimisation on RHS, in case substitution lets
719            -- you improve it.  The real simplifier never gets to look at it.
720   where
721     (subst', bndrs') = substBndrs subst bndrs
722
723 ------------------
724 substVects :: Subst -> [CoreVect] -> [CoreVect]
725 substVects subst = map (substVect subst)
726
727 ------------------
728 substVect :: Subst -> CoreVect -> CoreVect
729 substVect subst  (Vect v rhs)        = Vect v (simpleOptExprWith subst rhs)
730 substVect _subst vd@(NoVect _)       = vd
731 substVect _subst vd@(VectType _ _ _) = vd
732 substVect _subst vd@(VectClass _)    = vd
733 substVect _subst vd@(VectInst _)     = vd
734
735 ------------------
736 substVarSet :: Subst -> VarSet -> VarSet
737 substVarSet subst fvs
738   = foldVarSet (unionVarSet . subst_fv subst) emptyVarSet fvs
739   where
740     subst_fv subst fv 
741         | isId fv   = exprFreeVars (lookupIdSubst (text "substVarSet") subst fv)
742         | otherwise = Type.tyVarsOfType (lookupTvSubst subst fv)
743
744 ------------------
745 substTickish :: Subst -> Tickish Id -> Tickish Id
746 substTickish subst (Breakpoint n ids) = Breakpoint n (map do_one ids)
747  where do_one = getIdFromTrivialExpr . lookupIdSubst (text "subst_tickish") subst
748 substTickish _subst other = other
749
750 {- Note [substTickish]
751
752 A Breakpoint contains a list of Ids.  What happens if we ever want to
753 substitute an expression for one of these Ids?
754
755 First, we ensure that we only ever substitute trivial expressions for
756 these Ids, by marking them as NoOccInfo in the occurrence analyser.
757 Then, when substituting for the Id, we unwrap any type applications
758 and abstractions to get back to an Id, with getIdFromTrivialExpr.
759
760 Second, we have to ensure that we never try to substitute a literal
761 for an Id in a breakpoint.  We ensure this by never storing an Id with
762 an unlifted type in a Breakpoint - see Coverage.mkTickish.
763 Breakpoints can't handle free variables with unlifted types anyway.
764 -}
765 \end{code}
766
767 Note [Worker inlining]
768 ~~~~~~~~~~~~~~~~~~~~~~
769 A worker can get sustituted away entirely.
770         - it might be trivial
771         - it might simply be very small
772 We do not treat an InlWrapper as an 'occurrence' in the occurence 
773 analyser, so it's possible that the worker is not even in scope any more.
774
775 In all all these cases we simply drop the special case, returning to
776 InlVanilla.  The WARN is just so I can see if it happens a lot.
777
778
779 %************************************************************************
780 %*                                                                      *
781         The Very Simple Optimiser
782 %*                                                                      *
783 %************************************************************************
784
785 Note [Optimise coercion boxes agressively]
786 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
787
788 The simple expression optimiser needs to deal with Eq# boxes as follows:
789  1. If the result of optimising the RHS of a non-recursive binding is an
790     Eq# box, that box is substituted rather than turned into a let, just as
791     if it were trivial.
792        let eqv = Eq# co in e ==> e[Eq# co/eqv]
793
794  2. If the result of optimising a case scrutinee is a Eq# box and the case
795     deconstructs it in a trivial way, we evaluate the case then and there.
796       case Eq# co of Eq# cov -> e ==> e[co/cov]
797
798 We do this for two reasons:
799
800  1. Bindings/case scrutinisation of this form is often created by the
801     evidence-binding mechanism and we need them to be inlined to be able
802     desugar RULE LHSes that involve equalities (see e.g. T2291)
803
804  2. The test T4356 fails Lint because it creates a coercion between types
805     of kind (* -> * -> *) and (?? -> ? -> *), which differ. If we do this
806     inlining agressively we can collapse away the intermediate coercion between
807     these two types and hence pass Lint again. (This is a sort of a hack.)
808
809 In fact, our implementation uses slightly liberalised versions of the second rule
810 rule so that the optimisations are a bit more generally applicable. Precisely:
811  2a. We reduce any situation where we can spot a case-of-known-constructor
812
813 As a result, the only time we should get residual coercion boxes in the code is
814 when the type checker generates something like:
815
816   \eqv -> let eqv' = Eq# (case eqv of Eq# cov -> ... cov ...)
817
818 However, the case of lambda-bound equality evidence is fairly rare, so these two
819 rules should suffice for solving the rule LHS problem for now.
820
821 Annoyingly, we cannot use this modified rule 1a instead of 1:
822
823  1a. If we come across a let-bound constructor application with trivial arguments,
824      add an appropriate unfolding to the let binder.  We spot constructor applications
825      by using exprIsConApp_maybe, so this would actually let rule 2a reduce more.
826
827 The reason is that we REALLY NEED coercion boxes to be substituted away. With rule 1a
828 we wouldn't simplify this expression at all:
829
830   let eqv = Eq# co
831   in foo eqv (bar eqv)
832
833 The rule LHS desugarer can't deal with Let at all, so we need to push that box into
834 the use sites.
835
836 \begin{code}
837 simpleOptExpr :: CoreExpr -> CoreExpr
838 -- Do simple optimisation on an expression
839 -- The optimisation is very straightforward: just
840 -- inline non-recursive bindings that are used only once, 
841 -- or where the RHS is trivial
842 --
843 -- We also inline bindings that bind a Eq# box: see
844 -- See Note [Optimise coercion boxes agressively].
845 --
846 -- The result is NOT guaranteed occurence-analysed, because
847 -- in  (let x = y in ....) we substitute for x; so y's occ-info
848 -- may change radically
849
850 simpleOptExpr expr
851   = -- pprTrace "simpleOptExpr" (ppr init_subst $$ ppr expr)
852     simpleOptExprWith init_subst expr
853   where
854     init_subst = mkEmptySubst (mkInScopeSet (exprFreeVars expr))
855         -- It's potentially important to make a proper in-scope set
856         -- Consider  let x = ..y.. in \y. ...x...
857         -- Then we should remember to clone y before substituting
858         -- for x.  It's very unlikely to occur, because we probably
859         -- won't *be* substituting for x if it occurs inside a
860         -- lambda.  
861         --
862         -- It's a bit painful to call exprFreeVars, because it makes
863         -- three passes instead of two (occ-anal, and go)
864
865 simpleOptExprWith :: Subst -> InExpr -> OutExpr
866 simpleOptExprWith subst expr = simple_opt_expr subst (occurAnalyseExpr expr)
867
868 ----------------------
869 simpleOptPgm :: DynFlags -> Module 
870              -> CoreProgram -> [CoreRule] -> [CoreVect] 
871              -> IO (CoreProgram, [CoreRule], [CoreVect])
872 simpleOptPgm dflags this_mod binds rules vects
873   = do { dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
874                        (pprCoreBindings occ_anald_binds $$ pprRules rules );
875
876        ; return (reverse binds', substRulesForImportedIds subst' rules, substVects subst' vects) }
877   where
878     occ_anald_binds  = occurAnalysePgm this_mod (\_ -> False) {- No rules active -}
879                                        rules vects emptyVarEnv binds
880     (subst', binds') = foldl do_one (emptySubst, []) occ_anald_binds
881                        
882     do_one (subst, binds') bind 
883       = case simple_opt_bind subst bind of
884           (subst', Nothing)    -> (subst', binds')
885           (subst', Just bind') -> (subst', bind':binds')
886
887 ----------------------
888 type InVar   = Var
889 type OutVar  = Var
890 type InId    = Id
891 type OutId   = Id
892 type InExpr  = CoreExpr
893 type OutExpr = CoreExpr
894
895 -- In these functions the substitution maps InVar -> OutExpr
896
897 ----------------------
898 simple_opt_expr :: Subst -> InExpr -> OutExpr
899 simple_opt_expr subst expr
900   = go expr
901   where
902     in_scope_env = (substInScope subst, simpleUnfoldingFun)
903
904     go (Var v)          = lookupIdSubst (text "simpleOptExpr") subst v
905     go (App e1 e2)      = simple_app subst e1 [go e2]
906     go (Type ty)        = Type     (substTy subst ty)
907     go (Coercion co)    = Coercion (optCoercion (getCvSubst subst) co)
908     go (Lit lit)        = Lit lit
909     go (Tick tickish e) = Tick (substTickish subst tickish) (go e)
910     go (Cast e co)      | isReflCo co' = go e
911                         | otherwise    = Cast (go e) co' 
912                         where
913                           co' = optCoercion (getCvSubst subst) co
914
915     go (Let bind body) = case simple_opt_bind subst bind of
916                            (subst', Nothing)   -> simple_opt_expr subst' body
917                            (subst', Just bind) -> Let bind (simple_opt_expr subst' body)
918
919     go lam@(Lam {})     = go_lam [] subst lam
920     go (Case e b ty as)
921        -- See Note [Optimise coercion boxes agressively]
922       | isDeadBinder b
923       , Just (con, _tys, es) <- exprIsConApp_maybe in_scope_env e'
924       , Just (altcon, bs, rhs) <- findAlt (DataAlt con) as
925       = case altcon of
926           DEFAULT -> go rhs
927           _       -> mkLets (catMaybes mb_binds) $ simple_opt_expr subst' rhs
928             where (subst', mb_binds) = mapAccumL simple_opt_out_bind subst 
929                                                  (zipEqual "simpleOptExpr" bs es)
930
931       | otherwise
932       = Case e' b' (substTy subst ty)
933                    (map (go_alt subst') as)
934         where
935           e' = go e
936           (subst', b') = subst_opt_bndr subst b
937
938     ----------------------
939     go_alt subst (con, bndrs, rhs) 
940       = (con, bndrs', simple_opt_expr subst' rhs)
941       where
942         (subst', bndrs') = subst_opt_bndrs subst bndrs
943
944     ----------------------
945     -- go_lam tries eta reduction
946     go_lam bs' subst (Lam b e) 
947        = go_lam (b':bs') subst' e
948        where
949          (subst', b') = subst_opt_bndr subst b
950     go_lam bs' subst e 
951        | Just etad_e <- tryEtaReduce bs e' = etad_e
952        | otherwise                         = mkLams bs e'
953        where
954          bs = reverse bs'
955          e' = simple_opt_expr subst e
956
957 ----------------------
958 -- simple_app collects arguments for beta reduction
959 simple_app :: Subst -> InExpr -> [OutExpr] -> CoreExpr
960 simple_app subst (App e1 e2) as   
961   = simple_app subst e1 (simple_opt_expr subst e2 : as)
962 simple_app subst (Lam b e) (a:as) 
963   = case maybe_substitute subst b a of
964       Just ext_subst -> simple_app ext_subst e as
965       Nothing        -> Let (NonRec b2 a) (simple_app subst' e as)
966   where
967     (subst', b') = subst_opt_bndr subst b
968     b2 = add_info subst' b b'
969 simple_app subst e as
970   = foldl App (simple_opt_expr subst e) as
971
972 ----------------------
973 simple_opt_bind,simple_opt_bind' :: Subst -> CoreBind -> (Subst, Maybe CoreBind)
974 simple_opt_bind s b               -- Can add trace stuff here
975   = simple_opt_bind' s b
976
977 simple_opt_bind' subst (Rec prs)
978   = (subst'', res_bind)
979   where
980     res_bind            = Just (Rec (reverse rev_prs'))
981     (subst', bndrs')    = subst_opt_bndrs subst (map fst prs)
982     (subst'', rev_prs') = foldl do_pr (subst', []) (prs `zip` bndrs')
983     do_pr (subst, prs) ((b,r), b') 
984        = case maybe_substitute subst b r2 of
985            Just subst' -> (subst', prs)
986            Nothing     -> (subst,  (b2,r2):prs)
987        where
988          b2 = add_info subst b b'
989          r2 = simple_opt_expr subst r
990
991 simple_opt_bind' subst (NonRec b r)
992   = simple_opt_out_bind subst (b, simple_opt_expr subst r)
993
994 ----------------------
995 simple_opt_out_bind :: Subst -> (InVar, OutExpr) -> (Subst, Maybe CoreBind)
996 simple_opt_out_bind subst (b, r') 
997   | Just ext_subst <- maybe_substitute subst b r'
998   = (ext_subst, Nothing)
999   | otherwise
1000   = (subst', Just (NonRec b2 r'))
1001   where
1002     (subst', b') = subst_opt_bndr subst b
1003     b2 = add_info subst' b b'
1004
1005 ----------------------
1006 maybe_substitute :: Subst -> InVar -> OutExpr -> Maybe Subst
1007     -- (maybe_substitute subst in_var out_rhs)  
1008     --   either extends subst with (in_var -> out_rhs)
1009     --   or     returns Nothing
1010 maybe_substitute subst b r
1011   | Type ty <- r        -- let a::* = TYPE ty in <body>
1012   = ASSERT( isTyVar b )
1013     Just (extendTvSubst subst b ty)
1014
1015   | Coercion co <- r
1016   = ASSERT( isCoVar b )
1017     Just (extendCvSubst subst b co)
1018
1019   | isId b              -- let x = e in <body>
1020   , not (isCoVar b)     -- See Note [Do not inline CoVars unconditionally]
1021                         -- in SimplUtils
1022   , safe_to_inline (idOccInfo b) 
1023   , isAlwaysActive (idInlineActivation b)       -- Note [Inline prag in simplOpt]
1024   , not (isStableUnfolding (idUnfolding b))
1025   , not (isExportedId b)
1026   , not (isUnLiftedType (idType b)) || exprOkForSpeculation r
1027   = Just (extendIdSubst subst b r)
1028   
1029   | otherwise
1030   = Nothing
1031   where
1032         -- Unconditionally safe to inline
1033     safe_to_inline :: OccInfo -> Bool
1034     safe_to_inline (IAmALoopBreaker {})     = False
1035     safe_to_inline IAmDead                  = True
1036     safe_to_inline (OneOcc in_lam one_br _) = (not in_lam && one_br) || trivial
1037     safe_to_inline NoOccInfo                = trivial
1038
1039     trivial | exprIsTrivial r = True
1040             | (Var fun, args) <- collectArgs r
1041             , Just dc <- isDataConWorkId_maybe fun
1042             , dc `hasKey` eqBoxDataConKey
1043             , all exprIsTrivial args = True -- See Note [Optimise coercion boxes agressively]
1044             | otherwise = False
1045
1046 ----------------------
1047 subst_opt_bndr :: Subst -> InVar -> (Subst, OutVar)
1048 subst_opt_bndr subst bndr
1049   | isTyVar bndr  = substTyVarBndr subst bndr
1050   | isCoVar bndr  = substCoVarBndr subst bndr
1051   | otherwise     = subst_opt_id_bndr subst bndr
1052
1053 subst_opt_id_bndr :: Subst -> InId -> (Subst, OutId)
1054 -- Nuke all fragile IdInfo, unfolding, and RULES; 
1055 --    it gets added back later by add_info
1056 -- Rather like SimplEnv.substIdBndr
1057 --
1058 -- It's important to zap fragile OccInfo (which CoreSubst.substIdBndr 
1059 -- carefully does not do) because simplOptExpr invalidates it
1060
1061 subst_opt_id_bndr subst@(Subst in_scope id_subst tv_subst cv_subst) old_id
1062   = (Subst new_in_scope new_id_subst tv_subst cv_subst, new_id)
1063   where
1064     id1    = uniqAway in_scope old_id
1065     id2    = setIdType id1 (substTy subst (idType old_id))
1066     new_id = zapFragileIdInfo id2       -- Zaps rules, worker-info, unfolding
1067                                         -- and fragile OccInfo
1068     new_in_scope = in_scope `extendInScopeSet` new_id
1069
1070         -- Extend the substitution if the unique has changed,
1071         -- or there's some useful occurrence information
1072         -- See the notes with substTyVarBndr for the delSubstEnv
1073     new_id_subst | new_id /= old_id
1074                  = extendVarEnv id_subst old_id (Var new_id)
1075                  | otherwise 
1076                  = delVarEnv id_subst old_id
1077
1078 ----------------------
1079 subst_opt_bndrs :: Subst -> [InVar] -> (Subst, [OutVar])
1080 subst_opt_bndrs subst bndrs
1081   = mapAccumL subst_opt_bndr subst bndrs
1082
1083 ----------------------
1084 add_info :: Subst -> InVar -> OutVar -> OutVar
1085 add_info subst old_bndr new_bndr
1086  | isTyVar old_bndr = new_bndr
1087  | otherwise        = maybeModifyIdInfo mb_new_info new_bndr
1088  where mb_new_info = substIdInfo subst new_bndr (idInfo old_bndr)
1089
1090 simpleUnfoldingFun :: IdUnfoldingFun
1091 simpleUnfoldingFun id 
1092   | isAlwaysActive (idInlineActivation id) = idUnfolding id
1093   | otherwise                              = noUnfolding
1094 \end{code}
1095
1096 Note [Inline prag in simplOpt]
1097 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1098 If there's an INLINE/NOINLINE pragma that restricts the phase in 
1099 which the binder can be inlined, we don't inline here; after all,
1100 we don't know what phase we're in.  Here's an example
1101
1102   foo :: Int -> Int -> Int
1103   {-# INLINE foo #-}
1104   foo m n = inner m
1105      where
1106        {-# INLINE [1] inner #-}
1107        inner m = m+n
1108
1109   bar :: Int -> Int
1110   bar n = foo n 1
1111
1112 When inlining 'foo' in 'bar' we want the let-binding for 'inner' 
1113 to remain visible until Phase 1
1114
1115
1116 %************************************************************************
1117 %*                                                                      *
1118          exprIsConApp_maybe
1119 %*                                                                      *
1120 %************************************************************************
1121
1122 Note [exprIsConApp_maybe]
1123 ~~~~~~~~~~~~~~~~~~~~~~~~~
1124 exprIsConApp_maybe is a very important function.  There are two principal
1125 uses:
1126   * case e of { .... }
1127   * cls_op e, where cls_op is a class operation
1128
1129 In both cases you want to know if e is of form (C e1..en) where C is
1130 a data constructor.
1131
1132 However e might not *look* as if 
1133
1134 \begin{code}
1135 data ConCont = CC [CoreExpr] Coercion   
1136                   -- Substitution already applied
1137
1138 -- | Returns @Just (dc, [t1..tk], [x1..xn])@ if the argument expression is 
1139 -- a *saturated* constructor application of the form @dc t1..tk x1 .. xn@,
1140 -- where t1..tk are the *universally-qantified* type args of 'dc'
1141 exprIsConApp_maybe :: InScopeEnv -> CoreExpr -> Maybe (DataCon, [Type], [CoreExpr])
1142 exprIsConApp_maybe (in_scope, id_unf) expr
1143   = go (Left in_scope) expr (CC [] (mkReflCo Representational (exprType expr)))
1144   where
1145     go :: Either InScopeSet Subst 
1146        -> CoreExpr -> ConCont 
1147        -> Maybe (DataCon, [Type], [CoreExpr])
1148     go subst (Tick t expr) cont
1149        | not (tickishIsCode t) = go subst expr cont
1150     go subst (Cast expr co1) (CC [] co2)
1151        = go subst expr (CC [] (subst_co subst co1 `mkTransCo` co2))
1152     go subst (App fun arg) (CC args co)
1153        = go subst fun (CC (subst_arg subst arg : args) co)
1154     go subst (Lam var body) (CC (arg:args) co)
1155        | exprIsTrivial arg          -- Don't duplicate stuff!
1156        = go (extend subst var arg) body (CC args co)
1157     go (Right sub) (Var v) cont
1158        = go (Left (substInScope sub)) 
1159             (lookupIdSubst (text "exprIsConApp" <+> ppr expr) sub v) 
1160             cont
1161
1162     go (Left in_scope) (Var fun) cont@(CC args co)
1163         | Just con <- isDataConWorkId_maybe fun
1164         , count isValArg args == idArity fun
1165         = dealWithCoercion co con args
1166
1167         -- Look through dictionary functions; see Note [Unfolding DFuns]
1168         | DFunUnfolding { df_bndrs = bndrs, df_con = con, df_args = dfun_args } <- unfolding
1169         , bndrs `equalLength` args    -- See Note [DFun arity check]
1170         , let subst = mkOpenSubst in_scope (bndrs `zip` args)
1171         = dealWithCoercion co con (map (substExpr (text "exprIsConApp1") subst) dfun_args)
1172
1173         -- Look through unfoldings, but only arity-zero one; 
1174         -- if arity > 0 we are effectively inlining a function call,
1175         -- and that is the business of callSiteInline.
1176         -- In practice, without this test, most of the "hits" were
1177         -- CPR'd workers getting inlined back into their wrappers,
1178         | Just rhs <- expandUnfolding_maybe unfolding
1179         , unfoldingArity unfolding == 0 
1180         , let in_scope' = extendInScopeSetSet in_scope (exprFreeVars rhs)
1181         = go (Left in_scope') rhs cont
1182         where
1183           unfolding = id_unf fun
1184
1185     go _ _ _ = Nothing
1186
1187     ----------------------------
1188     -- Operations on the (Either InScopeSet CoreSubst)
1189     -- The Left case is wildly dominant
1190     subst_co (Left {}) co = co
1191     subst_co (Right s) co = CoreSubst.substCo s co
1192
1193     subst_arg (Left {}) e = e
1194     subst_arg (Right s) e = substExpr (text "exprIsConApp2") s e
1195
1196     extend (Left in_scope) v e = Right (extendSubst (mkEmptySubst in_scope) v e)
1197     extend (Right s)       v e = Right (extendSubst s v e)
1198
1199 dealWithCoercion :: Coercion -> DataCon -> [CoreExpr]
1200                  -> Maybe (DataCon, [Type], [CoreExpr])
1201 dealWithCoercion co dc dc_args
1202   | isReflCo co 
1203   , let (univ_ty_args, rest_args) = splitAtList (dataConUnivTyVars dc) dc_args
1204   = Just (dc, stripTypeArgs univ_ty_args, rest_args)
1205
1206   | Pair _from_ty to_ty <- coercionKind co
1207   , Just (to_tc, to_tc_arg_tys) <- splitTyConApp_maybe to_ty
1208   , to_tc == dataConTyCon dc
1209         -- These two tests can fail; we might see 
1210         --      (C x y) `cast` (g :: T a ~ S [a]),
1211         -- where S is a type function.  In fact, exprIsConApp
1212         -- will probably not be called in such circumstances,
1213         -- but there't nothing wrong with it 
1214
1215   =     -- Here we do the KPush reduction rule as described in the FC paper
1216         -- The transformation applies iff we have
1217         --      (C e1 ... en) `cast` co
1218         -- where co :: (T t1 .. tn) ~ to_ty
1219         -- The left-hand one must be a T, because exprIsConApp returned True
1220         -- but the right-hand one might not be.  (Though it usually will.)
1221     let
1222         tc_arity       = tyConArity to_tc
1223         dc_univ_tyvars = dataConUnivTyVars dc
1224         dc_ex_tyvars   = dataConExTyVars dc
1225         arg_tys        = dataConRepArgTys dc
1226
1227         non_univ_args  = dropList dc_univ_tyvars dc_args
1228         (ex_args, val_args) = splitAtList dc_ex_tyvars non_univ_args
1229
1230         -- Make the "theta" from Fig 3 of the paper
1231         gammas = decomposeCo tc_arity co
1232         theta_subst = liftCoSubstWith Representational
1233                          (dc_univ_tyvars ++ dc_ex_tyvars)
1234                                                 -- existentials are at role N
1235                          (gammas         ++ map (mkReflCo Nominal)
1236                                                 (stripTypeArgs ex_args))
1237
1238           -- Cast the value arguments (which include dictionaries)
1239         new_val_args = zipWith cast_arg arg_tys val_args
1240         cast_arg arg_ty arg = mkCast arg (theta_subst arg_ty)
1241
1242         dump_doc = vcat [ppr dc,      ppr dc_univ_tyvars, ppr dc_ex_tyvars,
1243                          ppr arg_tys, ppr dc_args,        
1244                          ppr ex_args, ppr val_args, ppr co, ppr _from_ty, ppr to_ty, ppr to_tc ]
1245     in
1246     ASSERT2( eqType _from_ty (mkTyConApp to_tc (stripTypeArgs $ takeList dc_univ_tyvars dc_args))
1247            , dump_doc )
1248     ASSERT2( all isTypeArg ex_args, dump_doc )
1249     ASSERT2( equalLength val_args arg_tys, dump_doc )
1250     Just (dc, to_tc_arg_tys, ex_args ++ new_val_args)
1251
1252   | otherwise
1253   = Nothing
1254
1255 stripTypeArgs :: [CoreExpr] -> [Type]
1256 stripTypeArgs args = ASSERT2( all isTypeArg args, ppr args )
1257                      [ty | Type ty <- args]
1258   -- We really do want isTypeArg here, not isTyCoArg!
1259 \end{code}
1260
1261 Note [Unfolding DFuns]
1262 ~~~~~~~~~~~~~~~~~~~~~~
1263 DFuns look like
1264
1265   df :: forall a b. (Eq a, Eq b) -> Eq (a,b)
1266   df a b d_a d_b = MkEqD (a,b) ($c1 a b d_a d_b)
1267                                ($c2 a b d_a d_b)
1268
1269 So to split it up we just need to apply the ops $c1, $c2 etc
1270 to the very same args as the dfun.  It takes a little more work
1271 to compute the type arguments to the dictionary constructor.
1272
1273 Note [DFun arity check]
1274 ~~~~~~~~~~~~~~~~~~~~~~~
1275 Here we check that the total number of supplied arguments (inclding 
1276 type args) matches what the dfun is expecting.  This may be *less*
1277 than the ordinary arity of the dfun: see Note [DFun unfoldings] in CoreSyn
1278
1279 \begin{code}
1280 exprIsLiteral_maybe :: InScopeEnv -> CoreExpr -> Maybe Literal
1281 -- Same deal as exprIsConApp_maybe, but much simpler
1282 -- Nevertheless we do need to look through unfoldings for
1283 -- Integer literals, which are vigorously hoisted to top level
1284 -- and not subsequently inlined
1285 exprIsLiteral_maybe env@(_, id_unf) e
1286   = case e of
1287       Lit l     -> Just l
1288       Tick _ e' -> exprIsLiteral_maybe env e' -- dubious?
1289       Var v     | Just rhs <- expandUnfolding_maybe (id_unf v)
1290                 -> exprIsLiteral_maybe env rhs
1291       _         -> Nothing
1292 \end{code}