Add OverloadedLists, allowing list syntax to be overloaded
[ghc.git] / compiler / typecheck / TcPat.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 TcPat: Typechecking patterns
7
8 \begin{code}
9 {-# OPTIONS -fno-warn-tabs #-}
10 -- The above warning supression flag is a temporary kludge.
11 -- While working on this module you are encouraged to remove it and
12 -- detab the module (please do the detabbing in a separate patch). See
13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
14 -- for details
15
16 module TcPat ( tcLetPat, TcSigFun, TcSigInfo(..), TcPragFun 
17              , LetBndrSpec(..), addInlinePrags, warnPrags
18              , tcPat, tcPats, newNoSigLetBndr, newSigLetBndr
19              , addDataConStupidTheta, badFieldCon, polyPatSig ) where
20
21 #include "HsVersions.h"
22
23 import {-# SOURCE #-}   TcExpr( tcSyntaxOp, tcInferRho)
24
25 import HsSyn
26 import TcHsSyn
27 import TcRnMonad
28 import Inst
29 import Id
30 import Var
31 import Name
32 import TcEnv
33 --import TcExpr
34 import TcMType
35 import TcValidity( arityErr )
36 import TcType
37 import TcUnify
38 import TcHsType
39 import TysWiredIn
40 import TcEvidence
41 import TyCon
42 import DataCon
43 import PrelNames
44 import BasicTypes hiding (SuccessFlag(..))
45 import DynFlags
46 import SrcLoc
47 import Util
48 import Outputable
49 import FastString
50 import Control.Monad
51 \end{code}
52
53
54 %************************************************************************
55 %*                                                                      *
56                 External interface
57 %*                                                                      *
58 %************************************************************************
59
60 \begin{code}
61 tcLetPat :: TcSigFun -> LetBndrSpec
62          -> LPat Name -> TcSigmaType 
63          -> TcM a
64          -> TcM (LPat TcId, a)
65 tcLetPat sig_fn no_gen pat pat_ty thing_inside
66   = tc_lpat pat pat_ty penv thing_inside 
67   where
68     penv = PE { pe_lazy = True
69               , pe_ctxt = LetPat sig_fn no_gen }
70
71 -----------------
72 tcPats :: HsMatchContext Name
73        -> [LPat Name]            -- Patterns,
74        -> [TcSigmaType]          --   and their types
75        -> TcM a                  --   and the checker for the body
76        -> TcM ([LPat TcId], a)
77
78 -- This is the externally-callable wrapper function
79 -- Typecheck the patterns, extend the environment to bind the variables,
80 -- do the thing inside, use any existentially-bound dictionaries to 
81 -- discharge parts of the returning LIE, and deal with pattern type
82 -- signatures
83
84 --   1. Initialise the PatState
85 --   2. Check the patterns
86 --   3. Check the body
87 --   4. Check that no existentials escape
88
89 tcPats ctxt pats pat_tys thing_inside
90   = tc_lpats penv pats pat_tys thing_inside
91   where
92     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
93
94 tcPat :: HsMatchContext Name
95       -> LPat Name -> TcSigmaType 
96       -> TcM a                 -- Checker for body, given
97                                -- its result type
98       -> TcM (LPat TcId, a)
99 tcPat ctxt pat pat_ty thing_inside
100   = tc_lpat pat pat_ty penv thing_inside
101   where
102     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
103    
104
105 -----------------
106 data PatEnv
107   = PE { pe_lazy :: Bool        -- True <=> lazy context, so no existentials allowed
108        , pe_ctxt :: PatCtxt     -- Context in which the whole pattern appears
109        }
110
111 data PatCtxt
112   = LamPat   -- Used for lambdas, case etc
113        (HsMatchContext Name) 
114
115   | LetPat   -- Used only for let(rec) bindings
116              -- See Note [Let binders]
117        TcSigFun        -- Tells type sig if any
118        LetBndrSpec     -- True <=> no generalisation of this let
119
120 data LetBndrSpec 
121   = LetLclBndr            -- The binder is just a local one;
122                           -- an AbsBinds will provide the global version
123
124   | LetGblBndr TcPragFun  -- There isn't going to be an AbsBinds;
125                           -- here is the inline-pragma information
126
127 makeLazy :: PatEnv -> PatEnv
128 makeLazy penv = penv { pe_lazy = True }
129
130 patSigCtxt :: PatEnv -> UserTypeCtxt
131 patSigCtxt (PE { pe_ctxt = LetPat {} }) = BindPatSigCtxt
132 patSigCtxt (PE { pe_ctxt = LamPat {} }) = LamPatSigCtxt
133
134 ---------------
135 type TcPragFun = Name -> [LSig Name]
136 type TcSigFun  = Name -> Maybe TcSigInfo
137
138 data TcSigInfo
139   = TcSigInfo {
140         sig_id     :: TcId,         --  *Polymorphic* binder for this value...
141
142         sig_tvs    :: [(Maybe Name, TcTyVar)],    
143                            -- Instantiated type and kind variables
144                            -- Just n <=> this skolem is lexically in scope with name n
145                            -- See Note [Kind vars in sig_tvs]
146                            -- See Note [More instantiated than scoped] in TcBinds
147
148         sig_theta  :: TcThetaType,  -- Instantiated theta
149
150         sig_tau    :: TcSigmaType,  -- Instantiated tau
151                                     -- See Note [sig_tau may be polymorphic]
152
153         sig_loc    :: SrcSpan       -- The location of the signature
154     }
155
156 instance Outputable TcSigInfo where
157     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau})
158         = ppr id <+> dcolon <+> vcat [ pprSigmaType (mkSigmaTy (map snd tyvars) theta tau)
159                                      , ppr (map fst tyvars) ]
160 \end{code}
161
162 Note [Kind vars in sig_tvs]
163 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
164 With kind polymorphism a signature like
165   f :: forall f a. f a -> f a
166 may actuallly give rise to 
167   f :: forall k. forall (f::k -> *) (a:k). f a -> f a
168 So the sig_tvs will be [k,f,a], but only f,a are scoped.
169 So the scoped ones are not necessarily the *inital* ones!
170
171
172 Note [sig_tau may be polymorphic]
173 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
174 Note that "sig_tau" might actually be a polymorphic type,
175 if the original function had a signature like
176    forall a. Eq a => forall b. Ord b => ....
177 But that's ok: tcMatchesFun (called by tcRhs) can deal with that
178 It happens, too!  See Note [Polymorphic methods] in TcClassDcl.
179
180 Note [Let binders]
181 ~~~~~~~~~~~~~~~~~~
182 eg   x :: Int
183      y :: Bool
184      (x,y) = e
185
186 ...more notes to add here..
187
188
189 Note [Existential check]
190 ~~~~~~~~~~~~~~~~~~~~~~~~
191 Lazy patterns can't bind existentials.  They arise in two ways:
192   * Let bindings      let { C a b = e } in b
193   * Twiddle patterns  f ~(C a b) = e
194 The pe_lazy field of PatEnv says whether we are inside a lazy
195 pattern (perhaps deeply)
196
197 If we aren't inside a lazy pattern then we can bind existentials,
198 but we need to be careful about "extra" tyvars. Consider
199     (\C x -> d) : pat_ty -> res_ty
200 When looking for existential escape we must check that the existential
201 bound by C don't unify with the free variables of pat_ty, OR res_ty
202 (or of course the environment).   Hence we need to keep track of the 
203 res_ty free vars.
204
205
206 %************************************************************************
207 %*                                                                      *
208                 Binders
209 %*                                                                      *
210 %************************************************************************
211
212 \begin{code}
213 tcPatBndr :: PatEnv -> Name -> TcSigmaType -> TcM (TcCoercion, TcId)
214 -- (coi, xp) = tcPatBndr penv x pat_ty
215 -- Then coi : pat_ty ~ typeof(xp)
216 --
217 tcPatBndr (PE { pe_ctxt = LetPat lookup_sig no_gen}) bndr_name pat_ty
218   | Just sig <- lookup_sig bndr_name
219   = do { bndr_id <- newSigLetBndr no_gen bndr_name sig
220        ; co <- unifyPatType (idType bndr_id) pat_ty
221        ; return (co, bndr_id) }
222       
223   | otherwise
224   = do { bndr_id <- newNoSigLetBndr no_gen bndr_name pat_ty
225        ; return (mkTcReflCo pat_ty, bndr_id) }
226
227 tcPatBndr (PE { pe_ctxt = _lam_or_proc }) bndr_name pat_ty
228   = do { bndr <- mkLocalBinder bndr_name pat_ty
229        ; return (mkTcReflCo pat_ty, bndr) }
230
231 ------------
232 newSigLetBndr :: LetBndrSpec -> Name -> TcSigInfo -> TcM TcId
233 newSigLetBndr LetLclBndr name sig
234   = do { mono_name <- newLocalName name
235        ; mkLocalBinder mono_name (sig_tau sig) }
236 newSigLetBndr (LetGblBndr prags) name sig
237   = addInlinePrags (sig_id sig) (prags name)
238
239 ------------
240 newNoSigLetBndr :: LetBndrSpec -> Name -> TcType -> TcM TcId
241 -- In the polymorphic case (no_gen = False), generate a "monomorphic version" 
242 --    of the Id; the original name will be bound to the polymorphic version
243 --    by the AbsBinds
244 -- In the monomorphic case there is no AbsBinds, and we use the original
245 --    name directly
246 newNoSigLetBndr LetLclBndr name ty 
247   =do  { mono_name <- newLocalName name
248        ; mkLocalBinder mono_name ty }
249 newNoSigLetBndr (LetGblBndr prags) name ty 
250   = do { id <- mkLocalBinder name ty
251        ; addInlinePrags id (prags name) }
252
253 ----------
254 addInlinePrags :: TcId -> [LSig Name] -> TcM TcId
255 addInlinePrags poly_id prags
256   = do { traceTc "addInlinePrags" (ppr poly_id $$ ppr prags) 
257        ; tc_inl inl_sigs }
258   where
259     inl_sigs = filter isInlineLSig prags
260     tc_inl [] = return poly_id
261     tc_inl (L loc (InlineSig _ prag) : other_inls)
262        = do { unless (null other_inls) (setSrcSpan loc warn_dup_inline)
263             ; traceTc "addInlinePrag" (ppr poly_id $$ ppr prag) 
264             ; return (poly_id `setInlinePragma` prag) }
265     tc_inl _ = panic "tc_inl"
266
267     warn_dup_inline = warnPrags poly_id inl_sigs $
268                       ptext (sLit "Duplicate INLINE pragmas for")
269
270 warnPrags :: Id -> [LSig Name] -> SDoc -> TcM ()
271 warnPrags id bad_sigs herald
272   = addWarnTc (hang (herald <+> quotes (ppr id))
273                   2 (ppr_sigs bad_sigs))
274   where
275     ppr_sigs sigs = vcat (map (ppr . getLoc) sigs)
276
277 -----------------
278 mkLocalBinder :: Name -> TcType -> TcM TcId
279 mkLocalBinder name ty
280   = return (Id.mkLocalId name ty)
281 \end{code}
282
283 Note [Polymorphism and pattern bindings]
284 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
285 When is_mono holds we are not generalising
286 But the signature can still be polymoprhic!
287      data T = MkT (forall a. a->a)
288      x :: forall a. a->a
289      MkT x = <rhs>
290 So the no_gen flag decides whether the pattern-bound variables should
291 have exactly the type in the type signature (when not generalising) or
292 the instantiated version (when generalising)
293
294 %************************************************************************
295 %*                                                                      *
296                 The main worker functions
297 %*                                                                      *
298 %************************************************************************
299
300 Note [Nesting]
301 ~~~~~~~~~~~~~~
302 tcPat takes a "thing inside" over which the pattern scopes.  This is partly
303 so that tcPat can extend the environment for the thing_inside, but also 
304 so that constraints arising in the thing_inside can be discharged by the
305 pattern.
306
307 This does not work so well for the ErrCtxt carried by the monad: we don't
308 want the error-context for the pattern to scope over the RHS. 
309 Hence the getErrCtxt/setErrCtxt stuff in tcMultiple
310
311 \begin{code}
312 --------------------
313 type Checker inp out =  forall r.
314                           inp
315                        -> PatEnv
316                        -> TcM r
317                        -> TcM (out, r)
318
319 tcMultiple :: Checker inp out -> Checker [inp] [out]
320 tcMultiple tc_pat args penv thing_inside
321   = do  { err_ctxt <- getErrCtxt
322         ; let loop _ []
323                 = do { res <- thing_inside
324                      ; return ([], res) }
325
326               loop penv (arg:args)
327                 = do { (p', (ps', res)) 
328                                 <- tc_pat arg penv $ 
329                                    setErrCtxt err_ctxt $
330                                    loop penv args
331                 -- setErrCtxt: restore context before doing the next pattern
332                 -- See note [Nesting] above
333                                 
334                      ; return (p':ps', res) }
335
336         ; loop penv args }
337
338 --------------------
339 tc_lpat :: LPat Name 
340         -> TcSigmaType
341         -> PatEnv
342         -> TcM a
343         -> TcM (LPat TcId, a)
344 tc_lpat (L span pat) pat_ty penv thing_inside
345   = setSrcSpan span $
346     do  { (pat', res) <- maybeWrapPatCtxt pat (tc_pat penv pat pat_ty)
347                                           thing_inside
348         ; return (L span pat', res) }
349
350 tc_lpats :: PatEnv
351          -> [LPat Name] -> [TcSigmaType]
352          -> TcM a       
353          -> TcM ([LPat TcId], a)
354 tc_lpats penv pats tys thing_inside 
355   = ASSERT2( equalLength pats tys, ppr pats $$ ppr tys )
356     tcMultiple (\(p,t) -> tc_lpat p t) 
357                 (zipEqual "tc_lpats" pats tys)
358                 penv thing_inside 
359
360 --------------------
361 tc_pat  :: PatEnv
362         -> Pat Name 
363         -> TcSigmaType  -- Fully refined result type
364         -> TcM a                -- Thing inside
365         -> TcM (Pat TcId,       -- Translated pattern
366                 a)              -- Result of thing inside
367
368 tc_pat penv (VarPat name) pat_ty thing_inside
369   = do  { (co, id) <- tcPatBndr penv name pat_ty
370         ; res <- tcExtendIdEnv1 name id thing_inside
371         ; return (mkHsWrapPatCo co (VarPat id) pat_ty, res) }
372
373 tc_pat penv (ParPat pat) pat_ty thing_inside
374   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
375         ; return (ParPat pat', res) }
376
377 tc_pat penv (BangPat pat) pat_ty thing_inside
378   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
379         ; return (BangPat pat', res) }
380
381 tc_pat penv lpat@(LazyPat pat) pat_ty thing_inside
382   = do  { (pat', (res, pat_ct)) 
383                 <- tc_lpat pat pat_ty (makeLazy penv) $ 
384                    captureConstraints thing_inside
385                 -- Ignore refined penv', revert to penv
386
387         ; emitConstraints pat_ct
388         -- captureConstraints/extendConstraints: 
389         --   see Note [Hopping the LIE in lazy patterns]
390
391         -- Check there are no unlifted types under the lazy pattern
392         ; when (any (isUnLiftedType . idType) $ collectPatBinders pat') $
393                lazyUnliftedPatErr lpat
394
395         -- Check that the expected pattern type is itself lifted
396         ; pat_ty' <- newFlexiTyVarTy liftedTypeKind
397         ; _ <- unifyType pat_ty pat_ty'
398
399         ; return (LazyPat pat', res) }
400
401 tc_pat _ p@(QuasiQuotePat _) _ _
402   = pprPanic "Should never see QuasiQuotePat in type checker" (ppr p)
403
404 tc_pat _ (WildPat _) pat_ty thing_inside
405   = do  { res <- thing_inside 
406         ; return (WildPat pat_ty, res) }
407
408 tc_pat penv (AsPat (L nm_loc name) pat) pat_ty thing_inside
409   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
410         ; (pat', res) <- tcExtendIdEnv1 name bndr_id $
411                          tc_lpat pat (idType bndr_id) penv thing_inside
412             -- NB: if we do inference on:
413             --          \ (y@(x::forall a. a->a)) = e
414             -- we'll fail.  The as-pattern infers a monotype for 'y', which then
415             -- fails to unify with the polymorphic type for 'x'.  This could 
416             -- perhaps be fixed, but only with a bit more work.
417             --
418             -- If you fix it, don't forget the bindInstsOfPatIds!
419         ; return (mkHsWrapPatCo co (AsPat (L nm_loc bndr_id) pat') pat_ty, res) }
420
421 tc_pat penv (ViewPat expr pat _) overall_pat_ty thing_inside 
422   = do  {
423          -- Morally, expr must have type `forall a1...aN. OPT' -> B` 
424          -- where overall_pat_ty is an instance of OPT'.
425          -- Here, we infer a rho type for it,
426          -- which replaces the leading foralls and constraints
427          -- with fresh unification variables.
428         ; (expr',expr'_inferred) <- tcInferRho expr
429
430          -- next, we check that expr is coercible to `overall_pat_ty -> pat_ty`
431          -- NOTE: this forces pat_ty to be a monotype (because we use a unification 
432          -- variable to find it).  this means that in an example like
433          -- (view -> f)    where view :: _ -> forall b. b
434          -- we will only be able to use view at one instantation in the
435          -- rest of the view
436         ; (expr_co, pat_ty) <- tcInfer $ \ pat_ty -> 
437                 unifyType expr'_inferred (mkFunTy overall_pat_ty pat_ty)
438         
439          -- pattern must have pat_ty
440         ; (pat', res) <- tc_lpat pat pat_ty penv thing_inside
441
442         ; return (ViewPat (mkLHsWrapCo expr_co expr') pat' overall_pat_ty, res) }
443
444 -- Type signatures in patterns
445 -- See Note [Pattern coercions] below
446 tc_pat penv (SigPatIn pat sig_ty) pat_ty thing_inside
447   = do  { (inner_ty, tv_binds, wrap) <- tcPatSig (patSigCtxt penv) sig_ty pat_ty
448         ; (pat', res) <- tcExtendTyVarEnv2 tv_binds $
449                          tc_lpat pat inner_ty penv thing_inside
450
451         ; return (mkHsWrapPat wrap (SigPatOut pat' inner_ty) pat_ty, res) }
452
453 ------------------------
454 -- Lists, tuples, arrays
455 tc_pat penv (ListPat pats _ Nothing) pat_ty thing_inside
456   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy pat_ty      
457         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
458                                      pats penv thing_inside
459         ; return (mkHsWrapPat coi (ListPat pats' elt_ty Nothing) pat_ty, res) 
460         }
461
462 tc_pat penv (ListPat pats _ (Just (_,e))) pat_ty thing_inside
463   = do  { list_pat_ty <- newFlexiTyVarTy liftedTypeKind
464         ; e' <- tcSyntaxOp ListOrigin e (mkFunTy pat_ty list_pat_ty)
465         ; (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy list_pat_ty
466         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
467                                      pats penv thing_inside
468         ; return (mkHsWrapPat coi (ListPat pats' elt_ty (Just (pat_ty,e'))) list_pat_ty, res) 
469         }
470
471 tc_pat penv (PArrPat pats _) pat_ty thing_inside
472   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedPArrTy pat_ty
473         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
474                                      pats penv thing_inside 
475         ; return (mkHsWrapPat coi (PArrPat pats' elt_ty) pat_ty, res)
476         }
477
478 tc_pat penv (TuplePat pats boxity _) pat_ty thing_inside
479   = do  { let tc = tupleTyCon (boxityNormalTupleSort boxity) (length pats)
480         ; (coi, arg_tys) <- matchExpectedPatTy (matchExpectedTyConApp tc) pat_ty
481         ; (pats', res) <- tc_lpats penv pats arg_tys thing_inside
482
483         ; dflags <- getDynFlags
484
485         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
486         -- so that we can experiment with lazy tuple-matching.
487         -- This is a pretty odd place to make the switch, but
488         -- it was easy to do.
489         ; let pat_ty'          = mkTyConApp tc arg_tys
490                                      -- pat_ty /= pat_ty iff coi /= IdCo
491               unmangled_result = TuplePat pats' boxity pat_ty'
492               possibly_mangled_result
493                 | gopt Opt_IrrefutableTuples dflags &&
494                   isBoxed boxity            = LazyPat (noLoc unmangled_result)
495                 | otherwise                 = unmangled_result
496
497         ; ASSERT( length arg_tys == length pats )      -- Syntactically enforced
498           return (mkHsWrapPat coi possibly_mangled_result pat_ty, res)
499         }
500
501 ------------------------
502 -- Data constructors
503 tc_pat penv (ConPatIn con arg_pats) pat_ty thing_inside
504   = tcConPat penv con pat_ty arg_pats thing_inside
505
506 ------------------------
507 -- Literal patterns
508 tc_pat _ (LitPat simple_lit) pat_ty thing_inside
509   = do  { let lit_ty = hsLitType simple_lit
510         ; co <- unifyPatType lit_ty pat_ty
511                 -- coi is of kind: pat_ty ~ lit_ty
512         ; res <- thing_inside 
513         ; return ( mkHsWrapPatCo co (LitPat simple_lit) pat_ty 
514                  , res) }
515
516 ------------------------
517 -- Overloaded patterns: n, and n+k
518 tc_pat _ (NPat over_lit mb_neg eq) pat_ty thing_inside
519   = do  { let orig = LiteralOrigin over_lit
520         ; lit'    <- newOverloadedLit orig over_lit pat_ty
521         ; eq'     <- tcSyntaxOp orig eq (mkFunTys [pat_ty, pat_ty] boolTy)
522         ; mb_neg' <- case mb_neg of
523                         Nothing  -> return Nothing      -- Positive literal
524                         Just neg ->     -- Negative literal
525                                         -- The 'negate' is re-mappable syntax
526                             do { neg' <- tcSyntaxOp orig neg (mkFunTy pat_ty pat_ty)
527                                ; return (Just neg') }
528         ; res <- thing_inside 
529         ; return (NPat lit' mb_neg' eq', res) }
530
531 tc_pat penv (NPlusKPat (L nm_loc name) lit ge minus) pat_ty thing_inside
532   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
533         ; let pat_ty' = idType bndr_id
534               orig    = LiteralOrigin lit
535         ; lit' <- newOverloadedLit orig lit pat_ty'
536
537         -- The '>=' and '-' parts are re-mappable syntax
538         ; ge'    <- tcSyntaxOp orig ge    (mkFunTys [pat_ty', pat_ty'] boolTy)
539         ; minus' <- tcSyntaxOp orig minus (mkFunTys [pat_ty', pat_ty'] pat_ty')
540         ; let pat' = NPlusKPat (L nm_loc bndr_id) lit' ge' minus'
541
542         -- The Report says that n+k patterns must be in Integral
543         -- We may not want this when using re-mappable syntax, though (ToDo?)
544         ; icls <- tcLookupClass integralClassName
545         ; instStupidTheta orig [mkClassPred icls [pat_ty']]     
546     
547         ; res <- tcExtendIdEnv1 name bndr_id thing_inside
548         ; return (mkHsWrapPatCo co pat' pat_ty, res) }
549
550 tc_pat _ _other_pat _ _ = panic "tc_pat"        -- ConPatOut, SigPatOut
551
552 ----------------
553 unifyPatType :: TcType -> TcType -> TcM TcCoercion
554 -- In patterns we want a coercion from the
555 -- context type (expected) to the actual pattern type
556 -- But we don't want to reverse the args to unifyType because
557 -- that controls the actual/expected stuff in error messages
558 unifyPatType actual_ty expected_ty
559   = do { coi <- unifyType actual_ty expected_ty
560        ; return (mkTcSymCo coi) }
561 \end{code}
562
563 Note [Hopping the LIE in lazy patterns]
564 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
565 In a lazy pattern, we must *not* discharge constraints from the RHS
566 from dictionaries bound in the pattern.  E.g.
567         f ~(C x) = 3
568 We can't discharge the Num constraint from dictionaries bound by
569 the pattern C!  
570
571 So we have to make the constraints from thing_inside "hop around" 
572 the pattern.  Hence the captureConstraints and emitConstraints.
573
574 The same thing ensures that equality constraints in a lazy match
575 are not made available in the RHS of the match. For example
576         data T a where { T1 :: Int -> T Int; ... }
577         f :: T a -> Int -> a
578         f ~(T1 i) y = y
579 It's obviously not sound to refine a to Int in the right
580 hand side, because the arugment might not match T1 at all!
581
582 Finally, a lazy pattern should not bind any existential type variables
583 because they won't be in scope when we do the desugaring
584
585
586 %************************************************************************
587 %*                                                                      *
588         Most of the work for constructors is here
589         (the rest is in the ConPatIn case of tc_pat)
590 %*                                                                      *
591 %************************************************************************
592
593 [Pattern matching indexed data types]
594 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
595 Consider the following declarations:
596
597   data family Map k :: * -> *
598   data instance Map (a, b) v = MapPair (Map a (Pair b v))
599
600 and a case expression
601
602   case x :: Map (Int, c) w of MapPair m -> ...
603
604 As explained by [Wrappers for data instance tycons] in MkIds.lhs, the
605 worker/wrapper types for MapPair are
606
607   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
608   $wMapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
609
610 So, the type of the scrutinee is Map (Int, c) w, but the tycon of MapPair is
611 :R123Map, which means the straight use of boxySplitTyConApp would give a type
612 error.  Hence, the smart wrapper function boxySplitTyConAppWithFamily calls
613 boxySplitTyConApp with the family tycon Map instead, which gives us the family
614 type list {(Int, c), w}.  To get the correct split for :R123Map, we need to
615 unify the family type list {(Int, c), w} with the instance types {(a, b), v}
616 (provided by tyConFamInst_maybe together with the family tycon).  This
617 unification yields the substitution [a -> Int, b -> c, v -> w], which gives us
618 the split arguments for the representation tycon :R123Map as {Int, c, w}
619
620 In other words, boxySplitTyConAppWithFamily implicitly takes the coercion 
621
622   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
623
624 moving between representation and family type into account.  To produce type
625 correct Core, this coercion needs to be used to case the type of the scrutinee
626 from the family to the representation type.  This is achieved by
627 unwrapFamInstScrutinee using a CoPat around the result pattern.
628
629 Now it might appear seem as if we could have used the previous GADT type
630 refinement infrastructure of refineAlt and friends instead of the explicit
631 unification and CoPat generation.  However, that would be wrong.  Why?  The
632 whole point of GADT refinement is that the refinement is local to the case
633 alternative.  In contrast, the substitution generated by the unification of
634 the family type list and instance types needs to be propagated to the outside.
635 Imagine that in the above example, the type of the scrutinee would have been
636 (Map x w), then we would have unified {x, w} with {(a, b), v}, yielding the
637 substitution [x -> (a, b), v -> w].  In contrast to GADT matching, the
638 instantiation of x with (a, b) must be global; ie, it must be valid in *all*
639 alternatives of the case expression, whereas in the GADT case it might vary
640 between alternatives.
641
642 RIP GADT refinement: refinements have been replaced by the use of explicit
643 equality constraints that are used in conjunction with implication constraints
644 to express the local scope of GADT refinements.
645
646 \begin{code}
647 --      Running example:
648 -- MkT :: forall a b c. (a~[b]) => b -> c -> T a
649 --       with scrutinee of type (T ty)
650
651 tcConPat :: PatEnv -> Located Name 
652          -> TcRhoType           -- Type of the pattern
653          -> HsConPatDetails Name -> TcM a
654          -> TcM (Pat TcId, a)
655 tcConPat penv (L con_span con_name) pat_ty arg_pats thing_inside
656   = do  { data_con <- tcLookupDataCon con_name
657         ; let tycon = dataConTyCon data_con
658                   -- For data families this is the representation tycon
659               (univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _)
660                 = dataConFullSig data_con
661
662           -- Instantiate the constructor type variables [a->ty]
663           -- This may involve doing a family-instance coercion, 
664           -- and building a wrapper 
665         ; (wrap, ctxt_res_tys) <- matchExpectedPatTy (matchExpectedConTy tycon) pat_ty
666
667           -- Add the stupid theta
668         ; setSrcSpan con_span $ addDataConStupidTheta data_con ctxt_res_tys
669
670         ; checkExistentials ex_tvs penv 
671         ; (tenv, ex_tvs') <- tcInstSuperSkolTyVarsX
672                                (zipTopTvSubst univ_tvs ctxt_res_tys) ex_tvs
673                      -- Get location from monad, not from ex_tvs
674
675         ; let pat_ty' = mkTyConApp tycon ctxt_res_tys
676               -- pat_ty' is type of the actual constructor application
677               -- pat_ty' /= pat_ty iff coi /= IdCo
678               
679               arg_tys' = substTys tenv arg_tys
680
681         ; if null ex_tvs && null eq_spec && null theta
682           then do { -- The common case; no class bindings etc 
683                     -- (see Note [Arrows and patterns])
684                     (arg_pats', res) <- tcConArgs data_con arg_tys' 
685                                                   arg_pats penv thing_inside
686                   ; let res_pat = ConPatOut { pat_con = L con_span data_con, 
687                                               pat_tvs = [], pat_dicts = [], 
688                                               pat_binds = emptyTcEvBinds,
689                                               pat_args = arg_pats', 
690                                               pat_ty = pat_ty' }
691
692                   ; return (mkHsWrapPat wrap res_pat pat_ty, res) }
693
694           else do   -- The general case, with existential, 
695                     -- and local equality constraints
696         { let theta'   = substTheta tenv (eqSpecPreds eq_spec ++ theta)
697                            -- order is *important* as we generate the list of
698                            -- dictionary binders from theta'
699               no_equalities = not (any isEqPred theta')
700               skol_info = case pe_ctxt penv of
701                             LamPat mc -> PatSkol data_con mc
702                             LetPat {} -> UnkSkol -- Doesn't matter
703  
704         ; gadts_on    <- xoptM Opt_GADTs
705         ; families_on <- xoptM Opt_TypeFamilies
706         ; checkTc (no_equalities || gadts_on || families_on)
707                   (ptext (sLit "A pattern match on a GADT requires -XGADTs or -XTypeFamilies"))
708                   -- Trac #2905 decided that a *pattern-match* of a GADT
709                   -- should require the GADT language flag.  
710                   -- Re TypeFamilies see also #7156 
711
712         ; given <- newEvVars theta'
713         ; (ev_binds, (arg_pats', res))
714              <- checkConstraints skol_info ex_tvs' given $
715                 tcConArgs data_con arg_tys' arg_pats penv thing_inside
716
717         ; let res_pat = ConPatOut { pat_con   = L con_span data_con, 
718                                     pat_tvs   = ex_tvs',
719                                     pat_dicts = given,
720                                     pat_binds = ev_binds,
721                                     pat_args  = arg_pats', 
722                                     pat_ty    = pat_ty' }
723         ; return (mkHsWrapPat wrap res_pat pat_ty, res)
724         } }
725
726 ----------------------------
727 matchExpectedPatTy :: (TcRhoType -> TcM (TcCoercion, a))
728                     -> TcRhoType -> TcM (HsWrapper, a) 
729 -- See Note [Matching polytyped patterns]
730 -- Returns a wrapper : pat_ty ~ inner_ty
731 matchExpectedPatTy inner_match pat_ty
732   | null tvs && null theta
733   = do { (co, res) <- inner_match pat_ty
734        ; return (coToHsWrapper (mkTcSymCo co), res) }
735          -- The Sym is because the inner_match returns a coercion
736          -- that is the other way round to matchExpectedPatTy
737
738   | otherwise
739   = do { (_, tys, subst) <- tcInstTyVars tvs
740        ; wrap1 <- instCall PatOrigin tys (substTheta subst theta)
741        ; (wrap2, arg_tys) <- matchExpectedPatTy inner_match (TcType.substTy subst tau)
742        ; return (wrap2 <.> wrap1 , arg_tys) }
743   where
744     (tvs, theta, tau) = tcSplitSigmaTy pat_ty
745
746 ----------------------------
747 matchExpectedConTy :: TyCon      -- The TyCon that this data 
748                                  -- constructor actually returns
749                    -> TcRhoType  -- The type of the pattern
750                    -> TcM (TcCoercion, [TcSigmaType])
751 -- See Note [Matching constructor patterns]
752 -- Returns a coercion : T ty1 ... tyn ~ pat_ty
753 -- This is the same way round as matchExpectedListTy etc
754 -- but the other way round to matchExpectedPatTy
755 matchExpectedConTy data_tc pat_ty
756   | Just (fam_tc, fam_args, co_tc) <- tyConFamInstSig_maybe data_tc
757          -- Comments refer to Note [Matching constructor patterns]
758          -- co_tc :: forall a. T [a] ~ T7 a
759   = do { (_, tys, subst) <- tcInstTyVars (tyConTyVars data_tc)
760              -- tys = [ty1,ty2]
761
762        ; traceTc "matchExpectedConTy" (vcat [ppr data_tc, 
763                                              ppr (tyConTyVars data_tc),
764                                              ppr fam_tc, ppr fam_args])
765        ; co1 <- unifyType (mkTyConApp fam_tc (substTys subst fam_args)) pat_ty
766              -- co1 : T (ty1,ty2) ~ pat_ty
767
768        ; let co2 = mkTcUnbranchedAxInstCo co_tc tys
769              -- co2 : T (ty1,ty2) ~ T7 ty1 ty2
770
771        ; return (mkTcSymCo co2 `mkTcTransCo` co1, tys) }
772
773   | otherwise
774   = matchExpectedTyConApp data_tc pat_ty
775              -- coi : T tys ~ pat_ty
776 \end{code}
777
778 Note [Matching constructor patterns]
779 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
780 Suppose (coi, tys) = matchExpectedConType data_tc pat_ty
781
782  * In the simple case, pat_ty = tc tys
783
784  * If pat_ty is a polytype, we want to instantiate it
785    This is like part of a subsumption check.  Eg
786       f :: (forall a. [a]) -> blah
787       f [] = blah
788
789  * In a type family case, suppose we have
790           data family T a
791           data instance T (p,q) = A p | B q
792        Then we'll have internally generated
793               data T7 p q = A p | B q
794               axiom coT7 p q :: T (p,q) ~ T7 p q
795  
796        So if pat_ty = T (ty1,ty2), we return (coi, [ty1,ty2]) such that
797            coi = coi2 . coi1 : T7 t ~ pat_ty
798            coi1 : T (ty1,ty2) ~ pat_ty
799            coi2 : T7 ty1 ty2 ~ T (ty1,ty2)
800
801    For families we do all this matching here, not in the unifier,
802    because we never want a whisper of the data_tycon to appear in
803    error messages; it's a purely internal thing
804
805 \begin{code}
806 tcConArgs :: DataCon -> [TcSigmaType]
807           -> Checker (HsConPatDetails Name) (HsConPatDetails Id)
808
809 tcConArgs data_con arg_tys (PrefixCon arg_pats) penv thing_inside
810   = do  { checkTc (con_arity == no_of_args)     -- Check correct arity
811                   (arityErr "Constructor" data_con con_arity no_of_args)
812         ; let pats_w_tys = zipEqual "tcConArgs" arg_pats arg_tys
813         ; (arg_pats', res) <- tcMultiple tcConArg pats_w_tys
814                                               penv thing_inside 
815         ; return (PrefixCon arg_pats', res) }
816   where
817     con_arity  = dataConSourceArity data_con
818     no_of_args = length arg_pats
819
820 tcConArgs data_con arg_tys (InfixCon p1 p2) penv thing_inside
821   = do  { checkTc (con_arity == 2)      -- Check correct arity
822                   (arityErr "Constructor" data_con con_arity 2)
823         ; let [arg_ty1,arg_ty2] = arg_tys       -- This can't fail after the arity check
824         ; ([p1',p2'], res) <- tcMultiple tcConArg [(p1,arg_ty1),(p2,arg_ty2)]
825                                               penv thing_inside
826         ; return (InfixCon p1' p2', res) }
827   where
828     con_arity  = dataConSourceArity data_con
829
830 tcConArgs data_con arg_tys (RecCon (HsRecFields rpats dd)) penv thing_inside
831   = do  { (rpats', res) <- tcMultiple tc_field rpats penv thing_inside
832         ; return (RecCon (HsRecFields rpats' dd), res) }
833   where
834     tc_field :: Checker (HsRecField FieldLabel (LPat Name)) (HsRecField TcId (LPat TcId))
835     tc_field (HsRecField field_lbl pat pun) penv thing_inside
836       = do { (sel_id, pat_ty) <- wrapLocFstM find_field_ty field_lbl
837            ; (pat', res) <- tcConArg (pat, pat_ty) penv thing_inside
838            ; return (HsRecField sel_id pat' pun, res) }
839
840     find_field_ty :: FieldLabel -> TcM (Id, TcType)
841     find_field_ty field_lbl
842         = case [ty | (f,ty) <- field_tys, f == field_lbl] of
843
844                 -- No matching field; chances are this field label comes from some
845                 -- other record type (or maybe none).  As well as reporting an
846                 -- error we still want to typecheck the pattern, principally to
847                 -- make sure that all the variables it binds are put into the
848                 -- environment, else the type checker crashes later:
849                 --      f (R { foo = (a,b) }) = a+b
850                 -- If foo isn't one of R's fields, we don't want to crash when
851                 -- typechecking the "a+b".
852            [] -> do { addErrTc (badFieldCon data_con field_lbl)
853                     ; bogus_ty <- newFlexiTyVarTy liftedTypeKind
854                     ; return (error "Bogus selector Id", bogus_ty) }
855
856                 -- The normal case, when the field comes from the right constructor
857            (pat_ty : extras) -> 
858                 ASSERT( null extras )
859                 do { sel_id <- tcLookupField field_lbl
860                    ; return (sel_id, pat_ty) }
861
862     field_tys :: [(FieldLabel, TcType)]
863     field_tys = zip (dataConFieldLabels data_con) arg_tys
864         -- Don't use zipEqual! If the constructor isn't really a record, then
865         -- dataConFieldLabels will be empty (and each field in the pattern
866         -- will generate an error below).
867
868 tcConArg :: Checker (LPat Name, TcSigmaType) (LPat Id)
869 tcConArg (arg_pat, arg_ty) penv thing_inside
870   = tc_lpat arg_pat arg_ty penv thing_inside
871 \end{code}
872
873 \begin{code}
874 addDataConStupidTheta :: DataCon -> [TcType] -> TcM ()
875 -- Instantiate the "stupid theta" of the data con, and throw 
876 -- the constraints into the constraint set
877 addDataConStupidTheta data_con inst_tys
878   | null stupid_theta = return ()
879   | otherwise         = instStupidTheta origin inst_theta
880   where
881     origin = OccurrenceOf (dataConName data_con)
882         -- The origin should always report "occurrence of C"
883         -- even when C occurs in a pattern
884     stupid_theta = dataConStupidTheta data_con
885     tenv = mkTopTvSubst (dataConUnivTyVars data_con `zip` inst_tys)
886          -- NB: inst_tys can be longer than the univ tyvars
887          --     because the constructor might have existentials
888     inst_theta = substTheta tenv stupid_theta
889 \end{code}
890
891 Note [Arrows and patterns]
892 ~~~~~~~~~~~~~~~~~~~~~~~~~~
893 (Oct 07) Arrow noation has the odd property that it involves 
894 "holes in the scope". For example:
895   expr :: Arrow a => a () Int
896   expr = proc (y,z) -> do
897           x <- term -< y
898           expr' -< x
899
900 Here the 'proc (y,z)' binding scopes over the arrow tails but not the
901 arrow body (e.g 'term').  As things stand (bogusly) all the
902 constraints from the proc body are gathered together, so constraints
903 from 'term' will be seen by the tcPat for (y,z).  But we must *not*
904 bind constraints from 'term' here, because the desugarer will not make
905 these bindings scope over 'term'.
906
907 The Right Thing is not to confuse these constraints together. But for
908 now the Easy Thing is to ensure that we do not have existential or
909 GADT constraints in a 'proc', and to short-cut the constraint
910 simplification for such vanilla patterns so that it binds no
911 constraints. Hence the 'fast path' in tcConPat; but it's also a good
912 plan for ordinary vanilla patterns to bypass the constraint
913 simplification step.
914
915 %************************************************************************
916 %*                                                                      *
917                 Note [Pattern coercions]
918 %*                                                                      *
919 %************************************************************************
920
921 In principle, these program would be reasonable:
922         
923         f :: (forall a. a->a) -> Int
924         f (x :: Int->Int) = x 3
925
926         g :: (forall a. [a]) -> Bool
927         g [] = True
928
929 In both cases, the function type signature restricts what arguments can be passed
930 in a call (to polymorphic ones).  The pattern type signature then instantiates this
931 type.  For example, in the first case,  (forall a. a->a) <= Int -> Int, and we
932 generate the translated term
933         f = \x' :: (forall a. a->a).  let x = x' Int in x 3
934
935 From a type-system point of view, this is perfectly fine, but it's *very* seldom useful.
936 And it requires a significant amount of code to implement, because we need to decorate
937 the translated pattern with coercion functions (generated from the subsumption check 
938 by tcSub).  
939
940 So for now I'm just insisting on type *equality* in patterns.  No subsumption. 
941
942 Old notes about desugaring, at a time when pattern coercions were handled:
943
944 A SigPat is a type coercion and must be handled one at at time.  We can't
945 combine them unless the type of the pattern inside is identical, and we don't
946 bother to check for that.  For example:
947
948         data T = T1 Int | T2 Bool
949         f :: (forall a. a -> a) -> T -> t
950         f (g::Int->Int)   (T1 i) = T1 (g i)
951         f (g::Bool->Bool) (T2 b) = T2 (g b)
952
953 We desugar this as follows:
954
955         f = \ g::(forall a. a->a) t::T ->
956             let gi = g Int
957             in case t of { T1 i -> T1 (gi i)
958                            other ->
959             let gb = g Bool
960             in case t of { T2 b -> T2 (gb b)
961                            other -> fail }}
962
963 Note that we do not treat the first column of patterns as a
964 column of variables, because the coerced variables (gi, gb)
965 would be of different types.  So we get rather grotty code.
966 But I don't think this is a common case, and if it was we could
967 doubtless improve it.
968
969 Meanwhile, the strategy is:
970         * treat each SigPat coercion (always non-identity coercions)
971                 as a separate block
972         * deal with the stuff inside, and then wrap a binding round
973                 the result to bind the new variable (gi, gb, etc)
974
975
976 %************************************************************************
977 %*                                                                      *
978 \subsection{Errors and contexts}
979 %*                                                                      *
980 %************************************************************************
981
982 \begin{code}
983 maybeWrapPatCtxt :: Pat Name -> (TcM a -> TcM b) -> TcM a -> TcM b
984 -- Not all patterns are worth pushing a context
985 maybeWrapPatCtxt pat tcm thing_inside 
986   | not (worth_wrapping pat) = tcm thing_inside
987   | otherwise                = addErrCtxt msg $ tcm $ popErrCtxt thing_inside
988                                -- Remember to pop before doing thing_inside
989   where
990    worth_wrapping (VarPat {}) = False
991    worth_wrapping (ParPat {}) = False
992    worth_wrapping (AsPat {})  = False
993    worth_wrapping _           = True
994    msg = hang (ptext (sLit "In the pattern:")) 2 (ppr pat)
995
996 -----------------------------------------------
997 checkExistentials :: [TyVar] -> PatEnv -> TcM ()
998           -- See Note [Arrows and patterns]
999 checkExistentials [] _                                 = return ()
1000 checkExistentials _ (PE { pe_ctxt = LetPat {}})        = failWithTc existentialLetPat
1001 checkExistentials _ (PE { pe_ctxt = LamPat ProcExpr }) = failWithTc existentialProcPat
1002 checkExistentials _ (PE { pe_lazy = True })            = failWithTc existentialLazyPat
1003 checkExistentials _ _                                  = return ()
1004
1005 existentialLazyPat :: SDoc
1006 existentialLazyPat
1007   = hang (ptext (sLit "An existential or GADT data constructor cannot be used"))
1008        2 (ptext (sLit "inside a lazy (~) pattern"))
1009
1010 existentialProcPat :: SDoc
1011 existentialProcPat 
1012   = ptext (sLit "Proc patterns cannot use existential or GADT data constructors")
1013
1014 existentialLetPat :: SDoc
1015 existentialLetPat
1016   = vcat [text "My brain just exploded",
1017           text "I can't handle pattern bindings for existential or GADT data constructors.",
1018           text "Instead, use a case-expression, or do-notation, to unpack the constructor."]
1019
1020 badFieldCon :: DataCon -> Name -> SDoc
1021 badFieldCon con field
1022   = hsep [ptext (sLit "Constructor") <+> quotes (ppr con),
1023           ptext (sLit "does not have field"), quotes (ppr field)]
1024
1025 polyPatSig :: TcType -> SDoc
1026 polyPatSig sig_ty
1027   = hang (ptext (sLit "Illegal polymorphic type signature in pattern:"))
1028        2 (ppr sig_ty)
1029
1030 lazyUnliftedPatErr :: OutputableBndr name => Pat name -> TcM ()
1031 lazyUnliftedPatErr pat
1032   = failWithTc $
1033     hang (ptext (sLit "A lazy (~) pattern cannot contain unlifted types:"))
1034        2 (ppr pat)
1035 \end{code}