3a8e433596a692b1960ac56c93c78005c6ea680b
[ghc.git] / compiler / hsSyn / HsPat.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5 \section[PatSyntax]{Abstract Haskell syntax---patterns}
6
7 \begin{code}
8 {-# LANGUAGE DeriveDataTypeable #-}
9
10 module HsPat (
11         Pat(..), InPat, OutPat, LPat,
12
13         HsConDetails(..),
14         HsConPatDetails, hsConPatArgs,
15         HsRecFields(..), HsRecField(..), hsRecFields,
16
17         mkPrefixConPat, mkCharLitPat, mkNilPat,
18
19         isBangHsBind, isLiftedPatBind,
20         isBangLPat, hsPatNeedsParens,
21         isIrrefutableHsPat,
22
23         pprParendLPat
24     ) where
25
26 import {-# SOURCE #-} HsExpr            (SyntaxExpr, LHsExpr, pprLExpr)
27
28 -- friends:
29 import HsBinds
30 import HsLit
31 import HsTypes
32 import TcEvidence
33 import BasicTypes
34 -- others:
35 import PprCore          ( {- instance OutputableBndr TyVar -} )
36 import TysWiredIn
37 import Var
38 import DataCon
39 import TyCon
40 import Outputable
41 import Type
42 import SrcLoc
43 import FastString
44 -- libraries:
45 import Data.Data hiding (TyCon)
46 import Data.Maybe
47 \end{code}
48
49
50 \begin{code}
51 type InPat id  = LPat id        -- No 'Out' constructors
52 type OutPat id = LPat id        -- No 'In' constructors
53
54 type LPat id = Located (Pat id)
55
56 data Pat id
57   =     ------------ Simple patterns ---------------
58     WildPat     PostTcType              -- Wild card
59         -- The sole reason for a type on a WildPat is to
60         -- support hsPatType :: Pat Id -> Type
61
62   | VarPat      id                      -- Variable
63   | LazyPat     (LPat id)               -- Lazy pattern
64   | AsPat       (Located id) (LPat id)  -- As pattern
65   | ParPat      (LPat id)               -- Parenthesised pattern
66                                         -- See Note [Parens in HsSyn] in HsExpr
67   | BangPat     (LPat id)               -- Bang pattern
68
69         ------------ Lists, tuples, arrays ---------------
70   | ListPat     [LPat id]                            -- Syntactic list
71                 PostTcType                           -- The type of the elements
72                 (Maybe (PostTcType, SyntaxExpr id))  -- For rebindable syntax
73                    -- For OverloadedLists a Just (ty,fn) gives
74                    -- overall type of the pattern, and the toList
75                    -- function to convert the scrutinee to a list value
76
77   | TuplePat    [LPat id]               -- Tuple
78                 Boxity                  -- UnitPat is TuplePat []
79                 PostTcType
80         -- You might think that the PostTcType was redundant, but it's essential
81         --      data T a where
82         --        T1 :: Int -> T Int
83         --      f :: (T a, a) -> Int
84         --      f (T1 x, z) = z
85         -- When desugaring, we must generate
86         --      f = /\a. \v::a.  case v of (t::T a, w::a) ->
87         --                       case t of (T1 (x::Int)) ->
88         -- Note the (w::a), NOT (w::Int), because we have not yet
89         -- refined 'a' to Int.  So we must know that the second component
90         -- of the tuple is of type 'a' not Int.  See selectMatchVar
91
92   | PArrPat     [LPat id]               -- Syntactic parallel array
93                 PostTcType              -- The type of the elements
94
95         ------------ Constructor patterns ---------------
96   | ConPatIn    (Located id)
97                 (HsConPatDetails id)
98
99   | ConPatOut {
100         pat_con   :: Located DataCon,
101         pat_tvs   :: [TyVar],           -- Existentially bound type variables (tyvars only)
102         pat_dicts :: [EvVar],           -- Ditto *coercion variables* and *dictionaries*
103                                         -- One reason for putting coercion variable here, I think,
104                                         --      is to ensure their kinds are zonked
105         pat_binds :: TcEvBinds,         -- Bindings involving those dictionaries
106         pat_args  :: HsConPatDetails id,
107         pat_ty    :: Type               -- The type of the pattern
108     }
109
110         ------------ View patterns ---------------
111   | ViewPat       (LHsExpr id)
112                   (LPat id)
113                   PostTcType        -- The overall type of the pattern
114                                     -- (= the argument type of the view function)
115                                     -- for hsPatType.
116
117         ------------ Quasiquoted patterns ---------------
118         -- See Note [Quasi-quote overview] in TcSplice
119   | QuasiQuotePat   (HsQuasiQuote id)
120
121         ------------ Literal and n+k patterns ---------------
122   | LitPat          HsLit               -- Used for *non-overloaded* literal patterns:
123                                         -- Int#, Char#, Int, Char, String, etc.
124
125   | NPat                -- Used for all overloaded literals,
126                         -- including overloaded strings with -XOverloadedStrings
127                     (HsOverLit id)              -- ALWAYS positive
128                     (Maybe (SyntaxExpr id))     -- Just (Name of 'negate') for negative
129                                                 -- patterns, Nothing otherwise
130                     (SyntaxExpr id)             -- Equality checker, of type t->t->Bool
131
132   | NPlusKPat       (Located id)        -- n+k pattern
133                     (HsOverLit id)      -- It'll always be an HsIntegral
134                     (SyntaxExpr id)     -- (>=) function, of type t->t->Bool
135                     (SyntaxExpr id)     -- Name of '-' (see RnEnv.lookupSyntaxName)
136
137         ------------ Pattern type signatures ---------------
138   | SigPatIn        (LPat id)                   -- Pattern with a type signature
139                     (HsWithBndrs (LHsType id))  -- Signature can bind both kind and type vars
140
141   | SigPatOut       (LPat id)           -- Pattern with a type signature
142                     Type
143
144         ------------ Pattern coercions (translation only) ---------------
145   | CoPat       HsWrapper               -- If co :: t1 ~ t2, p :: t2,
146                                         -- then (CoPat co p) :: t1
147                 (Pat id)                -- Why not LPat?  Ans: existing locn will do
148                 Type                    -- Type of whole pattern, t1
149         -- During desugaring a (CoPat co pat) turns into a cast with 'co' on
150         -- the scrutinee, followed by a match on 'pat'
151   deriving (Data, Typeable)
152 \end{code}
153
154 HsConDetails is use for patterns/expressions *and* for data type declarations
155
156 \begin{code}
157 data HsConDetails arg rec
158   = PrefixCon [arg]             -- C p1 p2 p3
159   | RecCon    rec               -- C { x = p1, y = p2 }
160   | InfixCon  arg arg           -- p1 `C` p2
161   deriving (Data, Typeable)
162
163 type HsConPatDetails id = HsConDetails (LPat id) (HsRecFields id (LPat id))
164
165 hsConPatArgs :: HsConPatDetails id -> [LPat id]
166 hsConPatArgs (PrefixCon ps)   = ps
167 hsConPatArgs (RecCon fs)      = map hsRecFieldArg (rec_flds fs)
168 hsConPatArgs (InfixCon p1 p2) = [p1,p2]
169 \end{code}
170
171 However HsRecFields is used only for patterns and expressions
172 (not data type declarations)
173
174 \begin{code}
175 data HsRecFields id arg         -- A bunch of record fields
176                                 --      { x = 3, y = True }
177         -- Used for both expressions and patterns
178   = HsRecFields { rec_flds   :: [HsRecField id arg],
179                   rec_dotdot :: Maybe Int }  -- Note [DotDot fields]
180   deriving (Data, Typeable)
181
182 -- Note [DotDot fields]
183 -- ~~~~~~~~~~~~~~~~~~~~
184 -- The rec_dotdot field means this:
185 --   Nothing => the normal case
186 --   Just n  => the group uses ".." notation,
187 --
188 -- In the latter case:
189 --
190 --   *before* renamer: rec_flds are exactly the n user-written fields
191 --
192 --   *after* renamer:  rec_flds includes *all* fields, with
193 --                     the first 'n' being the user-written ones
194 --                     and the remainder being 'filled in' implicitly
195
196 data HsRecField id arg = HsRecField {
197         hsRecFieldId  :: Located id,
198         hsRecFieldArg :: arg,           -- Filled in by renamer
199         hsRecPun      :: Bool           -- Note [Punning]
200   } deriving (Data, Typeable)
201
202 -- Note [Punning]
203 -- ~~~~~~~~~~~~~~
204 -- If you write T { x, y = v+1 }, the HsRecFields will be
205 --      HsRecField x x True ...
206 --      HsRecField y (v+1) False ...
207 -- That is, for "punned" field x is expanded (in the renamer)
208 -- to x=x; but with a punning flag so we can detect it later
209 -- (e.g. when pretty printing)
210 --
211 -- If the original field was qualified, we un-qualify it, thus
212 --    T { A.x } means T { A.x = x }
213
214 hsRecFields :: HsRecFields id arg -> [id]
215 hsRecFields rbinds = map (unLoc . hsRecFieldId) (rec_flds rbinds)
216 \end{code}
217
218 %************************************************************************
219 %*                                                                      *
220 %*              Printing patterns
221 %*                                                                      *
222 %************************************************************************
223
224 \begin{code}
225 instance (OutputableBndr name) => Outputable (Pat name) where
226     ppr = pprPat
227
228 pprPatBndr :: OutputableBndr name => name -> SDoc
229 pprPatBndr var                  -- Print with type info if -dppr-debug is on
230   = getPprStyle $ \ sty ->
231     if debugStyle sty then
232         parens (pprBndr LambdaBind var)         -- Could pass the site to pprPat
233                                                 -- but is it worth it?
234     else
235         ppr var
236
237 pprParendLPat :: (OutputableBndr name) => LPat name -> SDoc
238 pprParendLPat (L _ p) = pprParendPat p
239
240 pprParendPat :: (OutputableBndr name) => Pat name -> SDoc
241 pprParendPat p | hsPatNeedsParens p = parens (pprPat p)
242                | otherwise          = pprPat p
243
244 pprPat :: (OutputableBndr name) => Pat name -> SDoc
245 pprPat (VarPat var)       = pprPatBndr var
246 pprPat (WildPat _)        = char '_'
247 pprPat (LazyPat pat)      = char '~' <> pprParendLPat pat
248 pprPat (BangPat pat)      = char '!' <> pprParendLPat pat
249 pprPat (AsPat name pat)   = hcat [ppr name, char '@', pprParendLPat pat]
250 pprPat (ViewPat expr pat _) = hcat [pprLExpr expr, text " -> ", ppr pat]
251 pprPat (ParPat pat)         = parens (ppr pat)
252 pprPat (ListPat pats _ _)     = brackets (interpp'SP pats)
253 pprPat (PArrPat pats _)     = paBrackets (interpp'SP pats)
254 pprPat (TuplePat pats bx _) = tupleParens (boxityNormalTupleSort bx) (interpp'SP pats)
255
256 pprPat (ConPatIn con details) = pprUserCon con details
257 pprPat (ConPatOut { pat_con = con, pat_tvs = tvs, pat_dicts = dicts,
258                     pat_binds = binds, pat_args = details })
259   = getPprStyle $ \ sty ->      -- Tiresome; in TcBinds.tcRhs we print out a
260     if debugStyle sty then      -- typechecked Pat in an error message,
261                                 -- and we want to make sure it prints nicely
262         ppr con <> braces (sep [ hsep (map pprPatBndr (tvs ++ dicts))
263                                , ppr binds])
264                 <+> pprConArgs details
265     else pprUserCon con details
266
267 pprPat (LitPat s)           = ppr s
268 pprPat (NPat l Nothing  _)  = ppr l
269 pprPat (NPat l (Just _) _)  = char '-' <> ppr l
270 pprPat (NPlusKPat n k _ _)  = hcat [ppr n, char '+', ppr k]
271 pprPat (QuasiQuotePat qq)   = ppr qq
272 pprPat (CoPat co pat _)     = pprHsWrapper (ppr pat) co
273 pprPat (SigPatIn pat ty)    = ppr pat <+> dcolon <+> ppr ty
274 pprPat (SigPatOut pat ty)   = ppr pat <+> dcolon <+> ppr ty
275
276 pprUserCon :: (Outputable con, OutputableBndr id) => con -> HsConPatDetails id -> SDoc
277 pprUserCon c (InfixCon p1 p2) = ppr p1 <+> ppr c <+> ppr p2
278 pprUserCon c details          = ppr c <+> pprConArgs details
279
280 pprConArgs ::  OutputableBndr id => HsConPatDetails id -> SDoc
281 pprConArgs (PrefixCon pats) = sep (map pprParendLPat pats)
282 pprConArgs (InfixCon p1 p2) = sep [pprParendLPat p1, pprParendLPat p2]
283 pprConArgs (RecCon rpats)   = ppr rpats
284
285 instance (OutputableBndr id, Outputable arg)
286       => Outputable (HsRecFields id arg) where
287   ppr (HsRecFields { rec_flds = flds, rec_dotdot = Nothing })
288         = braces (fsep (punctuate comma (map ppr flds)))
289   ppr (HsRecFields { rec_flds = flds, rec_dotdot = Just n })
290         = braces (fsep (punctuate comma (map ppr (take n flds) ++ [dotdot])))
291         where
292           dotdot = ptext (sLit "..") <+> ifPprDebug (ppr (drop n flds))
293
294 instance (OutputableBndr id, Outputable arg)
295       => Outputable (HsRecField id arg) where
296   ppr (HsRecField { hsRecFieldId = f, hsRecFieldArg = arg,
297                     hsRecPun = pun })
298     = ppr f <+> (ppUnless pun $ equals <+> ppr arg)
299 \end{code}
300
301
302 %************************************************************************
303 %*                                                                      *
304 %*              Building patterns
305 %*                                                                      *
306 %************************************************************************
307
308 \begin{code}
309 mkPrefixConPat :: DataCon -> [OutPat id] -> Type -> OutPat id
310 -- Make a vanilla Prefix constructor pattern
311 mkPrefixConPat dc pats ty
312   = noLoc $ ConPatOut { pat_con = noLoc dc, pat_tvs = [], pat_dicts = [],
313                         pat_binds = emptyTcEvBinds, pat_args = PrefixCon pats,
314                         pat_ty = ty }
315
316 mkNilPat :: Type -> OutPat id
317 mkNilPat ty = mkPrefixConPat nilDataCon [] ty
318
319 mkCharLitPat :: Char -> OutPat id
320 mkCharLitPat c = mkPrefixConPat charDataCon [noLoc $ LitPat (HsCharPrim c)] charTy
321 \end{code}
322
323
324 %************************************************************************
325 %*                                                                      *
326 %* Predicates for checking things about pattern-lists in EquationInfo   *
327 %*                                                                      *
328 %************************************************************************
329
330 \subsection[Pat-list-predicates]{Look for interesting things in patterns}
331
332 Unlike in the Wadler chapter, where patterns are either ``variables''
333 or ``constructors,'' here we distinguish between:
334 \begin{description}
335 \item[unfailable:]
336 Patterns that cannot fail to match: variables, wildcards, and lazy
337 patterns.
338
339 These are the irrefutable patterns; the two other categories
340 are refutable patterns.
341
342 \item[constructor:]
343 A non-literal constructor pattern (see next category).
344
345 \item[literal patterns:]
346 At least the numeric ones may be overloaded.
347 \end{description}
348
349 A pattern is in {\em exactly one} of the above three categories; `as'
350 patterns are treated specially, of course.
351
352 The 1.3 report defines what ``irrefutable'' and ``failure-free'' patterns are.
353 \begin{code}
354 isBangLPat :: LPat id -> Bool
355 isBangLPat (L _ (BangPat {})) = True
356 isBangLPat (L _ (ParPat p))   = isBangLPat p
357 isBangLPat _                  = False
358
359 isBangHsBind :: HsBind id -> Bool
360 -- A pattern binding with an outermost bang
361 -- Defined in this module because HsPat is above HsBinds in the import graph
362 isBangHsBind (PatBind { pat_lhs = p }) = isBangLPat p
363 isBangHsBind _                         = False
364
365 isLiftedPatBind :: HsBind id -> Bool
366 -- A pattern binding with a compound pattern, not just a variable
367 --    (I# x)       yes
368 --    (# a, b #)   no, even if a::Int#
369 --    x            no, even if x::Int#
370 -- We want to warn about a missing bang-pattern on the yes's
371 isLiftedPatBind (PatBind { pat_lhs = p }) = isLiftedLPat p
372 isLiftedPatBind _                         = False
373
374 isLiftedLPat :: LPat id -> Bool
375 isLiftedLPat (L _ (ParPat p))   = isLiftedLPat p
376 isLiftedLPat (L _ (BangPat p))  = isLiftedLPat p
377 isLiftedLPat (L _ (AsPat _ p))  = isLiftedLPat p
378 isLiftedLPat (L _ (TuplePat _ Unboxed _)) = False
379 isLiftedLPat (L _ (VarPat {}))            = False
380 isLiftedLPat (L _ (WildPat {}))           = False
381 isLiftedLPat _                            = True
382
383 isIrrefutableHsPat :: OutputableBndr id => LPat id -> Bool
384 -- (isIrrefutableHsPat p) is true if matching against p cannot fail,
385 -- in the sense of falling through to the next pattern.
386 --      (NB: this is not quite the same as the (silly) defn
387 --      in 3.17.2 of the Haskell 98 report.)
388 --
389 -- isIrrefutableHsPat returns False if it's in doubt; specifically
390 -- on a ConPatIn it doesn't know the size of the constructor family
391 -- But if it returns True, the pattern is definitely irrefutable
392 isIrrefutableHsPat pat
393   = go pat
394   where
395     go (L _ pat) = go1 pat
396
397     go1 (WildPat {})        = True
398     go1 (VarPat {})         = True
399     go1 (LazyPat {})        = True
400     go1 (BangPat pat)       = go pat
401     go1 (CoPat _ pat _)     = go1 pat
402     go1 (ParPat pat)        = go pat
403     go1 (AsPat _ pat)       = go pat
404     go1 (ViewPat _ pat _)   = go pat
405     go1 (SigPatIn pat _)    = go pat
406     go1 (SigPatOut pat _)   = go pat
407     go1 (TuplePat pats _ _) = all go pats
408     go1 (ListPat {}) = False
409     go1 (PArrPat {})        = False     -- ?
410
411     go1 (ConPatIn {})       = False     -- Conservative
412     go1 (ConPatOut{ pat_con = L _ con, pat_args = details })
413         =  isJust (tyConSingleDataCon_maybe (dataConTyCon con))
414            -- NB: tyConSingleDataCon_maybe, *not* isProductTyCon, because
415            -- the latter is false of existentials. See Trac #4439
416         && all go (hsConPatArgs details)
417
418     go1 (LitPat {})    = False
419     go1 (NPat {})      = False
420     go1 (NPlusKPat {}) = False
421
422     go1 (QuasiQuotePat {}) = urk pat    -- Gotten rid of by renamer, before
423                                         -- isIrrefutablePat is called
424
425     urk pat = pprPanic "isIrrefutableHsPat:" (ppr pat)
426
427 hsPatNeedsParens :: Pat a -> Bool
428 hsPatNeedsParens (NPlusKPat {})      = True
429 hsPatNeedsParens (QuasiQuotePat {})  = True
430 hsPatNeedsParens (ConPatIn _ ds)     = conPatNeedsParens ds
431 hsPatNeedsParens p@(ConPatOut {})    = conPatNeedsParens (pat_args p)
432 hsPatNeedsParens (SigPatIn {})       = True
433 hsPatNeedsParens (SigPatOut {})      = True
434 hsPatNeedsParens (ViewPat {})        = True
435 hsPatNeedsParens (CoPat {})          = True
436 hsPatNeedsParens (WildPat {})        = False
437 hsPatNeedsParens (VarPat {})         = False
438 hsPatNeedsParens (LazyPat {})        = False
439 hsPatNeedsParens (BangPat {})        = False
440 hsPatNeedsParens (ParPat {})         = False
441 hsPatNeedsParens (AsPat {})          = False
442 hsPatNeedsParens (TuplePat {})       = False
443 hsPatNeedsParens (ListPat {})        = False
444 hsPatNeedsParens (PArrPat {})        = False
445 hsPatNeedsParens (LitPat {})         = False
446 hsPatNeedsParens (NPat {})           = False
447
448 conPatNeedsParens :: HsConDetails a b -> Bool
449 conPatNeedsParens (PrefixCon args) = not (null args)
450 conPatNeedsParens (InfixCon {})    = True
451 conPatNeedsParens (RecCon {})      = True
452 \end{code}
453