testsuite: Update performance metrics
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$TargetArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 dnl ** Does target have runtime linker support?
266 dnl --------------------------------------------------------------
267 case "$target" in
268     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
269         HaskellHaveRTSLinker=NO
270         ;;
271     *)
272         HaskellHaveRTSLinker=YES
273         ;;
274 esac
275 AC_SUBST(HaskellHaveRTSLinker)
276
277 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
278 FP_FIND_ROOT
279
280 fail() {
281     echo >&2
282     echo "$1" >&2
283     exit 1
284 }
285
286
287 if test "$HostOS" = "mingw32"
288 then
289     # Find the mingw-w64 7z file to extract.
290     # NB. If you update the tarballs to a new version of gcc, don't
291     # forget to tweak the paths in driver/gcc/gcc.c.
292     if test "$HostArch" = "i386"
293     then
294         mingw_arch="i686"
295         tarball_dest_dir="mingw-w64/x86"
296         tarball_mingw_dir="mingw32"
297     else
298         mingw_arch="x86_64"
299         tarball_dest_dir="mingw-w64/x86_64"
300         tarball_mingw_dir="mingw64"
301     fi
302 fi
303
304 set_up_tarballs() {
305     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
306     local action
307     if test "$TarballsAutodownload" = "NO"
308     then
309         action="verify"
310     else
311         action="download"
312     fi
313     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
314     case $? in
315         0)
316            rm missing-win32-tarballs
317            ;;
318         2)
319            echo
320            echo "Error:"
321            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
322            echo
323            echo "  * run configure with the --enable-tarballs-autodownload option"
324            echo
325            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
326            echo
327            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
328            echo "    them in the ghc-tarballs directory."
329            echo
330            exit 1
331            ;;
332         *)
333            echo
334            echo "Error fetching msys2 tarballs; see errors above."
335            exit 1
336            ;;
337     esac
338
339     # Extract all the tarballs in one go
340     if ! test -d inplace/mingw
341     then
342         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
343         rm -rf inplace/mingw
344         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
345         ( cd inplace &&
346         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
347         rm ".MTREE" &&
348         rm ".PKGINFO" &&
349         cd .. ) || fail "Error: Could not extract Windows toolchains."
350
351         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
352         touch inplace/mingw
353
354         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
355         # make a wrapper around it to give it the proper paths
356         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
357         PATH=`pwd`/inplace/mingw/bin:$PATH
358         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
359
360         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
361     fi
362 }
363
364 if test "$HostOS" = "mingw32"
365 then
366     test -d inplace || mkdir inplace
367
368     # NB. Download and extract the MingW-w64 distribution if required
369     set_up_tarballs
370
371     mingwbin="$hardtop/inplace/mingw/bin/"
372     CC="${mingwbin}gcc.exe"
373     LD="${mingwbin}ld.exe"
374     NM="${mingwbin}nm.exe"
375     RANLIB="${mingwbin}ranlib.exe"
376     OBJDUMP="${mingwbin}objdump.exe"
377     Windres="${mingwbin}windres.exe"
378     DllWrap="${mingwbin}dllwrap.exe"
379     fp_prog_ar="${mingwbin}ar.exe"
380
381     # NB. Download the perl binaries if required
382     if ! test -d inplace/perl ||
383          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
384     then
385         AC_MSG_NOTICE([Making in-tree perl tree])
386         rm -rf inplace/perl
387         mkdir inplace/perl
388         (
389             cd inplace/perl &&
390             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
391         )
392         AC_MSG_NOTICE([In-tree perl tree created])
393     fi
394 fi
395
396 FP_ICONV
397 FP_GMP
398 FP_CURSES
399
400 XCODE_VERSION()
401
402
403 dnl ** Building a cross compiler?
404 dnl --------------------------------------------------------------
405 CrossCompiling=NO
406 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
407 if test "$TargetPlatform" != "$HostPlatform" ; then
408     CrossCompiling=YES
409     cross_compiling=yes   # This tells configure that it can accept just 'target',
410                           # otherwise you get
411                           #   configure: error: cannot run C compiled programs.
412                           #   If you meant to cross compile, use `--host'.
413 fi
414 if test "$BuildPlatform" != "$HostPlatform" ; then
415    AC_MSG_ERROR([
416 You've selected:
417
418   BUILD:  $BuildPlatform   (the architecture we're building on)
419   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
420   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
421
422 BUILD must equal HOST; that is, we do not support building GHC itself
423 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
424 1 will be a cross-compiler, and stage 2 will be the cross-compiled
425 GHC.
426 ])
427 fi
428 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
429 # in calls to subproject configure scripts and thus must be set to the autoconf
430 # triple, not the normalized GHC triple that TargetPlatform is set to.
431 #
432 # We use the non-canonicalized triple, target_alias, here since the subproject
433 # configure scripts will use this triple to construct the names of the toolchain
434 # executables. If we instead passed down the triple produced by
435 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
436 # name (this is a known problem in the case of the Android NDK, which has
437 # slightly odd triples).
438 #
439 # It may be better to just do away with the GHC triples altogether. This would
440 # all be taken care of for us if we configured the subprojects using
441 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
442 # configuration.
443 #
444 # We also use non-canonicalized triple when install stage1 crosscompiler
445 if test -z "${target_alias}"
446 then
447   # --target wasn't given; use result from AC_CANONICAL_TARGET
448   TargetPlatformFull="${target}"
449 else
450   TargetPlatformFull="${target_alias}"
451 fi
452 if test "$CrossCompiling" = "YES"
453 then
454   # Use value passed by user from --target=
455   CrossCompilePrefix="${TargetPlatformFull}-"
456 else
457   CrossCompilePrefix=""
458 fi
459 AC_SUBST(CrossCompiling)
460 AC_SUBST(CrossCompilePrefix)
461 AC_SUBST(TargetPlatformFull)
462
463 dnl ** Which gcc to use?
464 dnl --------------------------------------------------------------
465
466 AC_ARG_WITH([gcc],
467         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
468         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
469
470 AC_ARG_WITH([clang],
471         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
472         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
473
474 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
475 dnl later CC is copied to CC_STAGE{1,2,3}
476 AC_PROG_CC([gcc clang])
477
478 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
479
480 dnl make extensions visible to allow feature-tests to detect them lateron
481 AC_USE_SYSTEM_EXTENSIONS
482
483 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
484 AC_PROG_CPP
485
486 # --with-hs-cpp/--with-hs-cpp-flags
487 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
488 AC_SUBST([HaskellCPPCmd])
489 AC_SUBST([HaskellCPPArgs])
490
491 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
492 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
493 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
494 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
495
496 dnl ** Which ld to use?
497 dnl --------------------------------------------------------------
498 FIND_LD([LdCmd])
499 AC_SUBST([LdCmd])
500
501 dnl ** Which nm to use?
502 dnl --------------------------------------------------------------
503 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
504
505 if test "$TargetOS_CPP" = "darwin"
506 then
507     AC_MSG_CHECKING(whether nm program is broken)
508     # Some versions of XCode ship a broken version of `nm`. Detect and work
509     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
510     nmver=$(${NM} --version | grep version | sed 's/ //g')
511     case "$nmver" in
512         LLVMversion7.3.0|LLVMversion7.3.1)
513             AC_MSG_RESULT(yes)
514             echo "The detected nm program is broken."
515             echo
516             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
517             echo
518             echo "Try re-running configure with:"
519             echo
520             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
521             echo
522             exit 1
523             ;;
524         *)
525             AC_MSG_RESULT(no)
526             ;;
527         esac
528 fi
529
530 NmCmd="$NM"
531 AC_SUBST([NmCmd])
532
533 dnl ** Which objdump to use?
534 dnl --------------------------------------------------------------
535 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
536 ObjdumpCmd="$OBJDUMP"
537 AC_SUBST([ObjdumpCmd])
538
539 dnl ** Which ar to use?
540 dnl --------------------------------------------------------------
541 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
542 ArCmd="$AR"
543 fp_prog_ar="$AR"
544 AC_SUBST([ArCmd])
545
546 dnl ** Which ranlib to use?
547 dnl --------------------------------------------------------------
548 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
549 RanlibCmd="$RANLIB"
550 RANLIB="$RanlibCmd"
551
552
553 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
554 case $HostOS_CPP in
555 cygwin32|mingw32)
556     dnl ** Which objdump to use?
557     dnl --------------------------------------------------------------
558     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
559     ObjdumpCmd="$OBJDUMP"
560     AC_SUBST([ObjdumpCmd])
561     ;;
562 esac
563
564 # Here is where we re-target which specific version of the LLVM
565 # tools we are looking for. In the past, GHC supported a number of
566 # versions of LLVM simultaneously, but that stopped working around
567 # 3.5/3.6 release of LLVM.
568 LlvmVersion=3.9
569 AC_SUBST([LlvmVersion])
570 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
571 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
572
573 dnl ** Which LLVM llc to use?
574 dnl --------------------------------------------------------------
575 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
576 LlcCmd="$LLC"
577 AC_SUBST([LlcCmd])
578
579 dnl ** Which LLVM opt to use?
580 dnl --------------------------------------------------------------
581 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
582 OptCmd="$OPT"
583 AC_SUBST([OptCmd])
584
585 dnl --------------------------------------------------------------
586 dnl End of configure script option section
587 dnl --------------------------------------------------------------
588
589
590 dnl --------------------------------------------------------------
591 dnl ** Can the unix package be built?
592 dnl --------------------------------------------------------------
593
594 if test "$TargetOS" = "mingw32"
595 then
596     GhcLibsWithUnix=NO
597 else
598     GhcLibsWithUnix=YES
599 fi
600 AC_SUBST([GhcLibsWithUnix])
601
602 dnl ** does #! work?
603 AC_SYS_INTERPRETER()
604
605 # Check for split-objs
606 SplitObjsBroken=NO
607 dnl ** look for `perl'
608 case $HostOS_CPP in
609 cygwin32|mingw32)
610   PerlCmd=$hardtop/inplace/perl/perl
611   ;;
612 *)
613     AC_PATH_PROG([PerlCmd],[perl])
614     if test -z "$PerlCmd"
615     then
616         AC_MSG_WARN([No Perl on PATH, disabling split object support])
617         SplitObjsBroken=YES
618     else
619         FPTOOLS_CHECK_PERL_VERSION
620     fi
621     ;;
622 esac
623 AC_SUBST([SplitObjsBroken])
624
625 dnl ** look for GCC and find out which version
626 dnl     Figure out which C compiler to use.  Gcc is preferred.
627 dnl     If gcc, make sure it's at least 3.0
628 dnl
629 FP_GCC_VERSION
630
631 dnl ** See whether gcc supports -no-pie
632 FP_GCC_SUPPORTS_NO_PIE
633
634 dnl ** look to see if we have a C compiler using an llvm back end.
635 dnl
636 FP_CC_LLVM_BACKEND
637
638 FP_PROG_LD_IS_GNU
639 FP_PROG_LD_BUILD_ID
640 FP_PROG_LD_NO_COMPACT_UNWIND
641 FP_PROG_LD_FILELIST
642
643
644 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
645 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
646 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
647 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
648 # Stage 3 won't be supported by cross-compilation
649
650 FP_GCC_EXTRA_FLAGS
651
652 # See rules/distdir-way-opts.mk for details.
653 # Flags passed to the C compiler
654 AC_SUBST(CONF_CC_OPTS_STAGE0)
655 AC_SUBST(CONF_CC_OPTS_STAGE1)
656 AC_SUBST(CONF_CC_OPTS_STAGE2)
657 # Flags passed to the C compiler when we ask it to link
658 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
659 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
660 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
661 # Flags passed to the linker when we ask it to link
662 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
663 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
664 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
665 # Flags passed to the C preprocessor
666 AC_SUBST(CONF_CPP_OPTS_STAGE0)
667 AC_SUBST(CONF_CPP_OPTS_STAGE1)
668 AC_SUBST(CONF_CPP_OPTS_STAGE2)
669 # Flags passed to the Haskell compiler
670 AC_SUBST(CONF_HC_OPTS_STAGE0)
671 AC_SUBST(CONF_HC_OPTS_STAGE1)
672 AC_SUBST(CONF_HC_OPTS_STAGE2)
673
674 dnl ** Set up the variables for the platform in the settings file.
675 dnl May need to use gcc to find platform details.
676 dnl --------------------------------------------------------------
677 FPTOOLS_SET_HASKELL_PLATFORM_VARS
678
679 dnl ** figure out how to do context diffs
680 FP_PROG_CONTEXT_DIFF
681
682 dnl Let's make sure install-sh is executable here.  If we got it from
683 dnl a darcs repo, it might not be (see bug #978).
684 chmod +x install-sh
685 dnl ** figure out how to do a BSD-ish install
686 AC_PROG_INSTALL
687
688 dnl ** how to invoke `ar' and `ranlib'
689 FP_PROG_AR_SUPPORTS_ATFILE
690 FP_PROG_AR_NEEDS_RANLIB
691
692 dnl ** Check to see whether ln -s works
693 AC_PROG_LN_S
694
695 FP_SETTINGS
696
697 dnl ** Find the path to sed
698 AC_PATH_PROGS(SedCmd,gsed sed,sed)
699
700
701 dnl ** check for time command
702 AC_PATH_PROG(TimeCmd,time)
703
704 dnl ** check for tar
705 dnl   if GNU tar is named gtar, look for it first.
706 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
707
708 dnl ** check for compressors
709 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
710 AC_PATH_PROGS(GzipCmd,gzip, gzip)
711 AC_PATH_PROGS(XzCmd,pxz xz, xz)
712
713 dnl ** check for patch
714 dnl if GNU patch is named gpatch, look for it first
715 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
716
717 dnl ** check for dtrace (currently only implemented for Mac OS X)
718 HaveDtrace=NO
719 AC_PATH_PROG(DtraceCmd,dtrace)
720 if test -n "$DtraceCmd"; then
721   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
722     HaveDtrace=YES
723   fi
724 fi
725 AC_SUBST(HaveDtrace)
726
727 AC_PATH_PROG(HSCOLOUR,HsColour)
728 # HsColour is passed to Cabal, so we need a native path
729 if test "$HostOS"      = "mingw32" && \
730    test "${HSCOLOUR}" != ""
731 then
732     # Canonicalise to <drive>:/path/to/gcc
733     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
734 fi
735
736 dnl ** check for Sphinx toolchain
737 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
738 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
739 changequote(, )dnl
740 [if test -n "$SPHINXBUILD"; then
741   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
742 fi;
743 changequote([, ])dnl
744 ])
745 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
746     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
747
748 dnl ** check for xelatex
749 AC_PATH_PROG(XELATEX,xelatex)
750
751 dnl ** check for ghc-pkg command
752 FP_PROG_GHC_PKG
753
754 dnl ** check for installed happy binary + version
755 FPTOOLS_HAPPY
756
757 dnl ** check for installed alex binary + version
758 FPTOOLS_ALEX
759
760 dnl --------------------------------------------------
761 dnl ### program checking section ends here ###
762 dnl --------------------------------------------------
763
764 dnl --------------------------------------------------
765 dnl * Platform header file and syscall feature tests
766 dnl ### checking the state of the local header files and syscalls ###
767
768 dnl ** check for full ANSI header (.h) files
769 AC_HEADER_STDC
770
771 dnl ** Enable large file support.  NB. do this before testing the type of
772 dnl    off_t, because it will affect the result of that test.
773 AC_SYS_LARGEFILE
774
775 dnl ** check for specific header (.h) files that we are interested in
776 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
777
778 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
779 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
780 [[#if HAVE_SYS_PARAM_H
781 # include <sys/param.h>
782 #endif
783 ]])
784
785 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
786 AC_HEADER_TIME
787
788 dnl ** do we have long longs?
789 AC_CHECK_TYPES([long long])
790
791 dnl ** what are the sizes of various types
792 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
793 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
794 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
795 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
796 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
797 if test "$ac_cv_type_long_long" = yes; then
798 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
799 fi
800 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
801 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
803 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
804 if test "$ac_cv_type_long_long" = yes; then
805 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
806 fi
807 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
808 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
809
810 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
811 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
812 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
813 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
814 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
815 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
816 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
817 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
818
819
820 dnl for use in settings.in
821 WordSize=$ac_cv_sizeof_void_p
822 AC_SUBST(WordSize)
823 FP_CHECK_FUNC([WinExec],
824   [@%:@include <windows.h>], [WinExec("",0)])
825
826 FP_CHECK_FUNC([GetModuleFileName],
827   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
828
829 dnl ** check for more functions
830 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
831 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
832
833 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
834 dnl ** _POSIX_C_SOURCE is defined
835 AC_CHECK_DECLS([ctime_r], , ,
836 [#define _POSIX_SOURCE 1
837 #define _POSIX_C_SOURCE 199506L
838 #include <time.h>])
839
840 dnl ** check for mingwex library
841 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
842 AC_SUBST(HaveLibMingwEx)
843
844 if test $HaveLibMingwEx = YES ; then
845   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
846 fi
847
848 dnl ** check for math library
849 dnl    Keep that check as early as possible.
850 dnl    as we need to know whether we need libm
851 dnl    for math functions or not
852 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
853 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
854 if test $HaveLibM = YES
855 then
856   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
857 fi
858
859 FP_BFD_SUPPORT
860
861 dnl ################################################################
862 dnl Check for libraries
863 dnl ################################################################
864
865 # system libffi
866
867 AC_ARG_WITH([system-libffi],
868 [AC_HELP_STRING([--with-system-libffi],
869   [Use system provided libffi for RTS [default=no]])
870 ])
871
872 AS_IF([test "x$with_system_libffi" = "xyes"],
873   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
874 )
875
876
877 AC_SUBST(UseSystemLibFFI)
878
879 AC_ARG_WITH([ffi-includes],
880 [AC_HELP_STRING([--with-ffi-includes=ARG],
881   [Find includes for libffi in ARG [default=system default]])
882 ],
883 [
884  if test "x$UseSystemLibFFI" != "xYES"; then
885     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
886  else
887     FFIIncludeDir="$withval"
888     LIBFFI_CFLAGS="-I$withval"
889  fi
890 ])
891
892 AC_SUBST(FFIIncludeDir)
893
894 AC_ARG_WITH([ffi-libraries],
895 [AC_HELP_STRING([--with-ffi-libraries=ARG],
896   [Find libffi in ARG [default=system default]])
897 ],
898 [
899  if test "x$UseSystemLibFFI" != "xYES"; then
900     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
901  else
902     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
903  fi
904 ])
905
906 AC_SUBST(FFILibDir)
907
908 AS_IF([test "$UseSystemLibFFI" = "YES"], [
909  CFLAGS2="$CFLAGS"
910  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
911  LDFLAGS2="$LDFLAGS"
912  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
913  if test "$HostOS" = "openbsd";
914  then
915    # OpenBSD's libffi is not directly linked to the libpthread but
916    # still requires pthread functionality. This means that any client
917    # binary which links with libffi also needs to link with
918    # libpthread. If it does not, then linking fails with unresolved
919    # symbols.
920    LDFLAGS="$LDFLAGS -lpthread"
921  fi
922  AC_CHECK_LIB(ffi, ffi_call,
923   [AC_CHECK_HEADERS([ffi.h], [break], [])
924    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
925   [AC_MSG_ERROR([Cannot find system libffi])])
926  CFLAGS="$CFLAGS2"
927  LDFLAGS="$LDFLAGS2"
928 ])
929
930 dnl ** check whether we need -ldl to get dlopen()
931 AC_CHECK_LIB(dl, dlopen)
932
933 dnl --------------------------------------------------
934 dnl * Miscellaneous feature tests
935 dnl --------------------------------------------------
936
937 dnl ** can we get alloca?
938 AC_FUNC_ALLOCA
939
940 dnl ** working vfork?
941 AC_FUNC_FORK
942
943 dnl ** determine whether or not const works
944 AC_C_CONST
945
946 dnl ** are we big endian?
947 AC_C_BIGENDIAN
948 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
949
950 dnl ** check for leading underscores in symbol names
951 FP_LEADING_UNDERSCORE
952
953 FP_VISIBILITY_HIDDEN
954
955 dnl ** check for librt
956 AC_CHECK_LIB(rt, clock_gettime)
957 AC_CHECK_FUNCS(clock_gettime timer_settime)
958 FP_CHECK_TIMER_CREATE
959
960 dnl ** check for Apple's "interesting" long double compatibility scheme
961 AC_MSG_CHECKING(for printf\$LDBLStub)
962 AC_TRY_LINK_FUNC(printf\$LDBLStub,
963     [
964         AC_MSG_RESULT(yes)
965         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
966             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
967     ],
968     [
969         AC_MSG_RESULT(no)
970         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
971             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
972     ])
973
974 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
975 dnl without linking against libpthread. Check whether -lpthread is necessary
976 dnl to use pthreads.
977 dnl
978 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
979 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
980 AC_CHECK_FUNC(pthread_create,
981     [
982         AC_MSG_RESULT(no)
983         need_lpthread=0
984     ],
985     [
986         AC_CHECK_LIB(pthread, pthread_create,
987             [
988                 AC_MSG_RESULT(yes)
989                 need_lpthread=1
990             ],
991             [
992                 AC_MSG_RESULT([no pthreads support found.])
993                 need_lpthread=0
994             ])
995     ])
996 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
997     [Define 1 if we need to link code using pthreads with -lpthread])
998
999 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1000 dnl    a different single-argument version.
1001 AC_CHECK_LIB(pthread, pthread_setname_np)
1002 AC_MSG_CHECKING(for pthread_setname_np)
1003 AC_TRY_LINK(
1004 [
1005 #define _GNU_SOURCE
1006 #include <pthread.h>
1007 ],
1008 [pthread_setname_np(pthread_self(), "name");],
1009     AC_MSG_RESULT(yes)
1010     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1011       [Define to 1 if you have the glibc version of pthread_setname_np]),
1012     AC_MSG_RESULT(no)
1013 )
1014
1015 dnl ** check for eventfd which is needed by the I/O manager
1016 AC_CHECK_HEADERS([sys/eventfd.h])
1017 AC_CHECK_FUNCS([eventfd])
1018
1019 dnl ** Check for __thread support in the compiler
1020 AC_MSG_CHECKING(for __thread support)
1021 AC_COMPILE_IFELSE(
1022   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1023   [
1024    AC_MSG_RESULT(yes)
1025    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1026   ],
1027   [
1028    AC_MSG_RESULT(no)
1029    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1030   ])
1031
1032 dnl large address space support (see includes/rts/storage/MBlock.h)
1033 dnl
1034 dnl Darwin has vm_allocate/vm_protect
1035 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1036 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1037 dnl (They also have MADV_DONTNEED, but it means something else!)
1038 dnl
1039 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1040 dnl it counts page-table space as committed memory, and so quickly
1041 dnl runs out of paging file when we have multiple processes reserving
1042 dnl 1TB of address space, we get the following error:
1043 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1044 dnl
1045
1046 AC_ARG_ENABLE(large-address-space,
1047     [AC_HELP_STRING([--enable-large-address-space],
1048         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1049     EnableLargeAddressSpace=$enableval,
1050     EnableLargeAddressSpace=yes
1051 )
1052
1053 use_large_address_space=no
1054 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1055     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1056         if test "$ghc_host_os" = "darwin" ; then
1057             use_large_address_space=yes
1058         elif test "$ghc_host_os" = "openbsd" ; then
1059             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1060             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1061             # but is completely ignored by OS mmap
1062             use_large_address_space=no
1063         else
1064             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1065                 [
1066                 #include <unistd.h>
1067                 #include <sys/types.h>
1068                 #include <sys/mman.h>
1069                 #include <fcntl.h>
1070             ])
1071             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1072                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1073                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1074                     use_large_address_space=yes
1075             fi
1076         fi
1077     fi
1078 fi
1079 if test "$use_large_address_space" = "yes" ; then
1080    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1081 fi
1082
1083 dnl ** Use MMAP in the runtime linker?
1084 dnl --------------------------------------------------------------
1085
1086 case ${TargetOS} in
1087     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1088         RtsLinkerUseMmap=1
1089         ;;
1090     darwin|ios)
1091         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1092         # reallocating. Reallocating is needed to allocate jump islands just
1093         # after each object image. Jumps to these jump islands use relative
1094         # branches which are limited to offsets that can be represented in
1095         # 24-bits.
1096         if test "$TargetArch" != "powerpc" ; then
1097             RtsLinkerUseMmap=1
1098         else
1099             RtsLinkerUseMmap=0
1100         fi
1101         ;;
1102     *)
1103         # Windows (which doesn't have mmap) and everything else.
1104         RtsLinkerUseMmap=0
1105         ;;
1106     esac
1107
1108 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1109                    [Use mmap in the runtime linker])
1110
1111 dnl ** Have libdw?
1112 dnl --------------------------------------------------------------
1113 UseLibdw=NO
1114 USE_LIBDW=0
1115 AC_ARG_ENABLE(dwarf-unwind,
1116     [AC_HELP_STRING([--enable-dwarf-unwind],
1117         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1118     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1119     [UseLibdw=NO]
1120 )
1121 AC_SUBST(UseLibdw)
1122 if test $UseLibdw = "YES" ; then
1123         USE_LIBDW=1
1124 fi
1125 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1126
1127 dnl ** Have libnuma?
1128 dnl --------------------------------------------------------------
1129 HaveLibNuma=0
1130 AC_CHECK_HEADERS([numa.h numaif.h])
1131
1132 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1133     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1134 fi
1135 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1136
1137 dnl ** Documentation
1138 dnl --------------------------------------------------------------
1139 if test -n "$SPHINXBUILD"; then
1140     BUILD_MAN=YES
1141     BUILD_SPHINX_HTML=YES
1142     if test -n "$XELATEX"; then
1143         BUILD_SPHINX_PDF=YES
1144     else
1145         BUILD_SPHINX_PDF=NO
1146     fi
1147 else
1148     BUILD_MAN=NO
1149     BUILD_SPHINX_HTML=NO
1150     BUILD_SPHINX_PDF=NO
1151 fi
1152 AC_SUBST(BUILD_MAN)
1153 AC_SUBST(BUILD_SPHINX_HTML)
1154 AC_SUBST(BUILD_SPHINX_PDF)
1155
1156 LIBRARY_VERSION(base)
1157 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1158 LIBRARY_VERSION(ghc-prim)
1159 LIBRARY_VERSION(ghc-compact)
1160 LIBRARY_ghc_VERSION="$ProjectVersion"
1161 AC_SUBST(LIBRARY_ghc_VERSION)
1162
1163 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1164    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1165 fi
1166
1167 # Create the configuration for the Hadrian build system if it is present
1168 if test -e hadrian/cfg/system.config.in; then
1169     AC_CONFIG_FILES([hadrian/cfg/system.config])
1170 fi
1171
1172 # We got caught by
1173 #     http://savannah.gnu.org/bugs/index.php?1516
1174 #     $(eval ...) inside conditionals causes errors
1175 # with make 3.80, so warn the user if it looks like they're about to
1176 # try to use it.
1177 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1178 print_make_warning=""
1179 checkMake380() {
1180     make_ver=`$1 --version 2>&1 | head -1`
1181     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1182     then
1183         print_make_warning="true"
1184     fi
1185     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1186     then
1187         MakeCmd=$1
1188         AC_SUBST(MakeCmd)
1189     fi
1190 }
1191
1192 checkMake380 make
1193 checkMake380 gmake
1194
1195 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1196 AC_OUTPUT
1197 [
1198 if test "$print_make_warning" = "true"; then
1199    echo
1200    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1201    echo "This version cannot be used to build GHC."
1202    echo "Please use GNU make >= 3.81."
1203 fi
1204
1205 echo "
1206 ----------------------------------------------------------------------
1207 Configure completed successfully.
1208
1209    Building GHC version  : $ProjectVersion
1210           Git commit id  : $ProjectGitCommitId
1211
1212    Build platform        : $BuildPlatform
1213    Host platform         : $HostPlatform
1214    Target platform       : $TargetPlatform
1215 "
1216
1217 echo "\
1218    Bootstrapping using   : $WithGhc
1219       which is version   : $GhcVersion
1220 "
1221
1222 if test "x$CC_LLVM_BACKEND" = "x1"; then
1223     if test "x$CC_CLANG_BACKEND" = "x1"; then
1224         CompilerName="clang        "
1225     else
1226         CompilerName="llvm-gcc     "
1227     fi
1228 else
1229     CompilerName="gcc          "
1230 fi
1231
1232 echo "\
1233    Using (for bootstrapping) : $CC_STAGE0
1234    Using $CompilerName       : $CC
1235       which is version       : $GccVersion
1236    Building a cross compiler : $CrossCompiling
1237    Unregisterised            : $Unregisterised
1238    hs-cpp       : $HaskellCPPCmd
1239    hs-cpp-flags : $HaskellCPPArgs
1240    ar           : $ArCmd
1241    ld           : $LdCmd
1242    nm           : $NmCmd
1243    objdump      : $ObjdumpCmd
1244    ranlib       : $RanlibCmd
1245    Happy        : $HappyCmd ($HappyVersion)
1246    Alex         : $AlexCmd ($AlexVersion)
1247    Perl         : $PerlCmd
1248    sphinx-build : $SPHINXBUILD
1249    xelatex      : $XELATEX
1250
1251    Using LLVM tools
1252       llc   : $LlcCmd
1253       opt   : $OptCmd"
1254
1255 if test "$HSCOLOUR" = ""; then
1256 echo "
1257    HsColour was not found; documentation will not contain source links
1258 "
1259 else
1260 echo "\
1261    HsColour : $HSCOLOUR
1262 "
1263 fi
1264
1265 echo "\
1266    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1267    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1268
1269 echo "----------------------------------------------------------------------
1270 "
1271
1272 echo "\
1273 For a standard build of GHC (fully optimised with profiling), type (g)make.
1274
1275 To make changes to the default build configuration, copy the file
1276 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1277
1278 For more information on how to configure your GHC build, see
1279    http://ghc.haskell.org/trac/ghc/wiki/Building
1280 "]