Pass DynFlags down to wordWidth
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 --
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 module AsmCodeGen ( nativeCodeGen ) where
11
12 #include "HsVersions.h"
13 #include "nativeGen/NCG.h"
14
15
16 import qualified X86.CodeGen
17 import qualified X86.Regs
18 import qualified X86.Instr
19 import qualified X86.Ppr
20
21 import qualified SPARC.CodeGen
22 import qualified SPARC.Regs
23 import qualified SPARC.Instr
24 import qualified SPARC.Ppr
25 import qualified SPARC.ShortcutJump
26 import qualified SPARC.CodeGen.Expand
27
28 import qualified PPC.CodeGen
29 import qualified PPC.Cond
30 import qualified PPC.Regs
31 import qualified PPC.RegInfo
32 import qualified PPC.Instr
33 import qualified PPC.Ppr
34
35 import RegAlloc.Liveness
36 import qualified RegAlloc.Linear.Main           as Linear
37
38 import qualified GraphColor                     as Color
39 import qualified RegAlloc.Graph.Main            as Color
40 import qualified RegAlloc.Graph.Stats           as Color
41 import qualified RegAlloc.Graph.TrivColorable   as Color
42
43 import TargetReg
44 import Platform
45 import Config
46 import Instruction
47 import PIC
48 import Reg
49 import NCGMonad
50
51 import BlockId
52 import CgUtils          ( fixStgRegisters )
53 import OldCmm
54 import CmmOpt           ( cmmEliminateDeadBlocks, cmmMiniInline, cmmMachOpFold )
55 import OldPprCmm
56 import CLabel
57
58 import UniqFM
59 import UniqSupply
60 import DynFlags
61 import Util
62
63 import BasicTypes       ( Alignment )
64 import Digraph
65 import qualified Pretty
66 import BufWrite
67 import Outputable
68 import FastString
69 import UniqSet
70 import ErrUtils
71 import Module
72 import Stream (Stream)
73 import qualified Stream
74
75 -- DEBUGGING ONLY
76 --import OrdList
77
78 import Data.List
79 import Data.Maybe
80 import Control.Monad
81 import System.IO
82
83 {-
84 The native-code generator has machine-independent and
85 machine-dependent modules.
86
87 This module ("AsmCodeGen") is the top-level machine-independent
88 module.  Before entering machine-dependent land, we do some
89 machine-independent optimisations (defined below) on the
90 'CmmStmts's.
91
92 We convert to the machine-specific 'Instr' datatype with
93 'cmmCodeGen', assuming an infinite supply of registers.  We then use
94 a machine-independent register allocator ('regAlloc') to rejoin
95 reality.  Obviously, 'regAlloc' has machine-specific helper
96 functions (see about "RegAllocInfo" below).
97
98 Finally, we order the basic blocks of the function so as to minimise
99 the number of jumps between blocks, by utilising fallthrough wherever
100 possible.
101
102 The machine-dependent bits break down as follows:
103
104   * ["MachRegs"]  Everything about the target platform's machine
105     registers (and immediate operands, and addresses, which tend to
106     intermingle/interact with registers).
107
108   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
109     have a module of its own), plus a miscellany of other things
110     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
111
112   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
113     machine instructions.
114
115   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
116     a 'SDoc').
117
118   * ["RegAllocInfo"] In the register allocator, we manipulate
119     'MRegsState's, which are 'BitSet's, one bit per machine register.
120     When we want to say something about a specific machine register
121     (e.g., ``it gets clobbered by this instruction''), we set/unset
122     its bit.  Obviously, we do this 'BitSet' thing for efficiency
123     reasons.
124
125     The 'RegAllocInfo' module collects together the machine-specific
126     info needed to do register allocation.
127
128    * ["RegisterAlloc"] The (machine-independent) register allocator.
129 -}
130
131 -- -----------------------------------------------------------------------------
132 -- Top-level of the native codegen
133
134 data NcgImpl statics instr jumpDest = NcgImpl {
135     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
136     generateJumpTableForInstr :: DynFlags -> instr -> Maybe (NatCmmDecl statics instr),
137     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
138     canShortcut               :: instr -> Maybe jumpDest,
139     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
140     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
141     pprNatCmmDecl             :: NatCmmDecl statics instr -> SDoc,
142     maxSpillSlots             :: Int,
143     allocatableRegs           :: Platform -> [RealReg],
144     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
145     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
146     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
147     }
148
149 --------------------
150 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
151 nativeCodeGen dflags h us cmms
152  = let platform = targetPlatform dflags
153        nCG' :: (Outputable statics, Outputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
154        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
155        x86NcgImpl = NcgImpl {
156                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
157                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr
158                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
159                         ,canShortcut               = X86.Instr.canShortcut
160                         ,shortcutStatics           = X86.Instr.shortcutStatics
161                         ,shortcutJump              = X86.Instr.shortcutJump
162                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
163                         ,maxSpillSlots             = X86.Instr.maxSpillSlots (target32Bit platform)
164                         ,allocatableRegs           = X86.Regs.allocatableRegs
165                         ,ncg_x86fp_kludge          = id
166                         ,ncgExpandTop              = id
167                         ,ncgMakeFarBranches        = id
168                     }
169    in case platformArch platform of
170                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
171                  ArchX86_64 -> nCG' x86NcgImpl
172                  ArchPPC ->
173                      nCG' $ NcgImpl {
174                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
175                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr
176                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
177                          ,canShortcut               = PPC.RegInfo.canShortcut
178                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
179                          ,shortcutJump              = PPC.RegInfo.shortcutJump
180                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
181                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots
182                          ,allocatableRegs           = PPC.Regs.allocatableRegs
183                          ,ncg_x86fp_kludge          = id
184                          ,ncgExpandTop              = id
185                          ,ncgMakeFarBranches        = makeFarBranches
186                      }
187                  ArchSPARC ->
188                      nCG' $ NcgImpl {
189                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
190                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr
191                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
192                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
193                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
194                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
195                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
196                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots
197                          ,allocatableRegs           = \_ -> SPARC.Regs.allocatableRegs
198                          ,ncg_x86fp_kludge          = id
199                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
200                          ,ncgMakeFarBranches        = id
201                      }
202                  ArchARM _ _ _ ->
203                      panic "nativeCodeGen: No NCG for ARM"
204                  ArchPPC_64 ->
205                      panic "nativeCodeGen: No NCG for PPC 64"
206                  ArchUnknown ->
207                      panic "nativeCodeGen: No NCG for unknown arch"
208
209 nativeCodeGen' :: (Outputable statics, Outputable instr, Instruction instr)
210                => DynFlags
211                -> NcgImpl statics instr jumpDest
212                -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
213 nativeCodeGen' dflags ncgImpl h us cmms
214  = do
215         let platform = targetPlatform dflags
216             split_cmms  = Stream.map add_split cmms
217         -- BufHandle is a performance hack.  We could hide it inside
218         -- Pretty if it weren't for the fact that we do lots of little
219         -- printDocs here (in order to do codegen in constant space).
220         bufh <- newBufHandle h
221         (imports, prof) <- cmmNativeGenStream dflags ncgImpl bufh us split_cmms [] [] 0
222         bFlush bufh
223
224         let (native, colorStats, linearStats)
225                 = unzip3 prof
226
227         -- dump native code
228         dumpIfSet_dyn dflags
229                 Opt_D_dump_asm "Asm code"
230                 (vcat $ map (pprNatCmmDecl ncgImpl) $ concat native)
231
232         -- dump global NCG stats for graph coloring allocator
233         (case concat $ catMaybes colorStats of
234           []    -> return ()
235           stats -> do
236                 -- build the global register conflict graph
237                 let graphGlobal
238                         = foldl Color.union Color.initGraph
239                         $ [ Color.raGraph stat
240                                 | stat@Color.RegAllocStatsStart{} <- stats]
241
242                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
243                         $ Color.pprStats stats graphGlobal
244
245                 dumpIfSet_dyn dflags
246                         Opt_D_dump_asm_conflicts "Register conflict graph"
247                         $ Color.dotGraph
248                                 (targetRegDotColor platform)
249                                 (Color.trivColorable platform
250                                         (targetVirtualRegSqueeze platform)
251                                         (targetRealRegSqueeze platform))
252                         $ graphGlobal)
253
254
255         -- dump global NCG stats for linear allocator
256         (case concat $ catMaybes linearStats of
257                 []      -> return ()
258                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
259                                 $ Linear.pprStats (concat native) stats)
260
261         -- write out the imports
262         Pretty.printDoc Pretty.LeftMode (pprCols dflags) h
263                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
264                 $ makeImportsDoc dflags (concat imports)
265
266         return  ()
267
268  where  add_split tops
269                 | dopt Opt_SplitObjs dflags = split_marker : tops
270                 | otherwise                 = tops
271
272         split_marker = CmmProc mapEmpty mkSplitMarkerLabel (ListGraph [])
273
274
275 cmmNativeGenStream :: (Outputable statics, Outputable instr, Instruction instr)
276               => DynFlags
277               -> NcgImpl statics instr jumpDest
278               -> BufHandle
279               -> UniqSupply
280               -> Stream IO RawCmmGroup ()
281               -> [[CLabel]]
282               -> [ ([NatCmmDecl statics instr],
283                    Maybe [Color.RegAllocStats statics instr],
284                    Maybe [Linear.RegAllocStats]) ]
285               -> Int
286               -> IO ( [[CLabel]],
287                       [([NatCmmDecl statics instr],
288                       Maybe [Color.RegAllocStats statics instr],
289                       Maybe [Linear.RegAllocStats])] )
290
291 cmmNativeGenStream dflags ncgImpl h us cmm_stream impAcc profAcc count
292  = do
293         r <- Stream.runStream cmm_stream
294         case r of
295           Left () -> return (reverse impAcc, reverse profAcc)
296           Right (cmms, cmm_stream') -> do
297             (impAcc,profAcc,us') <- cmmNativeGens dflags ncgImpl h us cmms
298                                               impAcc profAcc count
299             cmmNativeGenStream dflags ncgImpl h us' cmm_stream'
300                                               impAcc profAcc count
301
302
303 -- | Do native code generation on all these cmms.
304 --
305 cmmNativeGens :: (Outputable statics, Outputable instr, Instruction instr)
306               => DynFlags
307               -> NcgImpl statics instr jumpDest
308               -> BufHandle
309               -> UniqSupply
310               -> [RawCmmDecl]
311               -> [[CLabel]]
312               -> [ ([NatCmmDecl statics instr],
313                    Maybe [Color.RegAllocStats statics instr],
314                    Maybe [Linear.RegAllocStats]) ]
315               -> Int
316               -> IO ( [[CLabel]],
317                       [([NatCmmDecl statics instr],
318                        Maybe [Color.RegAllocStats statics instr],
319                        Maybe [Linear.RegAllocStats])],
320                       UniqSupply )
321
322 cmmNativeGens _ _ _ us [] impAcc profAcc _
323         = return (impAcc,profAcc,us)
324
325 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
326  = do
327         (us', native, imports, colorStats, linearStats)
328                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
329
330         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
331                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
332                 $ vcat $ map (pprNatCmmDecl ncgImpl) native
333
334            -- carefully evaluate this strictly.  Binding it with 'let'
335            -- and then using 'seq' doesn't work, because the let
336            -- apparently gets inlined first.
337         lsPprNative <- return $!
338                 if  dopt Opt_D_dump_asm       dflags
339                  || dopt Opt_D_dump_asm_stats dflags
340                         then native
341                         else []
342
343         count' <- return $! count + 1;
344
345         -- force evaulation all this stuff to avoid space leaks
346         {-# SCC "seqString" #-} seqString (showSDoc dflags $ vcat $ map ppr imports) `seq` return ()
347
348         cmmNativeGens dflags ncgImpl
349             h us' cmms
350                         (imports : impAcc)
351                         ((lsPprNative, colorStats, linearStats) : profAcc)
352                         count'
353
354  where  seqString []            = ()
355         seqString (x:xs)        = x `seq` seqString xs `seq` ()
356
357
358 -- | Complete native code generation phase for a single top-level chunk of Cmm.
359 --      Dumping the output of each stage along the way.
360 --      Global conflict graph and NGC stats
361 cmmNativeGen
362         :: (Outputable statics, Outputable instr, Instruction instr)
363     => DynFlags
364     -> NcgImpl statics instr jumpDest
365         -> UniqSupply
366         -> RawCmmDecl                                   -- ^ the cmm to generate code for
367         -> Int                                          -- ^ sequence number of this top thing
368         -> IO   ( UniqSupply
369                 , [NatCmmDecl statics instr]                -- native code
370                 , [CLabel]                                  -- things imported by this cmm
371                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
372                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
373
374 cmmNativeGen dflags ncgImpl us cmm count
375  = do
376         let platform = targetPlatform dflags
377
378         -- rewrite assignments to global regs
379         let fixed_cmm =
380                 {-# SCC "fixStgRegisters" #-}
381                 fixStgRegisters dflags cmm
382
383         -- cmm to cmm optimisations
384         let (opt_cmm, imports) =
385                 {-# SCC "cmmToCmm" #-}
386                 cmmToCmm dflags fixed_cmm
387
388         dumpIfSet_dyn dflags
389                 Opt_D_dump_opt_cmm "Optimised Cmm"
390                 (pprCmmGroup [opt_cmm])
391
392         -- generate native code from cmm
393         let ((native, lastMinuteImports), usGen) =
394                 {-# SCC "genMachCode" #-}
395                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
396
397         dumpIfSet_dyn dflags
398                 Opt_D_dump_asm_native "Native code"
399                 (vcat $ map (pprNatCmmDecl ncgImpl) native)
400
401         -- tag instructions with register liveness information
402         let (withLiveness, usLive) =
403                 {-# SCC "regLiveness" #-}
404                 initUs usGen
405                         $ mapM (regLiveness platform)
406                         $ map natCmmTopToLive native
407
408         dumpIfSet_dyn dflags
409                 Opt_D_dump_asm_liveness "Liveness annotations added"
410                 (vcat $ map ppr withLiveness)
411
412         -- allocate registers
413         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
414          if ( dopt Opt_RegsGraph dflags
415            || dopt Opt_RegsIterative dflags)
416           then do
417                 -- the regs usable for allocation
418                 let (alloc_regs :: UniqFM (UniqSet RealReg))
419                         = foldr (\r -> plusUFM_C unionUniqSets
420                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
421                                 emptyUFM
422                         $ allocatableRegs ncgImpl platform
423
424                 -- do the graph coloring register allocation
425                 let ((alloced, regAllocStats), usAlloc)
426                         = {-# SCC "RegAlloc" #-}
427                           initUs usLive
428                           $ Color.regAlloc
429                                 dflags
430                                 alloc_regs
431                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
432                                 withLiveness
433
434                 -- dump out what happened during register allocation
435                 dumpIfSet_dyn dflags
436                         Opt_D_dump_asm_regalloc "Registers allocated"
437                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
438
439                 dumpIfSet_dyn dflags
440                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
441                         (vcat   $ map (\(stage, stats)
442                                         -> text "# --------------------------"
443                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
444                                         $$ ppr stats)
445                                 $ zip [0..] regAllocStats)
446
447                 let mPprStats =
448                         if dopt Opt_D_dump_asm_stats dflags
449                          then Just regAllocStats else Nothing
450
451                 -- force evaluation of the Maybe to avoid space leak
452                 mPprStats `seq` return ()
453
454                 return  ( alloced, usAlloc
455                         , mPprStats
456                         , Nothing)
457
458           else do
459                 -- do linear register allocation
460                 let ((alloced, regAllocStats), usAlloc)
461                         = {-# SCC "RegAlloc" #-}
462                           initUs usLive
463                           $ liftM unzip
464                           $ mapM (Linear.regAlloc dflags) withLiveness
465
466                 dumpIfSet_dyn dflags
467                         Opt_D_dump_asm_regalloc "Registers allocated"
468                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
469
470                 let mPprStats =
471                         if dopt Opt_D_dump_asm_stats dflags
472                          then Just (catMaybes regAllocStats) else Nothing
473
474                 -- force evaluation of the Maybe to avoid space leak
475                 mPprStats `seq` return ()
476
477                 return  ( alloced, usAlloc
478                         , Nothing
479                         , mPprStats)
480
481         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
482         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
483         ---- is clear, and library functions can return odd results if it
484         ---- isn't.
485         ----
486         ---- NB. must happen before shortcutBranches, because that
487         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
488         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
489
490         ---- generate jump tables
491         let tabled      =
492                 {-# SCC "generateJumpTables" #-}
493                 generateJumpTables dflags ncgImpl kludged
494
495         ---- shortcut branches
496         let shorted     =
497                 {-# SCC "shortcutBranches" #-}
498                 shortcutBranches dflags ncgImpl tabled
499
500         ---- sequence blocks
501         let sequenced   =
502                 {-# SCC "sequenceBlocks" #-}
503                 map (sequenceTop ncgImpl) shorted
504
505         ---- expansion of SPARC synthetic instrs
506         let expanded =
507                 {-# SCC "sparc_expand" #-}
508                 ncgExpandTop ncgImpl sequenced
509
510         dumpIfSet_dyn dflags
511                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
512                 (vcat $ map (pprNatCmmDecl ncgImpl) expanded)
513
514         return  ( usAlloc
515                 , expanded
516                 , lastMinuteImports ++ imports
517                 , ppr_raStatsColor
518                 , ppr_raStatsLinear)
519
520
521 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
522 x86fp_kludge top@(CmmData _ _) = top
523 x86fp_kludge (CmmProc info lbl (ListGraph code)) =
524         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
525
526
527 -- | Build a doc for all the imports.
528 --
529 makeImportsDoc :: DynFlags -> [CLabel] -> SDoc
530 makeImportsDoc dflags imports
531  = dyld_stubs imports
532             $$
533             -- On recent versions of Darwin, the linker supports
534             -- dead-stripping of code and data on a per-symbol basis.
535             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
536             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
537              then text ".subsections_via_symbols"
538              else empty)
539             $$
540                 -- On recent GNU ELF systems one can mark an object file
541                 -- as not requiring an executable stack. If all objects
542                 -- linked into a program have this note then the program
543                 -- will not use an executable stack, which is good for
544                 -- security. GHC generated code does not need an executable
545                 -- stack so add the note in:
546             (if platformHasGnuNonexecStack (targetPlatform dflags)
547              then text ".section .note.GNU-stack,\"\",@progbits"
548              else empty)
549             $$
550                 -- And just because every other compiler does, lets stick in
551                 -- an identifier directive: .ident "GHC x.y.z"
552             (if platformHasIdentDirective (targetPlatform dflags)
553              then let compilerIdent = text "GHC" <+> text cProjectVersion
554                    in text ".ident" <+> doubleQuotes compilerIdent
555              else empty)
556
557  where
558         -- Generate "symbol stubs" for all external symbols that might
559         -- come from a dynamic library.
560         dyld_stubs :: [CLabel] -> SDoc
561 {-      dyld_stubs imps = vcat $ map pprDyldSymbolStub $
562                                     map head $ group $ sort imps-}
563
564         platform = targetPlatform dflags
565         arch = platformArch platform
566         os   = platformOS   platform
567
568         -- (Hack) sometimes two Labels pretty-print the same, but have
569         -- different uniques; so we compare their text versions...
570         dyld_stubs imps
571                 | needImportedSymbols dflags arch os
572                 = vcat $
573                         (pprGotDeclaration dflags arch os :) $
574                         map ( pprImportedSymbol dflags platform . fst . head) $
575                         groupBy (\(_,a) (_,b) -> a == b) $
576                         sortBy (\(_,a) (_,b) -> compare a b) $
577                         map doPpr $
578                         imps
579                 | otherwise
580                 = empty
581
582         doPpr lbl = (lbl, renderWithStyle dflags (pprCLabel platform lbl) astyle)
583         astyle = mkCodeStyle AsmStyle
584
585
586 -- -----------------------------------------------------------------------------
587 -- Sequencing the basic blocks
588
589 -- Cmm BasicBlocks are self-contained entities: they always end in a
590 -- jump, either non-local or to another basic block in the same proc.
591 -- In this phase, we attempt to place the basic blocks in a sequence
592 -- such that as many of the local jumps as possible turn into
593 -- fallthroughs.
594
595 sequenceTop
596         :: Instruction instr
597     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
598
599 sequenceTop _       top@(CmmData _ _) = top
600 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) =
601   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks info blocks)
602
603 -- The algorithm is very simple (and stupid): we make a graph out of
604 -- the blocks where there is an edge from one block to another iff the
605 -- first block ends by jumping to the second.  Then we topologically
606 -- sort this graph.  Then traverse the list: for each block, we first
607 -- output the block, then if it has an out edge, we move the
608 -- destination of the out edge to the front of the list, and continue.
609
610 -- FYI, the classic layout for basic blocks uses postorder DFS; this
611 -- algorithm is implemented in Hoopl.
612
613 sequenceBlocks
614         :: Instruction instr
615         => BlockEnv i
616         -> [NatBasicBlock instr]
617         -> [NatBasicBlock instr]
618
619 sequenceBlocks _ [] = []
620 sequenceBlocks infos (entry:blocks) =
621   seqBlocks infos (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
622   -- the first block is the entry point ==> it must remain at the start.
623
624
625 sccBlocks
626         :: Instruction instr
627         => [NatBasicBlock instr]
628         -> [SCC ( NatBasicBlock instr
629                 , BlockId
630                 , [BlockId])]
631
632 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
633
634 -- we're only interested in the last instruction of
635 -- the block, and only if it has a single destination.
636 getOutEdges
637         :: Instruction instr
638         => [instr] -> [BlockId]
639
640 getOutEdges instrs
641         = case jumpDestsOfInstr (last instrs) of
642                 [one] -> [one]
643                 _many -> []
644
645 mkNode :: (Instruction t)
646        => GenBasicBlock t
647        -> (GenBasicBlock t, BlockId, [BlockId])
648 mkNode block@(BasicBlock id instrs) = (block, id, getOutEdges instrs)
649
650 seqBlocks :: BlockEnv i -> [(GenBasicBlock t1, BlockId, [BlockId])]
651                         -> [GenBasicBlock t1]
652 seqBlocks _ [] = []
653 seqBlocks infos ((block,_,[]) : rest)
654   = block : seqBlocks infos rest
655 seqBlocks infos ((block@(BasicBlock id instrs),_,[next]) : rest)
656   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks infos rest'
657   | otherwise       = block : seqBlocks infos rest'
658   where
659         can_fallthrough = not (mapMember next infos) && can_reorder
660         (can_reorder, rest') = reorder next [] rest
661           -- TODO: we should do a better job for cycles; try to maximise the
662           -- fallthroughs within a loop.
663 seqBlocks _ _ = panic "AsmCodegen:seqBlocks"
664
665 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
666 reorder  _ accum [] = (False, reverse accum)
667 reorder id accum (b@(block,id',out) : rest)
668   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
669   | otherwise  = reorder id (b:accum) rest
670
671
672 -- -----------------------------------------------------------------------------
673 -- Making far branches
674
675 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
676 -- big, we have to work around this limitation.
677
678 makeFarBranches
679         :: [NatBasicBlock PPC.Instr.Instr]
680         -> [NatBasicBlock PPC.Instr.Instr]
681 makeFarBranches blocks
682     | last blockAddresses < nearLimit = blocks
683     | otherwise = zipWith handleBlock blockAddresses blocks
684     where
685         blockAddresses = scanl (+) 0 $ map blockLen blocks
686         blockLen (BasicBlock _ instrs) = length instrs
687
688         handleBlock addr (BasicBlock id instrs)
689                 = BasicBlock id (zipWith makeFar [addr..] instrs)
690
691         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
692         makeFar addr (PPC.Instr.BCC cond tgt)
693             | abs (addr - targetAddr) >= nearLimit
694             = PPC.Instr.BCCFAR cond tgt
695             | otherwise
696             = PPC.Instr.BCC cond tgt
697             where Just targetAddr = lookupUFM blockAddressMap tgt
698         makeFar _ other            = other
699
700         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
701                          -- distance, as we have a few pseudo-insns that are
702                          -- pretty-printed as multiple instructions,
703                          -- and it's just not worth the effort to calculate
704                          -- things exactly
705
706         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
707
708 -- -----------------------------------------------------------------------------
709 -- Generate jump tables
710
711 -- Analyzes all native code and generates data sections for all jump
712 -- table instructions.
713 generateJumpTables
714         :: DynFlags -> NcgImpl statics instr jumpDest
715     -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
716 generateJumpTables dflags ncgImpl xs = concatMap f xs
717     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
718           f p = [p]
719           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl dflags) xs)
720
721 -- -----------------------------------------------------------------------------
722 -- Shortcut branches
723
724 shortcutBranches
725         :: DynFlags
726     -> NcgImpl statics instr jumpDest
727         -> [NatCmmDecl statics instr]
728         -> [NatCmmDecl statics instr]
729
730 shortcutBranches dflags ncgImpl tops
731   | optLevel dflags < 1 = tops    -- only with -O or higher
732   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
733   where
734     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
735     mapping = foldr plusUFM emptyUFM mappings
736
737 build_mapping :: NcgImpl statics instr jumpDest
738               -> GenCmmDecl d (BlockEnv t) (ListGraph instr)
739               -> (GenCmmDecl d (BlockEnv t) (ListGraph instr), UniqFM jumpDest)
740 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
741 build_mapping _ (CmmProc info lbl (ListGraph []))
742   = (CmmProc info lbl (ListGraph []), emptyUFM)
743 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
744   = (CmmProc info lbl (ListGraph (head:others)), mapping)
745         -- drop the shorted blocks, but don't ever drop the first one,
746         -- because it is pointed to by a global label.
747   where
748     -- find all the blocks that just consist of a jump that can be
749     -- shorted.
750     -- Don't completely eliminate loops here -- that can leave a dangling jump!
751     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
752     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
753         | Just jd <- canShortcut ncgImpl insn,
754           Just dest <- getJumpDestBlockId ncgImpl jd,
755           not (has_info id),
756           (setMember dest s) || dest == id -- loop checks
757         = (s, shortcut_blocks, b : others)
758     split (s, shortcut_blocks, others) (BasicBlock id [insn])
759         | Just dest <- canShortcut ncgImpl insn,
760           not (has_info id)
761         = (setInsert id s, (id,dest) : shortcut_blocks, others)
762     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
763
764     -- do not eliminate blocks that have an info table
765     has_info l = mapMember l info
766
767     -- build a mapping from BlockId to JumpDest for shorting branches
768     mapping = foldl add emptyUFM shortcut_blocks
769     add ufm (id,dest) = addToUFM ufm id dest
770
771 apply_mapping :: NcgImpl statics instr jumpDest
772               -> UniqFM jumpDest
773               -> GenCmmDecl statics h (ListGraph instr)
774               -> GenCmmDecl statics h (ListGraph instr)
775 apply_mapping ncgImpl ufm (CmmData sec statics)
776   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
777 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
778   = CmmProc info lbl (ListGraph $ map short_bb blocks)
779   where
780     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
781     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
782                  -- shortcutJump should apply the mapping repeatedly,
783                  -- just in case we can short multiple branches.
784
785 -- -----------------------------------------------------------------------------
786 -- Instruction selection
787
788 -- Native code instruction selection for a chunk of stix code.  For
789 -- this part of the computation, we switch from the UniqSM monad to
790 -- the NatM monad.  The latter carries not only a Unique, but also an
791 -- Int denoting the current C stack pointer offset in the generated
792 -- code; this is needed for creating correct spill offsets on
793 -- architectures which don't offer, or for which it would be
794 -- prohibitively expensive to employ, a frame pointer register.  Viz,
795 -- x86.
796
797 -- The offset is measured in bytes, and indicates the difference
798 -- between the current (simulated) C stack-ptr and the value it was at
799 -- the beginning of the block.  For stacks which grow down, this value
800 -- should be either zero or negative.
801
802 -- Switching between the two monads whilst carrying along the same
803 -- Unique supply breaks abstraction.  Is that bad?
804
805 genMachCode
806         :: DynFlags
807         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
808         -> RawCmmDecl
809         -> UniqSM
810                 ( [NatCmmDecl statics instr]
811                 , [CLabel])
812
813 genMachCode dflags cmmTopCodeGen cmm_top
814   = do  { initial_us <- getUs
815         ; let initial_st           = mkNatM_State initial_us 0 dflags
816               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
817               final_delta          = natm_delta final_st
818               final_imports        = natm_imports final_st
819         ; if   final_delta == 0
820           then return (new_tops, final_imports)
821           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
822     }
823
824 -- -----------------------------------------------------------------------------
825 -- Generic Cmm optimiser
826
827 {-
828 Here we do:
829
830   (a) Constant folding
831   (b) Simple inlining: a temporary which is assigned to and then
832       used, once, can be shorted.
833   (c) Position independent code and dynamic linking
834         (i)  introduce the appropriate indirections
835              and position independent refs
836         (ii) compile a list of imported symbols
837   (d) Some arch-specific optimizations
838
839 (a) and (b) will be moving to the new Hoopl pipeline, however, (c) and
840 (d) are only needed by the native backend and will continue to live
841 here.
842
843 Ideas for other things we could do (put these in Hoopl please!):
844
845   - shortcut jumps-to-jumps
846   - simple CSE: if an expr is assigned to a temp, then replace later occs of
847     that expr with the temp, until the expr is no longer valid (can push through
848     temp assignments, and certain assigns to mem...)
849 -}
850
851 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
852 cmmToCmm _ top@(CmmData _ _) = (top, [])
853 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
854   let reachable_blocks | dopt Opt_TryNewCodeGen dflags = blocks
855                        | otherwise = cmmEliminateDeadBlocks blocks
856       -- The new codegen path has already eliminated unreachable blocks by now
857
858       inlined_blocks | dopt Opt_TryNewCodeGen dflags = reachable_blocks
859                      | otherwise = cmmMiniInline dflags reachable_blocks
860
861   blocks' <- mapM cmmBlockConFold inlined_blocks
862   return $ CmmProc info lbl (ListGraph blocks')
863
864 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
865
866 instance Monad CmmOptM where
867   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
868   (CmmOptM f) >>= g =
869     CmmOptM $ \(imports, dflags) ->
870                 case f (imports, dflags) of
871                   (# x, imports' #) ->
872                     case g x of
873                       CmmOptM g' -> g' (imports', dflags)
874
875 addImportCmmOpt :: CLabel -> CmmOptM ()
876 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
877
878 instance HasDynFlags CmmOptM where
879     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
880
881 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
882 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
883                         (# result, imports #) -> (result, imports)
884
885 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
886 cmmBlockConFold (BasicBlock id stmts) = do
887   stmts' <- mapM cmmStmtConFold stmts
888   return $ BasicBlock id stmts'
889
890 -- This does three optimizations, but they're very quick to check, so we don't
891 -- bother turning them off even when the Hoopl code is active.  Since
892 -- this is on the old Cmm representation, we can't reuse the code either:
893 --  * reg = reg      --> nop
894 --  * if 0 then jump --> nop
895 --  * if 1 then jump --> jump
896 -- We might be tempted to skip this step entirely of not Opt_PIC, but
897 -- there is some PowerPC code for the non-PIC case, which would also
898 -- have to be separated.
899 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
900 cmmStmtConFold stmt
901    = case stmt of
902         CmmAssign reg src
903            -> do src' <- cmmExprConFold DataReference src
904                  return $ case src' of
905                    CmmReg reg' | reg == reg' -> CmmNop
906                    new_src -> CmmAssign reg new_src
907
908         CmmStore addr src
909            -> do addr' <- cmmExprConFold DataReference addr
910                  src'  <- cmmExprConFold DataReference src
911                  return $ CmmStore addr' src'
912
913         CmmJump addr live
914            -> do addr' <- cmmExprConFold JumpReference addr
915                  return $ CmmJump addr' live
916
917         CmmCall target regs args returns
918            -> do target' <- case target of
919                               CmmCallee e conv -> do
920                                 e' <- cmmExprConFold CallReference e
921                                 return $ CmmCallee e' conv
922                               op@(CmmPrim _ Nothing) ->
923                                 return op
924                               CmmPrim op (Just stmts) ->
925                                 do stmts' <- mapM cmmStmtConFold stmts
926                                    return $ CmmPrim op (Just stmts')
927                  args' <- mapM (\(CmmHinted arg hint) -> do
928                                   arg' <- cmmExprConFold DataReference arg
929                                   return (CmmHinted arg' hint)) args
930                  return $ CmmCall target' regs args' returns
931
932         CmmCondBranch test dest
933            -> do test' <- cmmExprConFold DataReference test
934                  dflags <- getDynFlags
935                  return $ case test' of
936                    CmmLit (CmmInt 0 _) ->
937                      CmmComment (mkFastString ("deleted: " ++
938                                         showSDoc dflags (pprStmt stmt)))
939
940                    CmmLit (CmmInt _ _) -> CmmBranch dest
941                    _other -> CmmCondBranch test' dest
942
943         CmmSwitch expr ids
944            -> do expr' <- cmmExprConFold DataReference expr
945                  return $ CmmSwitch expr' ids
946
947         other
948            -> return other
949
950 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
951 cmmExprConFold referenceKind expr = do
952     dflags <- getDynFlags
953     -- Skip constant folding if new code generator is running
954     -- (this optimization is done in Hoopl)
955     -- SDM: re-enabled for now, while cmmRewriteAssignments is turned off
956     let expr' = if False -- dopt Opt_TryNewCodeGen dflags
957                     then expr
958                     else cmmExprCon dflags expr
959     cmmExprNative referenceKind expr'
960
961 cmmExprCon :: DynFlags -> CmmExpr -> CmmExpr
962 cmmExprCon dflags (CmmLoad addr rep) = CmmLoad (cmmExprCon dflags addr) rep
963 cmmExprCon dflags (CmmMachOp mop args)
964     = cmmMachOpFold dflags mop (map (cmmExprCon dflags) args)
965 cmmExprCon _ other = other
966
967 -- handles both PIC and non-PIC cases... a very strange mixture
968 -- of things to do.
969 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
970 cmmExprNative referenceKind expr = do
971      dflags <- getDynFlags
972      let platform = targetPlatform dflags
973          arch = platformArch platform
974      case expr of
975         CmmLoad addr rep
976            -> do addr' <- cmmExprNative DataReference addr
977                  return $ CmmLoad addr' rep
978
979         CmmMachOp mop args
980            -> do args' <- mapM (cmmExprNative DataReference) args
981                  return $ CmmMachOp mop args'
982
983         CmmLit (CmmBlock id)
984            -> cmmExprNative referenceKind (CmmLit (CmmLabel (infoTblLbl id)))
985            -- we must convert block Ids to CLabels here, because we
986            -- might have to do the PIC transformation.  Hence we must
987            -- not modify BlockIds beyond this point.
988
989         CmmLit (CmmLabel lbl)
990            -> do
991                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
992         CmmLit (CmmLabelOff lbl off)
993            -> do
994                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
995                  -- need to optimize here, since it's late
996                  return $ cmmMachOpFold dflags (MO_Add (wordWidth dflags)) [
997                      dynRef,
998                      (CmmLit $ CmmInt (fromIntegral off) (wordWidth dflags))
999                    ]
1000
1001         -- On powerpc (non-PIC), it's easier to jump directly to a label than
1002         -- to use the register table, so we replace these registers
1003         -- with the corresponding labels:
1004         CmmReg (CmmGlobal EagerBlackholeInfo)
1005           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1006           -> cmmExprNative referenceKind $
1007              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
1008         CmmReg (CmmGlobal GCEnter1)
1009           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1010           -> cmmExprNative referenceKind $
1011              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
1012         CmmReg (CmmGlobal GCFun)
1013           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1014           -> cmmExprNative referenceKind $
1015              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
1016
1017         other
1018            -> return other
1019
1020 \end{code}
1021