Delete all /* ! __GLASGOW_HASKELL__ */ code
[ghc.git] / compiler / basicTypes / Unique.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 @Uniques@ are used to distinguish entities in the compiler (@Ids@,
7 @Classes@, etc.) from each other.  Thus, @Uniques@ are the basic
8 comparison key in the compiler.
9
10 If there is any single operation that needs to be fast, it is @Unique@
11 comparison.  Unsurprisingly, there is quite a bit of huff-and-puff
12 directed to that end.
13
14 Some of the other hair in this code is to be able to use a
15 ``splittable @UniqueSupply@'' if requested/possible (not standard
16 Haskell).
17
18 \begin{code}
19 {-# LANGUAGE CPP, BangPatterns, MagicHash #-}
20
21 module Unique (
22         -- * Main data types
23         Unique, Uniquable(..),
24
25         -- ** Constructors, desctructors and operations on 'Unique's
26         hasKey,
27
28         pprUnique,
29
30         mkUniqueGrimily,                -- Used in UniqSupply only!
31         getKey, getKeyFastInt,          -- Used in Var, UniqFM, Name only!
32         mkUnique, unpkUnique,           -- Used in BinIface only
33
34         incrUnique,                     -- Used for renumbering
35         deriveUnique,                   -- Ditto
36         newTagUnique,                   -- Used in CgCase
37         initTyVarUnique,
38
39         -- ** Making built-in uniques
40
41         -- now all the built-in Uniques (and functions to make them)
42         -- [the Oh-So-Wonderful Haskell module system wins again...]
43         mkAlphaTyVarUnique,
44         mkPrimOpIdUnique,
45         mkTupleTyConUnique, mkTupleDataConUnique,
46         mkPreludeMiscIdUnique, mkPreludeDataConUnique,
47         mkPreludeTyConUnique, mkPreludeClassUnique,
48         mkPArrDataConUnique,
49
50     mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique,
51         mkRegSingleUnique, mkRegPairUnique, mkRegClassUnique, mkRegSubUnique,
52         mkCostCentreUnique,
53
54         mkBuiltinUnique,
55         mkPseudoUniqueD,
56         mkPseudoUniqueE,
57         mkPseudoUniqueH
58     ) where
59
60 #include "HsVersions.h"
61
62 import BasicTypes
63 import FastTypes
64 import FastString
65 import Outputable
66 -- import StaticFlags
67 import Util
68
69 --just for implementing a fast [0,61) -> Char function
70 import GHC.Exts (indexCharOffAddr#, Char(..))
71
72 import Data.Char        ( chr, ord )
73 \end{code}
74
75 %************************************************************************
76 %*                                                                      *
77 \subsection[Unique-type]{@Unique@ type and operations}
78 %*                                                                      *
79 %************************************************************************
80
81 The @Chars@ are ``tag letters'' that identify the @UniqueSupply@.
82 Fast comparison is everything on @Uniques@:
83
84 \begin{code}
85 --why not newtype Int?
86
87 -- | The type of unique identifiers that are used in many places in GHC
88 -- for fast ordering and equality tests. You should generate these with
89 -- the functions from the 'UniqSupply' module
90 data Unique = MkUnique FastInt
91 \end{code}
92
93 Now come the functions which construct uniques from their pieces, and vice versa.
94 The stuff about unique *supplies* is handled further down this module.
95
96 \begin{code}
97 unpkUnique      :: Unique -> (Char, Int)        -- The reverse
98
99 mkUniqueGrimily :: Int -> Unique                -- A trap-door for UniqSupply
100 getKey          :: Unique -> Int                -- for Var
101 getKeyFastInt   :: Unique -> FastInt            -- for Var
102
103 incrUnique      :: Unique -> Unique
104 deriveUnique    :: Unique -> Int -> Unique
105 newTagUnique    :: Unique -> Char -> Unique
106 \end{code}
107
108
109 \begin{code}
110 mkUniqueGrimily x = MkUnique (iUnbox x)
111
112 {-# INLINE getKey #-}
113 getKey (MkUnique x) = iBox x
114 {-# INLINE getKeyFastInt #-}
115 getKeyFastInt (MkUnique x) = x
116
117 incrUnique (MkUnique i) = MkUnique (i +# _ILIT(1))
118
119 -- deriveUnique uses an 'X' tag so that it won't clash with
120 -- any of the uniques produced any other way
121 deriveUnique (MkUnique i) delta = mkUnique 'X' (iBox i + delta)
122
123 -- newTagUnique changes the "domain" of a unique to a different char
124 newTagUnique u c = mkUnique c i where (_,i) = unpkUnique u
125
126 -- pop the Char in the top 8 bits of the Unique(Supply)
127
128 -- No 64-bit bugs here, as long as we have at least 32 bits. --JSM
129
130 -- and as long as the Char fits in 8 bits, which we assume anyway!
131
132 mkUnique :: Char -> Int -> Unique       -- Builds a unique from pieces
133 -- NOT EXPORTED, so that we can see all the Chars that
134 --               are used in this one module
135 mkUnique c i
136   = MkUnique (tag `bitOrFastInt` bits)
137   where
138     !tag  = fastOrd (cUnbox c) `shiftLFastInt` _ILIT(24)
139     !bits = iUnbox i `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-}
140
141 unpkUnique (MkUnique u)
142   = let
143         -- as long as the Char may have its eighth bit set, we
144         -- really do need the logical right-shift here!
145         tag = cBox (fastChr (u `shiftRLFastInt` _ILIT(24)))
146         i   = iBox (u `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-})
147     in
148     (tag, i)
149 \end{code}
150
151
152
153 %************************************************************************
154 %*                                                                      *
155 \subsection[Uniquable-class]{The @Uniquable@ class}
156 %*                                                                      *
157 %************************************************************************
158
159 \begin{code}
160 -- | Class of things that we can obtain a 'Unique' from
161 class Uniquable a where
162     getUnique :: a -> Unique
163
164 hasKey          :: Uniquable a => a -> Unique -> Bool
165 x `hasKey` k    = getUnique x == k
166
167 instance Uniquable FastString where
168  getUnique fs = mkUniqueGrimily (iBox (uniqueOfFS fs))
169
170 instance Uniquable Int where
171  getUnique i = mkUniqueGrimily i
172 \end{code}
173
174
175 %************************************************************************
176 %*                                                                      *
177 \subsection[Unique-instances]{Instance declarations for @Unique@}
178 %*                                                                      *
179 %************************************************************************
180
181 And the whole point (besides uniqueness) is fast equality.  We don't
182 use `deriving' because we want {\em precise} control of ordering
183 (equality on @Uniques@ is v common).
184
185 \begin{code}
186 eqUnique, ltUnique, leUnique :: Unique -> Unique -> Bool
187 eqUnique (MkUnique u1) (MkUnique u2) = u1 ==# u2
188 ltUnique (MkUnique u1) (MkUnique u2) = u1 <#  u2
189 leUnique (MkUnique u1) (MkUnique u2) = u1 <=# u2
190
191 cmpUnique :: Unique -> Unique -> Ordering
192 cmpUnique (MkUnique u1) (MkUnique u2)
193   = if u1 ==# u2 then EQ else if u1 <# u2 then LT else GT
194
195 instance Eq Unique where
196     a == b = eqUnique a b
197     a /= b = not (eqUnique a b)
198
199 instance Ord Unique where
200     a  < b = ltUnique a b
201     a <= b = leUnique a b
202     a  > b = not (leUnique a b)
203     a >= b = not (ltUnique a b)
204     compare a b = cmpUnique a b
205
206 -----------------
207 instance Uniquable Unique where
208     getUnique u = u
209 \end{code}
210
211 We do sometimes make strings with @Uniques@ in them:
212 \begin{code}
213 showUnique :: Unique -> String
214 showUnique uniq
215   = case unpkUnique uniq of
216       (tag, u) -> finish_show tag u (iToBase62 u)
217
218 finish_show :: Char -> Int -> String -> String
219 finish_show 't' u _pp_u | u < 26
220   = -- Special case to make v common tyvars, t1, t2, ...
221     -- come out as a, b, ... (shorter, easier to read)
222     [chr (ord 'a' + u)]
223 finish_show tag _ pp_u = tag : pp_u
224
225 pprUnique :: Unique -> SDoc
226 pprUnique u = text (showUnique u)
227
228 instance Outputable Unique where
229     ppr = pprUnique
230
231 instance Show Unique where
232     show uniq = showUnique uniq
233 \end{code}
234
235 %************************************************************************
236 %*                                                                      *
237 \subsection[Utils-base62]{Base-62 numbers}
238 %*                                                                      *
239 %************************************************************************
240
241 A character-stingy way to read/write numbers (notably Uniques).
242 The ``62-its'' are \tr{[0-9a-zA-Z]}.  We don't handle negative Ints.
243 Code stolen from Lennart.
244
245 \begin{code}
246 iToBase62 :: Int -> String
247 iToBase62 n_
248   = ASSERT(n_ >= 0) go (iUnbox n_) ""
249   where
250     go n cs | n <# _ILIT(62)
251              = case chooseChar62 n of { c -> c `seq` (c : cs) }
252              | otherwise
253              =  case (quotRem (iBox n) 62) of { (q_, r_) ->
254                 case iUnbox q_ of { q -> case iUnbox r_ of { r ->
255                 case (chooseChar62 r) of { c -> c `seq`
256                 (go q (c : cs)) }}}}
257
258     chooseChar62 :: FastInt -> Char
259     {-# INLINE chooseChar62 #-}
260     chooseChar62 n = C# (indexCharOffAddr# chars62 n)
261     !chars62 = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"#
262 \end{code}
263
264 %************************************************************************
265 %*                                                                      *
266 \subsection[Uniques-prelude]{@Uniques@ for wired-in Prelude things}
267 %*                                                                      *
268 %************************************************************************
269
270 Allocation of unique supply characters:
271         v,t,u : for renumbering value-, type- and usage- vars.
272         B:   builtin
273         C-E: pseudo uniques     (used in native-code generator)
274         X:   uniques derived by deriveUnique
275         _:   unifiable tyvars   (above)
276         0-9: prelude things below
277              (no numbers left any more..)
278         ::   (prelude) parallel array data constructors
279
280         other a-z: lower case chars for unique supplies.  Used so far:
281
282         d       desugarer
283         f       AbsC flattener
284         g       SimplStg
285         n       Native codegen
286         r       Hsc name cache
287         s       simplifier
288
289 \begin{code}
290 mkAlphaTyVarUnique     :: Int -> Unique
291 mkPreludeClassUnique   :: Int -> Unique
292 mkPreludeTyConUnique   :: Int -> Unique
293 mkTupleTyConUnique     :: TupleSort -> Int -> Unique
294 mkPreludeDataConUnique :: Int -> Unique
295 mkTupleDataConUnique   :: TupleSort -> Int -> Unique
296 mkPrimOpIdUnique       :: Int -> Unique
297 mkPreludeMiscIdUnique  :: Int -> Unique
298 mkPArrDataConUnique    :: Int -> Unique
299
300 mkAlphaTyVarUnique i            = mkUnique '1' i
301
302 mkPreludeClassUnique i          = mkUnique '2' i
303
304 -- Prelude type constructors occupy *three* slots.
305 -- The first is for the tycon itself; the latter two
306 -- are for the generic to/from Ids.  See TysWiredIn.mk_tc_gen_info.
307
308 mkPreludeTyConUnique i          = mkUnique '3' (3*i)
309 mkTupleTyConUnique BoxedTuple   a       = mkUnique '4' (3*a)
310 mkTupleTyConUnique UnboxedTuple a       = mkUnique '5' (3*a)
311 mkTupleTyConUnique ConstraintTuple a    = mkUnique 'k' (3*a)
312
313 -- Data constructor keys occupy *two* slots.  The first is used for the
314 -- data constructor itself and its wrapper function (the function that
315 -- evaluates arguments as necessary and calls the worker). The second is
316 -- used for the worker function (the function that builds the constructor
317 -- representation).
318
319 mkPreludeDataConUnique i        = mkUnique '6' (2*i)    -- Must be alphabetic
320 mkTupleDataConUnique BoxedTuple   a = mkUnique '7' (2*a)        -- ditto (*may* be used in C labels)
321 mkTupleDataConUnique UnboxedTuple    a = mkUnique '8' (2*a)
322 mkTupleDataConUnique ConstraintTuple a = mkUnique 'h' (2*a)
323
324 mkPrimOpIdUnique op         = mkUnique '9' op
325 mkPreludeMiscIdUnique  i    = mkUnique '0' i
326
327 -- No numbers left anymore, so I pick something different for the character tag
328 mkPArrDataConUnique a           = mkUnique ':' (2*a)
329
330 -- The "tyvar uniques" print specially nicely: a, b, c, etc.
331 -- See pprUnique for details
332
333 initTyVarUnique :: Unique
334 initTyVarUnique = mkUnique 't' 0
335
336 mkPseudoUniqueD, mkPseudoUniqueE, mkPseudoUniqueH,
337    mkBuiltinUnique :: Int -> Unique
338
339 mkBuiltinUnique i = mkUnique 'B' i
340 mkPseudoUniqueD i = mkUnique 'D' i -- used in NCG for getUnique on RealRegs
341 mkPseudoUniqueE i = mkUnique 'E' i -- used in NCG spiller to create spill VirtualRegs
342 mkPseudoUniqueH i = mkUnique 'H' i -- used in NCG spiller to create spill VirtualRegs
343
344 mkRegSingleUnique, mkRegPairUnique, mkRegSubUnique, mkRegClassUnique :: Int -> Unique
345 mkRegSingleUnique = mkUnique 'R'
346 mkRegSubUnique    = mkUnique 'S'
347 mkRegPairUnique   = mkUnique 'P'
348 mkRegClassUnique  = mkUnique 'L'
349
350 mkCostCentreUnique :: Int -> Unique
351 mkCostCentreUnique = mkUnique 'C'
352
353 mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique :: FastString -> Unique
354 -- See Note [The Unique of an OccName] in OccName
355 mkVarOccUnique  fs = mkUnique 'i' (iBox (uniqueOfFS fs))
356 mkDataOccUnique fs = mkUnique 'd' (iBox (uniqueOfFS fs))
357 mkTvOccUnique   fs = mkUnique 'v' (iBox (uniqueOfFS fs))
358 mkTcOccUnique   fs = mkUnique 'c' (iBox (uniqueOfFS fs))
359 \end{code}
360