Make {-# UNPACK #-} work for type/data family invocations
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 module Simplify ( simplTopBinds, simplExpr ) where
8
9 #include "HsVersions.h"
10
11 import DynFlags
12 import SimplMonad
13 import Type hiding      ( substTy, extendTvSubst, substTyVar )
14 import SimplEnv
15 import SimplUtils
16 import FamInstEnv       ( FamInstEnv )
17 import Literal          ( litIsLifted )
18 import Id
19 import MkId             ( seqId, realWorldPrimId )
20 import MkCore           ( mkImpossibleExpr, castBottomExpr )
21 import IdInfo
22 import Name             ( mkSystemVarName, isExternalName )
23 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
24 import OptCoercion      ( optCoercion )
25 import FamInstEnv       ( topNormaliseType )
26 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness, isMarkedStrict )
27 import CoreMonad        ( Tick(..), SimplifierMode(..) )
28 import CoreSyn
29 import Demand           ( isStrictDmd, StrictSig(..), dmdTypeDepth )
30 import PprCore          ( pprParendExpr, pprCoreExpr )
31 import CoreUnfold
32 import CoreUtils
33 import qualified CoreSubst
34 import CoreArity
35 import Rules            ( lookupRule, getRules )
36 import BasicTypes       ( Arity )
37 import TysPrim          ( realWorldStatePrimTy )
38 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
39 import MonadUtils       ( foldlM, mapAccumLM, liftIO )
40 import Maybes           ( orElse, isNothing )
41 import Control.Monad
42 import Data.List        ( mapAccumL )
43 import Outputable
44 import FastString
45 import Pair
46 import Util
47 import ErrUtils
48 \end{code}
49
50
51 The guts of the simplifier is in this module, but the driver loop for
52 the simplifier is in SimplCore.lhs.
53
54
55 -----------------------------------------
56         *** IMPORTANT NOTE ***
57 -----------------------------------------
58 The simplifier used to guarantee that the output had no shadowing, but
59 it does not do so any more.   (Actually, it never did!)  The reason is
60 documented with simplifyArgs.
61
62
63 -----------------------------------------
64         *** IMPORTANT NOTE ***
65 -----------------------------------------
66 Many parts of the simplifier return a bunch of "floats" as well as an
67 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
68
69 All "floats" are let-binds, not case-binds, but some non-rec lets may
70 be unlifted (with RHS ok-for-speculation).
71
72
73
74 -----------------------------------------
75         ORGANISATION OF FUNCTIONS
76 -----------------------------------------
77 simplTopBinds
78   - simplify all top-level binders
79   - for NonRec, call simplRecOrTopPair
80   - for Rec,    call simplRecBind
81
82
83         ------------------------------
84 simplExpr (applied lambda)      ==> simplNonRecBind
85 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
86 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
87
88         ------------------------------
89 simplRecBind    [binders already simplfied]
90   - use simplRecOrTopPair on each pair in turn
91
92 simplRecOrTopPair [binder already simplified]
93   Used for: recursive bindings (top level and nested)
94             top-level non-recursive bindings
95   Returns:
96   - check for PreInlineUnconditionally
97   - simplLazyBind
98
99 simplNonRecBind
100   Used for: non-top-level non-recursive bindings
101             beta reductions (which amount to the same thing)
102   Because it can deal with strict arts, it takes a
103         "thing-inside" and returns an expression
104
105   - check for PreInlineUnconditionally
106   - simplify binder, including its IdInfo
107   - if strict binding
108         simplStrictArg
109         mkAtomicArgs
110         completeNonRecX
111     else
112         simplLazyBind
113         addFloats
114
115 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
116   Used for: binding case-binder and constr args in a known-constructor case
117   - check for PreInLineUnconditionally
118   - simplify binder
119   - completeNonRecX
120
121         ------------------------------
122 simplLazyBind:  [binder already simplified, RHS not]
123   Used for: recursive bindings (top level and nested)
124             top-level non-recursive bindings
125             non-top-level, but *lazy* non-recursive bindings
126         [must not be strict or unboxed]
127   Returns floats + an augmented environment, not an expression
128   - substituteIdInfo and add result to in-scope
129         [so that rules are available in rec rhs]
130   - simplify rhs
131   - mkAtomicArgs
132   - float if exposes constructor or PAP
133   - completeBind
134
135
136 completeNonRecX:        [binder and rhs both simplified]
137   - if the the thing needs case binding (unlifted and not ok-for-spec)
138         build a Case
139    else
140         completeBind
141         addFloats
142
143 completeBind:   [given a simplified RHS]
144         [used for both rec and non-rec bindings, top level and not]
145   - try PostInlineUnconditionally
146   - add unfolding [this is the only place we add an unfolding]
147   - add arity
148
149
150
151 Right hand sides and arguments
152 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
153 In many ways we want to treat
154         (a) the right hand side of a let(rec), and
155         (b) a function argument
156 in the same way.  But not always!  In particular, we would
157 like to leave these arguments exactly as they are, so they
158 will match a RULE more easily.
159
160         f (g x, h x)
161         g (+ x)
162
163 It's harder to make the rule match if we ANF-ise the constructor,
164 or eta-expand the PAP:
165
166         f (let { a = g x; b = h x } in (a,b))
167         g (\y. + x y)
168
169 On the other hand if we see the let-defns
170
171         p = (g x, h x)
172         q = + x
173
174 then we *do* want to ANF-ise and eta-expand, so that p and q
175 can be safely inlined.
176
177 Even floating lets out is a bit dubious.  For let RHS's we float lets
178 out if that exposes a value, so that the value can be inlined more vigorously.
179 For example
180
181         r = let x = e in (x,x)
182
183 Here, if we float the let out we'll expose a nice constructor. We did experiments
184 that showed this to be a generally good thing.  But it was a bad thing to float
185 lets out unconditionally, because that meant they got allocated more often.
186
187 For function arguments, there's less reason to expose a constructor (it won't
188 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
189 So for the moment we don't float lets out of function arguments either.
190
191
192 Eta expansion
193 ~~~~~~~~~~~~~~
194 For eta expansion, we want to catch things like
195
196         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
197
198 If the \x was on the RHS of a let, we'd eta expand to bring the two
199 lambdas together.  And in general that's a good thing to do.  Perhaps
200 we should eta expand wherever we find a (value) lambda?  Then the eta
201 expansion at a let RHS can concentrate solely on the PAP case.
202
203
204 %************************************************************************
205 %*                                                                      *
206 \subsection{Bindings}
207 %*                                                                      *
208 %************************************************************************
209
210 \begin{code}
211 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
212
213 simplTopBinds env0 binds0
214   = do  {       -- Put all the top-level binders into scope at the start
215                 -- so that if a transformation rule has unexpectedly brought
216                 -- anything into scope, then we don't get a complaint about that.
217                 -- It's rather as if the top-level binders were imported.
218                 -- See note [Glomming] in OccurAnal.
219         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
220         ; dflags <- getDynFlags
221         ; let dump_flag = dopt Opt_D_verbose_core2core dflags
222         ; env2 <- simpl_binds dump_flag env1 binds0
223         ; freeTick SimplifierDone
224         ; return env2 }
225   where
226         -- We need to track the zapped top-level binders, because
227         -- they should have their fragile IdInfo zapped (notably occurrence info)
228         -- That's why we run down binds and bndrs' simultaneously.
229         --
230         -- The dump-flag emits a trace for each top-level binding, which
231         -- helps to locate the tracing for inlining and rule firing
232     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
233     simpl_binds _    env []           = return env
234     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
235                                                      simpl_bind env bind
236                                            ; simpl_binds dump env' binds }
237
238     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
239     trace_bind False _    = \x -> x
240
241     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
242     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
243         where
244           (env', b') = addBndrRules env b (lookupRecBndr env b)
245 \end{code}
246
247
248 %************************************************************************
249 %*                                                                      *
250 \subsection{Lazy bindings}
251 %*                                                                      *
252 %************************************************************************
253
254 simplRecBind is used for
255         * recursive bindings only
256
257 \begin{code}
258 simplRecBind :: SimplEnv -> TopLevelFlag
259              -> [(InId, InExpr)]
260              -> SimplM SimplEnv
261 simplRecBind env0 top_lvl pairs0
262   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
263         ; env1 <- go (zapFloats env_with_info) triples
264         ; return (env0 `addRecFloats` env1) }
265         -- addFloats adds the floats from env1,
266         -- _and_ updates env0 with the in-scope set from env1
267   where
268     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
269         -- Add the (substituted) rules to the binder
270     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
271         where
272           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
273
274     go env [] = return env
275
276     go env ((old_bndr, new_bndr, rhs) : pairs)
277         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
278              ; go env' pairs }
279 \end{code}
280
281 simplOrTopPair is used for
282         * recursive bindings (whether top level or not)
283         * top-level non-recursive bindings
284
285 It assumes the binder has already been simplified, but not its IdInfo.
286
287 \begin{code}
288 simplRecOrTopPair :: SimplEnv
289                   -> TopLevelFlag -> RecFlag
290                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
291                   -> SimplM SimplEnv    -- Returns an env that includes the binding
292
293 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
294   = do dflags <- getDynFlags
295        -- Check for unconditional inline
296        if preInlineUnconditionally dflags env top_lvl old_bndr rhs
297            then do tick (PreInlineUnconditionally old_bndr)
298                    return (extendIdSubst env old_bndr (mkContEx env rhs))
299            else simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env
300 \end{code}
301
302
303 simplLazyBind is used for
304   * [simplRecOrTopPair] recursive bindings (whether top level or not)
305   * [simplRecOrTopPair] top-level non-recursive bindings
306   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
307
308 Nota bene:
309     1. It assumes that the binder is *already* simplified,
310        and is in scope, and its IdInfo too, except unfolding
311
312     2. It assumes that the binder type is lifted.
313
314     3. It does not check for pre-inline-unconditionallly;
315        that should have been done already.
316
317 \begin{code}
318 simplLazyBind :: SimplEnv
319               -> TopLevelFlag -> RecFlag
320               -> InId -> OutId          -- Binder, both pre-and post simpl
321                                         -- The OutId has IdInfo, except arity, unfolding
322               -> InExpr -> SimplEnv     -- The RHS and its environment
323               -> SimplM SimplEnv
324
325 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
326   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
327     do  { let   rhs_env     = rhs_se `setInScope` env
328                 (tvs, body) = case collectTyBinders rhs of
329                                 (tvs, body) | not_lam body -> (tvs,body)
330                                             | otherwise    -> ([], rhs)
331                 not_lam (Lam _ _) = False
332                 not_lam _         = True
333                         -- Do not do the "abstract tyyvar" thing if there's
334                         -- a lambda inside, becuase it defeats eta-reduction
335                         --    f = /\a. \x. g a x
336                         -- should eta-reduce
337
338
339         ; (body_env, tvs') <- simplBinders rhs_env tvs
340                 -- See Note [Floating and type abstraction] in SimplUtils
341
342         -- Simplify the RHS
343         ; let   body_out_ty :: OutType
344                 body_out_ty = substTy body_env (exprType body)
345         ; (body_env1, body1) <- simplExprF body_env body (mkRhsStop body_out_ty)
346         -- ANF-ise a constructor or PAP rhs
347         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
348
349         ; (env', rhs')
350             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
351                 then                            -- No floating, revert to body1
352                      do { rhs' <- mkLam env tvs' (wrapFloats body_env1 body1)
353                         ; return (env, rhs') }
354
355                 else if null tvs then           -- Simple floating
356                      do { tick LetFloatFromLet
357                         ; return (addFloats env body_env2, body2) }
358
359                 else                            -- Do type-abstraction first
360                      do { tick LetFloatFromLet
361                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
362                         ; rhs' <- mkLam env tvs' body3
363                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
364                         ; return (env', rhs') }
365
366         ; completeBind env' top_lvl bndr bndr1 rhs' }
367 \end{code}
368
369 A specialised variant of simplNonRec used when the RHS is already simplified,
370 notably in knownCon.  It uses case-binding where necessary.
371
372 \begin{code}
373 simplNonRecX :: SimplEnv
374              -> InId            -- Old binder
375              -> OutExpr         -- Simplified RHS
376              -> SimplM SimplEnv
377
378 simplNonRecX env bndr new_rhs
379   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
380   = return env          --               Here c is dead, and we avoid creating
381                         --               the binding c = (a,b)
382   | Coercion co <- new_rhs
383   = return (extendCvSubst env bndr co)
384   | otherwise           --               the binding b = (a,b)
385   = do  { (env', bndr') <- simplBinder env bndr
386         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
387                 -- simplNonRecX is only used for NotTopLevel things
388
389 completeNonRecX :: TopLevelFlag -> SimplEnv
390                 -> Bool
391                 -> InId                 -- Old binder
392                 -> OutId                -- New binder
393                 -> OutExpr              -- Simplified RHS
394                 -> SimplM SimplEnv
395
396 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
397   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
398         ; (env2, rhs2) <-
399                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
400                 then do { tick LetFloatFromLet
401                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
402                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
403         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
404 \end{code}
405
406 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
407    Doing so risks exponential behaviour, because new_rhs has been simplified once already
408    In the cases described by the folowing commment, postInlineUnconditionally will
409    catch many of the relevant cases.
410         -- This happens; for example, the case_bndr during case of
411         -- known constructor:  case (a,b) of x { (p,q) -> ... }
412         -- Here x isn't mentioned in the RHS, so we don't want to
413         -- create the (dead) let-binding  let x = (a,b) in ...
414         --
415         -- Similarly, single occurrences can be inlined vigourously
416         -- e.g.  case (f x, g y) of (a,b) -> ....
417         -- If a,b occur once we can avoid constructing the let binding for them.
418
419    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
420         -- Consider     case I# (quotInt# x y) of
421         --                I# v -> let w = J# v in ...
422         -- If we gaily inline (quotInt# x y) for v, we end up building an
423         -- extra thunk:
424         --                let w = J# (quotInt# x y) in ...
425         -- because quotInt# can fail.
426
427   | preInlineUnconditionally env NotTopLevel bndr new_rhs
428   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
429 -}
430
431 ----------------------------------
432 prepareRhs takes a putative RHS, checks whether it's a PAP or
433 constructor application and, if so, converts it to ANF, so that the
434 resulting thing can be inlined more easily.  Thus
435         x = (f a, g b)
436 becomes
437         t1 = f a
438         t2 = g b
439         x = (t1,t2)
440
441 We also want to deal well cases like this
442         v = (f e1 `cast` co) e2
443 Here we want to make e1,e2 trivial and get
444         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
445 That's what the 'go' loop in prepareRhs does
446
447 \begin{code}
448 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
449 -- Adds new floats to the env iff that allows us to return a good RHS
450 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
451   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
452   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
453   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
454         ; return (env', Cast rhs' co) }
455   where
456     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
457                                    `setDemandInfo`     demandInfo info
458     info = idInfo id
459
460 prepareRhs top_lvl env0 _ rhs0
461   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
462         ; return (env1, rhs1) }
463   where
464     go n_val_args env (Cast rhs co)
465         = do { (is_exp, env', rhs') <- go n_val_args env rhs
466              ; return (is_exp, env', Cast rhs' co) }
467     go n_val_args env (App fun (Type ty))
468         = do { (is_exp, env', rhs') <- go n_val_args env fun
469              ; return (is_exp, env', App rhs' (Type ty)) }
470     go n_val_args env (App fun arg)
471         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
472              ; case is_exp of
473                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
474                            ; return (True, env'', App fun' arg') }
475                 False -> return (False, env, App fun arg) }
476     go n_val_args env (Var fun)
477         = return (is_exp, env, Var fun)
478         where
479           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
480                         -- See Note [CONLIKE pragma] in BasicTypes
481                         -- The definition of is_exp should match that in
482                         -- OccurAnal.occAnalApp
483
484     go _ env other
485         = return (False, env, other)
486 \end{code}
487
488
489 Note [Float coercions]
490 ~~~~~~~~~~~~~~~~~~~~~~
491 When we find the binding
492         x = e `cast` co
493 we'd like to transform it to
494         x' = e
495         x = x `cast` co         -- A trivial binding
496 There's a chance that e will be a constructor application or function, or something
497 like that, so moving the coerion to the usage site may well cancel the coersions
498 and lead to further optimisation.  Example:
499
500      data family T a :: *
501      data instance T Int = T Int
502
503      foo :: Int -> Int -> Int
504      foo m n = ...
505         where
506           x = T m
507           go 0 = 0
508           go n = case x of { T m -> go (n-m) }
509                 -- This case should optimise
510
511 Note [Preserve strictness when floating coercions]
512 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
513 In the Note [Float coercions] transformation, keep the strictness info.
514 Eg
515         f = e `cast` co    -- f has strictness SSL
516 When we transform to
517         f' = e             -- f' also has strictness SSL
518         f = f' `cast` co   -- f still has strictness SSL
519
520 Its not wrong to drop it on the floor, but better to keep it.
521
522 Note [Float coercions (unlifted)]
523 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
524 BUT don't do [Float coercions] if 'e' has an unlifted type.
525 This *can* happen:
526
527      foo :: Int = (error (# Int,Int #) "urk")
528                   `cast` CoUnsafe (# Int,Int #) Int
529
530 If do the makeTrivial thing to the error call, we'll get
531     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
532 But 'v' isn't in scope!
533
534 These strange casts can happen as a result of case-of-case
535         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
536                 (# p,q #) -> p+q
537
538
539 \begin{code}
540 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
541 -- Binds the expression to a variable, if it's not trivial, returning the variable
542 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
543
544 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo
545                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
546 -- Propagate strictness and demand info to the new binder
547 -- Note [Preserve strictness when floating coercions]
548 -- Returned SimplEnv has same substitution as incoming one
549 makeTrivialWithInfo top_lvl env info expr
550   | exprIsTrivial expr                          -- Already trivial
551   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
552                                                 --   See Note [Cannot trivialise]
553   = return (env, expr)
554   | otherwise           -- See Note [Take care] below
555   = do  { uniq <- getUniqueM
556         ; let name = mkSystemVarName uniq (fsLit "a")
557               var = mkLocalIdWithInfo name expr_ty info
558         ; env'  <- completeNonRecX top_lvl env False var var expr
559         ; expr' <- simplVar env' var
560         ; return (env', expr') }
561         -- The simplVar is needed becase we're constructing a new binding
562         --     a = rhs
563         -- And if rhs is of form (rhs1 |> co), then we might get
564         --     a1 = rhs1
565         --     a = a1 |> co
566         -- and now a's RHS is trivial and can be substituted out, and that
567         -- is what completeNonRecX will do
568         -- To put it another way, it's as if we'd simplified
569         --    let var = e in var
570   where
571     expr_ty = exprType expr
572
573 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
574 -- True iff we can have a binding of this expression at this level
575 -- Precondition: the type is the type of the expression
576 bindingOk top_lvl _ expr_ty
577   | isTopLevel top_lvl = not (isUnLiftedType expr_ty)
578   | otherwise          = True
579 \end{code}
580
581 Note [Cannot trivialise]
582 ~~~~~~~~~~~~~~~~~~~~~~~~
583 Consider tih
584    f :: Int -> Addr#
585
586    foo :: Bar
587    foo = Bar (f 3)
588
589 Then we can't ANF-ise foo, even though we'd like to, because
590 we can't make a top-level binding for the Addr# (f 3). And if
591 so we don't want to turn it into
592    foo = let x = f 3 in Bar x
593 because we'll just end up inlining x back, and that makes the
594 simplifier loop.  Better not to ANF-ise it at all.
595
596 A case in point is literal strings (a MachStr is not regarded as
597 trivial):
598
599    foo = Ptr "blob"#
600
601 We don't want to ANF-ise this.
602
603 %************************************************************************
604 %*                                                                      *
605 \subsection{Completing a lazy binding}
606 %*                                                                      *
607 %************************************************************************
608
609 completeBind
610   * deals only with Ids, not TyVars
611   * takes an already-simplified binder and RHS
612   * is used for both recursive and non-recursive bindings
613   * is used for both top-level and non-top-level bindings
614
615 It does the following:
616   - tries discarding a dead binding
617   - tries PostInlineUnconditionally
618   - add unfolding [this is the only place we add an unfolding]
619   - add arity
620
621 It does *not* attempt to do let-to-case.  Why?  Because it is used for
622   - top-level bindings (when let-to-case is impossible)
623   - many situations where the "rhs" is known to be a WHNF
624                 (so let-to-case is inappropriate).
625
626 Nor does it do the atomic-argument thing
627
628 \begin{code}
629 completeBind :: SimplEnv
630              -> TopLevelFlag            -- Flag stuck into unfolding
631              -> InId                    -- Old binder
632              -> OutId -> OutExpr        -- New binder and RHS
633              -> SimplM SimplEnv
634 -- completeBind may choose to do its work
635 --      * by extending the substitution (e.g. let x = y in ...)
636 --      * or by adding to the floats in the envt
637
638 completeBind env top_lvl old_bndr new_bndr new_rhs
639  | isCoVar old_bndr
640  = case new_rhs of
641      Coercion co -> return (extendCvSubst env old_bndr co)
642      _           -> return (addNonRec env new_bndr new_rhs)
643
644  | otherwise
645  = ASSERT( isId new_bndr )
646    do { let old_info = idInfo old_bndr
647             old_unf  = unfoldingInfo old_info
648             occ_info = occInfo old_info
649
650         -- Do eta-expansion on the RHS of the binding
651         -- See Note [Eta-expanding at let bindings] in SimplUtils
652       ; (new_arity, final_rhs) <- tryEtaExpand env new_bndr new_rhs
653
654         -- Simplify the unfolding
655       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
656
657       ; dflags <- getDynFlags
658       ; if postInlineUnconditionally dflags env top_lvl new_bndr occ_info
659                                      final_rhs new_unfolding
660
661                         -- Inline and discard the binding
662         then do  { tick (PostInlineUnconditionally old_bndr)
663                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
664                 -- Use the substitution to make quite, quite sure that the
665                 -- substitution will happen, since we are going to discard the binding
666         else
667    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
668
669               -- Unfolding info: Note [Setting the new unfolding]
670             info2 = info1 `setUnfoldingInfo` new_unfolding
671
672               -- Demand info: Note [Setting the demand info]
673               --
674               -- We also have to nuke demand info if for some reason
675               -- eta-expansion *reduces* the arity of the binding to less
676               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
677             info3 | isEvaldUnfolding new_unfolding
678                     || (case strictnessInfo info2 of
679                           Just (StrictSig dmd_ty) -> new_arity < dmdTypeDepth dmd_ty
680                           Nothing                 -> False)
681                   = zapDemandInfo info2 `orElse` info2
682                   | otherwise
683                   = info2
684
685             final_id = new_bndr `setIdInfo` info3
686
687       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
688         return (addNonRec env final_id final_rhs) } }
689                 -- The addNonRec adds it to the in-scope set too
690
691 ------------------------------
692 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
693 -- Add a new binding to the environment, complete with its unfolding
694 -- but *do not* do postInlineUnconditionally, because we have already
695 -- processed some of the scope of the binding
696 -- We still want the unfolding though.  Consider
697 --      let
698 --            x = /\a. let y = ... in Just y
699 --      in body
700 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
701 -- but 'x' may well then be inlined in 'body' in which case we'd like the
702 -- opportunity to inline 'y' too.
703 --
704 -- INVARIANT: the arity is correct on the incoming binders
705
706 addPolyBind top_lvl env (NonRec poly_id rhs)
707   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
708                         -- Assumes that poly_id did not have an INLINE prag
709                         -- which is perhaps wrong.  ToDo: think about this
710         ; let final_id = setIdInfo poly_id $
711                          idInfo poly_id `setUnfoldingInfo` unfolding
712
713         ; return (addNonRec env final_id rhs) }
714
715 addPolyBind _ env bind@(Rec _)
716   = return (extendFloats env bind)
717         -- Hack: letrecs are more awkward, so we extend "by steam"
718         -- without adding unfoldings etc.  At worst this leads to
719         -- more simplifier iterations
720
721 ------------------------------
722 simplUnfolding :: SimplEnv-> TopLevelFlag
723                -> InId
724                -> OutExpr
725                -> Unfolding -> SimplM Unfolding
726 -- Note [Setting the new unfolding]
727 simplUnfolding env _ _ _ (DFunUnfolding ar con ops)
728   = return (DFunUnfolding ar con ops')
729   where
730     ops' = map (fmap (substExpr (text "simplUnfolding") env)) ops
731
732 simplUnfolding env top_lvl id _
733     (CoreUnfolding { uf_tmpl = expr, uf_arity = arity
734                    , uf_src = src, uf_guidance = guide })
735   | isStableSource src
736   = do { expr' <- simplExpr rule_env expr
737        ; let src' = CoreSubst.substUnfoldingSource (mkCoreSubst (text "inline-unf") env) src
738              is_top_lvl = isTopLevel top_lvl
739        ; case guide of
740            UnfWhen sat_ok _    -- Happens for INLINE things
741               -> let guide' = UnfWhen sat_ok (inlineBoringOk expr')
742                      -- Refresh the boring-ok flag, in case expr'
743                      -- has got small. This happens, notably in the inlinings
744                      -- for dfuns for single-method classes; see
745                      -- Note [Single-method classes] in TcInstDcls.
746                      -- A test case is Trac #4138
747                  in return (mkCoreUnfolding src' is_top_lvl expr' arity guide')
748                  -- See Note [Top-level flag on inline rules] in CoreUnfold
749
750            _other              -- Happens for INLINABLE things
751               -> let bottoming = isBottomingId id
752                  in bottoming `seq` -- See Note [Force bottoming field]
753                     do dflags <- getDynFlags
754                        return (mkUnfolding dflags src' is_top_lvl bottoming expr')
755                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
756                 -- unfolding, and we need to make sure the guidance is kept up
757                 -- to date with respect to any changes in the unfolding.
758        }
759   where
760     act      = idInlineActivation id
761     rule_env = updMode (updModeForInlineRules act) env
762                -- See Note [Simplifying inside InlineRules] in SimplUtils
763
764 simplUnfolding _ top_lvl id new_rhs _
765   = let bottoming = isBottomingId id
766     in bottoming `seq`  -- See Note [Force bottoming field]
767        do dflags <- getDynFlags
768           return (mkUnfolding dflags InlineRhs (isTopLevel top_lvl) bottoming new_rhs)
769           -- We make an  unfolding *even for loop-breakers*.
770           -- Reason: (a) It might be useful to know that they are WHNF
771           --         (b) In TidyPgm we currently assume that, if we want to
772           --             expose the unfolding then indeed we *have* an unfolding
773           --             to expose.  (We could instead use the RHS, but currently
774           --             we don't.)  The simple thing is always to have one.
775 \end{code}
776
777 Note [Force bottoming field]
778 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
779 We need to force bottoming, or the new unfolding holds
780 on to the old unfolding (which is part of the id).
781
782 Note [Arity decrease]
783 ~~~~~~~~~~~~~~~~~~~~~
784 Generally speaking the arity of a binding should not decrease.  But it *can*
785 legitimately happen becuase of RULES.  Eg
786         f = g Int
787 where g has arity 2, will have arity 2.  But if there's a rewrite rule
788         g Int --> h
789 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
790 which is in the output of Specialise:
791
792      Rec {
793         $dm {Arity 2} = \d.\x. op d
794         {-# RULES forall d. $dm Int d = $s$dm #-}
795
796         dInt = MkD .... opInt ...
797         opInt {Arity 1} = $dm dInt
798
799         $s$dm {Arity 0} = \x. op dInt }
800
801 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
802 That's why Specialise goes to a little trouble to pin the right arity
803 on specialised functions too.
804
805 Note [Setting the new unfolding]
806 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
807 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
808   should do nothing at all, but simplifying gently might get rid of
809   more crap.
810
811 * If not, we make an unfolding from the new RHS.  But *only* for
812   non-loop-breakers. Making loop breakers not have an unfolding at all
813   means that we can avoid tests in exprIsConApp, for example.  This is
814   important: if exprIsConApp says 'yes' for a recursive thing, then we
815   can get into an infinite loop
816
817 If there's an InlineRule on a loop breaker, we hang on to the inlining.
818 It's pretty dodgy, but the user did say 'INLINE'.  May need to revisit
819 this choice.
820
821 Note [Setting the demand info]
822 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
823 If the unfolding is a value, the demand info may
824 go pear-shaped, so we nuke it.  Example:
825      let x = (a,b) in
826      case x of (p,q) -> h p q x
827 Here x is certainly demanded. But after we've nuked
828 the case, we'll get just
829      let x = (a,b) in h a b x
830 and now x is not demanded (I'm assuming h is lazy)
831 This really happens.  Similarly
832      let f = \x -> e in ...f..f...
833 After inlining f at some of its call sites the original binding may
834 (for example) be no longer strictly demanded.
835 The solution here is a bit ad hoc...
836
837
838 %************************************************************************
839 %*                                                                      *
840 \subsection[Simplify-simplExpr]{The main function: simplExpr}
841 %*                                                                      *
842 %************************************************************************
843
844 The reason for this OutExprStuff stuff is that we want to float *after*
845 simplifying a RHS, not before.  If we do so naively we get quadratic
846 behaviour as things float out.
847
848 To see why it's important to do it after, consider this (real) example:
849
850         let t = f x
851         in fst t
852 ==>
853         let t = let a = e1
854                     b = e2
855                 in (a,b)
856         in fst t
857 ==>
858         let a = e1
859             b = e2
860             t = (a,b)
861         in
862         a       -- Can't inline a this round, cos it appears twice
863 ==>
864         e1
865
866 Each of the ==> steps is a round of simplification.  We'd save a
867 whole round if we float first.  This can cascade.  Consider
868
869         let f = g d
870         in \x -> ...f...
871 ==>
872         let f = let d1 = ..d.. in \y -> e
873         in \x -> ...f...
874 ==>
875         let d1 = ..d..
876         in \x -> ...(\y ->e)...
877
878 Only in this second round can the \y be applied, and it
879 might do the same again.
880
881
882 \begin{code}
883 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
884 simplExpr env expr = simplExprC env expr (mkBoringStop expr_out_ty)
885   where
886     expr_out_ty :: OutType
887     expr_out_ty = substTy env (exprType expr)
888
889 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
890         -- Simplify an expression, given a continuation
891 simplExprC env expr cont
892   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
893     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
894         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
895           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
896           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
897           return (wrapFloats env' expr') }
898
899 --------------------------------------------------
900 simplExprF :: SimplEnv -> InExpr -> SimplCont
901            -> SimplM (SimplEnv, OutExpr)
902
903 simplExprF env e cont
904   = {- pprTrace "simplExprF" (vcat
905       [ ppr e
906       , text "cont =" <+> ppr cont
907       , text "inscope =" <+> ppr (seInScope env)
908       , text "tvsubst =" <+> ppr (seTvSubst env)
909       , text "idsubst =" <+> ppr (seIdSubst env)
910       , text "cvsubst =" <+> ppr (seCvSubst env)
911       {- , ppr (seFloats env) -}
912       ]) $ -}
913     simplExprF1 env e cont
914
915 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
916             -> SimplM (SimplEnv, OutExpr)
917 simplExprF1 env (Var v)        cont = simplIdF env v cont
918 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
919 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
920 simplExprF1 env (Cast body co) cont = simplCast env body co cont
921 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
922 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
923                                       rebuild env (Type (substTy env ty)) cont
924 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
925                                       ApplyTo NoDup arg env cont
926
927 simplExprF1 env expr@(Lam {}) cont
928   = simplLam env zapped_bndrs body cont
929         -- The main issue here is under-saturated lambdas
930         --   (\x1. \x2. e) arg1
931         -- Here x1 might have "occurs-once" occ-info, because occ-info
932         -- is computed assuming that a group of lambdas is applied
933         -- all at once.  If there are too few args, we must zap the
934         -- occ-info, UNLESS the remaining binders are one-shot
935   where
936     (bndrs, body) = collectBinders expr
937     zapped_bndrs | need_to_zap = map zap bndrs
938                  | otherwise   = bndrs
939
940     need_to_zap = any zappable_bndr (drop n_args bndrs)
941     n_args = countArgs cont
942         -- NB: countArgs counts all the args (incl type args)
943         -- and likewise drop counts all binders (incl type lambdas)
944
945     zappable_bndr b = isId b && not (isOneShotBndr b)
946     zap b | isTyVar b = b
947           | otherwise = zapLamIdInfo b
948
949 simplExprF1 env (Case scrut bndr alts_ty alts) cont
950   | sm_case_case (getMode env)
951   =     -- Simplify the scrutinee with a Select continuation
952     simplExprF env scrut (Select NoDup bndr alts env cont)
953
954   | otherwise
955   =     -- If case-of-case is off, simply simplify the case expression
956         -- in a vanilla Stop context, and rebuild the result around it
957     do  { case_expr' <- simplExprC env scrut
958                              (Select NoDup bndr alts env (mkBoringStop alts_out_ty))
959         ; rebuild env case_expr' cont }
960   where
961     alts_out_ty = substTy env alts_ty
962
963 simplExprF1 env (Let (Rec pairs) body) cont
964   = do  { env' <- simplRecBndrs env (map fst pairs)
965                 -- NB: bndrs' don't have unfoldings or rules
966                 -- We add them as we go down
967
968         ; env'' <- simplRecBind env' NotTopLevel pairs
969         ; simplExprF env'' body cont }
970
971 simplExprF1 env (Let (NonRec bndr rhs) body) cont
972   = simplNonRecE env bndr (rhs, env) ([], body) cont
973
974 ---------------------------------
975 simplType :: SimplEnv -> InType -> SimplM OutType
976         -- Kept monadic just so we can do the seqType
977 simplType env ty
978   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
979     seqType new_ty `seq` return new_ty
980   where
981     new_ty = substTy env ty
982
983 ---------------------------------
984 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
985                -> SimplM (SimplEnv, OutExpr)
986 simplCoercionF env co cont
987   = do { co' <- simplCoercion env co
988        ; rebuild env (Coercion co') cont }
989
990 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
991 simplCoercion env co
992   = let opt_co = optCoercion (getCvSubst env) co
993     in seqCo opt_co `seq` return opt_co
994
995 -----------------------------------
996 -- | Push a TickIt context outwards past applications and cases, as
997 -- long as this is a non-scoping tick, to let case and application
998 -- optimisations apply.
999
1000 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1001           -> SimplM (SimplEnv, OutExpr)
1002 simplTick env tickish expr cont
1003   -- A scoped tick turns into a continuation, so that we can spot
1004   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1005   -- it this way, then it would take two passes of the simplifier to
1006   -- reduce ((scc t (\x . e)) e').
1007   -- NB, don't do this with counting ticks, because if the expr is
1008   -- bottom, then rebuildCall will discard the continuation.
1009
1010 -- XXX: we cannot do this, because the simplifier assumes that
1011 -- the context can be pushed into a case with a single branch. e.g.
1012 --    scc<f>  case expensive of p -> e
1013 -- becomes
1014 --    case expensive of p -> scc<f> e
1015 --
1016 -- So I'm disabling this for now.  It just means we will do more
1017 -- simplifier iterations that necessary in some cases.
1018
1019 --  | tickishScoped tickish && not (tickishCounts tickish)
1020 --  = simplExprF env expr (TickIt tickish cont)
1021
1022   -- For non-scoped ticks, we push the continuation inside the
1023   -- tick.  This has the effect of moving the tick to the outside of a
1024   -- case or application context, allowing the normal case and
1025   -- application optimisations to fire.
1026   | not (tickishScoped tickish)
1027   = do { (env', expr') <- simplExprF env expr cont
1028        ; return (env', mkTick tickish expr')
1029        }
1030
1031   -- For breakpoints, we cannot do any floating of bindings around the
1032   -- tick, because breakpoints cannot be split into tick/scope pairs.
1033   | not (tickishCanSplit tickish)
1034   = no_floating_past_tick
1035
1036   | interesting_cont, Just expr' <- push_tick_inside tickish expr
1037     -- see Note [case-of-scc-of-case]
1038   = simplExprF env expr' cont
1039
1040   | otherwise
1041   = no_floating_past_tick -- was: wrap_floats, see below
1042
1043  where
1044   interesting_cont = case cont of
1045                         Select {} -> True
1046                         _ -> False
1047
1048   push_tick_inside t expr0
1049      | not (tickishCanSplit t) = Nothing
1050      | otherwise
1051        = case expr0 of
1052            Tick t' expr
1053               -- scc t (tick t' E)
1054               --   Pull the tick to the outside
1055               -- This one is important for #5363
1056               | not (tickishScoped t')
1057                  -> Just (Tick t' (Tick t expr))
1058
1059               -- scc t (scc t' E)
1060               --   Try to push t' into E first, and if that works,
1061               --   try to push t in again
1062               | Just expr' <- push_tick_inside t' expr
1063                  -> push_tick_inside t expr'
1064
1065               | otherwise -> Nothing
1066
1067            Case scrut bndr ty alts
1068               -> Just (Case (mkTick t scrut) bndr ty alts')
1069              where t_scope = mkNoTick t -- drop the tick on the dup'd ones
1070                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1071            _other -> Nothing
1072     where
1073
1074   no_floating_past_tick =
1075     do { let (inc,outc) = splitCont cont
1076        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1077        ; let tickish' = simplTickish env tickish
1078        ; (env'', expr'') <- rebuild (zapFloats env')
1079                                     (wrapFloats env' expr')
1080                                     (TickIt tickish' outc)
1081        ; return (addFloats env env'', expr'')
1082        }
1083
1084 -- Alternative version that wraps outgoing floats with the tick.  This
1085 -- results in ticks being duplicated, as we don't make any attempt to
1086 -- eliminate the tick if we re-inline the binding (because the tick
1087 -- semantics allows unrestricted inlining of HNFs), so I'm not doing
1088 -- this any more.  FloatOut will catch any real opportunities for
1089 -- floating.
1090 --
1091 --  wrap_floats =
1092 --    do { let (inc,outc) = splitCont cont
1093 --       ; (env', expr') <- simplExprF (zapFloats env) expr inc
1094 --       ; let tickish' = simplTickish env tickish
1095 --       ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1096 --                                   mkTick (mkNoTick tickish') rhs)
1097 --              -- when wrapping a float with mkTick, we better zap the Id's
1098 --              -- strictness info and arity, because it might be wrong now.
1099 --       ; let env'' = addFloats env (mapFloats env' wrap_float)
1100 --       ; rebuild env'' expr' (TickIt tickish' outc)
1101 --       }
1102
1103
1104   simplTickish env tickish
1105     | Breakpoint n ids <- tickish
1106           = Breakpoint n (map (getDoneId . substId env) ids)
1107     | otherwise = tickish
1108
1109   -- push type application and coercion inside a tick
1110   splitCont :: SimplCont -> (SimplCont, SimplCont)
1111   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1112     where (inc,outc) = splitCont c
1113   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1114     where (inc,outc) = splitCont c
1115   splitCont other = (mkBoringStop (contInputType other), other)
1116
1117   getDoneId (DoneId id) = id
1118   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1119   getDoneId other = pprPanic "getDoneId" (ppr other)
1120
1121 -- Note [case-of-scc-of-case]
1122 -- It's pretty important to be able to transform case-of-case when
1123 -- there's an SCC in the way.  For example, the following comes up
1124 -- in nofib/real/compress/Encode.hs:
1125 --
1126 --        case scctick<code_string.r1>
1127 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1128 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1129 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1130 --             }
1131 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1132 --        tick<code_string.f1>
1133 --        (ww_s12Y,
1134 --         ww1_s12Z,
1135 --         PTTrees.PT
1136 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1137 --        }
1138 --
1139 -- We really want this case-of-case to fire, because then the 3-tuple
1140 -- will go away (indeed, the CPR optimisation is relying on this
1141 -- happening).  But the scctick is in the way - we need to push it
1142 -- inside to expose the case-of-case.  So we perform this
1143 -- transformation on the inner case:
1144 --
1145 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1146 --    ==>
1147 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1148 --
1149 -- So we've moved a constant amount of work out of the scc to expose
1150 -- the case.  We only do this when the continuation is interesting: in
1151 -- for now, it has to be another Case (maybe generalise this later).
1152 \end{code}
1153
1154
1155 %************************************************************************
1156 %*                                                                      *
1157 \subsection{The main rebuilder}
1158 %*                                                                      *
1159 %************************************************************************
1160
1161 \begin{code}
1162 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1163 -- At this point the substitution in the SimplEnv should be irrelevant
1164 -- only the in-scope set and floats should matter
1165 rebuild env expr cont
1166   = case cont of
1167       Stop {}                       -> return (env, expr)
1168       CoerceIt co cont              -> rebuild env (mkCast expr co) cont
1169                                     -- NB: mkCast implements the (Coercion co |> g) optimisation
1170       Select _ bndr alts se cont    -> rebuildCase (se `setFloats` env) expr bndr alts cont
1171       StrictArg info _ cont         -> rebuildCall env (info `addArgTo` expr) cont
1172       StrictBind b bs body se cont  -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1173                                           ; simplLam env' bs body cont }
1174       ApplyTo dup_flag arg se cont  -- See Note [Avoid redundant simplification]
1175         | isSimplified dup_flag     -> rebuild env (App expr arg) cont
1176         | otherwise                 -> do { arg' <- simplExpr (se `setInScope` env) arg
1177                                           ; rebuild env (App expr arg') cont }
1178       TickIt t cont                 -> rebuild env (mkTick t expr) cont
1179 \end{code}
1180
1181
1182 %************************************************************************
1183 %*                                                                      *
1184 \subsection{Lambdas}
1185 %*                                                                      *
1186 %************************************************************************
1187
1188 \begin{code}
1189 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1190           -> SimplM (SimplEnv, OutExpr)
1191 simplCast env body co0 cont0
1192   = do  { co1 <- simplCoercion env co0
1193         ; -- pprTrace "simplCast" (ppr co1) $
1194           simplExprF env body (addCoerce co1 cont0) }
1195   where
1196        addCoerce co cont = add_coerce co (coercionKind co) cont
1197
1198        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1199          | s1 `eqType` k1 = cont    -- is a no-op
1200
1201        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1202          | (Pair _l1 t1) <- coercionKind co2
1203                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1204                 -- ==>
1205                 --      e,                       if S1=T1
1206                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1207                 --
1208                 -- For example, in the initial form of a worker
1209                 -- we may find  (coerce T (coerce S (\x.e))) y
1210                 -- and we'd like it to simplify to e[y/x] in one round
1211                 -- of simplification
1212          , s1 `eqType` t1  = cont            -- The coerces cancel out
1213          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1214
1215        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1216                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1217                 -- This implements the PushT rule from the paper
1218          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1219          = ASSERT( isTyVar tyvar )
1220            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1221          where
1222            new_cast = mkInstCo co arg_ty'
1223            arg_ty' | isSimplified dup = arg_ty
1224                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1225
1226        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1227          | isFunTy s1s2   -- This implements the Push rule from the paper
1228          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1229                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1230                 -- ===>
1231                 --      (e (f |> (arg g :: t1~s1))
1232                 --      |> (res g :: s2->t2)
1233                 --
1234                 -- t1t2 must be a function type, t1->t2, because it's applied
1235                 -- to something but s1s2 might conceivably not be
1236                 --
1237                 -- When we build the ApplyTo we can't mix the out-types
1238                 -- with the InExpr in the argument, so we simply substitute
1239                 -- to make it all consistent.  It's a bit messy.
1240                 -- But it isn't a common case.
1241                 --
1242                 -- Example of use: Trac #995
1243          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1244          where
1245            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1246            -- t2 ~ s2 with left and right on the curried form:
1247            --    (->) t1 t2 ~ (->) s1 s2
1248            [co1, co2] = decomposeCo 2 co
1249            new_arg    = mkCast arg' (mkSymCo co1)
1250            arg'       = substExpr (text "move-cast") arg_se' arg
1251            arg_se'    = arg_se `setInScope` env
1252
1253        add_coerce co _ cont = CoerceIt co cont
1254 \end{code}
1255
1256
1257 %************************************************************************
1258 %*                                                                      *
1259 \subsection{Lambdas}
1260 %*                                                                      *
1261 %************************************************************************
1262
1263 Note [Zap unfolding when beta-reducing]
1264 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1265 Lambda-bound variables can have stable unfoldings, such as
1266    $j = \x. \b{Unf=Just x}. e
1267 See Note [Case binders and join points] below; the unfolding for lets
1268 us optimise e better.  However when we beta-reduce it we want to
1269 revert to using the actual value, otherwise we can end up in the
1270 stupid situation of
1271           let x = blah in
1272           let b{Unf=Just x} = y
1273           in ...b...
1274 Here it'd be far better to drop the unfolding and use the actual RHS.
1275
1276 \begin{code}
1277 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1278          -> SimplM (SimplEnv, OutExpr)
1279
1280 simplLam env [] body cont = simplExprF env body cont
1281
1282         -- Beta reduction
1283 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1284   = do  { tick (BetaReduction bndr)
1285         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1286   where
1287     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1288       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1289       = setIdUnfolding bndr NoUnfolding
1290       | otherwise = bndr
1291
1292       -- discard a non-counting tick on a lambda.  This may change the
1293       -- cost attribution slightly (moving the allocation of the
1294       -- lambda elsewhere), but we don't care: optimisation changes
1295       -- cost attribution all the time.
1296 simplLam env bndrs body (TickIt tickish cont)
1297   | not (tickishCounts tickish)
1298   = simplLam env bndrs body cont
1299
1300         -- Not enough args, so there are real lambdas left to put in the result
1301 simplLam env bndrs body cont
1302   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1303         ; body' <- simplExpr env' body
1304         ; new_lam <- mkLam env' bndrs' body'
1305         ; rebuild env' new_lam cont }
1306
1307 ------------------
1308 simplNonRecE :: SimplEnv
1309              -> InBndr                  -- The binder
1310              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1311              -> ([InBndr], InExpr)      -- Body of the let/lambda
1312                                         --      \xs.e
1313              -> SimplCont
1314              -> SimplM (SimplEnv, OutExpr)
1315
1316 -- simplNonRecE is used for
1317 --  * non-top-level non-recursive lets in expressions
1318 --  * beta reduction
1319 --
1320 -- It deals with strict bindings, via the StrictBind continuation,
1321 -- which may abort the whole process
1322 --
1323 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1324 -- representing a lambda; so we recurse back to simplLam
1325 -- Why?  Because of the binder-occ-info-zapping done before
1326 --       the call to simplLam in simplExprF (Lam ...)
1327
1328         -- First deal with type applications and type lets
1329         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1330 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1331   = ASSERT( isTyVar bndr )
1332     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1333         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1334
1335 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1336   = do dflags <- getDynFlags
1337        case () of
1338          _
1339           | preInlineUnconditionally dflags env NotTopLevel bndr rhs ->
1340             do  { tick (PreInlineUnconditionally bndr)
1341                 ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1342                   simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1343
1344           | isStrictId bndr ->           -- Includes coercions
1345             do  { simplExprF (rhs_se `setFloats` env) rhs
1346                              (StrictBind bndr bndrs body env cont) }
1347
1348           | otherwise ->
1349             ASSERT( not (isTyVar bndr) )
1350             do  { (env1, bndr1) <- simplNonRecBndr env bndr
1351                 ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1352                 ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1353                 ; simplLam env3 bndrs body cont }
1354 \end{code}
1355
1356 %************************************************************************
1357 %*                                                                      *
1358                      Variables
1359 %*                                                                      *
1360 %************************************************************************
1361
1362 \begin{code}
1363 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1364 -- Look up an InVar in the environment
1365 simplVar env var
1366   | isTyVar var = return (Type (substTyVar env var))
1367   | isCoVar var = return (Coercion (substCoVar env var))
1368   | otherwise
1369   = case substId env var of
1370         DoneId var1          -> return (Var var1)
1371         DoneEx e             -> return e
1372         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1373
1374 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1375 simplIdF env var cont
1376   = case substId env var of
1377         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1378         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1379         DoneId var1          -> completeCall env var1 cont
1380                 -- Note [zapSubstEnv]
1381                 -- The template is already simplified, so don't re-substitute.
1382                 -- This is VITAL.  Consider
1383                 --      let x = e in
1384                 --      let y = \z -> ...x... in
1385                 --      \ x -> ...y...
1386                 -- We'll clone the inner \x, adding x->x' in the id_subst
1387                 -- Then when we inline y, we must *not* replace x by x' in
1388                 -- the inlined copy!!
1389
1390 ---------------------------------------------------------
1391 --      Dealing with a call site
1392
1393 completeCall :: SimplEnv -> OutId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1394 completeCall env var cont
1395   = do  {   ------------- Try inlining ----------------
1396           dflags <- getDynFlags
1397         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1398                 -- The args are OutExprs, obtained by *lazily* substituting
1399                 -- in the args found in cont.  These args are only examined
1400                 -- to limited depth (unless a rule fires).  But we must do
1401                 -- the substitution; rule matching on un-simplified args would
1402                 -- be bogus
1403
1404                n_val_args = length arg_infos
1405                interesting_cont = interestingCallContext call_cont
1406                unfolding    = activeUnfolding env var
1407                maybe_inline = callSiteInline dflags var unfolding
1408                                              lone_variable arg_infos interesting_cont
1409         ; case maybe_inline of {
1410             Just expr      -- There is an inlining!
1411               ->  do { checkedTick (UnfoldingDone var)
1412                      ; dump_inline dflags expr cont
1413                      ; simplExprF (zapSubstEnv env) expr cont }
1414
1415             ; Nothing -> do               -- No inlining!
1416
1417         { rule_base <- getSimplRules
1418         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1419         ; rebuildCall env info cont
1420     }}}
1421   where
1422     dump_inline dflags unfolding cont
1423       | not (dopt Opt_D_dump_inlinings dflags) = return ()
1424       | not (dopt Opt_D_verbose_core2core dflags)
1425       = when (isExternalName (idName var)) $
1426             liftIO $ printInfoForUser dflags alwaysQualify $
1427                 sep [text "Inlining done:", nest 4 (ppr var)]
1428       | otherwise
1429       = liftIO $ printInfoForUser dflags alwaysQualify $
1430            sep [text "Inlining done: " <> ppr var,
1431                 nest 4 (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1432                               text "Cont:  " <+> ppr cont])]
1433
1434 rebuildCall :: SimplEnv
1435             -> ArgInfo
1436             -> SimplCont
1437             -> SimplM (SimplEnv, OutExpr)
1438 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1439   -- When we run out of strictness args, it means
1440   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1441   -- Then we want to discard the entire strict continuation.  E.g.
1442   --    * case (error "hello") of { ... }
1443   --    * (error "Hello") arg
1444   --    * f (error "Hello") where f is strict
1445   --    etc
1446   -- Then, especially in the first of these cases, we'd like to discard
1447   -- the continuation, leaving just the bottoming expression.  But the
1448   -- type might not be right, so we may have to add a coerce.
1449   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1450   = return (env, castBottomExpr res cont_ty)  -- contination to discard, else we do it
1451   where                                       -- again and again!
1452     res     = mkApps (Var fun) (reverse rev_args)
1453     cont_ty = contResultType cont
1454
1455 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1456   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1457                     else simplType (se `setInScope` env) arg_ty
1458        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1459
1460 rebuildCall env info@(ArgInfo { ai_encl = encl_rules, ai_type = fun_ty
1461                               , ai_strs = str:strs, ai_discs = disc:discs })
1462             (ApplyTo dup_flag arg arg_se cont)
1463   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1464   = rebuildCall env (addArgTo info' arg) cont
1465
1466   | str                 -- Strict argument
1467   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1468     simplExprF (arg_se `setFloats` env) arg
1469                (StrictArg info' cci cont)
1470                 -- Note [Shadowing]
1471
1472   | otherwise                           -- Lazy argument
1473         -- DO NOT float anything outside, hence simplExprC
1474         -- There is no benefit (unlike in a let-binding), and we'd
1475         -- have to be very careful about bogus strictness through
1476         -- floating a demanded let.
1477   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1478                              (mkLazyArgStop (funArgTy fun_ty) cci)
1479         ; rebuildCall env (addArgTo info' arg') cont }
1480   where
1481     info' = info { ai_strs = strs, ai_discs = discs }
1482     cci | encl_rules || disc > 0 = ArgCtxt encl_rules  -- Be keener here
1483         | otherwise              = BoringCtxt          -- Nothing interesting
1484
1485 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1486   = do {  -- We've accumulated a simplified call in <fun,rev_args>
1487           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1488           -- See also Note [Rules for recursive functions]
1489         ; let args = reverse rev_args
1490               env' = zapSubstEnv env
1491         ; mb_rule <- tryRules env rules fun args cont
1492         ; case mb_rule of {
1493              Just (n_args, rule_rhs) -> simplExprF env' rule_rhs $
1494                                         pushSimplifiedArgs env' (drop n_args args) cont ;
1495                  -- n_args says how many args the rule consumed
1496            ; Nothing -> rebuild env (mkApps (Var fun) args) cont      -- No rules
1497     } }
1498 \end{code}
1499
1500 Note [RULES apply to simplified arguments]
1501 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1502 It's very desirable to try RULES once the arguments have been simplified, because
1503 doing so ensures that rule cascades work in one pass.  Consider
1504    {-# RULES g (h x) = k x
1505              f (k x) = x #-}
1506    ...f (g (h x))...
1507 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1508 we match f's rules against the un-simplified RHS, it won't match.  This
1509 makes a particularly big difference when superclass selectors are involved:
1510         op ($p1 ($p2 (df d)))
1511 We want all this to unravel in one sweeep.
1512
1513 Note [Avoid redundant simplification]
1514 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1515 Because RULES apply to simplified arguments, there's a danger of repeatedly
1516 simplifying already-simplified arguments.  An important example is that of
1517         (>>=) d e1 e2
1518 Here e1, e2 are simplified before the rule is applied, but don't really
1519 participate in the rule firing. So we mark them as Simplified to avoid
1520 re-simplifying them.
1521
1522 Note [Shadowing]
1523 ~~~~~~~~~~~~~~~~
1524 This part of the simplifier may break the no-shadowing invariant
1525 Consider
1526         f (...(\a -> e)...) (case y of (a,b) -> e')
1527 where f is strict in its second arg
1528 If we simplify the innermost one first we get (...(\a -> e)...)
1529 Simplifying the second arg makes us float the case out, so we end up with
1530         case y of (a,b) -> f (...(\a -> e)...) e'
1531 So the output does not have the no-shadowing invariant.  However, there is
1532 no danger of getting name-capture, because when the first arg was simplified
1533 we used an in-scope set that at least mentioned all the variables free in its
1534 static environment, and that is enough.
1535
1536 We can't just do innermost first, or we'd end up with a dual problem:
1537         case x of (a,b) -> f e (...(\a -> e')...)
1538
1539 I spent hours trying to recover the no-shadowing invariant, but I just could
1540 not think of an elegant way to do it.  The simplifier is already knee-deep in
1541 continuations.  We have to keep the right in-scope set around; AND we have
1542 to get the effect that finding (error "foo") in a strict arg position will
1543 discard the entire application and replace it with (error "foo").  Getting
1544 all this at once is TOO HARD!
1545
1546
1547 %************************************************************************
1548 %*                                                                      *
1549                 Rewrite rules
1550 %*                                                                      *
1551 %************************************************************************
1552
1553 \begin{code}
1554 tryRules :: SimplEnv -> [CoreRule]
1555          -> Id -> [OutExpr] -> SimplCont
1556          -> SimplM (Maybe (Arity, CoreExpr)) -- The arity is the number of
1557                                              -- args consumed by the rule
1558 tryRules env rules fn args call_cont
1559   | null rules
1560   = return Nothing
1561   | otherwise
1562   = do { dflags <- getDynFlags
1563        ; case lookupRule dflags (activeRule env) (getUnfoldingInRuleMatch env)
1564                          (getInScope env) fn args rules of {
1565            Nothing               -> return Nothing ;   -- No rule matches
1566            Just (rule, rule_rhs) ->
1567
1568              do { checkedTick (RuleFired (ru_name rule))
1569                 ; dflags <- getDynFlags
1570                 ; dump dflags rule rule_rhs
1571                 ; return (Just (ruleArity rule, rule_rhs)) }}}
1572   where
1573     dump dflags rule rule_rhs
1574       | dopt Opt_D_dump_rule_rewrites dflags
1575       = log_rule dflags Opt_D_dump_rule_rewrites "Rule fired" $ vcat
1576           [ text "Rule:" <+> ftext (ru_name rule)
1577           , text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args))
1578           , text "After: " <+> pprCoreExpr rule_rhs
1579           , text "Cont:  " <+> ppr call_cont ]
1580
1581       | dopt Opt_D_dump_rule_firings dflags
1582       = log_rule dflags Opt_D_dump_rule_firings "Rule fired:" $
1583           ftext (ru_name rule)
1584
1585       | otherwise
1586       = return ()
1587
1588     log_rule dflags flag hdr details = liftIO . dumpSDoc dflags flag "" $
1589       sep [text hdr, nest 4 details]
1590
1591 \end{code}
1592
1593 Note [Rules for recursive functions]
1594 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1595 You might think that we shouldn't apply rules for a loop breaker:
1596 doing so might give rise to an infinite loop, because a RULE is
1597 rather like an extra equation for the function:
1598      RULE:           f (g x) y = x+y
1599      Eqn:            f a     y = a-y
1600
1601 But it's too drastic to disable rules for loop breakers.
1602 Even the foldr/build rule would be disabled, because foldr
1603 is recursive, and hence a loop breaker:
1604      foldr k z (build g) = g k z
1605 So it's up to the programmer: rules can cause divergence
1606
1607
1608 %************************************************************************
1609 %*                                                                      *
1610                 Rebuilding a case expression
1611 %*                                                                      *
1612 %************************************************************************
1613
1614 Note [Case elimination]
1615 ~~~~~~~~~~~~~~~~~~~~~~~
1616 The case-elimination transformation discards redundant case expressions.
1617 Start with a simple situation:
1618
1619         case x# of      ===>   let y# = x# in e
1620           y# -> e
1621
1622 (when x#, y# are of primitive type, of course).  We can't (in general)
1623 do this for algebraic cases, because we might turn bottom into
1624 non-bottom!
1625
1626 The code in SimplUtils.prepareAlts has the effect of generalise this
1627 idea to look for a case where we're scrutinising a variable, and we
1628 know that only the default case can match.  For example:
1629
1630         case x of
1631           0#      -> ...
1632           DEFAULT -> ...(case x of
1633                          0#      -> ...
1634                          DEFAULT -> ...) ...
1635
1636 Here the inner case is first trimmed to have only one alternative, the
1637 DEFAULT, after which it's an instance of the previous case.  This
1638 really only shows up in eliminating error-checking code.
1639
1640 Note that SimplUtils.mkCase combines identical RHSs.  So
1641
1642         case e of       ===> case e of DEFAULT -> r
1643            True  -> r
1644            False -> r
1645
1646 Now again the case may be elminated by the CaseElim transformation.
1647 This includes things like (==# a# b#)::Bool so that we simplify
1648       case ==# a# b# of { True -> x; False -> x }
1649 to just
1650       x
1651 This particular example shows up in default methods for
1652 comparision operations (e.g. in (>=) for Int.Int32)
1653
1654 Note [Case elimination: lifted case]
1655 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1656 We also make sure that we deal with this very common case,
1657 where x has a lifted type:
1658
1659         case e of
1660           x -> ...x...
1661
1662 Here we are using the case as a strict let; if x is used only once
1663 then we want to inline it.  We have to be careful that this doesn't
1664 make the program terminate when it would have diverged before, so we
1665 check that
1666         (a) 'e' is already evaluated (it may so if e is a variable)
1667             Specifically we check (exprIsHNF e)
1668 or
1669         (b) the scrutinee is a variable and 'x' is used strictly
1670 or
1671         (c) 'x' is not used at all and e is ok-for-speculation
1672
1673 For the (c), consider
1674    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1675      r -> blah
1676 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1677 not want to transform to
1678    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1679    in blah
1680 because that builds an unnecessary thunk.
1681
1682 Note [Case elimination: unlifted case]
1683 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1684 Consider
1685    case a +# b of r -> ...r...
1686 Then we do case-elimination (to make a let) followed by inlining,
1687 to get
1688         .....(a +# b)....
1689 If we have
1690    case indexArray# a i of r -> ...r...
1691 we might like to do the same, and inline the (indexArray# a i).
1692 But indexArray# is not okForSpeculation, so we don't build a let
1693 in rebuildCase (lest it get floated *out*), so the inlining doesn't
1694 happen either.
1695
1696 This really isn't a big deal I think. The let can be
1697
1698
1699 Further notes about case elimination
1700 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1701 Consider:       test :: Integer -> IO ()
1702                 test = print
1703
1704 Turns out that this compiles to:
1705     Print.test
1706       = \ eta :: Integer
1707           eta1 :: State# RealWorld ->
1708           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1709           case hPutStr stdout
1710                  (PrelNum.jtos eta ($w[] @ Char))
1711                  eta1
1712           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1713
1714 Notice the strange '<' which has no effect at all. This is a funny one.
1715 It started like this:
1716
1717 f x y = if x < 0 then jtos x
1718           else if y==0 then "" else jtos x
1719
1720 At a particular call site we have (f v 1).  So we inline to get
1721
1722         if v < 0 then jtos x
1723         else if 1==0 then "" else jtos x
1724
1725 Now simplify the 1==0 conditional:
1726
1727         if v<0 then jtos v else jtos v
1728
1729 Now common-up the two branches of the case:
1730
1731         case (v<0) of DEFAULT -> jtos v
1732
1733 Why don't we drop the case?  Because it's strict in v.  It's technically
1734 wrong to drop even unnecessary evaluations, and in practice they
1735 may be a result of 'seq' so we *definitely* don't want to drop those.
1736 I don't really know how to improve this situation.
1737
1738 \begin{code}
1739 ---------------------------------------------------------
1740 --      Eliminate the case if possible
1741
1742 rebuildCase, reallyRebuildCase
1743    :: SimplEnv
1744    -> OutExpr          -- Scrutinee
1745    -> InId             -- Case binder
1746    -> [InAlt]          -- Alternatives (inceasing order)
1747    -> SimplCont
1748    -> SimplM (SimplEnv, OutExpr)
1749
1750 --------------------------------------------------
1751 --      1. Eliminate the case if there's a known constructor
1752 --------------------------------------------------
1753
1754 rebuildCase env scrut case_bndr alts cont
1755   | Lit lit <- scrut    -- No need for same treatment as constructors
1756                         -- because literals are inlined more vigorously
1757   , not (litIsLifted lit)
1758   = do  { tick (KnownBranch case_bndr)
1759         ; case findAlt (LitAlt lit) alts of
1760             Nothing           -> missingAlt env case_bndr alts cont
1761             Just (_, bs, rhs) -> simple_rhs bs rhs }
1762
1763   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1764         -- Works when the scrutinee is a variable with a known unfolding
1765         -- as well as when it's an explicit constructor application
1766   = do  { tick (KnownBranch case_bndr)
1767         ; case findAlt (DataAlt con) alts of
1768             Nothing  -> missingAlt env case_bndr alts cont
1769             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1770             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args
1771                                                 case_bndr bs rhs cont
1772         }
1773   where
1774     simple_rhs bs rhs = ASSERT( null bs )
1775                         do { env' <- simplNonRecX env case_bndr scrut
1776                            ; simplExprF env' rhs cont }
1777
1778
1779 --------------------------------------------------
1780 --      2. Eliminate the case if scrutinee is evaluated
1781 --------------------------------------------------
1782
1783 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1784   -- See if we can get rid of the case altogether
1785   -- See Note [Case elimination]
1786   -- mkCase made sure that if all the alternatives are equal,
1787   -- then there is now only one (DEFAULT) rhs
1788  | all isDeadBinder bndrs       -- bndrs are [InId]
1789
1790  , if isUnLiftedType (idType case_bndr)
1791    then elim_unlifted        -- Satisfy the let-binding invariant
1792    else elim_lifted
1793   = do  { -- pprTrace "case elim" (vcat [ppr case_bndr, ppr (exprIsHNF scrut),
1794           --                            ppr strict_case_bndr, ppr (scrut_is_var scrut),
1795           --                            ppr ok_for_spec,
1796           --                            ppr scrut]) $
1797           tick (CaseElim case_bndr)
1798         ; env' <- simplNonRecX env case_bndr scrut
1799           -- If case_bndr is dead, simplNonRecX will discard
1800         ; simplExprF env' rhs cont }
1801   where
1802     elim_lifted   -- See Note [Case elimination: lifted case]
1803       = exprIsHNF scrut
1804      || (strict_case_bndr && scrut_is_var scrut)
1805               -- The case binder is going to be evaluated later,
1806               -- and the scrutinee is a simple variable
1807
1808      || (is_plain_seq && ok_for_spec)
1809               -- Note: not the same as exprIsHNF
1810
1811     elim_unlifted
1812       | is_plain_seq = exprOkForSideEffects scrut
1813             -- The entire case is dead, so we can drop it,
1814             -- _unless_ the scrutinee has side effects
1815       | otherwise    = exprOkForSpeculation scrut
1816             -- The case-binder is alive, but we may be able
1817             -- turn the case into a let, if the expression is ok-for-spec
1818             -- See Note [Case elimination: unlifted case]
1819
1820     ok_for_spec      = exprOkForSpeculation scrut
1821     is_plain_seq     = isDeadBinder case_bndr -- Evaluation *only* for effect
1822     strict_case_bndr = isStrictDmd (idDemandInfo case_bndr)
1823
1824     scrut_is_var (Cast s _) = scrut_is_var s
1825     scrut_is_var (Var _)    = True
1826     scrut_is_var _          = False
1827
1828
1829 --------------------------------------------------
1830 --      3. Try seq rules; see Note [User-defined RULES for seq] in MkId
1831 --------------------------------------------------
1832
1833 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1834   | all isDeadBinder (case_bndr : bndrs)  -- So this is just 'seq'
1835   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1836              out_args = [Type (substTy env (idType case_bndr)),
1837                          Type (exprType rhs'), scrut, rhs']
1838                       -- Lazily evaluated, so we don't do most of this
1839
1840        ; rule_base <- getSimplRules
1841        ; mb_rule <- tryRules env (getRules rule_base seqId) seqId out_args cont
1842        ; case mb_rule of
1843            Just (n_args, res) -> simplExprF (zapSubstEnv env)
1844                                             (mkApps res (drop n_args out_args))
1845                                             cont
1846            Nothing -> reallyRebuildCase env scrut case_bndr alts cont }
1847
1848 rebuildCase env scrut case_bndr alts cont
1849   = reallyRebuildCase env scrut case_bndr alts cont
1850
1851 --------------------------------------------------
1852 --      3. Catch-all case
1853 --------------------------------------------------
1854
1855 reallyRebuildCase env scrut case_bndr alts cont
1856   = do  {       -- Prepare the continuation;
1857                 -- The new subst_env is in place
1858           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1859
1860         -- Simplify the alternatives
1861         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1862
1863         ; dflags <- getDynFlags
1864         ; let alts_ty' = contResultType dup_cont
1865         ; case_expr <- mkCase dflags scrut' case_bndr' alts_ty' alts'
1866
1867         -- Notice that rebuild gets the in-scope set from env', not alt_env
1868         -- (which in any case is only build in simplAlts)
1869         -- The case binder *not* scope over the whole returned case-expression
1870         ; rebuild env' case_expr nodup_cont }
1871 \end{code}
1872
1873 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1874 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1875 way, there's a chance that v will now only be used once, and hence
1876 inlined.
1877
1878 Historical note: we use to do the "case binder swap" in the Simplifier
1879 so there were additional complications if the scrutinee was a variable.
1880 Now the binder-swap stuff is done in the occurrence analyer; see
1881 OccurAnal Note [Binder swap].
1882
1883 Note [zapOccInfo]
1884 ~~~~~~~~~~~~~~~~~
1885 If the case binder is not dead, then neither are the pattern bound
1886 variables:
1887         case <any> of x { (a,b) ->
1888         case x of { (p,q) -> p } }
1889 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1890 The point is that we bring into the envt a binding
1891         let x = (a,b)
1892 after the outer case, and that makes (a,b) alive.  At least we do unless
1893 the case binder is guaranteed dead.
1894
1895 In practice, the scrutinee is almost always a variable, so we pretty
1896 much always zap the OccInfo of the binders.  It doesn't matter much though.
1897
1898 Note [Improving seq]
1899 ~~~~~~~~~~~~~~~~~~~
1900 Consider
1901         type family F :: * -> *
1902         type instance F Int = Int
1903
1904         ... case e of x { DEFAULT -> rhs } ...
1905
1906 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1907
1908         case e `cast` co of x'::Int
1909            I# x# -> let x = x' `cast` sym co
1910                     in rhs
1911
1912 so that 'rhs' can take advantage of the form of x'.
1913
1914 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result.
1915
1916 Nota Bene: We only do the [Improving seq] transformation if the
1917 case binder 'x' is actually used in the rhs; that is, if the case
1918 is *not* a *pure* seq.
1919   a) There is no point in adding the cast to a pure seq.
1920   b) There is a good reason not to: doing so would interfere
1921      with seq rules (Note [Built-in RULES for seq] in MkId).
1922      In particular, this [Improving seq] thing *adds* a cast
1923      while [Built-in RULES for seq] *removes* one, so they
1924      just flip-flop.
1925
1926 You might worry about
1927    case v of x { __DEFAULT ->
1928       ... case (v `cast` co) of y { I# -> ... }}
1929 This is a pure seq (since x is unused), so [Improving seq] won't happen.
1930 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
1931    case v of x { __DEFAULT ->
1932       ... case (x `cast` co) of y { I# -> ... }}
1933 Now the outer case is not a pure seq, so [Improving seq] will happen,
1934 and then the inner case will disappear.
1935
1936 The need for [Improving seq] showed up in Roman's experiments.  Example:
1937   foo :: F Int -> Int -> Int
1938   foo t n = t `seq` bar n
1939      where
1940        bar 0 = 0
1941        bar n = bar (n - case t of TI i -> i)
1942 Here we'd like to avoid repeated evaluating t inside the loop, by
1943 taking advantage of the `seq`.
1944
1945 At one point I did transformation in LiberateCase, but it's more
1946 robust here.  (Otherwise, there's a danger that we'll simply drop the
1947 'seq' altogether, before LiberateCase gets to see it.)
1948
1949 \begin{code}
1950 simplAlts :: SimplEnv
1951           -> OutExpr
1952           -> InId                       -- Case binder
1953           -> [InAlt]                    -- Non-empty
1954           -> SimplCont
1955           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
1956 -- Like simplExpr, this just returns the simplified alternatives;
1957 -- it does not return an environment
1958 -- The returned alternatives can be empty, none are possible
1959
1960 simplAlts env scrut case_bndr alts cont'
1961   = do  { let env0 = zapFloats env
1962
1963         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
1964
1965         ; fam_envs <- getFamEnvs
1966         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut
1967                                                        case_bndr case_bndr1 alts
1968
1969         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
1970           -- NB: it's possible that the returned in_alts is empty: this is handled
1971           -- by the caller (rebuildCase) in the missingAlt function
1972
1973         ; let mb_var_scrut = case scrut' of { Var v -> Just v; _ -> Nothing }
1974         ; alts' <- mapM (simplAlt alt_env' mb_var_scrut
1975                              imposs_deflt_cons case_bndr' cont') in_alts
1976         ; -- pprTrace "simplAlts" (ppr case_bndr $$ ppr alts_ty $$ ppr alts_ty' $$ ppr alts $$ ppr cont') $
1977           return (scrut', case_bndr', alts') }
1978
1979
1980 ------------------------------------
1981 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
1982            -> OutExpr -> InId -> OutId -> [InAlt]
1983            -> SimplM (SimplEnv, OutExpr, OutId)
1984 -- Note [Improving seq]
1985 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
1986   | not (isDeadBinder case_bndr) -- Not a pure seq!  See Note [Improving seq]
1987   , Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
1988   = do { case_bndr2 <- newId (fsLit "nt") ty2
1989         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
1990               env2 = extendIdSubst env case_bndr rhs
1991         ; return (env2, scrut `Cast` co, case_bndr2) }
1992
1993 improveSeq _ env scrut _ case_bndr1 _
1994   = return (env, scrut, case_bndr1)
1995
1996
1997 ------------------------------------
1998 simplAlt :: SimplEnv
1999          -> Maybe OutId    -- Scrutinee
2000          -> [AltCon]       -- These constructors can't be present when
2001                            -- matching the DEFAULT alternative
2002          -> OutId          -- The case binder
2003          -> SimplCont
2004          -> InAlt
2005          -> SimplM OutAlt
2006
2007 simplAlt env scrut imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
2008   = ASSERT( null bndrs )
2009     do  { let env' = addBinderUnfolding env scrut case_bndr'
2010                                         (mkOtherCon imposs_deflt_cons)
2011                 -- Record the constructors that the case-binder *can't* be.
2012         ; rhs' <- simplExprC env' rhs cont'
2013         ; return (DEFAULT, [], rhs') }
2014
2015 simplAlt env scrut _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
2016   = ASSERT( null bndrs )
2017     do  { dflags <- getDynFlags
2018         ; let env' = addBinderUnfolding env scrut case_bndr'
2019                                         (mkSimpleUnfolding dflags (Lit lit))
2020         ; rhs' <- simplExprC env' rhs cont'
2021         ; return (LitAlt lit, [], rhs') }
2022
2023 simplAlt env scrut _ case_bndr' cont' (DataAlt con, vs, rhs)
2024   = do  { dflags <- getDynFlags
2025
2026                 -- Deal with the pattern-bound variables
2027                 -- Mark the ones that are in ! positions in the
2028                 -- data constructor as certainly-evaluated.
2029                 -- NB: simplLamBinders preserves this eval info
2030         ; let vs_with_evals = add_evals (dataConRepStrictness con)
2031         ; (env', vs') <- simplLamBndrs env vs_with_evals
2032
2033                 -- Bind the case-binder to (con args)
2034         ; let inst_tys' = tyConAppArgs (idType case_bndr')
2035               con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
2036               unf       = mkSimpleUnfolding dflags (mkConApp con con_args)
2037               env''     = addBinderUnfolding env' scrut case_bndr' unf
2038
2039         ; rhs' <- simplExprC env'' rhs cont'
2040         ; return (DataAlt con, vs', rhs') }
2041   where
2042         -- add_evals records the evaluated-ness of the bound variables of
2043         -- a case pattern.  This is *important*.  Consider
2044         --      data T = T !Int !Int
2045         --
2046         --      case x of { T a b -> T (a+1) b }
2047         --
2048         -- We really must record that b is already evaluated so that we don't
2049         -- go and re-evaluate it when constructing the result.
2050         -- See Note [Data-con worker strictness] in MkId.lhs
2051     add_evals the_strs
2052         = go vs the_strs
2053         where
2054           go [] [] = []
2055           go (v:vs') strs | isTyVar v = v : go vs' strs
2056           go (v:vs') (str:strs)
2057             | isMarkedStrict str = evald_v  : go vs' strs
2058             | otherwise          = zapped_v : go vs' strs
2059             where
2060               zapped_v = zapBndrOccInfo keep_occ_info v
2061               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2062           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2063
2064         -- See Note [zapOccInfo]
2065         -- zap_occ_info: if the case binder is alive, then we add the unfolding
2066         --      case_bndr = C vs
2067         -- to the envt; so vs are now very much alive
2068         -- Note [Aug06] I can't see why this actually matters, but it's neater
2069         --        case e of t { (a,b) -> ...(case t of (p,q) -> p)... }
2070         --   ==>  case e of t { (a,b) -> ...(a)... }
2071         -- Look, Ma, a is alive now.
2072     keep_occ_info = isDeadBinder case_bndr' && isNothing scrut
2073
2074 addBinderUnfolding :: SimplEnv -> Maybe OutId -> Id -> Unfolding -> SimplEnv
2075 addBinderUnfolding env scrut bndr unf
2076   = case scrut of
2077        Just v -> modifyInScope env1 (v `setIdUnfolding` unf)
2078        _      -> env1
2079   where
2080     env1 = modifyInScope env bndr_w_unf
2081     bndr_w_unf = bndr `setIdUnfolding` unf
2082
2083 zapBndrOccInfo :: Bool -> Id -> Id
2084 -- Consider  case e of b { (a,b) -> ... }
2085 -- Then if we bind b to (a,b) in "...", and b is not dead,
2086 -- then we must zap the deadness info on a,b
2087 zapBndrOccInfo keep_occ_info pat_id
2088   | keep_occ_info = pat_id
2089   | otherwise     = zapIdOccInfo pat_id
2090 \end{code}
2091
2092 Note [Add unfolding for scrutinee]
2093 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2094 In general it's unlikely that a variable scrutinee will appear
2095 in the case alternatives   case x of { ...x unlikely to appear... }
2096 because the binder-swap in OccAnal has got rid of all such occcurrences
2097 See Note [Binder swap] in OccAnal.
2098
2099 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2100 variable scrutinee, in simplAlt.  Here's why
2101    case x of y
2102      (a,b) -> case b of c
2103                 I# v -> ...(f y)...
2104 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2105 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2106     RULE f (p, I# q) = ...
2107 we want that rule to match, so we must extend the in-scope env with a
2108 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2109 it's also good for case-elimintation -- suppose that 'f' was inlined
2110 and did multi-level case analysis, then we'd solve it in one
2111 simplifier sweep instead of two.
2112
2113 Exactly the same issue arises in SpecConstr;
2114 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2115
2116 %************************************************************************
2117 %*                                                                      *
2118 \subsection{Known constructor}
2119 %*                                                                      *
2120 %************************************************************************
2121
2122 We are a bit careful with occurrence info.  Here's an example
2123
2124         (\x* -> case x of (a*, b) -> f a) (h v, e)
2125
2126 where the * means "occurs once".  This effectively becomes
2127         case (h v, e) of (a*, b) -> f a)
2128 and then
2129         let a* = h v; b = e in f a
2130 and then
2131         f (h v)
2132
2133 All this should happen in one sweep.
2134
2135 \begin{code}
2136 knownCon :: SimplEnv
2137          -> OutExpr                             -- The scrutinee
2138          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2139          -> InId -> [InBndr] -> InExpr          -- The alternative
2140          -> SimplCont
2141          -> SimplM (SimplEnv, OutExpr)
2142
2143 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2144   = do  { env'  <- bind_args env bs dc_args
2145         ; env'' <- bind_case_bndr env'
2146         ; simplExprF env'' rhs cont }
2147   where
2148     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2149
2150                   -- Ugh!
2151     bind_args env' [] _  = return env'
2152
2153     bind_args env' (b:bs') (Type ty : args)
2154       = ASSERT( isTyVar b )
2155         bind_args (extendTvSubst env' b ty) bs' args
2156
2157     bind_args env' (b:bs') (arg : args)
2158       = ASSERT( isId b )
2159         do { let b' = zap_occ b
2160              -- Note that the binder might be "dead", because it doesn't
2161              -- occur in the RHS; and simplNonRecX may therefore discard
2162              -- it via postInlineUnconditionally.
2163              -- Nevertheless we must keep it if the case-binder is alive,
2164              -- because it may be used in the con_app.  See Note [zapOccInfo]
2165            ; env'' <- simplNonRecX env' b' arg
2166            ; bind_args env'' bs' args }
2167
2168     bind_args _ _ _ =
2169       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2170                              text "scrut:" <+> ppr scrut
2171
2172        -- It's useful to bind bndr to scrut, rather than to a fresh
2173        -- binding      x = Con arg1 .. argn
2174        -- because very often the scrut is a variable, so we avoid
2175        -- creating, and then subsequently eliminating, a let-binding
2176        -- BUT, if scrut is a not a variable, we must be careful
2177        -- about duplicating the arg redexes; in that case, make
2178        -- a new con-app from the args
2179     bind_case_bndr env
2180       | isDeadBinder bndr   = return env
2181       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2182       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2183                                          -- dc_ty_args are aready OutTypes,
2184                                          -- but bs are InBndrs
2185                                  ; let con_app = Var (dataConWorkId dc)
2186                                                  `mkTyApps` dc_ty_args
2187                                                  `mkApps`   dc_args
2188                                  ; simplNonRecX env bndr con_app }
2189
2190 -------------------
2191 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2192                 -- This isn't strictly an error, although it is unusual.
2193                 -- It's possible that the simplifer might "see" that
2194                 -- an inner case has no accessible alternatives before
2195                 -- it "sees" that the entire branch of an outer case is
2196                 -- inaccessible.  So we simply put an error case here instead.
2197 missingAlt env case_bndr _ cont
2198   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2199     return (env, mkImpossibleExpr (contResultType cont))
2200 \end{code}
2201
2202
2203 %************************************************************************
2204 %*                                                                      *
2205 \subsection{Duplicating continuations}
2206 %*                                                                      *
2207 %************************************************************************
2208
2209 \begin{code}
2210 prepareCaseCont :: SimplEnv
2211                 -> [InAlt] -> SimplCont
2212                 -> SimplM (SimplEnv, SimplCont, SimplCont)
2213 -- We are considering
2214 --     K[case _ of { p1 -> r1; ...; pn -> rn }]
2215 -- where K is some enclosing continuation for the case
2216 -- Goal: split K into two pieces Kdup,Knodup so that
2217 --       a) Kdup can be duplicated
2218 --       b) Knodup[Kdup[e]] = K[e]
2219 -- The idea is that we'll transform thus:
2220 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2221 --
2222 -- We also return some extra bindings in SimplEnv (that scope over
2223 -- the entire continuation)
2224
2225 prepareCaseCont env alts cont
2226   | many_alts alts = mkDupableCont env cont
2227   | otherwise      = return (env, cont, mkBoringStop (contResultType cont))
2228   where
2229     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2230     many_alts []  = False         -- See Note [Bottom alternatives]
2231     many_alts [_] = False
2232     many_alts (alt:alts)
2233       | is_bot_alt alt = many_alts alts
2234       | otherwise      = not (all is_bot_alt alts)
2235
2236     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2237 \end{code}
2238
2239 Note [Bottom alternatives]
2240 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2241 When we have
2242      case (case x of { A -> error .. ; B -> e; C -> error ..)
2243        of alts
2244 then we can just duplicate those alts because the A and C cases
2245 will disappear immediately.  This is more direct than creating
2246 join points and inlining them away; and in some cases we would
2247 not even create the join points (see Note [Single-alternative case])
2248 and we would keep the case-of-case which is silly.  See Trac #4930.
2249
2250 \begin{code}
2251 mkDupableCont :: SimplEnv -> SimplCont
2252               -> SimplM (SimplEnv, SimplCont, SimplCont)
2253
2254 mkDupableCont env cont
2255   | contIsDupable cont
2256   = return (env, cont, mkBoringStop (contResultType cont))
2257
2258 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2259
2260 mkDupableCont env (CoerceIt ty cont)
2261   = do  { (env', dup, nodup) <- mkDupableCont env cont
2262         ; return (env', CoerceIt ty dup, nodup) }
2263
2264 -- Duplicating ticks for now, not sure if this is good or not
2265 mkDupableCont env cont@(TickIt{})
2266   = return (env, mkBoringStop (contInputType cont), cont)
2267
2268 mkDupableCont env cont@(StrictBind {})
2269   =  return (env, mkBoringStop (contInputType cont), cont)
2270         -- See Note [Duplicating StrictBind]
2271
2272 mkDupableCont env (StrictArg info cci cont)
2273         -- See Note [Duplicating StrictArg]
2274   = do { (env', dup, nodup) <- mkDupableCont env cont
2275        ; (env'', args')     <- mapAccumLM (makeTrivial NotTopLevel) env' (ai_args info)
2276        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2277
2278 mkDupableCont env (ApplyTo _ arg se cont)
2279   =     -- e.g.         [...hole...] (...arg...)
2280         --      ==>
2281         --              let a = ...arg...
2282         --              in [...hole...] a
2283     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2284         ; arg' <- simplExpr (se `setInScope` env') arg
2285         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2286         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2287         ; return (env'', app_cont, nodup_cont) }
2288
2289 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2290 --  See Note [Single-alternative case]
2291 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2292 --  | not (isDeadBinder case_bndr)
2293   | all isDeadBinder bs  -- InIds
2294     && not (isUnLiftedType (idType case_bndr))
2295     -- Note [Single-alternative-unlifted]
2296   = return (env, mkBoringStop (contInputType cont), cont)
2297
2298 mkDupableCont env (Select _ case_bndr alts se cont)
2299   =     -- e.g.         (case [...hole...] of { pi -> ei })
2300         --      ===>
2301         --              let ji = \xij -> ei
2302         --              in case [...hole...] of { pi -> ji xij }
2303     do  { tick (CaseOfCase case_bndr)
2304         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2305                 -- NB: We call prepareCaseCont here.  If there is only one
2306                 -- alternative, then dup_cont may be big, but that's ok
2307                 -- becuase we push it into the single alternative, and then
2308                 -- use mkDupableAlt to turn that simplified alternative into
2309                 -- a join point if it's too big to duplicate.
2310                 -- And this is important: see Note [Fusing case continuations]
2311
2312         ; let alt_env = se `setInScope` env'
2313
2314         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2315         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2316         -- Safe to say that there are no handled-cons for the DEFAULT case
2317                 -- NB: simplBinder does not zap deadness occ-info, so
2318                 -- a dead case_bndr' will still advertise its deadness
2319                 -- This is really important because in
2320                 --      case e of b { (# p,q #) -> ... }
2321                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2322                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2323                 -- In the new alts we build, we have the new case binder, so it must retain
2324                 -- its deadness.
2325         -- NB: we don't use alt_env further; it has the substEnv for
2326         --     the alternatives, and we don't want that
2327
2328         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2329         ; return (env'',  -- Note [Duplicated env]
2330                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'')
2331                          (mkBoringStop (contInputType nodup_cont)),
2332                   nodup_cont) }
2333
2334
2335 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2336               -> SimplM (SimplEnv, [InAlt])
2337 -- Absorbs the continuation into the new alternatives
2338
2339 mkDupableAlts env case_bndr' the_alts
2340   = go env the_alts
2341   where
2342     go env0 [] = return (env0, [])
2343     go env0 (alt:alts)
2344         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2345              ; (env2, alts') <- go env1 alts
2346              ; return (env2, alt' : alts' ) }
2347
2348 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2349               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2350 mkDupableAlt env case_bndr (con, bndrs', rhs') = do
2351   dflags <- getDynFlags
2352   if exprIsDupable dflags rhs'  -- Note [Small alternative rhs]
2353    then return (env, (con, bndrs', rhs'))
2354    else
2355     do  { let rhs_ty'  = exprType rhs'
2356               scrut_ty = idType case_bndr
2357               case_bndr_w_unf
2358                 = case con of
2359                       DEFAULT    -> case_bndr
2360                       DataAlt dc -> setIdUnfolding case_bndr unf
2361                           where
2362                                  -- See Note [Case binders and join points]
2363                              unf = mkInlineUnfolding Nothing rhs
2364                              rhs = mkConApp dc (map Type (tyConAppArgs scrut_ty)
2365                                                 ++ varsToCoreExprs bndrs')
2366
2367                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2368                                                 <+> ppr case_bndr <+> ppr con )
2369                                    case_bndr
2370                            -- The case binder is alive but trivial, so why has
2371                            -- it not been substituted away?
2372
2373               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2374                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2375
2376               abstract_over bndr
2377                   | isTyVar bndr = True -- Abstract over all type variables just in case
2378                   | otherwise    = not (isDeadBinder bndr)
2379                         -- The deadness info on the new Ids is preserved by simplBinders
2380
2381         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2382                 <- if (any isId used_bndrs')
2383                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2384                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
2385                             ; return ([rw_id], [Var realWorldPrimId]) }
2386
2387         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2388                 -- Note [Funky mkPiTypes]
2389
2390         ; let   -- We make the lambdas into one-shot-lambdas.  The
2391                 -- join point is sure to be applied at most once, and doing so
2392                 -- prevents the body of the join point being floated out by
2393                 -- the full laziness pass
2394                 really_final_bndrs     = map one_shot final_bndrs'
2395                 one_shot v | isId v    = setOneShotLambda v
2396                            | otherwise = v
2397                 join_rhs   = mkLams really_final_bndrs rhs'
2398                 join_arity = exprArity join_rhs
2399                 join_call  = mkApps (Var join_bndr) final_args
2400
2401         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2402         ; return (env', (con, bndrs', join_call)) }
2403                 -- See Note [Duplicated env]
2404 \end{code}
2405
2406 Note [Fusing case continuations]
2407 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2408 It's important to fuse two successive case continuations when the
2409 first has one alternative.  That's why we call prepareCaseCont here.
2410 Consider this, which arises from thunk splitting (see Note [Thunk
2411 splitting] in WorkWrap):
2412
2413       let
2414         x* = case (case v of {pn -> rn}) of
2415                I# a -> I# a
2416       in body
2417
2418 The simplifier will find
2419     (Var v) with continuation
2420             Select (pn -> rn) (
2421             Select [I# a -> I# a] (
2422             StrictBind body Stop
2423
2424 So we'll call mkDupableCont on
2425    Select [I# a -> I# a] (StrictBind body Stop)
2426 There is just one alternative in the first Select, so we want to
2427 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2428 Supposing that body is big, we end up with
2429           let $j a = <let x = I# a in body>
2430           in case v of { pn -> case rn of
2431                                  I# a -> $j a }
2432 This is just what we want because the rn produces a box that
2433 the case rn cancels with.
2434
2435 See Trac #4957 a fuller example.
2436
2437 Note [Case binders and join points]
2438 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2439 Consider this
2440    case (case .. ) of c {
2441      I# c# -> ....c....
2442
2443 If we make a join point with c but not c# we get
2444   $j = \c -> ....c....
2445
2446 But if later inlining scrutines the c, thus
2447
2448   $j = \c -> ... case c of { I# y -> ... } ...
2449
2450 we won't see that 'c' has already been scrutinised.  This actually
2451 happens in the 'tabulate' function in wave4main, and makes a significant
2452 difference to allocation.
2453
2454 An alternative plan is this:
2455
2456    $j = \c# -> let c = I# c# in ...c....
2457
2458 but that is bad if 'c' is *not* later scrutinised.
2459
2460 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2461 (an InlineRule) that it's really I# c#, thus
2462
2463    $j = \c# -> \c[=I# c#] -> ...c....
2464
2465 Absence analysis may later discard 'c'.
2466
2467 NB: take great care when doing strictness analysis;
2468     see Note [Lamba-bound unfoldings] in DmdAnal.
2469
2470 Also note that we can still end up passing stuff that isn't used.  Before
2471 strictness analysis we have
2472    let $j x y c{=(x,y)} = (h c, ...)
2473    in ...
2474 After strictness analysis we see that h is strict, we end up with
2475    let $j x y c{=(x,y)} = ($wh x y, ...)
2476 and c is unused.
2477
2478 Note [Duplicated env]
2479 ~~~~~~~~~~~~~~~~~~~~~
2480 Some of the alternatives are simplified, but have not been turned into a join point
2481 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2482 bind the join point, because it might to do PostInlineUnconditionally, and
2483 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2484 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2485 at worst delays the join-point inlining.
2486
2487 Note [Small alternative rhs]
2488 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2489 It is worth checking for a small RHS because otherwise we
2490 get extra let bindings that may cause an extra iteration of the simplifier to
2491 inline back in place.  Quite often the rhs is just a variable or constructor.
2492 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2493 iterations because the version with the let bindings looked big, and so wasn't
2494 inlined, but after the join points had been inlined it looked smaller, and so
2495 was inlined.
2496
2497 NB: we have to check the size of rhs', not rhs.
2498 Duplicating a small InAlt might invalidate occurrence information
2499 However, if it *is* dupable, we return the *un* simplified alternative,
2500 because otherwise we'd need to pair it up with an empty subst-env....
2501 but we only have one env shared between all the alts.
2502 (Remember we must zap the subst-env before re-simplifying something).
2503 Rather than do this we simply agree to re-simplify the original (small) thing later.
2504
2505 Note [Funky mkPiTypes]
2506 ~~~~~~~~~~~~~~~~~~~~~~
2507 Notice the funky mkPiTypes.  If the contructor has existentials
2508 it's possible that the join point will be abstracted over
2509 type varaibles as well as term variables.
2510  Example:  Suppose we have
2511         data T = forall t.  C [t]
2512  Then faced with
2513         case (case e of ...) of
2514             C t xs::[t] -> rhs
2515  We get the join point
2516         let j :: forall t. [t] -> ...
2517             j = /\t \xs::[t] -> rhs
2518         in
2519         case (case e of ...) of
2520             C t xs::[t] -> j t xs
2521
2522 Note [Join point abstaction]
2523 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2524 If we try to lift a primitive-typed something out
2525 for let-binding-purposes, we will *caseify* it (!),
2526 with potentially-disastrous strictness results.  So
2527 instead we turn it into a function: \v -> e
2528 where v::State# RealWorld#.  The value passed to this function
2529 is realworld#, which generates (almost) no code.
2530
2531 There's a slight infelicity here: we pass the overall
2532 case_bndr to all the join points if it's used in *any* RHS,
2533 because we don't know its usage in each RHS separately
2534
2535 We used to say "&& isUnLiftedType rhs_ty'" here, but now
2536 we make the join point into a function whenever used_bndrs'
2537 is empty.  This makes the join-point more CPR friendly.
2538 Consider:       let j = if .. then I# 3 else I# 4
2539                 in case .. of { A -> j; B -> j; C -> ... }
2540
2541 Now CPR doesn't w/w j because it's a thunk, so
2542 that means that the enclosing function can't w/w either,
2543 which is a lose.  Here's the example that happened in practice:
2544         kgmod :: Int -> Int -> Int
2545         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2546                     then 78
2547                     else 5
2548
2549 I have seen a case alternative like this:
2550         True -> \v -> ...
2551 It's a bit silly to add the realWorld dummy arg in this case, making
2552         $j = \s v -> ...
2553            True -> $j s
2554 (the \v alone is enough to make CPR happy) but I think it's rare
2555
2556 Note [Duplicating StrictArg]
2557 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2558 The original plan had (where E is a big argument)
2559 e.g.    f E [..hole..]
2560         ==>     let $j = \a -> f E a
2561                 in $j [..hole..]
2562
2563 But this is terrible! Here's an example:
2564         && E (case x of { T -> F; F -> T })
2565 Now, && is strict so we end up simplifying the case with
2566 an ArgOf continuation.  If we let-bind it, we get
2567         let $j = \v -> && E v
2568         in simplExpr (case x of { T -> F; F -> T })
2569                      (ArgOf (\r -> $j r)
2570 And after simplifying more we get
2571         let $j = \v -> && E v
2572         in case x of { T -> $j F; F -> $j T }
2573 Which is a Very Bad Thing
2574
2575 What we do now is this
2576         f E [..hole..]
2577         ==>     let a = E
2578                 in f a [..hole..]
2579 Now if the thing in the hole is a case expression (which is when
2580 we'll call mkDupableCont), we'll push the function call into the
2581 branches, which is what we want.  Now RULES for f may fire, and
2582 call-pattern specialisation.  Here's an example from Trac #3116
2583      go (n+1) (case l of
2584                  1  -> bs'
2585                  _  -> Chunk p fpc (o+1) (l-1) bs')
2586 If we can push the call for 'go' inside the case, we get
2587 call-pattern specialisation for 'go', which is *crucial* for
2588 this program.
2589
2590 Here is the (&&) example:
2591         && E (case x of { T -> F; F -> T })
2592   ==>   let a = E in
2593         case x of { T -> && a F; F -> && a T }
2594 Much better!
2595
2596 Notice that
2597   * Arguments to f *after* the strict one are handled by
2598     the ApplyTo case of mkDupableCont.  Eg
2599         f [..hole..] E
2600
2601   * We can only do the let-binding of E because the function
2602     part of a StrictArg continuation is an explicit syntax
2603     tree.  In earlier versions we represented it as a function
2604     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2605
2606 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2607 nothing by propagating them into the expressions, and we do lose a
2608 lot.
2609
2610 The desire not to duplicate is the entire reason that
2611 mkDupableCont returns a pair of continuations.
2612
2613 Note [Duplicating StrictBind]
2614 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2615 Unlike StrictArg, there doesn't seem anything to gain from
2616 duplicating a StrictBind continuation, so we don't.
2617
2618
2619 Note [Single-alternative cases]
2620 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2621 This case is just like the ArgOf case.  Here's an example:
2622         data T a = MkT !a
2623         ...(MkT (abs x))...
2624 Then we get
2625         case (case x of I# x' ->
2626               case x' <# 0# of
2627                 True  -> I# (negate# x')
2628                 False -> I# x') of y {
2629           DEFAULT -> MkT y
2630 Because the (case x) has only one alternative, we'll transform to
2631         case x of I# x' ->
2632         case (case x' <# 0# of
2633                 True  -> I# (negate# x')
2634                 False -> I# x') of y {
2635           DEFAULT -> MkT y
2636 But now we do *NOT* want to make a join point etc, giving
2637         case x of I# x' ->
2638         let $j = \y -> MkT y
2639         in case x' <# 0# of
2640                 True  -> $j (I# (negate# x'))
2641                 False -> $j (I# x')
2642 In this case the $j will inline again, but suppose there was a big
2643 strict computation enclosing the orginal call to MkT.  Then, it won't
2644 "see" the MkT any more, because it's big and won't get duplicated.
2645 And, what is worse, nothing was gained by the case-of-case transform.
2646
2647 So, in circumstances like these, we don't want to build join points
2648 and push the outer case into the branches of the inner one. Instead,
2649 don't duplicate the continuation.
2650
2651 When should we use this strategy?  We should not use it on *every*
2652 single-alternative case:
2653   e.g.  case (case ....) of (a,b) -> (# a,b #)
2654 Here we must push the outer case into the inner one!
2655 Other choices:
2656
2657    * Match [(DEFAULT,_,_)], but in the common case of Int,
2658      the alternative-filling-in code turned the outer case into
2659                 case (...) of y { I# _ -> MkT y }
2660
2661    * Match on single alternative plus (not (isDeadBinder case_bndr))
2662      Rationale: pushing the case inwards won't eliminate the construction.
2663      But there's a risk of
2664                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2665      Now y looks dead, but it'll come alive again.  Still, this
2666      seems like the best option at the moment.
2667
2668    * Match on single alternative plus (all (isDeadBinder bndrs))
2669      Rationale: this is essentially  seq.
2670
2671    * Match when the rhs is *not* duplicable, and hence would lead to a
2672      join point.  This catches the disaster-case above.  We can test
2673      the *un-simplified* rhs, which is fine.  It might get bigger or
2674      smaller after simplification; if it gets smaller, this case might
2675      fire next time round.  NB also that we must test contIsDupable
2676      case_cont *too, because case_cont might be big!
2677
2678      HOWEVER: I found that this version doesn't work well, because
2679      we can get         let x = case (...) of { small } in ...case x...
2680      When x is inlined into its full context, we find that it was a bad
2681      idea to have pushed the outer case inside the (...) case.
2682
2683 Note [Single-alternative-unlifted]
2684 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2685 Here's another single-alternative where we really want to do case-of-case:
2686
2687 data Mk1 = Mk1 Int# | Mk2 Int#
2688
2689 M1.f =
2690     \r [x_s74 y_s6X]
2691         case
2692             case y_s6X of tpl_s7m {
2693               M1.Mk1 ipv_s70 -> ipv_s70;
2694               M1.Mk2 ipv_s72 -> ipv_s72;
2695             }
2696         of
2697         wild_s7c
2698         { __DEFAULT ->
2699               case
2700                   case x_s74 of tpl_s7n {
2701                     M1.Mk1 ipv_s77 -> ipv_s77;
2702                     M1.Mk2 ipv_s79 -> ipv_s79;
2703                   }
2704               of
2705               wild1_s7b
2706               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2707               };
2708         };
2709
2710 So the outer case is doing *nothing at all*, other than serving as a
2711 join-point.  In this case we really want to do case-of-case and decide
2712 whether to use a real join point or just duplicate the continuation:
2713
2714     let $j s7c = case x of
2715                    Mk1 ipv77 -> (==) s7c ipv77
2716                    Mk1 ipv79 -> (==) s7c ipv79
2717     in
2718     case y of
2719       Mk1 ipv70 -> $j ipv70
2720       Mk2 ipv72 -> $j ipv72
2721
2722 Hence: check whether the case binder's type is unlifted, because then
2723 the outer case is *not* a seq.