2101fb5df8996ac172c3147090104d3fcf359f2b
[ghc.git] / compiler / main / HscTypes.lhs
1 %
2 % (c) The University of Glasgow, 2006
3 %
4 \section[HscTypes]{Types for the per-module compiler}
5
6 \begin{code}
7
8 -- | Types for the per-module compiler
9 module HscTypes (
10         -- * compilation state
11         HscEnv(..), hscEPS,
12         FinderCache, FindResult(..), ModLocationCache,
13         Target(..), TargetId(..), pprTarget, pprTargetId,
14         ModuleGraph, emptyMG,
15
16         -- * Information about modules
17         ModDetails(..), emptyModDetails,
18         ModGuts(..), CgGuts(..), ForeignStubs(..), appendStubC,
19         ImportedMods, ImportedModsVal,
20
21         ModSummary(..), ms_imps, ms_mod_name, showModMsg, isBootSummary,
22         msHsFilePath, msHiFilePath, msObjFilePath,
23         SourceModified(..),
24
25         -- * Information about the module being compiled
26         HscSource(..), isHsBoot, hscSourceString,       -- Re-exported from DriverPhases
27
28         -- * State relating to modules in this package
29         HomePackageTable, HomeModInfo(..), emptyHomePackageTable,
30         hptInstances, hptRules, hptVectInfo,
31         hptObjs,
32
33         -- * State relating to known packages
34         ExternalPackageState(..), EpsStats(..), addEpsInStats,
35         PackageTypeEnv, PackageIfaceTable, emptyPackageIfaceTable,
36         lookupIfaceByModule, emptyModIface,
37
38         PackageInstEnv, PackageRuleBase,
39
40         mkSOName, soExt,
41
42         -- * Annotations
43         prepareAnnotations,
44
45         -- * Interactive context
46         InteractiveContext(..), emptyInteractiveContext,
47         icPrintUnqual, icInScopeTTs, icPlusGblRdrEnv,
48         extendInteractiveContext, substInteractiveContext,
49         setInteractivePrintName,
50         InteractiveImport(..),
51         mkPrintUnqualified, pprModulePrefix,
52
53         -- * Interfaces
54         ModIface(..), mkIfaceWarnCache, mkIfaceHashCache, mkIfaceFixCache,
55         emptyIfaceWarnCache,
56
57         -- * Fixity
58         FixityEnv, FixItem(..), lookupFixity, emptyFixityEnv,
59
60         -- * TyThings and type environments
61         TyThing(..),  tyThingAvailInfo,
62         tyThingTyCon, tyThingDataCon,
63         tyThingId, tyThingCoAxiom, tyThingParent_maybe, tyThingsTyVars,
64         implicitTyThings, implicitTyConThings, implicitClassThings,
65         isImplicitTyThing,
66
67         TypeEnv, lookupType, lookupTypeHscEnv, mkTypeEnv, emptyTypeEnv,
68         typeEnvFromEntities, mkTypeEnvWithImplicits,
69         extendTypeEnv, extendTypeEnvList, extendTypeEnvWithIds, lookupTypeEnv,
70         typeEnvElts, typeEnvTyCons, typeEnvIds,
71         typeEnvDataCons, typeEnvCoAxioms, typeEnvClasses,
72
73         -- * MonadThings
74         MonadThings(..),
75
76         -- * Information on imports and exports
77         WhetherHasOrphans, IsBootInterface, Usage(..),
78         Dependencies(..), noDependencies,
79         NameCache(..), OrigNameCache,
80         IfaceExport,
81
82         -- * Warnings
83         Warnings(..), WarningTxt(..), plusWarns,
84
85         -- * Linker stuff
86         Linkable(..), isObjectLinkable, linkableObjs,
87         Unlinked(..), CompiledByteCode,
88         isObject, nameOfObject, isInterpretable, byteCodeOfObject,
89
90         -- * Program coverage
91         HpcInfo(..), emptyHpcInfo, isHpcUsed, AnyHpcUsage,
92
93         -- * Breakpoints
94         ModBreaks (..), BreakIndex, emptyModBreaks,
95
96         -- * Vectorisation information
97         VectInfo(..), IfaceVectInfo(..), noVectInfo, plusVectInfo,
98         noIfaceVectInfo, isNoIfaceVectInfo,
99
100         -- * Safe Haskell information
101         IfaceTrustInfo, getSafeMode, setSafeMode, noIfaceTrustInfo,
102         trustInfoToNum, numToTrustInfo, IsSafeImport,
103
104         -- * result of the parser
105         HsParsedModule(..),
106
107         -- * Compilation errors and warnings
108         SourceError, GhcApiError, mkSrcErr, srcErrorMessages, mkApiErr,
109         throwOneError, handleSourceError,
110         handleFlagWarnings, printOrThrowWarnings,
111     ) where
112
113 #include "HsVersions.h"
114
115 #ifdef GHCI
116 import ByteCodeAsm      ( CompiledByteCode )
117 import {-# SOURCE #-}  InteractiveEval ( Resume )
118 #endif
119
120 import HsSyn
121 import RdrName
122 import Avail
123 import Module
124 import InstEnv          ( InstEnv, ClsInst )
125 import FamInstEnv
126 import Rules            ( RuleBase )
127 import CoreSyn          ( CoreProgram )
128 import Name
129 import NameEnv
130 import NameSet
131 import VarEnv
132 import VarSet
133 import Var
134 import Id
135 import IdInfo           ( IdDetails(..) )
136 import Type
137
138 import Annotations
139 import Class
140 import TyCon
141 import CoAxiom
142 import DataCon
143 import PrelNames        ( gHC_PRIM, ioTyConName, printName )
144 import Packages hiding  ( Version(..) )
145 import DynFlags
146 import DriverPhases
147 import BasicTypes
148 import IfaceSyn
149 import CoreSyn          ( CoreRule, CoreVect )
150 import Maybes
151 import Outputable
152 import BreakArray
153 import SrcLoc
154 import Unique
155 import UniqFM
156 import UniqSupply
157 import FastString
158 import StringBuffer     ( StringBuffer )
159 import Fingerprint
160 import MonadUtils
161 import Bag
162 import ErrUtils
163 import Platform
164 import Util
165
166 import Control.Monad    ( mplus, guard, liftM, when )
167 import Data.Array       ( Array, array )
168 import Data.IORef
169 import Data.Time
170 import Data.Word
171 import Data.Typeable    ( Typeable )
172 import Exception
173 import System.FilePath
174
175 -- -----------------------------------------------------------------------------
176 -- Source Errors
177
178 -- When the compiler (HscMain) discovers errors, it throws an
179 -- exception in the IO monad.
180
181 mkSrcErr :: ErrorMessages -> SourceError
182 mkSrcErr = SourceError
183
184 srcErrorMessages :: SourceError -> ErrorMessages
185 srcErrorMessages (SourceError msgs) = msgs
186
187 mkApiErr :: DynFlags -> SDoc -> GhcApiError
188 mkApiErr dflags msg = GhcApiError (showSDoc dflags msg)
189
190 throwOneError :: MonadIO m => ErrMsg -> m ab
191 throwOneError err = liftIO $ throwIO $ mkSrcErr $ unitBag err
192
193 -- | A source error is an error that is caused by one or more errors in the
194 -- source code.  A 'SourceError' is thrown by many functions in the
195 -- compilation pipeline.  Inside GHC these errors are merely printed via
196 -- 'log_action', but API clients may treat them differently, for example,
197 -- insert them into a list box.  If you want the default behaviour, use the
198 -- idiom:
199 --
200 -- > handleSourceError printExceptionAndWarnings $ do
201 -- >   ... api calls that may fail ...
202 --
203 -- The 'SourceError's error messages can be accessed via 'srcErrorMessages'.
204 -- This list may be empty if the compiler failed due to @-Werror@
205 -- ('Opt_WarnIsError').
206 --
207 -- See 'printExceptionAndWarnings' for more information on what to take care
208 -- of when writing a custom error handler.
209 newtype SourceError = SourceError ErrorMessages
210   deriving Typeable
211
212 instance Show SourceError where
213   show (SourceError msgs) = unlines . map show . bagToList $ msgs
214
215 instance Exception SourceError
216
217 -- | Perform the given action and call the exception handler if the action
218 -- throws a 'SourceError'.  See 'SourceError' for more information.
219 handleSourceError :: (ExceptionMonad m) =>
220                      (SourceError -> m a) -- ^ exception handler
221                   -> m a -- ^ action to perform
222                   -> m a
223 handleSourceError handler act =
224   gcatch act (\(e :: SourceError) -> handler e)
225
226 -- | An error thrown if the GHC API is used in an incorrect fashion.
227 newtype GhcApiError = GhcApiError String
228   deriving Typeable
229
230 instance Show GhcApiError where
231   show (GhcApiError msg) = msg
232
233 instance Exception GhcApiError
234
235 -- | Given a bag of warnings, turn them into an exception if
236 -- -Werror is enabled, or print them out otherwise.
237 printOrThrowWarnings :: DynFlags -> Bag WarnMsg -> IO ()
238 printOrThrowWarnings dflags warns
239   | gopt Opt_WarnIsError dflags
240   = when (not (isEmptyBag warns)) $ do
241       throwIO $ mkSrcErr $ warns `snocBag` warnIsErrorMsg dflags
242   | otherwise
243   = printBagOfErrors dflags warns
244
245 handleFlagWarnings :: DynFlags -> [Located String] -> IO ()
246 handleFlagWarnings dflags warns
247  = when (wopt Opt_WarnDeprecatedFlags dflags) $ do
248         -- It would be nicer if warns :: [Located MsgDoc], but that
249         -- has circular import problems.
250       let bag = listToBag [ mkPlainWarnMsg dflags loc (text warn)
251                           | L loc warn <- warns ]
252
253       printOrThrowWarnings dflags bag
254 \end{code}
255
256 %************************************************************************
257 %*                                                                      *
258 \subsection{HscEnv}
259 %*                                                                      *
260 %************************************************************************
261
262 \begin{code}
263
264 -- | Hscenv is like 'Session', except that some of the fields are immutable.
265 -- An HscEnv is used to compile a single module from plain Haskell source
266 -- code (after preprocessing) to either C, assembly or C--.  Things like
267 -- the module graph don't change during a single compilation.
268 --
269 -- Historical note: \"hsc\" used to be the name of the compiler binary,
270 -- when there was a separate driver and compiler.  To compile a single
271 -- module, the driver would invoke hsc on the source code... so nowadays
272 -- we think of hsc as the layer of the compiler that deals with compiling
273 -- a single module.
274 data HscEnv
275   = HscEnv {
276         hsc_dflags :: DynFlags,
277                 -- ^ The dynamic flag settings
278
279         hsc_targets :: [Target],
280                 -- ^ The targets (or roots) of the current session
281
282         hsc_mod_graph :: ModuleGraph,
283                 -- ^ The module graph of the current session
284
285         hsc_IC :: InteractiveContext,
286                 -- ^ The context for evaluating interactive statements
287
288         hsc_HPT    :: HomePackageTable,
289                 -- ^ The home package table describes already-compiled
290                 -- home-package modules, /excluding/ the module we
291                 -- are compiling right now.
292                 -- (In one-shot mode the current module is the only
293                 -- home-package module, so hsc_HPT is empty.  All other
294                 -- modules count as \"external-package\" modules.
295                 -- However, even in GHCi mode, hi-boot interfaces are
296                 -- demand-loaded into the external-package table.)
297                 --
298                 -- 'hsc_HPT' is not mutable because we only demand-load
299                 -- external packages; the home package is eagerly
300                 -- loaded, module by module, by the compilation manager.
301                 --
302                 -- The HPT may contain modules compiled earlier by @--make@
303                 -- but not actually below the current module in the dependency
304                 -- graph.
305                 --
306                 -- (This changes a previous invariant: changed Jan 05.)
307
308         hsc_EPS :: {-# UNPACK #-} !(IORef ExternalPackageState),
309                 -- ^ Information about the currently loaded external packages.
310                 -- This is mutable because packages will be demand-loaded during
311                 -- a compilation run as required.
312
313         hsc_NC  :: {-# UNPACK #-} !(IORef NameCache),
314                 -- ^ As with 'hsc_EPS', this is side-effected by compiling to
315                 -- reflect sucking in interface files.  They cache the state of
316                 -- external interface files, in effect.
317
318         hsc_FC   :: {-# UNPACK #-} !(IORef FinderCache),
319                 -- ^ The cached result of performing finding in the file system
320         hsc_MLC  :: {-# UNPACK #-} !(IORef ModLocationCache),
321                 -- ^ This caches the location of modules, so we don't have to
322                 -- search the filesystem multiple times. See also 'hsc_FC'.
323
324         hsc_type_env_var :: Maybe (Module, IORef TypeEnv)
325                 -- ^ Used for one-shot compilation only, to initialise
326                 -- the 'IfGblEnv'. See 'TcRnTypes.tcg_type_env_var' for
327                 -- 'TcRunTypes.TcGblEnv'
328  }
329
330 instance ContainsDynFlags HscEnv where
331     extractDynFlags env = hsc_dflags env
332     replaceDynFlags env dflags = env {hsc_dflags = dflags}
333
334 -- | Retrieve the ExternalPackageState cache.
335 hscEPS :: HscEnv -> IO ExternalPackageState
336 hscEPS hsc_env = readIORef (hsc_EPS hsc_env)
337
338 -- | A compilation target.
339 --
340 -- A target may be supplied with the actual text of the
341 -- module.  If so, use this instead of the file contents (this
342 -- is for use in an IDE where the file hasn't been saved by
343 -- the user yet).
344 data Target
345   = Target {
346       targetId           :: TargetId, -- ^ module or filename
347       targetAllowObjCode :: Bool,     -- ^ object code allowed?
348       targetContents     :: Maybe (StringBuffer,UTCTime)
349                                         -- ^ in-memory text buffer?
350     }
351
352 data TargetId
353   = TargetModule ModuleName
354         -- ^ A module name: search for the file
355   | TargetFile FilePath (Maybe Phase)
356         -- ^ A filename: preprocess & parse it to find the module name.
357         -- If specified, the Phase indicates how to compile this file
358         -- (which phase to start from).  Nothing indicates the starting phase
359         -- should be determined from the suffix of the filename.
360   deriving Eq
361
362 pprTarget :: Target -> SDoc
363 pprTarget (Target id obj _) =
364     (if obj then char '*' else empty) <> pprTargetId id
365
366 instance Outputable Target where
367     ppr = pprTarget
368
369 pprTargetId :: TargetId -> SDoc
370 pprTargetId (TargetModule m) = ppr m
371 pprTargetId (TargetFile f _) = text f
372
373 instance Outputable TargetId where
374     ppr = pprTargetId
375 \end{code}
376
377 %************************************************************************
378 %*                                                                      *
379 \subsection{Package and Module Tables}
380 %*                                                                      *
381 %************************************************************************
382
383 \begin{code}
384 -- | Helps us find information about modules in the home package
385 type HomePackageTable  = ModuleNameEnv HomeModInfo
386         -- Domain = modules in the home package that have been fully compiled
387         -- "home" package name cached here for convenience
388
389 -- | Helps us find information about modules in the imported packages
390 type PackageIfaceTable = ModuleEnv ModIface
391         -- Domain = modules in the imported packages
392
393 -- | Constructs an empty HomePackageTable
394 emptyHomePackageTable :: HomePackageTable
395 emptyHomePackageTable  = emptyUFM
396
397 -- | Constructs an empty PackageIfaceTable
398 emptyPackageIfaceTable :: PackageIfaceTable
399 emptyPackageIfaceTable = emptyModuleEnv
400
401 -- | Information about modules in the package being compiled
402 data HomeModInfo
403   = HomeModInfo {
404       hm_iface    :: !ModIface,
405         -- ^ The basic loaded interface file: every loaded module has one of
406         -- these, even if it is imported from another package
407       hm_details  :: !ModDetails,
408         -- ^ Extra information that has been created from the 'ModIface' for
409         -- the module, typically during typechecking
410       hm_linkable :: !(Maybe Linkable)
411         -- ^ The actual artifact we would like to link to access things in
412         -- this module.
413         --
414         -- 'hm_linkable' might be Nothing:
415         --
416         --   1. If this is an .hs-boot module
417         --
418         --   2. Temporarily during compilation if we pruned away
419         --      the old linkable because it was out of date.
420         --
421         -- After a complete compilation ('GHC.load'), all 'hm_linkable' fields
422         -- in the 'HomePackageTable' will be @Just@.
423         --
424         -- When re-linking a module ('HscMain.HscNoRecomp'), we construct the
425         -- 'HomeModInfo' by building a new 'ModDetails' from the old
426         -- 'ModIface' (only).
427     }
428
429 -- | Find the 'ModIface' for a 'Module', searching in both the loaded home
430 -- and external package module information
431 lookupIfaceByModule
432         :: DynFlags
433         -> HomePackageTable
434         -> PackageIfaceTable
435         -> Module
436         -> Maybe ModIface
437 lookupIfaceByModule dflags hpt pit mod
438   | modulePackageId mod == thisPackage dflags
439         -- The module comes from the home package, so look first
440         -- in the HPT.  If it's not from the home package it's wrong to look
441         -- in the HPT, because the HPT is indexed by *ModuleName* not Module
442   = fmap hm_iface (lookupUFM hpt (moduleName mod))
443     `mplus` lookupModuleEnv pit mod
444
445   | otherwise = lookupModuleEnv pit mod         -- Look in PIT only
446
447 -- If the module does come from the home package, why do we look in the PIT as well?
448 -- (a) In OneShot mode, even home-package modules accumulate in the PIT
449 -- (b) Even in Batch (--make) mode, there is *one* case where a home-package
450 --     module is in the PIT, namely GHC.Prim when compiling the base package.
451 -- We could eliminate (b) if we wanted, by making GHC.Prim belong to a package
452 -- of its own, but it doesn't seem worth the bother.
453
454
455 -- | Find all the instance declarations (of classes and families) that are in
456 -- modules imported by this one, directly or indirectly, and are in the Home
457 -- Package Table.  This ensures that we don't see instances from modules @--make@
458 -- compiled before this one, but which are not below this one.
459 hptInstances :: HscEnv -> (ModuleName -> Bool) -> ([ClsInst], [FamInst Branched])
460 hptInstances hsc_env want_this_module
461   = let (insts, famInsts) = unzip $ flip hptAllThings hsc_env $ \mod_info -> do
462                 guard (want_this_module (moduleName (mi_module (hm_iface mod_info))))
463                 let details = hm_details mod_info
464                 return (md_insts details, md_fam_insts details)
465     in (concat insts, concat famInsts)
466
467 -- | Get the combined VectInfo of all modules in the home package table. In
468 -- contrast to instances and rules, we don't care whether the modules are
469 -- "below" us in the dependency sense. The VectInfo of those modules not "below"
470 -- us does not affect the compilation of the current module.
471 hptVectInfo :: HscEnv -> VectInfo
472 hptVectInfo = concatVectInfo . hptAllThings ((: []) . md_vect_info . hm_details)
473
474 -- | Get rules from modules "below" this one (in the dependency sense)
475 hptRules :: HscEnv -> [(ModuleName, IsBootInterface)] -> [CoreRule]
476 hptRules = hptSomeThingsBelowUs (md_rules . hm_details) False
477
478
479 -- | Get annotations from modules "below" this one (in the dependency sense)
480 hptAnns :: HscEnv -> Maybe [(ModuleName, IsBootInterface)] -> [Annotation]
481 hptAnns hsc_env (Just deps) = hptSomeThingsBelowUs (md_anns . hm_details) False hsc_env deps
482 hptAnns hsc_env Nothing = hptAllThings (md_anns . hm_details) hsc_env
483
484 hptAllThings :: (HomeModInfo -> [a]) -> HscEnv -> [a]
485 hptAllThings extract hsc_env = concatMap extract (eltsUFM (hsc_HPT hsc_env))
486
487 -- | Get things from modules "below" this one (in the dependency sense)
488 -- C.f Inst.hptInstances
489 hptSomeThingsBelowUs :: (HomeModInfo -> [a]) -> Bool -> HscEnv -> [(ModuleName, IsBootInterface)] -> [a]
490 hptSomeThingsBelowUs extract include_hi_boot hsc_env deps
491   | isOneShot (ghcMode (hsc_dflags hsc_env)) = []
492
493   | otherwise
494   = let hpt = hsc_HPT hsc_env
495     in
496     [ thing
497     |   -- Find each non-hi-boot module below me
498       (mod, is_boot_mod) <- deps
499     , include_hi_boot || not is_boot_mod
500
501         -- unsavoury: when compiling the base package with --make, we
502         -- sometimes try to look up RULES etc for GHC.Prim. GHC.Prim won't
503         -- be in the HPT, because we never compile it; it's in the EPT
504         -- instead. ToDo: clean up, and remove this slightly bogus filter:
505     , mod /= moduleName gHC_PRIM
506
507         -- Look it up in the HPT
508     , let things = case lookupUFM hpt mod of
509                     Just info -> extract info
510                     Nothing -> pprTrace "WARNING in hptSomeThingsBelowUs" msg []
511           msg = vcat [ptext (sLit "missing module") <+> ppr mod,
512                       ptext (sLit "Probable cause: out-of-date interface files")]
513                         -- This really shouldn't happen, but see Trac #962
514
515         -- And get its dfuns
516     , thing <- things ]
517
518 hptObjs :: HomePackageTable -> [FilePath]
519 hptObjs hpt = concat (map (maybe [] linkableObjs . hm_linkable) (eltsUFM hpt))
520 \end{code}
521
522 %************************************************************************
523 %*                                                                      *
524 \subsection{Dealing with Annotations}
525 %*                                                                      *
526 %************************************************************************
527
528 \begin{code}
529 -- | Deal with gathering annotations in from all possible places
530 --   and combining them into a single 'AnnEnv'
531 prepareAnnotations :: HscEnv -> Maybe ModGuts -> IO AnnEnv
532 prepareAnnotations hsc_env mb_guts = do
533     eps <- hscEPS hsc_env
534     let -- Extract annotations from the module being compiled if supplied one
535         mb_this_module_anns = fmap (mkAnnEnv . mg_anns) mb_guts
536         -- Extract dependencies of the module if we are supplied one,
537         -- otherwise load annotations from all home package table
538         -- entries regardless of dependency ordering.
539         home_pkg_anns  = (mkAnnEnv . hptAnns hsc_env) $ fmap (dep_mods . mg_deps) mb_guts
540         other_pkg_anns = eps_ann_env eps
541         ann_env        = foldl1' plusAnnEnv $ catMaybes [mb_this_module_anns,
542                                                          Just home_pkg_anns,
543                                                          Just other_pkg_anns]
544     return ann_env
545 \end{code}
546
547 %************************************************************************
548 %*                                                                      *
549 \subsection{The Finder cache}
550 %*                                                                      *
551 %************************************************************************
552
553 \begin{code}
554 -- | The 'FinderCache' maps home module names to the result of
555 -- searching for that module. It records the results of searching for
556 -- modules along the search path. On @:load@, we flush the entire
557 -- contents of this cache.
558 --
559 -- Although the @FinderCache@ range is 'FindResult' for convenience,
560 -- in fact it will only ever contain 'Found' or 'NotFound' entries.
561 --
562 type FinderCache = ModuleNameEnv FindResult
563
564 -- | The result of searching for an imported module.
565 data FindResult
566   = Found ModLocation Module
567         -- ^ The module was found
568   | NoPackage PackageId
569         -- ^ The requested package was not found
570   | FoundMultiple [PackageId]
571         -- ^ _Error_: both in multiple packages
572
573         -- | Not found
574   | NotFound
575       { fr_paths       :: [FilePath]       -- Places where I looked
576
577       , fr_pkg         :: Maybe PackageId  -- Just p => module is in this package's
578                                            --           manifest, but couldn't find
579                                            --           the .hi file
580
581       , fr_mods_hidden :: [PackageId]      -- Module is in these packages,
582                                            --   but the *module* is hidden
583
584       , fr_pkgs_hidden :: [PackageId]      -- Module is in these packages,
585                                            --   but the *package* is hidden
586
587       , fr_suggestions :: [Module]         -- Possible mis-spelled modules
588       }
589
590 -- | Cache that remembers where we found a particular module.  Contains both
591 -- home modules and package modules.  On @:load@, only home modules are
592 -- purged from this cache.
593 type ModLocationCache = ModuleEnv ModLocation
594 \end{code}
595
596 %************************************************************************
597 %*                                                                      *
598 \subsection{Symbol tables and Module details}
599 %*                                                                      *
600 %************************************************************************
601
602 \begin{code}
603 -- | A 'ModIface' plus a 'ModDetails' summarises everything we know
604 -- about a compiled module.  The 'ModIface' is the stuff *before* linking,
605 -- and can be written out to an interface file. The 'ModDetails is after
606 -- linking and can be completely recovered from just the 'ModIface'.
607 --
608 -- When we read an interface file, we also construct a 'ModIface' from it,
609 -- except that we explicitly make the 'mi_decls' and a few other fields empty;
610 -- as when reading we consolidate the declarations etc. into a number of indexed
611 -- maps and environments in the 'ExternalPackageState'.
612 data ModIface
613   = ModIface {
614         mi_module     :: !Module,             -- ^ Name of the module we are for
615         mi_iface_hash :: !Fingerprint,        -- ^ Hash of the whole interface
616         mi_mod_hash   :: !Fingerprint,        -- ^ Hash of the ABI only
617         mi_flag_hash  :: !Fingerprint,        -- ^ Hash of the important flags
618                                               -- used when compiling this module
619
620         mi_orphan     :: !WhetherHasOrphans,  -- ^ Whether this module has orphans
621         mi_finsts     :: !WhetherHasFamInst,  -- ^ Whether this module has family instances
622         mi_boot       :: !IsBootInterface,    -- ^ Read from an hi-boot file?
623
624         mi_deps     :: Dependencies,
625                 -- ^ The dependencies of the module.  This is
626                 -- consulted for directly-imported modules, but not
627                 -- for anything else (hence lazy)
628
629         mi_usages   :: [Usage],
630                 -- ^ Usages; kept sorted so that it's easy to decide
631                 -- whether to write a new iface file (changing usages
632                 -- doesn't affect the hash of this module)
633                 -- NOT STRICT!  we read this field lazily from the interface file
634                 -- It is *only* consulted by the recompilation checker
635
636         mi_exports  :: ![IfaceExport],
637                 -- ^ Exports
638                 -- Kept sorted by (mod,occ), to make version comparisons easier
639                 -- Records the modules that are the declaration points for things
640                 -- exported by this module, and the 'OccName's of those things
641
642         mi_exp_hash :: !Fingerprint,
643                 -- ^ Hash of export list
644
645         mi_used_th  :: !Bool,
646                 -- ^ Module required TH splices when it was compiled.
647                 -- This disables recompilation avoidance (see #481).
648
649         mi_fixities :: [(OccName,Fixity)],
650                 -- ^ Fixities
651                 -- NOT STRICT!  we read this field lazily from the interface file
652
653         mi_warns    :: Warnings,
654                 -- ^ Warnings
655                 -- NOT STRICT!  we read this field lazily from the interface file
656
657         mi_anns     :: [IfaceAnnotation],
658                 -- ^ Annotations
659                 -- NOT STRICT!  we read this field lazily from the interface file
660
661
662         mi_decls    :: [(Fingerprint,IfaceDecl)],
663                 -- ^ Type, class and variable declarations
664                 -- The hash of an Id changes if its fixity or deprecations change
665                 --      (as well as its type of course)
666                 -- Ditto data constructors, class operations, except that
667                 -- the hash of the parent class/tycon changes
668
669         mi_globals  :: !(Maybe GlobalRdrEnv),
670                 -- ^ Binds all the things defined at the top level in
671                 -- the /original source/ code for this module. which
672                 -- is NOT the same as mi_exports, nor mi_decls (which
673                 -- may contains declarations for things not actually
674                 -- defined by the user).  Used for GHCi and for inspecting
675                 -- the contents of modules via the GHC API only.
676                 --
677                 -- (We need the source file to figure out the
678                 -- top-level environment, if we didn't compile this module
679                 -- from source then this field contains @Nothing@).
680                 --
681                 -- Strictly speaking this field should live in the
682                 -- 'HomeModInfo', but that leads to more plumbing.
683
684                 -- Instance declarations and rules
685         mi_insts       :: [IfaceClsInst],     -- ^ Sorted class instance
686         mi_fam_insts   :: [IfaceFamInst],  -- ^ Sorted family instances
687         mi_rules       :: [IfaceRule],     -- ^ Sorted rules
688         mi_orphan_hash :: !Fingerprint,    -- ^ Hash for orphan rules, class and family
689                                            -- instances, and vectorise pragmas combined
690
691         mi_vect_info :: !IfaceVectInfo,    -- ^ Vectorisation information
692
693                 -- Cached environments for easy lookup
694                 -- These are computed (lazily) from other fields
695                 -- and are not put into the interface file
696         mi_warn_fn   :: Name -> Maybe WarningTxt,        -- ^ Cached lookup for 'mi_warns'
697         mi_fix_fn    :: OccName -> Fixity,                -- ^ Cached lookup for 'mi_fixities'
698         mi_hash_fn   :: OccName -> Maybe (OccName, Fingerprint),
699                 -- ^ Cached lookup for 'mi_decls'.
700                 -- The @Nothing@ in 'mi_hash_fn' means that the thing
701                 -- isn't in decls. It's useful to know that when
702                 -- seeing if we are up to date wrt. the old interface.
703                 -- The 'OccName' is the parent of the name, if it has one.
704
705         mi_hpc       :: !AnyHpcUsage,
706                 -- ^ True if this program uses Hpc at any point in the program.
707
708         mi_trust     :: !IfaceTrustInfo,
709                 -- ^ Safe Haskell Trust information for this module.
710
711         mi_trust_pkg :: !Bool
712                 -- ^ Do we require the package this module resides in be trusted
713                 -- to trust this module? This is used for the situation where a
714                 -- module is Safe (so doesn't require the package be trusted
715                 -- itself) but imports some trustworthy modules from its own
716                 -- package (which does require its own package be trusted).
717                 -- See Note [RnNames . Trust Own Package]
718      }
719
720 -- | The original names declared of a certain module that are exported
721 type IfaceExport = AvailInfo
722
723 -- | Constructs an empty ModIface
724 emptyModIface :: Module -> ModIface
725 emptyModIface mod
726   = ModIface { mi_module      = mod,
727                mi_iface_hash  = fingerprint0,
728                mi_mod_hash    = fingerprint0,
729                mi_flag_hash   = fingerprint0,
730                mi_orphan      = False,
731                mi_finsts      = False,
732                mi_boot        = False,
733                mi_deps        = noDependencies,
734                mi_usages      = [],
735                mi_exports     = [],
736                mi_exp_hash    = fingerprint0,
737                mi_used_th     = False,
738                mi_fixities    = [],
739                mi_warns       = NoWarnings,
740                mi_anns        = [],
741                mi_insts       = [],
742                mi_fam_insts   = [],
743                mi_rules       = [],
744                mi_decls       = [],
745                mi_globals     = Nothing,
746                mi_orphan_hash = fingerprint0,
747                mi_vect_info   = noIfaceVectInfo,
748                mi_warn_fn     = emptyIfaceWarnCache,
749                mi_fix_fn      = emptyIfaceFixCache,
750                mi_hash_fn     = emptyIfaceHashCache,
751                mi_hpc         = False,
752                mi_trust       = noIfaceTrustInfo,
753                mi_trust_pkg   = False }
754
755
756 -- | Constructs cache for the 'mi_hash_fn' field of a 'ModIface'
757 mkIfaceHashCache :: [(Fingerprint,IfaceDecl)]
758                  -> (OccName -> Maybe (OccName, Fingerprint))
759 mkIfaceHashCache pairs
760   = \occ -> lookupOccEnv env occ
761   where
762     env = foldr add_decl emptyOccEnv pairs
763     add_decl (v,d) env0 = foldr add env0 (ifaceDeclFingerprints v d)
764       where
765         add (occ,hash) env0 = extendOccEnv env0 occ (occ,hash)
766
767 emptyIfaceHashCache :: OccName -> Maybe (OccName, Fingerprint)
768 emptyIfaceHashCache _occ = Nothing
769
770
771 -- | The 'ModDetails' is essentially a cache for information in the 'ModIface'
772 -- for home modules only. Information relating to packages will be loaded into
773 -- global environments in 'ExternalPackageState'.
774 data ModDetails
775   = ModDetails {
776         -- The next two fields are created by the typechecker
777         md_exports   :: [AvailInfo],
778         md_types     :: !TypeEnv,       -- ^ Local type environment for this particular module
779         md_insts     :: ![ClsInst],    -- ^ 'DFunId's for the instances in this module
780         md_fam_insts :: ![FamInst Branched],
781         md_rules     :: ![CoreRule],    -- ^ Domain may include 'Id's from other modules
782         md_anns      :: ![Annotation],  -- ^ Annotations present in this module: currently
783                                         -- they only annotate things also declared in this module
784         md_vect_info :: !VectInfo       -- ^ Module vectorisation information
785      }
786
787 -- | Constructs an empty ModDetails
788 emptyModDetails :: ModDetails
789 emptyModDetails
790   = ModDetails { md_types     = emptyTypeEnv,
791                  md_exports   = [],
792                  md_insts     = [],
793                  md_rules     = [],
794                  md_fam_insts = [],
795                  md_anns      = [],
796                  md_vect_info = noVectInfo }
797
798 -- | Records the modules directly imported by a module for extracting e.g. usage information
799 type ImportedMods = ModuleEnv [ImportedModsVal]
800 type ImportedModsVal = (ModuleName, Bool, SrcSpan, IsSafeImport)
801
802 -- | A ModGuts is carried through the compiler, accumulating stuff as it goes
803 -- There is only one ModGuts at any time, the one for the module
804 -- being compiled right now.  Once it is compiled, a 'ModIface' and
805 -- 'ModDetails' are extracted and the ModGuts is discarded.
806 data ModGuts
807   = ModGuts {
808         mg_module    :: !Module,         -- ^ Module being compiled
809         mg_boot      :: IsBootInterface, -- ^ Whether it's an hs-boot module
810         mg_exports   :: ![AvailInfo],    -- ^ What it exports
811         mg_deps      :: !Dependencies,   -- ^ What it depends on, directly or
812                                          -- otherwise
813         mg_dir_imps  :: !ImportedMods,   -- ^ Directly-imported modules; used to
814                                          -- generate initialisation code
815         mg_used_names:: !NameSet,        -- ^ What the module needed (used in 'MkIface.mkIface')
816
817         mg_used_th   :: !Bool,           -- ^ Did we run a TH splice?
818         mg_rdr_env   :: !GlobalRdrEnv,   -- ^ Top-level lexical environment
819
820         -- These fields all describe the things **declared in this module**
821         mg_fix_env   :: !FixityEnv,      -- ^ Fixities declared in this module
822                                          -- ToDo: I'm unconvinced this is actually used anywhere
823         mg_tcs       :: ![TyCon],        -- ^ TyCons declared in this module
824                                          -- (includes TyCons for classes)
825         mg_insts     :: ![ClsInst],      -- ^ Class instances declared in this module
826         mg_fam_insts :: ![FamInst Branched], 
827                                          -- ^ Family instances declared in this module
828         mg_rules     :: ![CoreRule],     -- ^ Before the core pipeline starts, contains
829                                          -- See Note [Overall plumbing for rules] in Rules.lhs
830         mg_binds     :: !CoreProgram,    -- ^ Bindings for this module
831         mg_foreign   :: !ForeignStubs,   -- ^ Foreign exports declared in this module
832         mg_warns     :: !Warnings,       -- ^ Warnings declared in the module
833         mg_anns      :: [Annotation],    -- ^ Annotations declared in this module
834         mg_hpc_info  :: !HpcInfo,        -- ^ Coverage tick boxes in the module
835         mg_modBreaks :: !ModBreaks,      -- ^ Breakpoints for the module
836         mg_vect_decls:: ![CoreVect],     -- ^ Vectorisation declarations in this module
837                                          --   (produced by desugarer & consumed by vectoriser)
838         mg_vect_info :: !VectInfo,       -- ^ Pool of vectorised declarations in the module
839
840         -- The next two fields are unusual, because they give instance
841         -- environments for *all* modules in the home package, including
842         -- this module, rather than for *just* this module.
843         -- Reason: when looking up an instance we don't want to have to
844         --        look at each module in the home package in turn
845         mg_inst_env     :: InstEnv,
846         -- ^ Class instance environment from /home-package/ modules (including
847         -- this one); c.f. 'tcg_inst_env'
848         mg_fam_inst_env :: FamInstEnv,
849         -- ^ Type-family instance enviroment for /home-package/ modules
850         -- (including this one); c.f. 'tcg_fam_inst_env'
851         mg_safe_haskell :: SafeHaskellMode,
852         -- ^ Safe Haskell mode
853         mg_trust_pkg    :: Bool,
854         -- ^ Do we need to trust our own package for Safe Haskell?
855         -- See Note [RnNames . Trust Own Package]
856         mg_dependent_files :: [FilePath] -- ^ dependencies from addDependentFile
857     }
858
859 -- The ModGuts takes on several slightly different forms:
860 --
861 -- After simplification, the following fields change slightly:
862 --      mg_rules        Orphan rules only (local ones now attached to binds)
863 --      mg_binds        With rules attached
864
865
866 ---------------------------------------------------------
867 -- The Tidy pass forks the information about this module:
868 --      * one lot goes to interface file generation (ModIface)
869 --        and later compilations (ModDetails)
870 --      * the other lot goes to code generation (CgGuts)
871
872 -- | A restricted form of 'ModGuts' for code generation purposes
873 data CgGuts
874   = CgGuts {
875         cg_module    :: !Module,
876                 -- ^ Module being compiled
877
878         cg_tycons    :: [TyCon],
879                 -- ^ Algebraic data types (including ones that started
880                 -- life as classes); generate constructors and info
881                 -- tables. Includes newtypes, just for the benefit of
882                 -- External Core
883
884         cg_binds     :: CoreProgram,
885                 -- ^ The tidied main bindings, including
886                 -- previously-implicit bindings for record and class
887                 -- selectors, and data construtor wrappers.  But *not*
888                 -- data constructor workers; reason: we we regard them
889                 -- as part of the code-gen of tycons
890
891         cg_foreign   :: !ForeignStubs,   -- ^ Foreign export stubs
892         cg_dep_pkgs  :: ![PackageId],    -- ^ Dependent packages, used to
893                                          -- generate #includes for C code gen
894         cg_hpc_info  :: !HpcInfo,        -- ^ Program coverage tick box information
895         cg_modBreaks :: !ModBreaks       -- ^ Module breakpoints
896     }
897
898 -----------------------------------
899 -- | Foreign export stubs
900 data ForeignStubs
901   = NoStubs
902       -- ^ We don't have any stubs
903   | ForeignStubs SDoc SDoc
904       -- ^ There are some stubs. Parameters:
905       --
906       --  1) Header file prototypes for
907       --     "foreign exported" functions
908       --
909       --  2) C stubs to use when calling
910       --     "foreign exported" functions
911
912 appendStubC :: ForeignStubs -> SDoc -> ForeignStubs
913 appendStubC NoStubs            c_code = ForeignStubs empty c_code
914 appendStubC (ForeignStubs h c) c_code = ForeignStubs h (c $$ c_code)
915 \end{code}
916
917 %************************************************************************
918 %*                                                                      *
919 \subsection{The interactive context}
920 %*                                                                      *
921 %************************************************************************
922
923 \begin{code}
924 -- | Interactive context, recording information about the state of the
925 -- context in which statements are executed in a GHC session.
926 data InteractiveContext
927   = InteractiveContext {
928          ic_dflags     :: DynFlags,
929              -- ^ The 'DynFlags' used to evaluate interative expressions
930              -- and statements.
931
932          ic_monad      :: Name,
933              -- ^ The monad that GHCi is executing in
934
935          ic_imports    :: [InteractiveImport],
936              -- ^ The GHCi context is extended with these imports
937              --
938              -- This field is only stored here so that the client
939              -- can retrieve it with GHC.getContext. GHC itself doesn't
940              -- use it, but does reset it to empty sometimes (such
941              -- as before a GHC.load). The context is set with GHC.setContext.
942
943          ic_rn_gbl_env :: GlobalRdrEnv,
944              -- ^ The cached 'GlobalRdrEnv', built by
945              -- 'InteractiveEval.setContext' and updated regularly
946
947          ic_tythings   :: [TyThing],
948              -- ^ TyThings defined by the user, in reverse order of
949              -- definition.  At a breakpoint, this list includes the
950              -- local variables in scope at that point
951
952          ic_sys_vars   :: [Id],
953              -- ^ Variables defined automatically by the system (e.g.
954              -- record field selectors).  See Notes [ic_sys_vars]
955
956          ic_instances  :: ([ClsInst], [FamInst Branched]),
957              -- ^ All instances and family instances created during
958              -- this session.  These are grabbed en masse after each
959              -- update to be sure that proper overlapping is retained.
960              -- That is, rather than re-check the overlapping each
961              -- time we update the context, we just take the results
962              -- from the instance code that already does that.
963
964          ic_fix_env :: FixityEnv,
965             -- ^ Fixities declared in let statements
966          
967          ic_int_print  :: Name,
968              -- ^ The function that is used for printing results
969              -- of expressions in ghci and -e mode.
970
971          ic_default :: Maybe [Type],
972              -- ^ The current default types, set by a 'default' declaration
973
974 #ifdef GHCI
975           ic_resume :: [Resume],
976              -- ^ The stack of breakpoint contexts
977 #endif
978
979           ic_cwd :: Maybe FilePath
980              -- virtual CWD of the program
981     }
982
983 {-
984 Note [ic_sys_vars]
985 ~~~~~~~~~~~~~~~~~~
986 This list constains any Ids that arise from TyCons, Classes or
987 instances defined interactively, but that are not given by
988 'implicitTyThings'.  This includes record selectors, default methods,
989 and dfuns.
990
991 We *could* get rid of this list and generate these Ids from
992 ic_tythings:
993
994    - dfuns come from Instances
995    - record selectors from TyCons
996    - default methods from Classes
997
998 For record selectors the TyCon gives the Name, but in order to make an
999 Id we would have to construct the type ourselves.  Similarly for
1000 default methods.  So for now we collect the Ids after tidying (see
1001 hscDeclsWithLocation) and save them in ic_sys_vars.
1002 -}
1003
1004 -- | Constructs an empty InteractiveContext.
1005 emptyInteractiveContext :: DynFlags -> InteractiveContext
1006 emptyInteractiveContext dflags
1007   = InteractiveContext { ic_dflags     = dflags,
1008                          -- IO monad by default
1009                          ic_monad      = ioTyConName,
1010                          ic_imports    = [],
1011                          ic_rn_gbl_env = emptyGlobalRdrEnv,
1012                          ic_tythings   = [],
1013                          ic_sys_vars   = [],
1014                          ic_instances  = ([],[]),
1015                          ic_fix_env    = emptyNameEnv,
1016                          -- System.IO.print by default
1017                          ic_int_print  = printName,
1018                          ic_default    = Nothing,
1019 #ifdef GHCI
1020                          ic_resume     = [],
1021 #endif
1022                          ic_cwd        = Nothing }
1023
1024 -- | This function returns the list of visible TyThings (useful for
1025 -- e.g. showBindings)
1026 icInScopeTTs :: InteractiveContext -> [TyThing]
1027 icInScopeTTs = ic_tythings
1028
1029 -- | Get the PrintUnqualified function based on the flags and this InteractiveContext
1030 icPrintUnqual :: DynFlags -> InteractiveContext -> PrintUnqualified
1031 icPrintUnqual dflags InteractiveContext{ ic_rn_gbl_env = grenv } =
1032     mkPrintUnqualified dflags grenv
1033
1034 -- | This function is called with new TyThings recently defined to update the
1035 -- InteractiveContext to include them.  Ids are easily removed when shadowed,
1036 -- but Classes and TyCons are not.  Some work could be done to determine
1037 -- whether they are entirely shadowed, but as you could still have references
1038 -- to them (e.g. instances for classes or values of the type for TyCons), it's
1039 -- not clear whether removing them is even the appropriate behavior.
1040 extendInteractiveContext :: InteractiveContext -> [TyThing] -> InteractiveContext
1041 extendInteractiveContext ictxt new_tythings
1042   = ictxt { ic_tythings   = new_tythings ++ old_tythings
1043           , ic_rn_gbl_env = new_tythings `icPlusGblRdrEnv` ic_rn_gbl_env ictxt
1044           }
1045   where
1046     old_tythings = filter (not . shadowed) (ic_tythings ictxt)
1047
1048     shadowed (AnId id) = ((`elem` new_names) . nameOccName . idName) id
1049     shadowed _         = False
1050
1051     new_names = [ nameOccName (getName id) | AnId id <- new_tythings ]
1052
1053 setInteractivePrintName :: InteractiveContext -> Name -> InteractiveContext
1054 setInteractivePrintName ic n = ic{ic_int_print = n}
1055
1056     -- ToDo: should not add Ids to the gbl env here
1057
1058 -- | Add TyThings to the GlobalRdrEnv, earlier ones in the list shadowing
1059 -- later ones, and shadowing existing entries in the GlobalRdrEnv.
1060 icPlusGblRdrEnv :: [TyThing] -> GlobalRdrEnv -> GlobalRdrEnv
1061 icPlusGblRdrEnv tythings env = extendOccEnvList env list
1062   where new_gres = gresFromAvails LocalDef (map tyThingAvailInfo tythings)
1063         list = [ (nameOccName (gre_name gre), [gre]) | gre <- new_gres ]
1064
1065 substInteractiveContext :: InteractiveContext -> TvSubst -> InteractiveContext
1066 substInteractiveContext ictxt subst
1067     | isEmptyTvSubst subst = ictxt
1068
1069 substInteractiveContext ictxt@InteractiveContext{ ic_tythings = tts } subst
1070     = ictxt { ic_tythings = map subst_ty tts }
1071   where subst_ty (AnId id) = AnId $ id `setIdType` substTy subst (idType id)
1072         subst_ty tt        = tt
1073
1074 data InteractiveImport
1075   = IIDecl (ImportDecl RdrName)
1076       -- ^ Bring the exports of a particular module
1077       -- (filtered by an import decl) into scope
1078
1079   | IIModule ModuleName
1080       -- ^ Bring into scope the entire top-level envt of
1081       -- of this module, including the things imported
1082       -- into it.
1083
1084 instance Outputable InteractiveImport where
1085   ppr (IIModule m) = char '*' <> ppr m
1086   ppr (IIDecl d)   = ppr d
1087
1088 \end{code}
1089
1090 %************************************************************************
1091 %*                                                                      *
1092         Building a PrintUnqualified
1093 %*                                                                      *
1094 %************************************************************************
1095
1096 Note [Printing original names]
1097 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1098 Deciding how to print names is pretty tricky.  We are given a name
1099 P:M.T, where P is the package name, M is the defining module, and T is
1100 the occurrence name, and we have to decide in which form to display
1101 the name given a GlobalRdrEnv describing the current scope.
1102
1103 Ideally we want to display the name in the form in which it is in
1104 scope.  However, the name might not be in scope at all, and that's
1105 where it gets tricky.  Here are the cases:
1106
1107  1. T uniquely maps to  P:M.T      --->  "T"      NameUnqual
1108  2. There is an X for which X.T
1109        uniquely maps to  P:M.T     --->  "X.T"    NameQual X
1110  3. There is no binding for "M.T"  --->  "M.T"    NameNotInScope1
1111  4. Otherwise                      --->  "P:M.T"  NameNotInScope2
1112
1113 (3) and (4) apply when the entity P:M.T is not in the GlobalRdrEnv at
1114 all. In these cases we still want to refer to the name as "M.T", *but*
1115 "M.T" might mean something else in the current scope (e.g. if there's
1116 an "import X as M"), so to avoid confusion we avoid using "M.T" if
1117 there's already a binding for it.  Instead we write P:M.T.
1118
1119 There's one further subtlety: in case (3), what if there are two
1120 things around, P1:M.T and P2:M.T?  Then we don't want to print both of
1121 them as M.T!  However only one of the modules P1:M and P2:M can be
1122 exposed (say P2), so we use M.T for that, and P1:M.T for the other one.
1123 This is handled by the qual_mod component of PrintUnqualified, inside
1124 the (ppr mod) of case (3), in Name.pprModulePrefix
1125
1126 \begin{code}
1127 -- | Creates some functions that work out the best ways to format
1128 -- names for the user according to a set of heuristics
1129 mkPrintUnqualified :: DynFlags -> GlobalRdrEnv -> PrintUnqualified
1130 mkPrintUnqualified dflags env = (qual_name, qual_mod)
1131   where
1132   qual_name name
1133         | [gre] <- unqual_gres, right_name gre = NameUnqual
1134                 -- If there's a unique entity that's in scope unqualified with 'occ'
1135                 -- AND that entity is the right one, then we can use the unqualified name
1136
1137         | [gre] <- qual_gres = NameQual (get_qual_mod (gre_prov gre))
1138
1139         | null qual_gres =
1140               if null (lookupGRE_RdrName (mkRdrQual (moduleName mod) occ) env)
1141                    then NameNotInScope1
1142                    else NameNotInScope2
1143
1144         | otherwise = NameNotInScope1   -- Can happen if 'f' is bound twice in the module
1145                                         -- Eg  f = True; g = 0; f = False
1146       where
1147         mod = nameModule name
1148         occ = nameOccName name
1149
1150         is_rdr_orig = nameUnique name == mkUniqueGrimily 0
1151          -- Note [Outputable Orig RdrName]
1152
1153         right_name gre
1154           | is_rdr_orig = nameModule_maybe (gre_name gre) == Just mod
1155           | otherwise   = gre_name gre == name
1156
1157         unqual_gres = lookupGRE_RdrName (mkRdrUnqual occ) env
1158         qual_gres   = filter right_name (lookupGlobalRdrEnv env occ)
1159
1160         get_qual_mod LocalDef      = moduleName mod
1161         get_qual_mod (Imported is) = ASSERT( not (null is) ) is_as (is_decl (head is))
1162
1163     -- we can mention a module P:M without the P: qualifier iff
1164     -- "import M" would resolve unambiguously to P:M.  (if P is the
1165     -- current package we can just assume it is unqualified).
1166
1167   qual_mod mod
1168      | modulePackageId mod == thisPackage dflags = False
1169
1170      | [pkgconfig] <- [pkg | (pkg,exposed_module) <- lookup,
1171                              exposed pkg && exposed_module],
1172        packageConfigId pkgconfig == modulePackageId mod
1173         -- this says: we are given a module P:M, is there just one exposed package
1174         -- that exposes a module M, and is it package P?
1175      = False
1176
1177      | otherwise = True
1178      where lookup = lookupModuleInAllPackages dflags (moduleName mod)
1179
1180 -- Note [Outputable Orig RdrName]
1181 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1182 -- This is a Grotesque Hack.  The Outputable instance for RdrEnv wants
1183 -- to print Orig names, which are just pairs of (Module,OccName).  But
1184 -- we want to use full Names here, because in GHCi we might have Ids
1185 -- that have the same (Module,OccName) pair but a different Unique
1186 -- (this happens when you shadow a TyCon or Class in GHCi).
1187 --
1188 -- So in Outputable RdrName we just use a dummy Unique (0), and check
1189 -- for it here.
1190 --
1191 -- Arguably GHCi is invalidating the assumption that (Module,OccName)
1192 -- uniquely identifies an entity.  But we do want to be able to shadow
1193 -- old declarations with new ones in GHCi, and it would be hard to
1194 -- delete all references to the old declaration when that happened.
1195 -- See also Note [interactive name cache] in IfaceEnv for somewhere
1196 -- else that this broken assumption bites.
1197 --
1198 \end{code}
1199
1200
1201 %************************************************************************
1202 %*                                                                      *
1203                 Implicit TyThings
1204 %*                                                                      *
1205 %************************************************************************
1206
1207 Note [Implicit TyThings]
1208 ~~~~~~~~~~~~~~~~~~~~~~~~
1209   DEFINITION: An "implicit" TyThing is one that does not have its own
1210   IfaceDecl in an interface file.  Instead, its binding in the type
1211   environment is created as part of typechecking the IfaceDecl for
1212   some other thing.
1213
1214 Examples:
1215   * All DataCons are implicit, because they are generated from the
1216     IfaceDecl for the data/newtype.  Ditto class methods.
1217
1218   * Record selectors are *not* implicit, because they get their own
1219     free-standing IfaceDecl.
1220
1221   * Associated data/type families are implicit because they are
1222     included in the IfaceDecl of the parent class.  (NB: the
1223     IfaceClass decl happens to use IfaceDecl recursively for the
1224     associated types, but that's irrelevant here.)
1225
1226   * Dictionary function Ids are not implict.
1227
1228   * Axioms for newtypes are implicit (same as above), but axioms
1229     for data/type family instances are *not* implicit (like DFunIds).
1230
1231 \begin{code}
1232 -- | Determine the 'TyThing's brought into scope by another 'TyThing'
1233 -- /other/ than itself. For example, Id's don't have any implicit TyThings
1234 -- as they just bring themselves into scope, but classes bring their
1235 -- dictionary datatype, type constructor and some selector functions into
1236 -- scope, just for a start!
1237
1238 -- N.B. the set of TyThings returned here *must* match the set of
1239 -- names returned by LoadIface.ifaceDeclImplicitBndrs, in the sense that
1240 -- TyThing.getOccName should define a bijection between the two lists.
1241 -- This invariant is used in LoadIface.loadDecl (see note [Tricky iface loop])
1242 -- The order of the list does not matter.
1243 implicitTyThings :: TyThing -> [TyThing]
1244 implicitTyThings (AnId _)       = []
1245 implicitTyThings (ACoAxiom _cc) = []
1246 implicitTyThings (ATyCon tc)    = implicitTyConThings tc
1247 implicitTyThings (ADataCon dc)  = map AnId (dataConImplicitIds dc)
1248     -- For data cons add the worker and (possibly) wrapper
1249
1250 implicitClassThings :: Class -> [TyThing]
1251 implicitClassThings cl
1252   = -- Does not include default methods, because those Ids may have
1253     --    their own pragmas, unfoldings etc, not derived from the Class object
1254     -- associated types
1255     --    No extras_plus (recursive call) for the classATs, because they
1256     --    are only the family decls; they have no implicit things
1257     map ATyCon (classATs cl) ++
1258     -- superclass and operation selectors
1259     map AnId (classAllSelIds cl)
1260
1261 implicitTyConThings :: TyCon -> [TyThing]
1262 implicitTyConThings tc
1263   = class_stuff ++
1264       -- fields (names of selectors)
1265
1266       -- (possibly) implicit newtype coercion
1267     implicitCoTyCon tc ++
1268
1269       -- for each data constructor in order,
1270       --   the contructor, worker, and (possibly) wrapper
1271     concatMap (extras_plus . ADataCon) (tyConDataCons tc)
1272       -- NB. record selectors are *not* implicit, they have fully-fledged
1273       -- bindings that pass through the compilation pipeline as normal.
1274   where
1275     class_stuff = case tyConClass_maybe tc of
1276         Nothing -> []
1277         Just cl -> implicitClassThings cl
1278
1279 -- add a thing and recursive call
1280 extras_plus :: TyThing -> [TyThing]
1281 extras_plus thing = thing : implicitTyThings thing
1282
1283 -- For newtypes (only) add the implicit coercion tycon
1284 implicitCoTyCon :: TyCon -> [TyThing]
1285 implicitCoTyCon tc
1286   | Just co <- newTyConCo_maybe tc = [ACoAxiom $ toBranchedAxiom co]
1287   | otherwise                      = []
1288
1289 -- | Returns @True@ if there should be no interface-file declaration
1290 -- for this thing on its own: either it is built-in, or it is part
1291 -- of some other declaration, or it is generated implicitly by some
1292 -- other declaration.
1293 isImplicitTyThing :: TyThing -> Bool
1294 isImplicitTyThing (ADataCon {}) = True
1295 isImplicitTyThing (AnId id)     = isImplicitId id
1296 isImplicitTyThing (ATyCon tc)   = isImplicitTyCon tc
1297 isImplicitTyThing (ACoAxiom ax) = isImplicitCoAxiom ax
1298
1299 -- | tyThingParent_maybe x returns (Just p)
1300 -- when pprTyThingInContext sould print a declaration for p
1301 -- (albeit with some "..." in it) when asked to show x
1302 -- It returns the *immediate* parent.  So a datacon returns its tycon
1303 -- but the tycon could be the associated type of a class, so it in turn
1304 -- might have a parent.
1305 tyThingParent_maybe :: TyThing -> Maybe TyThing
1306 tyThingParent_maybe (ADataCon dc) = Just (ATyCon (dataConTyCon dc))
1307 tyThingParent_maybe (ATyCon tc)   = case tyConAssoc_maybe tc of
1308                                       Just cls -> Just (ATyCon (classTyCon cls))
1309                                       Nothing  -> Nothing
1310 tyThingParent_maybe (AnId id)     = case idDetails id of
1311                                          RecSelId { sel_tycon = tc } -> Just (ATyCon tc)
1312                                          ClassOpId cls               -> Just (ATyCon (classTyCon cls))
1313                                          _other                      -> Nothing
1314 tyThingParent_maybe _other = Nothing
1315
1316 tyThingsTyVars :: [TyThing] -> TyVarSet
1317 tyThingsTyVars tts =
1318     unionVarSets $ map ttToVarSet tts
1319     where
1320         ttToVarSet (AnId id)     = tyVarsOfType $ idType id
1321         ttToVarSet (ADataCon dc) = tyVarsOfType $ dataConRepType dc
1322         ttToVarSet (ATyCon tc)
1323           = case tyConClass_maybe tc of
1324               Just cls -> (mkVarSet . fst . classTvsFds) cls
1325               Nothing  -> tyVarsOfType $ tyConKind tc
1326         ttToVarSet _             = emptyVarSet
1327
1328 -- | The Names that a TyThing should bring into scope.  Used to build
1329 -- the GlobalRdrEnv for the InteractiveContext.
1330 tyThingAvailInfo :: TyThing -> AvailInfo
1331 tyThingAvailInfo (ATyCon t)
1332    = case tyConClass_maybe t of
1333         Just c  -> AvailTC n (n : map getName (classMethods c)
1334                   ++ map getName (classATs c))
1335              where n = getName c
1336         Nothing -> AvailTC n (n : map getName dcs ++
1337                                    concatMap dataConFieldLabels dcs)
1338              where n = getName t
1339                    dcs = tyConDataCons t
1340 tyThingAvailInfo t
1341    = Avail (getName t)
1342 \end{code}
1343
1344 %************************************************************************
1345 %*                                                                      *
1346                 TypeEnv
1347 %*                                                                      *
1348 %************************************************************************
1349
1350 \begin{code}
1351 -- | A map from 'Name's to 'TyThing's, constructed by typechecking
1352 -- local declarations or interface files
1353 type TypeEnv = NameEnv TyThing
1354
1355 emptyTypeEnv    :: TypeEnv
1356 typeEnvElts     :: TypeEnv -> [TyThing]
1357 typeEnvTyCons   :: TypeEnv -> [TyCon]
1358 typeEnvCoAxioms :: TypeEnv -> [CoAxiom Branched]
1359 typeEnvIds      :: TypeEnv -> [Id]
1360 typeEnvDataCons :: TypeEnv -> [DataCon]
1361 typeEnvClasses  :: TypeEnv -> [Class]
1362 lookupTypeEnv   :: TypeEnv -> Name -> Maybe TyThing
1363
1364 emptyTypeEnv        = emptyNameEnv
1365 typeEnvElts     env = nameEnvElts env
1366 typeEnvTyCons   env = [tc | ATyCon tc   <- typeEnvElts env]
1367 typeEnvCoAxioms env = [ax | ACoAxiom ax <- typeEnvElts env]
1368 typeEnvIds      env = [id | AnId id     <- typeEnvElts env]
1369 typeEnvDataCons env = [dc | ADataCon dc <- typeEnvElts env]
1370 typeEnvClasses  env = [cl | tc <- typeEnvTyCons env,
1371                             Just cl <- [tyConClass_maybe tc]]
1372
1373 mkTypeEnv :: [TyThing] -> TypeEnv
1374 mkTypeEnv things = extendTypeEnvList emptyTypeEnv things
1375
1376 mkTypeEnvWithImplicits :: [TyThing] -> TypeEnv
1377 mkTypeEnvWithImplicits things =
1378   mkTypeEnv things
1379     `plusNameEnv`
1380   mkTypeEnv (concatMap implicitTyThings things)
1381
1382 typeEnvFromEntities :: [Id] -> [TyCon] -> [FamInst Branched] -> TypeEnv
1383 typeEnvFromEntities ids tcs famInsts =
1384   mkTypeEnv (   map AnId ids
1385              ++ map ATyCon all_tcs
1386              ++ concatMap implicitTyConThings all_tcs
1387              ++ map (ACoAxiom . famInstAxiom) famInsts
1388             )
1389  where
1390   all_tcs = tcs ++ famInstsRepTyCons famInsts
1391
1392 lookupTypeEnv = lookupNameEnv
1393
1394 -- Extend the type environment
1395 extendTypeEnv :: TypeEnv -> TyThing -> TypeEnv
1396 extendTypeEnv env thing = extendNameEnv env (getName thing) thing
1397
1398 extendTypeEnvList :: TypeEnv -> [TyThing] -> TypeEnv
1399 extendTypeEnvList env things = foldl extendTypeEnv env things
1400
1401 extendTypeEnvWithIds :: TypeEnv -> [Id] -> TypeEnv
1402 extendTypeEnvWithIds env ids
1403   = extendNameEnvList env [(getName id, AnId id) | id <- ids]
1404
1405 \end{code}
1406
1407 \begin{code}
1408 -- | Find the 'TyThing' for the given 'Name' by using all the resources
1409 -- at our disposal: the compiled modules in the 'HomePackageTable' and the
1410 -- compiled modules in other packages that live in 'PackageTypeEnv'. Note
1411 -- that this does NOT look up the 'TyThing' in the module being compiled: you
1412 -- have to do that yourself, if desired
1413 lookupType :: DynFlags
1414            -> HomePackageTable
1415            -> PackageTypeEnv
1416            -> Name
1417            -> Maybe TyThing
1418
1419 lookupType dflags hpt pte name
1420   -- in one-shot, we don't use the HPT
1421   | not (isOneShot (ghcMode dflags)) && modulePackageId mod == this_pkg
1422   = do hm <- lookupUFM hpt (moduleName mod) -- Maybe monad
1423        x <- lookupNameEnv (md_types (hm_details hm)) name
1424        return x
1425   | otherwise
1426   = lookupNameEnv pte name
1427   where 
1428     mod = ASSERT2( isExternalName name, ppr name ) nameModule name
1429     this_pkg = thisPackage dflags
1430
1431 -- | As 'lookupType', but with a marginally easier-to-use interface
1432 -- if you have a 'HscEnv'
1433 lookupTypeHscEnv :: HscEnv -> Name -> IO (Maybe TyThing)
1434 lookupTypeHscEnv hsc_env name = do
1435     eps <- readIORef (hsc_EPS hsc_env)
1436     return $! lookupType dflags hpt (eps_PTE eps) name
1437   where
1438     dflags = hsc_dflags hsc_env
1439     hpt = hsc_HPT hsc_env
1440 \end{code}
1441
1442 \begin{code}
1443 -- | Get the 'TyCon' from a 'TyThing' if it is a type constructor thing. Panics otherwise
1444 tyThingTyCon :: TyThing -> TyCon
1445 tyThingTyCon (ATyCon tc) = tc
1446 tyThingTyCon other       = pprPanic "tyThingTyCon" (pprTyThing other)
1447
1448 -- | Get the 'CoAxiom' from a 'TyThing' if it is a coercion axiom thing. Panics otherwise
1449 tyThingCoAxiom :: TyThing -> CoAxiom Branched
1450 tyThingCoAxiom (ACoAxiom ax) = ax
1451 tyThingCoAxiom other         = pprPanic "tyThingCoAxiom" (pprTyThing other)
1452
1453 -- | Get the 'DataCon' from a 'TyThing' if it is a data constructor thing. Panics otherwise
1454 tyThingDataCon :: TyThing -> DataCon
1455 tyThingDataCon (ADataCon dc) = dc
1456 tyThingDataCon other         = pprPanic "tyThingDataCon" (pprTyThing other)
1457
1458 -- | Get the 'Id' from a 'TyThing' if it is a id *or* data constructor thing. Panics otherwise
1459 tyThingId :: TyThing -> Id
1460 tyThingId (AnId id)     = id
1461 tyThingId (ADataCon dc) = dataConWrapId dc
1462 tyThingId other         = pprPanic "tyThingId" (pprTyThing other)
1463 \end{code}
1464
1465 %************************************************************************
1466 %*                                                                      *
1467 \subsection{MonadThings and friends}
1468 %*                                                                      *
1469 %************************************************************************
1470
1471 \begin{code}
1472 -- | Class that abstracts out the common ability of the monads in GHC
1473 -- to lookup a 'TyThing' in the monadic environment by 'Name'. Provides
1474 -- a number of related convenience functions for accessing particular
1475 -- kinds of 'TyThing'
1476 class Monad m => MonadThings m where
1477         lookupThing :: Name -> m TyThing
1478
1479         lookupId :: Name -> m Id
1480         lookupId = liftM tyThingId . lookupThing
1481
1482         lookupDataCon :: Name -> m DataCon
1483         lookupDataCon = liftM tyThingDataCon . lookupThing
1484
1485         lookupTyCon :: Name -> m TyCon
1486         lookupTyCon = liftM tyThingTyCon . lookupThing
1487 \end{code}
1488
1489 %************************************************************************
1490 %*                                                                      *
1491 \subsection{Auxiliary types}
1492 %*                                                                      *
1493 %************************************************************************
1494
1495 These types are defined here because they are mentioned in ModDetails,
1496 but they are mostly elaborated elsewhere
1497
1498 \begin{code}
1499 ------------------ Warnings -------------------------
1500 -- | Warning information for a module
1501 data Warnings
1502   = NoWarnings                          -- ^ Nothing deprecated
1503   | WarnAll WarningTxt                  -- ^ Whole module deprecated
1504   | WarnSome [(OccName,WarningTxt)]     -- ^ Some specific things deprecated
1505
1506      -- Only an OccName is needed because
1507      --    (1) a deprecation always applies to a binding
1508      --        defined in the module in which the deprecation appears.
1509      --    (2) deprecations are only reported outside the defining module.
1510      --        this is important because, otherwise, if we saw something like
1511      --
1512      --        {-# DEPRECATED f "" #-}
1513      --        f = ...
1514      --        h = f
1515      --        g = let f = undefined in f
1516      --
1517      --        we'd need more information than an OccName to know to say something
1518      --        about the use of f in h but not the use of the locally bound f in g
1519      --
1520      --        however, because we only report about deprecations from the outside,
1521      --        and a module can only export one value called f,
1522      --        an OccName suffices.
1523      --
1524      --        this is in contrast with fixity declarations, where we need to map
1525      --        a Name to its fixity declaration.
1526   deriving( Eq )
1527
1528 -- | Constructs the cache for the 'mi_warn_fn' field of a 'ModIface'
1529 mkIfaceWarnCache :: Warnings -> Name -> Maybe WarningTxt
1530 mkIfaceWarnCache NoWarnings  = \_ -> Nothing
1531 mkIfaceWarnCache (WarnAll t) = \_ -> Just t
1532 mkIfaceWarnCache (WarnSome pairs) = lookupOccEnv (mkOccEnv pairs) . nameOccName
1533
1534 emptyIfaceWarnCache :: Name -> Maybe WarningTxt
1535 emptyIfaceWarnCache _ = Nothing
1536
1537 plusWarns :: Warnings -> Warnings -> Warnings
1538 plusWarns d NoWarnings = d
1539 plusWarns NoWarnings d = d
1540 plusWarns _ (WarnAll t) = WarnAll t
1541 plusWarns (WarnAll t) _ = WarnAll t
1542 plusWarns (WarnSome v1) (WarnSome v2) = WarnSome (v1 ++ v2)
1543 \end{code}
1544
1545 \begin{code}
1546 -- | Creates cached lookup for the 'mi_fix_fn' field of 'ModIface'
1547 mkIfaceFixCache :: [(OccName, Fixity)] -> OccName -> Fixity
1548 mkIfaceFixCache pairs
1549   = \n -> lookupOccEnv env n `orElse` defaultFixity
1550   where
1551    env = mkOccEnv pairs
1552
1553 emptyIfaceFixCache :: OccName -> Fixity
1554 emptyIfaceFixCache _ = defaultFixity
1555
1556 -- | Fixity environment mapping names to their fixities
1557 type FixityEnv = NameEnv FixItem
1558
1559 -- | Fixity information for an 'Name'. We keep the OccName in the range
1560 -- so that we can generate an interface from it
1561 data FixItem = FixItem OccName Fixity
1562
1563 instance Outputable FixItem where
1564   ppr (FixItem occ fix) = ppr fix <+> ppr occ
1565
1566 emptyFixityEnv :: FixityEnv
1567 emptyFixityEnv = emptyNameEnv
1568
1569 lookupFixity :: FixityEnv -> Name -> Fixity
1570 lookupFixity env n = case lookupNameEnv env n of
1571                         Just (FixItem _ fix) -> fix
1572                         Nothing         -> defaultFixity
1573 \end{code}
1574
1575
1576 %************************************************************************
1577 %*                                                                      *
1578 \subsection{WhatsImported}
1579 %*                                                                      *
1580 %************************************************************************
1581
1582 \begin{code}
1583 -- | Records whether a module has orphans. An \"orphan\" is one of:
1584 --
1585 -- * An instance declaration in a module other than the definition
1586 --   module for one of the type constructors or classes in the instance head
1587 --
1588 -- * A transformation rule in a module other than the one defining
1589 --   the function in the head of the rule
1590 --
1591 -- * A vectorisation pragma
1592 type WhetherHasOrphans   = Bool
1593
1594 -- | Does this module define family instances?
1595 type WhetherHasFamInst = Bool
1596
1597 -- | Did this module originate from a *-boot file?
1598 type IsBootInterface = Bool
1599
1600 -- | Dependency information about modules and packages below this one
1601 -- in the import hierarchy.
1602 --
1603 -- Invariant: the dependencies of a module @M@ never includes @M@.
1604 --
1605 -- Invariant: none of the lists contain duplicates.
1606 data Dependencies
1607   = Deps { dep_mods   :: [(ModuleName, IsBootInterface)]
1608                         -- ^ Home-package module dependencies
1609          , dep_pkgs   :: [(PackageId, Bool)]
1610                        -- ^ External package dependencies. The bool indicates
1611                         -- if the package is required to be trusted when the
1612                         -- module is imported as a safe import (Safe Haskell).
1613                         -- See Note [RnNames . Tracking Trust Transitively]
1614          , dep_orphs  :: [Module]
1615                         -- ^ Orphan modules (whether home or external pkg),
1616                         -- *not* including family instance orphans as they
1617                         -- are anyway included in 'dep_finsts'
1618          , dep_finsts :: [Module]
1619                         -- ^ Modules that contain family instances (whether the
1620                         -- instances are from the home or an external package)
1621          }
1622   deriving( Eq )
1623         -- Equality used only for old/new comparison in MkIface.addFingerprints
1624         -- See 'TcRnTypes.ImportAvails' for details on dependencies.
1625
1626 noDependencies :: Dependencies
1627 noDependencies = Deps [] [] [] []
1628
1629 -- | Records modules that we depend on by making a direct import from
1630 data Usage
1631   -- | Module from another package
1632   = UsagePackageModule {
1633         usg_mod      :: Module,
1634            -- ^ External package module depended on
1635         usg_mod_hash :: Fingerprint,
1636             -- ^ Cached module fingerprint
1637         usg_safe :: IsSafeImport
1638             -- ^ Was this module imported as a safe import
1639     }
1640   -- | Module from the current package
1641   | UsageHomeModule {
1642         usg_mod_name :: ModuleName,
1643             -- ^ Name of the module
1644         usg_mod_hash :: Fingerprint,
1645             -- ^ Cached module fingerprint
1646         usg_entities :: [(OccName,Fingerprint)],
1647             -- ^ Entities we depend on, sorted by occurrence name and fingerprinted.
1648             -- NB: usages are for parent names only, e.g. type constructors
1649             -- but not the associated data constructors.
1650         usg_exports  :: Maybe Fingerprint,
1651             -- ^ Fingerprint for the export list we used to depend on this module,
1652             -- if we depend on the export list
1653         usg_safe :: IsSafeImport
1654             -- ^ Was this module imported as a safe import
1655     }                                           -- ^ Module from the current package
1656   | UsageFile {
1657         usg_file_path  :: FilePath,
1658         usg_mtime      :: UTCTime
1659         -- ^ External file dependency. From a CPP #include or TH addDependentFile. Should be absolute.
1660   }
1661     deriving( Eq )
1662         -- The export list field is (Just v) if we depend on the export list:
1663         --      i.e. we imported the module directly, whether or not we
1664         --           enumerated the things we imported, or just imported
1665         --           everything
1666         -- We need to recompile if M's exports change, because
1667         -- if the import was    import M,       we might now have a name clash
1668         --                                      in the importing module.
1669         -- if the import was    import M(x)     M might no longer export x
1670         -- The only way we don't depend on the export list is if we have
1671         --                      import M()
1672         -- And of course, for modules that aren't imported directly we don't
1673         -- depend on their export lists
1674 \end{code}
1675
1676
1677 %************************************************************************
1678 %*                                                                      *
1679                 The External Package State
1680 %*                                                                      *
1681 %************************************************************************
1682
1683 \begin{code}
1684 type PackageTypeEnv    = TypeEnv
1685 type PackageRuleBase   = RuleBase
1686 type PackageInstEnv    = InstEnv
1687 type PackageFamInstEnv = FamInstEnv
1688 type PackageVectInfo   = VectInfo
1689 type PackageAnnEnv     = AnnEnv
1690
1691 -- | Information about other packages that we have slurped in by reading
1692 -- their interface files
1693 data ExternalPackageState
1694   = EPS {
1695         eps_is_boot :: !(ModuleNameEnv (ModuleName, IsBootInterface)),
1696                 -- ^ In OneShot mode (only), home-package modules
1697                 -- accumulate in the external package state, and are
1698                 -- sucked in lazily.  For these home-pkg modules
1699                 -- (only) we need to record which are boot modules.
1700                 -- We set this field after loading all the
1701                 -- explicitly-imported interfaces, but before doing
1702                 -- anything else
1703                 --
1704                 -- The 'ModuleName' part is not necessary, but it's useful for
1705                 -- debug prints, and it's convenient because this field comes
1706                 -- direct from 'TcRnTypes.imp_dep_mods'
1707
1708         eps_PIT :: !PackageIfaceTable,
1709                 -- ^ The 'ModIface's for modules in external packages
1710                 -- whose interfaces we have opened.
1711                 -- The declarations in these interface files are held in the
1712                 -- 'eps_decls', 'eps_inst_env', 'eps_fam_inst_env' and 'eps_rules'
1713                 -- fields of this record, not in the 'mi_decls' fields of the
1714                 -- interface we have sucked in.
1715                 --
1716                 -- What /is/ in the PIT is:
1717                 --
1718                 -- * The Module
1719                 --
1720                 -- * Fingerprint info
1721                 --
1722                 -- * Its exports
1723                 --
1724                 -- * Fixities
1725                 --
1726                 -- * Deprecations and warnings
1727
1728         eps_PTE :: !PackageTypeEnv,
1729                 -- ^ Result of typechecking all the external package
1730                 -- interface files we have sucked in. The domain of
1731                 -- the mapping is external-package modules
1732
1733         eps_inst_env     :: !PackageInstEnv,   -- ^ The total 'InstEnv' accumulated
1734                                                -- from all the external-package modules
1735         eps_fam_inst_env :: !PackageFamInstEnv,-- ^ The total 'FamInstEnv' accumulated
1736                                                -- from all the external-package modules
1737         eps_rule_base    :: !PackageRuleBase,  -- ^ The total 'RuleEnv' accumulated
1738                                                -- from all the external-package modules
1739         eps_vect_info    :: !PackageVectInfo,  -- ^ The total 'VectInfo' accumulated
1740                                                -- from all the external-package modules
1741         eps_ann_env      :: !PackageAnnEnv,    -- ^ The total 'AnnEnv' accumulated
1742                                                -- from all the external-package modules
1743
1744         eps_mod_fam_inst_env :: !(ModuleEnv FamInstEnv), -- ^ The family instances accumulated from external
1745                                                          -- packages, keyed off the module that declared them
1746
1747         eps_stats :: !EpsStats                 -- ^ Stastics about what was loaded from external packages
1748   }
1749
1750 -- | Accumulated statistics about what we are putting into the 'ExternalPackageState'.
1751 -- \"In\" means stuff that is just /read/ from interface files,
1752 -- \"Out\" means actually sucked in and type-checked
1753 data EpsStats = EpsStats { n_ifaces_in
1754                          , n_decls_in, n_decls_out
1755                          , n_rules_in, n_rules_out
1756                          , n_insts_in, n_insts_out :: !Int }
1757
1758 addEpsInStats :: EpsStats -> Int -> Int -> Int -> EpsStats
1759 -- ^ Add stats for one newly-read interface
1760 addEpsInStats stats n_decls n_insts n_rules
1761   = stats { n_ifaces_in = n_ifaces_in stats + 1
1762           , n_decls_in  = n_decls_in stats + n_decls
1763           , n_insts_in  = n_insts_in stats + n_insts
1764           , n_rules_in  = n_rules_in stats + n_rules }
1765 \end{code}
1766
1767 Names in a NameCache are always stored as a Global, and have the SrcLoc
1768 of their binding locations.
1769
1770 Actually that's not quite right.  When we first encounter the original
1771 name, we might not be at its binding site (e.g. we are reading an
1772 interface file); so we give it 'noSrcLoc' then.  Later, when we find
1773 its binding site, we fix it up.
1774
1775 \begin{code}
1776 -- | The NameCache makes sure that there is just one Unique assigned for
1777 -- each original name; i.e. (module-name, occ-name) pair and provides
1778 -- something of a lookup mechanism for those names.
1779 data NameCache
1780  = NameCache {  nsUniqs :: UniqSupply,
1781                 -- ^ Supply of uniques
1782                 nsNames :: OrigNameCache
1783                 -- ^ Ensures that one original name gets one unique
1784    }
1785
1786 -- | Per-module cache of original 'OccName's given 'Name's
1787 type OrigNameCache   = ModuleEnv (OccEnv Name)
1788 \end{code}
1789
1790
1791 \begin{code}
1792 mkSOName :: Platform -> FilePath -> FilePath
1793 mkSOName platform root
1794     = case platformOS platform of
1795       OSDarwin  -> ("lib" ++ root) <.> "dylib"
1796       OSMinGW32 ->           root  <.> "dll"
1797       _         -> ("lib" ++ root) <.> "so"
1798
1799 soExt :: Platform -> FilePath
1800 soExt platform
1801     = case platformOS platform of
1802       OSDarwin  -> "dylib"
1803       OSMinGW32 -> "dll"
1804       _         -> "so"
1805 \end{code}
1806
1807
1808 %************************************************************************
1809 %*                                                                      *
1810                 The module graph and ModSummary type
1811         A ModSummary is a node in the compilation manager's
1812         dependency graph, and it's also passed to hscMain
1813 %*                                                                      *
1814 %************************************************************************
1815
1816 \begin{code}
1817 -- | A ModuleGraph contains all the nodes from the home package (only).
1818 -- There will be a node for each source module, plus a node for each hi-boot
1819 -- module.
1820 --
1821 -- The graph is not necessarily stored in topologically-sorted order.  Use
1822 -- 'GHC.topSortModuleGraph' and 'Digraph.flattenSCC' to achieve this.
1823 type ModuleGraph = [ModSummary]
1824
1825 emptyMG :: ModuleGraph
1826 emptyMG = []
1827
1828 -- | A single node in a 'ModuleGraph. The nodes of the module graph are one of:
1829 --
1830 -- * A regular Haskell source module
1831 --
1832 -- * A hi-boot source module
1833 --
1834 -- * An external-core source module
1835 data ModSummary
1836    = ModSummary {
1837         ms_mod          :: Module,              -- ^ Identity of the module
1838         ms_hsc_src      :: HscSource,           -- ^ The module source either plain Haskell, hs-boot or external core
1839         ms_location     :: ModLocation,         -- ^ Location of the various files belonging to the module
1840         ms_hs_date      :: UTCTime,             -- ^ Timestamp of source file
1841         ms_obj_date     :: Maybe UTCTime,       -- ^ Timestamp of object, if we have one
1842         ms_srcimps      :: [Located (ImportDecl RdrName)],      -- ^ Source imports of the module
1843         ms_textual_imps :: [Located (ImportDecl RdrName)],      -- ^ Non-source imports of the module from the module *text*
1844         ms_hspp_file    :: FilePath,            -- ^ Filename of preprocessed source file
1845         ms_hspp_opts    :: DynFlags,            -- ^ Cached flags from @OPTIONS@, @INCLUDE@
1846                                                 -- and @LANGUAGE@ pragmas in the modules source code
1847         ms_hspp_buf     :: Maybe StringBuffer   -- ^ The actual preprocessed source, if we have it
1848      }
1849
1850 ms_mod_name :: ModSummary -> ModuleName
1851 ms_mod_name = moduleName . ms_mod
1852
1853 ms_imps :: ModSummary -> [Located (ImportDecl RdrName)]
1854 ms_imps ms = ms_textual_imps ms ++ map mk_additional_import (dynFlagDependencies (ms_hspp_opts ms))
1855   where
1856     -- This is a not-entirely-satisfactory means of creating an import that corresponds to an
1857     -- import that did not occur in the program text, such as those induced by the use of
1858     -- plugins (the -plgFoo flag)
1859     mk_additional_import mod_nm = noLoc $ ImportDecl {
1860       ideclName      = noLoc mod_nm,
1861       ideclPkgQual   = Nothing,
1862       ideclSource    = False,
1863       ideclImplicit  = True, -- Maybe implicit because not "in the program text"
1864       ideclQualified = False,
1865       ideclAs        = Nothing,
1866       ideclHiding    = Nothing,
1867       ideclSafe      = False
1868     }
1869
1870 -- The ModLocation contains both the original source filename and the
1871 -- filename of the cleaned-up source file after all preprocessing has been
1872 -- done.  The point is that the summariser will have to cpp/unlit/whatever
1873 -- all files anyway, and there's no point in doing this twice -- just
1874 -- park the result in a temp file, put the name of it in the location,
1875 -- and let @compile@ read from that file on the way back up.
1876
1877 -- The ModLocation is stable over successive up-sweeps in GHCi, wheres
1878 -- the ms_hs_date and imports can, of course, change
1879
1880 msHsFilePath, msHiFilePath, msObjFilePath :: ModSummary -> FilePath
1881 msHsFilePath  ms = expectJust "msHsFilePath" (ml_hs_file  (ms_location ms))
1882 msHiFilePath  ms = ml_hi_file  (ms_location ms)
1883 msObjFilePath ms = ml_obj_file (ms_location ms)
1884
1885 -- | Did this 'ModSummary' originate from a hs-boot file?
1886 isBootSummary :: ModSummary -> Bool
1887 isBootSummary ms = isHsBoot (ms_hsc_src ms)
1888
1889 instance Outputable ModSummary where
1890    ppr ms
1891       = sep [text "ModSummary {",
1892              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
1893                           text "ms_mod =" <+> ppr (ms_mod ms)
1894                                 <> text (hscSourceString (ms_hsc_src ms)) <> comma,
1895                           text "ms_textual_imps =" <+> ppr (ms_textual_imps ms),
1896                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
1897              char '}'
1898             ]
1899
1900 showModMsg :: DynFlags -> HscTarget -> Bool -> ModSummary -> String
1901 showModMsg dflags target recomp mod_summary
1902   = showSDoc dflags $
1903         hsep [text (mod_str ++ replicate (max 0 (16 - length mod_str)) ' '),
1904               char '(', text (normalise $ msHsFilePath mod_summary) <> comma,
1905               case target of
1906                   HscInterpreted | recomp
1907                              -> text "interpreted"
1908                   HscNothing -> text "nothing"
1909                   _          -> text (normalise $ msObjFilePath mod_summary),
1910               char ')']
1911  where
1912     mod     = moduleName (ms_mod mod_summary)
1913     mod_str = showPpr dflags mod ++ hscSourceString (ms_hsc_src mod_summary)
1914 \end{code}
1915
1916 %************************************************************************
1917 %*                                                                      *
1918 \subsection{Recmpilation}
1919 %*                                                                      *
1920 %************************************************************************
1921
1922 \begin{code}
1923 -- | Indicates whether a given module's source has been modified since it
1924 -- was last compiled.
1925 data SourceModified
1926   = SourceModified
1927        -- ^ the source has been modified
1928   | SourceUnmodified
1929        -- ^ the source has not been modified.  Compilation may or may
1930        -- not be necessary, depending on whether any dependencies have
1931        -- changed since we last compiled.
1932   | SourceUnmodifiedAndStable
1933        -- ^ the source has not been modified, and furthermore all of
1934        -- its (transitive) dependencies are up to date; it definitely
1935        -- does not need to be recompiled.  This is important for two
1936        -- reasons: (a) we can omit the version check in checkOldIface,
1937        -- and (b) if the module used TH splices we don't need to force
1938        -- recompilation.
1939 \end{code}
1940
1941 %************************************************************************
1942 %*                                                                      *
1943 \subsection{Hpc Support}
1944 %*                                                                      *
1945 %************************************************************************
1946
1947 \begin{code}
1948 -- | Information about a modules use of Haskell Program Coverage
1949 data HpcInfo
1950   = HpcInfo
1951      { hpcInfoTickCount :: Int
1952      , hpcInfoHash      :: Int
1953      }
1954   | NoHpcInfo
1955      { hpcUsed          :: AnyHpcUsage  -- ^ Is hpc used anywhere on the module \*tree\*?
1956      }
1957
1958 -- | This is used to signal if one of my imports used HPC instrumentation
1959 -- even if there is no module-local HPC usage
1960 type AnyHpcUsage = Bool
1961
1962 emptyHpcInfo :: AnyHpcUsage -> HpcInfo
1963 emptyHpcInfo = NoHpcInfo
1964
1965 -- | Find out if HPC is used by this module or any of the modules
1966 -- it depends upon
1967 isHpcUsed :: HpcInfo -> AnyHpcUsage
1968 isHpcUsed (HpcInfo {})                   = True
1969 isHpcUsed (NoHpcInfo { hpcUsed = used }) = used
1970 \end{code}
1971
1972 %************************************************************************
1973 %*                                                                      *
1974 \subsection{Vectorisation Support}
1975 %*                                                                      *
1976 %************************************************************************
1977
1978 The following information is generated and consumed by the vectorisation
1979 subsystem.  It communicates the vectorisation status of declarations from one
1980 module to another.
1981
1982 Why do we need both f and f_v in the ModGuts/ModDetails/EPS version VectInfo
1983 below?  We need to know `f' when converting to IfaceVectInfo.  However, during
1984 vectorisation, we need to know `f_v', whose `Var' we cannot lookup based
1985 on just the OccName easily in a Core pass.
1986
1987 \begin{code}
1988 -- |Vectorisation information for 'ModGuts', 'ModDetails' and 'ExternalPackageState'; see also
1989 -- documentation at 'Vectorise.Env.GlobalEnv'.
1990 --
1991 -- NB: The following tables may also include 'Var's, 'TyCon's and 'DataCon's from imported modules,
1992 --     which have been subsequently vectorised in the current module.
1993 --
1994 data VectInfo
1995   = VectInfo
1996     { vectInfoVar          :: VarEnv  (Var    , Var  )    -- ^ @(f, f_v)@ keyed on @f@
1997     , vectInfoTyCon        :: NameEnv (TyCon  , TyCon)    -- ^ @(T, T_v)@ keyed on @T@
1998     , vectInfoDataCon      :: NameEnv (DataCon, DataCon)  -- ^ @(C, C_v)@ keyed on @C@
1999     , vectInfoScalarVars   :: VarSet                      -- ^ set of purely scalar variables
2000     , vectInfoScalarTyCons :: NameSet                     -- ^ set of scalar type constructors
2001     }
2002
2003 -- |Vectorisation information for 'ModIface'; i.e, the vectorisation information propagated
2004 -- across module boundaries.
2005 --
2006 -- NB: The field 'ifaceVectInfoVar' explicitly contains the workers of data constructors as well as
2007 --     class selectors — i.e., their mappings are /not/ implicitly generated from the data types.
2008 --     Moreover, whether the worker of a data constructor is in 'ifaceVectInfoVar' determines
2009 --     whether that data constructor was vectorised (or is part of an abstractly vectorised type
2010 --     constructor).
2011 --
2012 data IfaceVectInfo
2013   = IfaceVectInfo
2014     { ifaceVectInfoVar          :: [Name]  -- ^ All variables in here have a vectorised variant
2015     , ifaceVectInfoTyCon        :: [Name]  -- ^ All 'TyCon's in here have a vectorised variant;
2016                                            -- the name of the vectorised variant and those of its
2017                                            -- data constructors are determined by
2018                                            -- 'OccName.mkVectTyConOcc' and
2019                                            -- 'OccName.mkVectDataConOcc'; the names of the
2020                                            -- isomorphisms are determined by 'OccName.mkVectIsoOcc'
2021     , ifaceVectInfoTyConReuse   :: [Name]  -- ^ The vectorised form of all the 'TyCon's in here
2022                                            -- coincides with the unconverted form; the name of the
2023                                            -- isomorphisms is determined by 'OccName.mkVectIsoOcc'
2024     , ifaceVectInfoScalarVars   :: [Name]  -- iface version of 'vectInfoScalarVar'
2025     , ifaceVectInfoScalarTyCons :: [Name]  -- iface version of 'vectInfoScalarTyCon'
2026     }
2027
2028 noVectInfo :: VectInfo
2029 noVectInfo
2030   = VectInfo emptyVarEnv emptyNameEnv emptyNameEnv emptyVarSet emptyNameSet
2031
2032 plusVectInfo :: VectInfo -> VectInfo -> VectInfo
2033 plusVectInfo vi1 vi2 =
2034   VectInfo (vectInfoVar          vi1 `plusVarEnv`    vectInfoVar          vi2)
2035            (vectInfoTyCon        vi1 `plusNameEnv`   vectInfoTyCon        vi2)
2036            (vectInfoDataCon      vi1 `plusNameEnv`   vectInfoDataCon      vi2)
2037            (vectInfoScalarVars   vi1 `unionVarSet`   vectInfoScalarVars   vi2)
2038            (vectInfoScalarTyCons vi1 `unionNameSets` vectInfoScalarTyCons vi2)
2039
2040 concatVectInfo :: [VectInfo] -> VectInfo
2041 concatVectInfo = foldr plusVectInfo noVectInfo
2042
2043 noIfaceVectInfo :: IfaceVectInfo
2044 noIfaceVectInfo = IfaceVectInfo [] [] [] [] []
2045
2046 isNoIfaceVectInfo :: IfaceVectInfo -> Bool
2047 isNoIfaceVectInfo (IfaceVectInfo l1 l2 l3 l4 l5)
2048   = null l1 && null l2 && null l3 && null l4 && null l5
2049
2050 instance Outputable VectInfo where
2051   ppr info = vcat
2052              [ ptext (sLit "variables     :") <+> ppr (vectInfoVar          info)
2053              , ptext (sLit "tycons        :") <+> ppr (vectInfoTyCon        info)
2054              , ptext (sLit "datacons      :") <+> ppr (vectInfoDataCon      info)
2055              , ptext (sLit "scalar vars   :") <+> ppr (vectInfoScalarVars   info)
2056              , ptext (sLit "scalar tycons :") <+> ppr (vectInfoScalarTyCons info)
2057              ]
2058 \end{code}
2059
2060 %************************************************************************
2061 %*                                                                      *
2062 \subsection{Safe Haskell Support}
2063 %*                                                                      *
2064 %************************************************************************
2065
2066 This stuff here is related to supporting the Safe Haskell extension,
2067 primarily about storing under what trust type a module has been compiled.
2068
2069 \begin{code}
2070 -- | Is an import a safe import?
2071 type IsSafeImport = Bool
2072
2073 -- | Safe Haskell information for 'ModIface'
2074 -- Simply a wrapper around SafeHaskellMode to sepperate iface and flags
2075 newtype IfaceTrustInfo = TrustInfo SafeHaskellMode
2076
2077 getSafeMode :: IfaceTrustInfo -> SafeHaskellMode
2078 getSafeMode (TrustInfo x) = x
2079
2080 setSafeMode :: SafeHaskellMode -> IfaceTrustInfo
2081 setSafeMode = TrustInfo
2082
2083 noIfaceTrustInfo :: IfaceTrustInfo
2084 noIfaceTrustInfo = setSafeMode Sf_None
2085
2086 trustInfoToNum :: IfaceTrustInfo -> Word8
2087 trustInfoToNum it
2088   = case getSafeMode it of
2089             Sf_None         -> 0
2090             Sf_Unsafe       -> 1
2091             Sf_Trustworthy  -> 2
2092             Sf_Safe         -> 3
2093             Sf_SafeInferred -> 4
2094
2095 numToTrustInfo :: Word8 -> IfaceTrustInfo
2096 numToTrustInfo 0 = setSafeMode Sf_None
2097 numToTrustInfo 1 = setSafeMode Sf_Unsafe
2098 numToTrustInfo 2 = setSafeMode Sf_Trustworthy
2099 numToTrustInfo 3 = setSafeMode Sf_Safe
2100 numToTrustInfo 4 = setSafeMode Sf_SafeInferred
2101 numToTrustInfo n = error $ "numToTrustInfo: bad input number! (" ++ show n ++ ")"
2102
2103 instance Outputable IfaceTrustInfo where
2104     ppr (TrustInfo Sf_None)          = ptext $ sLit "none"
2105     ppr (TrustInfo Sf_Unsafe)        = ptext $ sLit "unsafe"
2106     ppr (TrustInfo Sf_Trustworthy)   = ptext $ sLit "trustworthy"
2107     ppr (TrustInfo Sf_Safe)          = ptext $ sLit "safe"
2108     ppr (TrustInfo Sf_SafeInferred)  = ptext $ sLit "safe-inferred"
2109 \end{code}
2110
2111 %************************************************************************
2112 %*                                                                      *
2113 \subsection{Parser result}
2114 %*                                                                      *
2115 %************************************************************************
2116
2117 \begin{code}
2118 data HsParsedModule = HsParsedModule {
2119     hpm_module    :: Located (HsModule RdrName),
2120     hpm_src_files :: [FilePath]
2121        -- ^ extra source files (e.g. from #includes).  The lexer collects
2122        -- these from '# <file> <line>' pragmas, which the C preprocessor
2123        -- leaves behind.  These files and their timestamps are stored in
2124        -- the .hi file, so that we can force recompilation if any of
2125        -- them change (#3589)
2126   }
2127 \end{code}
2128
2129 %************************************************************************
2130 %*                                                                      *
2131 \subsection{Linkable stuff}
2132 %*                                                                      *
2133 %************************************************************************
2134
2135 This stuff is in here, rather than (say) in Linker.lhs, because the Linker.lhs
2136 stuff is the *dynamic* linker, and isn't present in a stage-1 compiler
2137
2138 \begin{code}
2139 -- | Information we can use to dynamically link modules into the compiler
2140 data Linkable = LM {
2141   linkableTime     :: UTCTime,          -- ^ Time at which this linkable was built
2142                                         -- (i.e. when the bytecodes were produced,
2143                                         --       or the mod date on the files)
2144   linkableModule   :: Module,           -- ^ The linkable module itself
2145   linkableUnlinked :: [Unlinked]
2146     -- ^ Those files and chunks of code we have yet to link.
2147     --
2148     -- INVARIANT: A valid linkable always has at least one 'Unlinked' item.
2149     -- If this list is empty, the Linkable represents a fake linkable, which
2150     -- is generated in HscNothing mode to avoid recompiling modules.
2151     --
2152     -- ToDo: Do items get removed from this list when they get linked?
2153  }
2154
2155 isObjectLinkable :: Linkable -> Bool
2156 isObjectLinkable l = not (null unlinked) && all isObject unlinked
2157   where unlinked = linkableUnlinked l
2158         -- A linkable with no Unlinked's is treated as a BCO.  We can
2159         -- generate a linkable with no Unlinked's as a result of
2160         -- compiling a module in HscNothing mode, and this choice
2161         -- happens to work well with checkStability in module GHC.
2162
2163 linkableObjs :: Linkable -> [FilePath]
2164 linkableObjs l = [ f | DotO f <- linkableUnlinked l ]
2165
2166 instance Outputable Linkable where
2167    ppr (LM when_made mod unlinkeds)
2168       = (text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod)
2169         $$ nest 3 (ppr unlinkeds)
2170
2171 -------------------------------------------
2172
2173 -- | Objects which have yet to be linked by the compiler
2174 data Unlinked
2175    = DotO FilePath      -- ^ An object file (.o)
2176    | DotA FilePath      -- ^ Static archive file (.a)
2177    | DotDLL FilePath    -- ^ Dynamically linked library file (.so, .dll, .dylib)
2178    | BCOs CompiledByteCode ModBreaks    -- ^ A byte-code object, lives only in memory
2179
2180 #ifndef GHCI
2181 data CompiledByteCode = CompiledByteCodeUndefined
2182 _unused :: CompiledByteCode
2183 _unused = CompiledByteCodeUndefined
2184 #endif
2185
2186 instance Outputable Unlinked where
2187    ppr (DotO path)   = text "DotO" <+> text path
2188    ppr (DotA path)   = text "DotA" <+> text path
2189    ppr (DotDLL path) = text "DotDLL" <+> text path
2190 #ifdef GHCI
2191    ppr (BCOs bcos _) = text "BCOs" <+> ppr bcos
2192 #else
2193    ppr (BCOs _ _)    = text "No byte code"
2194 #endif
2195
2196 -- | Is this an actual file on disk we can link in somehow?
2197 isObject :: Unlinked -> Bool
2198 isObject (DotO _)   = True
2199 isObject (DotA _)   = True
2200 isObject (DotDLL _) = True
2201 isObject _          = False
2202
2203 -- | Is this a bytecode linkable with no file on disk?
2204 isInterpretable :: Unlinked -> Bool
2205 isInterpretable = not . isObject
2206
2207 -- | Retrieve the filename of the linkable if possible. Panic if it is a byte-code object
2208 nameOfObject :: Unlinked -> FilePath
2209 nameOfObject (DotO fn)   = fn
2210 nameOfObject (DotA fn)   = fn
2211 nameOfObject (DotDLL fn) = fn
2212 nameOfObject other       = pprPanic "nameOfObject" (ppr other)
2213
2214 -- | Retrieve the compiled byte-code if possible. Panic if it is a file-based linkable
2215 byteCodeOfObject :: Unlinked -> CompiledByteCode
2216 byteCodeOfObject (BCOs bc _) = bc
2217 byteCodeOfObject other       = pprPanic "byteCodeOfObject" (ppr other)
2218 \end{code}
2219
2220 %************************************************************************
2221 %*                                                                      *
2222 \subsection{Breakpoint Support}
2223 %*                                                                      *
2224 %************************************************************************
2225
2226 \begin{code}
2227 -- | Breakpoint index
2228 type BreakIndex = Int
2229
2230 -- | All the information about the breakpoints for a given module
2231 data ModBreaks
2232    = ModBreaks
2233    { modBreaks_flags :: BreakArray
2234         -- ^ The array of flags, one per breakpoint,
2235         -- indicating which breakpoints are enabled.
2236    , modBreaks_locs :: !(Array BreakIndex SrcSpan)
2237         -- ^ An array giving the source span of each breakpoint.
2238    , modBreaks_vars :: !(Array BreakIndex [OccName])
2239         -- ^ An array giving the names of the free variables at each breakpoint.
2240    , modBreaks_decls :: !(Array BreakIndex [String])
2241         -- ^ An array giving the names of the declarations enclosing each breakpoint.
2242    }
2243
2244 -- | Construct an empty ModBreaks
2245 emptyModBreaks :: ModBreaks
2246 emptyModBreaks = ModBreaks
2247    { modBreaks_flags = error "ModBreaks.modBreaks_array not initialised"
2248          -- ToDo: can we avoid this?
2249    , modBreaks_locs  = array (0,-1) []
2250    , modBreaks_vars  = array (0,-1) []
2251    , modBreaks_decls = array (0,-1) []
2252    }
2253 \end{code}
2254