1e43896727a6c3f6474b8f1164ba4e625532174b
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   dnl ToDo, once "ld command" is reliably available.
126   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
127   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
129   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
130   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 fi
132
133 dnl ** Must have GHC to build GHC
134 if test "$WithGhc" = ""
135 then
136     AC_MSG_ERROR([GHC is required.])
137 fi
138 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
139     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
140
141 if test `expr $GhcMinVersion % 2` = "1"
142 then
143     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
144     then
145         AC_MSG_ERROR([
146      $WithGhc is a development snapshot of GHC, version $GhcVersion.
147      Bootstrapping using this version of GHC is not supported, and may not
148      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
149      or --with-ghc to specify a different GHC to use.])
150     fi
151 fi
152
153 GHC_PACKAGE_DB_FLAG=package-db
154 AC_SUBST(GHC_PACKAGE_DB_FLAG)
155
156 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
157 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
158                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
160 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
161
162 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
163                     SUPPORTS_COMPONENT_ID=NO,
164                     SUPPORTS_COMPONENT_ID=YES)
165 AC_SUBST(SUPPORTS_COMPONENT_ID)
166
167 # GHC is passed to Cabal, so we need a native path
168 if test "${WithGhc}" != ""
169 then
170     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
171
172     if test "$ghc_host_os" = "mingw32"
173     then
174         if test "${OSTYPE}" = "msys"
175         then
176             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
177         else
178             # Canonicalise to <drive>:/path/to/ghc
179             WithGhc=`cygpath -m "${WithGhc}"`
180         fi
181         echo "GHC path canonicalised to: ${WithGhc}"
182     fi
183 fi
184 AC_SUBST([WithGhc])
185
186 dnl ** Without optimization some INLINE trickery fails for GHCi
187 SRC_CC_OPTS="-O"
188
189 dnl--------------------------------------------------------------------
190 dnl * Choose host(/target/build) platform
191 dnl--------------------------------------------------------------------
192 dnl If we aren't explicitly told what values to use with configure flags,
193 dnl we ask the bootstrapping compiler what platform it is for
194
195 if test "${WithGhc}" != ""
196 then
197         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
198         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         if test "$bootstrap_host" != "$bootstrap_target"
200         then
201                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
202         fi
203 fi
204
205 # We have to run these unconditionally, but we may discard their
206 # results in the following code
207 AC_CANONICAL_BUILD
208 AC_CANONICAL_HOST
209 AC_CANONICAL_TARGET
210
211 FPTOOLS_SET_PLATFORM_VARS
212
213 # Verify that the installed (bootstrap) GHC is capable of generating
214 # code for the requested build platform.
215 if test "$BuildPlatform" != "$bootstrap_target"
216 then
217     echo "This GHC (${WithGhc}) does not generate code for the build platform"
218     echo "   GHC target platform    : $bootstrap_target"
219     echo "   Desired build platform : $BuildPlatform"
220     exit 1
221 fi
222
223 # Testing if we shall enable shared libs support on Solaris.
224 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
225
226 SOLARIS_BROKEN_SHLD=NO
227
228 case $host in
229      i386-*-solaris2)
230      # here we go with the test
231      MINOR=`uname -r|cut -d '.' -f 2-`
232      if test "$MINOR" -lt "11"; then
233          SOLARIS_BROKEN_SHLD=YES
234      fi
235      ;;
236 esac
237
238 AC_SUBST(SOLARIS_BROKEN_SHLD)
239
240 dnl ** Do an unregisterised build?
241 dnl --------------------------------------------------------------
242 case "$HostArch" in
243     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
244         UnregisterisedDefault=NO
245         ;;
246     *)
247         UnregisterisedDefault=YES
248         ;;
249 esac
250 AC_ARG_ENABLE(unregisterised,
251 [AC_HELP_STRING([--enable-unregisterised],
252 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
253 [ if test x"$enableval" = x"yes"; then
254         Unregisterised=YES
255   else
256         Unregisterised=NO
257   fi
258 ],
259 [Unregisterised="$UnregisterisedDefault"]
260 )
261 AC_SUBST(Unregisterised)
262
263 AC_ARG_WITH(hc,
264 [AC_HELP_STRING([--with-hc=ARG],
265         [Use ARG as the path to the compiler for compiling ordinary
266          Haskell code  (default= value of --with-ghc)])],
267 [WithHc="$withval"],
268 [WithHc=$WithGhc]
269 )
270 AC_SUBST(WithHc)
271
272 # This uses GHC, so put it after the "GHC is required" check above:
273 FP_INTREE_GHC_PWD
274 FP_FIND_ROOT
275
276 fail() {
277     echo >&2
278     echo "$1" >&2
279     exit 1
280 }
281
282
283 if test "$HostOS" = "mingw32"
284 then
285     # Find the mingw-w64 7z file to extract.
286     # NB. If you update the tarballs to a new version of gcc, don't
287     # forget to tweak the paths in driver/gcc/gcc.c.
288     if test "$HostArch" = "i386"
289     then
290         mingw_arch="i686"
291         tarball_dest_dir="mingw-w64/x86"
292         tarball_mingw_dir="mingw32"
293     else
294         mingw_arch="x86_64"
295         tarball_dest_dir="mingw-w64/x86_64"
296         tarball_mingw_dir="mingw64"
297     fi
298 fi
299
300 set_up_tarballs() {
301     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
302     local action
303     if test "$TarballsAutodownload" = "NO"
304     then
305         action="verify"
306     else
307         action="download"
308     fi
309     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
310     case $? in
311         0)
312            rm missing-win32-tarballs
313            ;;
314         2)
315            echo
316            echo "Error:"
317            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
318            echo
319            echo "  * run configure with the --enable-tarballs-autodownload option"
320            echo
321            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
322            echo
323            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
324            echo "    them in the ghc-tarballs directory."
325            echo
326            exit 1
327            ;;
328         *)
329            echo
330            echo "Error fetching msys2 tarballs; see errors above."
331            exit 1
332            ;;
333     esac
334
335     # Extract all the tarballs in one go
336     if ! test -d inplace/mingw
337     then
338         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
339         rm -rf inplace/mingw
340         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
341         ( cd inplace &&
342         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
343         rm ".MTREE" &&
344         rm ".PKGINFO" &&
345         cd .. ) || fail "Error: Could not extract Windows toolchains."
346
347         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
348         touch inplace/mingw
349
350         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
351         # make a wrapper around it to give it the proper paths
352         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
353         PATH=`pwd`/inplace/mingw/bin:$PATH
354         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
355
356         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
357     fi
358 }
359
360 if test "$HostOS" = "mingw32"
361 then
362     test -d inplace || mkdir inplace
363
364     # NB. Download and extract the MingW-w64 distribution if required
365     set_up_tarballs
366
367     mingwbin="$hardtop/inplace/mingw/bin/"
368     CC="${mingwbin}gcc.exe"
369     LD="${mingwbin}ld.exe"
370     NM="${mingwbin}nm.exe"
371     RANLIB="${mingwbin}ranlib.exe"
372     OBJDUMP="${mingwbin}objdump.exe"
373     fp_prog_ar="${mingwbin}ar.exe"
374
375     # NB. Download the perl binaries if required
376     if ! test -d inplace/perl ||
377          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
378     then
379         AC_MSG_NOTICE([Making in-tree perl tree])
380         rm -rf inplace/perl
381         mkdir inplace/perl
382         (
383             cd inplace/perl &&
384             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
385         )
386         AC_MSG_NOTICE([In-tree perl tree created])
387     fi
388 fi
389
390 FP_ICONV
391 FP_GMP
392 FP_CURSES
393
394 XCODE_VERSION()
395
396 SplitObjsBroken=NO
397 if test "$TargetOS_CPP" = "darwin"
398 then
399     # Split objects is broken (#4013) with XCode < 3.2
400     if test "$XCodeVersion1" -lt 3
401     then
402         SplitObjsBroken=YES
403     else
404         if test "$XCodeVersion1" -eq 3
405         then
406             if test "$XCodeVersion2" -lt 2
407             then
408                 SplitObjsBroken=YES
409             fi
410         fi
411     fi
412 fi
413 AC_SUBST([SplitObjsBroken])
414
415 dnl ** Building a cross compiler?
416 dnl --------------------------------------------------------------
417 CrossCompiling=NO
418 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
419 if test "$target" != "$host" ; then
420     CrossCompiling=YES
421     cross_compiling=yes   # This tells configure that it can accept just 'target',
422                           # otherwise you get
423                           #   configure: error: cannot run C compiled programs.
424                           #   If you meant to cross compile, use `--host'.
425 fi
426 if test "$build" != "$host" ; then
427    AC_MSG_ERROR([
428 You've selected:
429
430   BUILD:  $build   (the architecture we're building on)
431   HOST:   $host    (the architecture the compiler we're building will execute on)
432   TARGET: $target  (the architecture the compiler we're building will produce code for)
433
434 BUILD must equal HOST; that is, we do not support building GHC itself
435 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
436 1 will be a cross-compiler, and stage 2 will be the cross-compiled
437 GHC.
438 ])
439 fi
440 if test "$CrossCompiling" = "YES"
441 then
442   CrossCompilePrefix="${target}-"
443 else
444   CrossCompilePrefix=""
445 fi
446 TargetPlatformFull="${target}"
447 AC_SUBST(CrossCompiling)
448 AC_SUBST(CrossCompilePrefix)
449 AC_SUBST(TargetPlatformFull)
450
451 dnl ** Which gcc to use?
452 dnl --------------------------------------------------------------
453 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
454 CC="$WhatGccIsCalled"
455 export CC
456
457 # If --with-gcc was used, and we're not cross-compiling, then it also
458 # applies to the stage0 compiler.
459 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
463 AC_PROG_CPP
464
465 # --with-hs-cpp/--with-hs-cpp-flags
466 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
467 AC_SUBST([HaskellCPPCmd])
468 AC_SUBST([HaskellCPPArgs])
469
470 dnl ** Which ld to use?
471 dnl --------------------------------------------------------------
472 FIND_LD([LdCmd])
473 AC_SUBST([LdCmd])
474
475 dnl ** Which nm to use?
476 dnl --------------------------------------------------------------
477 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
478 NmCmd="$NM"
479 AC_SUBST([NmCmd])
480
481 dnl ** Which ar to use?
482 dnl --------------------------------------------------------------
483 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
484 ArCmd="$AR"
485 fp_prog_ar="$AR"
486 AC_SUBST([ArCmd])
487
488 dnl ** Which ranlib to use?
489 dnl --------------------------------------------------------------
490 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
491 RanlibCmd="$RANLIB"
492 RANLIB="$RanlibCmd"
493
494
495 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
496 case $HostOS_CPP in
497 cygwin32|mingw32)
498     dnl ** Which objdump to use?
499     dnl --------------------------------------------------------------
500     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
501     ObjdumpCmd="$OBJDUMP"
502     AC_SUBST([ObjdumpCmd])
503     ;;
504 esac
505
506 # Here is where we re-target which specific version of the LLVM
507 # tools we are looking for. In the past, GHC supported a number of
508 # versions of LLVM simultaneously, but that stopped working around
509 # 3.5/3.6 release of LLVM.
510 LlvmVersion=3.7
511 AC_SUBST([LlvmVersion])
512 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
513 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
514
515 dnl ** Which LLVM llc to use?
516 dnl --------------------------------------------------------------
517 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
518 LlcCmd="$LLC"
519 AC_SUBST([LlcCmd])
520
521 dnl ** Which LLVM opt to use?
522 dnl --------------------------------------------------------------
523 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
524 OptCmd="$OPT"
525 AC_SUBST([OptCmd])
526
527 dnl --------------------------------------------------------------
528 dnl End of configure script option section
529 dnl --------------------------------------------------------------
530
531
532 dnl --------------------------------------------------------------
533 dnl * General configuration checks
534 dnl --------------------------------------------------------------
535
536 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
537 dnl Unfortunately we don't know whether the user is going to request a
538 dnl build with the LLVM backend as this is only given in build.mk.
539 dnl
540 dnl Instead, we try to do as much work as possible here, checking
541 dnl whether -fllvm is the stage 0 compiler's default. If so we
542 dnl fail. If not, we check whether -fllvm is affected explicitly and
543 dnl if so set a flag. The build system will later check this flag
544 dnl after the desired build flags are known.
545
546 dnl This problem is further complicated by the fact that the llvm
547 dnl version used by the bootstrap compiler may be different from the
548 dnl version we arre trying to compile GHC against. Therefore, we need
549 dnl to find the boostrap compiler's `settings` file then check to see
550 dnl if the `opt` and `llc` command strings are non-empty and if these
551 dnl programs exist. Only if they exist to we test for bug #9439.
552
553 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
554 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
555
556 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
557 then
558     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
559     echo "main = putStrLn \"%function\"" > conftestghc.hs
560
561     # Check whether LLVM backend is default for this platform
562     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
563     res=`./conftestghc`
564     if test "x$res" = "x%object"
565     then
566         AC_MSG_RESULT(yes)
567         echo "Buggy bootstrap compiler"
568         echo ""
569         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
570         echo "and therefore will miscompile the LLVM backend if -fllvm is"
571         echo "used."
572         echo
573         echo "Please use another bootstrap compiler"
574         exit 1
575     fi
576
577     # -fllvm is not the default, but set a flag so the Makefile can check
578     # -for it in the build flags later on
579     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
580     if test $? = 0
581     then
582         res=`./conftestghc`
583         if test "x$res" = "x%object"
584         then
585             AC_MSG_RESULT(yes)
586             GHC_LLVM_AFFECTED_BY_9439=1
587         elif test "x$res" = "x%function"
588         then
589             AC_MSG_RESULT(no)
590             GHC_LLVM_AFFECTED_BY_9439=0
591         else
592             AC_MSG_WARN(unexpected output $res)
593         fi
594     else
595         AC_MSG_RESULT(failed to compile, assuming no)
596     fi
597 fi
598 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
599
600 dnl ** Can the unix package be built?
601 dnl --------------------------------------------------------------
602
603 if test "$TargetOS" = "mingw32"
604 then
605     GhcLibsWithUnix=NO
606 else
607     GhcLibsWithUnix=YES
608 fi
609 AC_SUBST([GhcLibsWithUnix])
610
611 dnl ** does #! work?
612 AC_SYS_INTERPRETER()
613
614 dnl ** look for `perl'
615 case $HostOS_CPP in
616 cygwin32|mingw32)
617     PerlCmd=$hardtop/inplace/perl/perl
618     ;;
619 *)
620     AC_PATH_PROG(PerlCmd,perl)
621     if test -z "$PerlCmd"
622     then
623         echo "You must install perl before you can continue"
624         echo "Perhaps it is already installed, but not in your PATH?"
625         exit 1
626     else
627         FPTOOLS_CHECK_PERL_VERSION
628     fi
629     ;;
630 esac
631
632 dnl ** look for GCC and find out which version
633 dnl     Figure out which C compiler to use.  Gcc is preferred.
634 dnl     If gcc, make sure it's at least 3.0
635 dnl
636 FP_GCC_VERSION
637
638 dnl ** look to see if we have a C compiler using an llvm back end.
639 dnl
640 FP_CC_LLVM_BACKEND
641
642 FP_PROG_LD_IS_GNU
643 FP_PROG_LD_BUILD_ID
644 FP_PROG_LD_NO_COMPACT_UNWIND
645 FP_PROG_LD_FILELIST
646
647
648 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
649 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
650 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
651 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
652 # Stage 3 won't be supported by cross-compilation
653
654 FP_GCC_EXTRA_FLAGS
655
656 AC_SUBST(CONF_CC_OPTS_STAGE0)
657 AC_SUBST(CONF_CC_OPTS_STAGE1)
658 AC_SUBST(CONF_CC_OPTS_STAGE2)
659 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
660 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
661 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
662 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
663 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
664 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
665 AC_SUBST(CONF_CPP_OPTS_STAGE0)
666 AC_SUBST(CONF_CPP_OPTS_STAGE1)
667 AC_SUBST(CONF_CPP_OPTS_STAGE2)
668
669 dnl ** Set up the variables for the platform in the settings file.
670 dnl May need to use gcc to find platform details.
671 dnl --------------------------------------------------------------
672 FPTOOLS_SET_HASKELL_PLATFORM_VARS
673
674 dnl ** figure out how to do context diffs
675 FP_PROG_CONTEXT_DIFF
676
677 dnl Let's make sure install-sh is executable here.  If we got it from
678 dnl a darcs repo, it might not be (see bug #978).
679 chmod +x install-sh
680 dnl ** figure out how to do a BSD-ish install
681 AC_PROG_INSTALL
682
683 dnl ** how to invoke `ar' and `ranlib'
684 FP_PROG_AR_SUPPORTS_ATFILE
685 FP_PROG_AR_NEEDS_RANLIB
686
687 dnl ** Check to see whether ln -s works
688 AC_PROG_LN_S
689
690 FP_SETTINGS
691
692 dnl ** Find the path to sed
693 AC_PATH_PROGS(SedCmd,gsed sed,sed)
694
695
696 dnl ** check for time command
697 AC_PATH_PROG(TimeCmd,time)
698
699 dnl ** check for tar
700 dnl   if GNU tar is named gtar, look for it first.
701 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
702
703 dnl ** check for patch
704 dnl if GNU patch is named gpatch, look for it first
705 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
706
707 dnl ** check for dtrace (currently only implemented for Mac OS X)
708 HaveDtrace=NO
709 AC_PATH_PROG(DtraceCmd,dtrace)
710 if test -n "$DtraceCmd"; then
711   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
712     HaveDtrace=YES
713   fi
714 fi
715 AC_SUBST(HaveDtrace)
716
717 AC_PATH_PROG(HSCOLOUR,HsColour)
718 # HsColour is passed to Cabal, so we need a native path
719 if test "$HostOS"      = "mingw32" && \
720    test "${OSTYPE}"   != "msys"    && \
721    test "${HSCOLOUR}" != ""
722 then
723     # Canonicalise to <drive>:/path/to/gcc
724     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
725 fi
726
727 dnl ** check for Sphinx toolchain
728 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
729 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
730 changequote(, )dnl
731 [if test -n "$SPHINXBUILD"; then
732   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
733 fi;
734 changequote([, ])dnl
735 ])
736 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
737     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
738
739 dnl ** check for xelatex
740 AC_PATH_PROG(XELATEX,xelatex)
741
742 dnl ** check for ghc-pkg command
743 FP_PROG_GHC_PKG
744
745 dnl ** check for installed happy binary + version
746 FPTOOLS_HAPPY
747
748 dnl ** check for installed alex binary + version
749 FPTOOLS_ALEX
750
751 dnl --------------------------------------------------
752 dnl ### program checking section ends here ###
753 dnl --------------------------------------------------
754
755 dnl --------------------------------------------------
756 dnl * Platform header file and syscall feature tests
757 dnl ### checking the state of the local header files and syscalls ###
758
759 dnl ** check for full ANSI header (.h) files
760 AC_HEADER_STDC
761
762 dnl ** Enable large file support.  NB. do this before testing the type of
763 dnl    off_t, because it will affect the result of that test.
764 AC_SYS_LARGEFILE
765
766 dnl ** check for specific header (.h) files that we are interested in
767 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
768
769 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
770 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
771 [[#if HAVE_SYS_PARAM_H
772 # include <sys/param.h>
773 #endif
774 ]])
775
776 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
777 AC_HEADER_TIME
778
779 dnl ** do we have long longs?
780 AC_CHECK_TYPES([long long])
781
782 dnl ** what are the sizes of various types
783 AC_CHECK_SIZEOF(char,               1)
784 AC_CHECK_SIZEOF(double,             8)
785 AC_CHECK_SIZEOF(float,              4)
786 AC_CHECK_SIZEOF(int,                4)
787 AC_CHECK_SIZEOF(long,               4)
788 if test "$ac_cv_type_long_long" = yes; then
789 AC_CHECK_SIZEOF(long long,          8)
790 fi
791 AC_CHECK_SIZEOF(short,              2)
792 AC_CHECK_SIZEOF(unsigned char,      1)
793 AC_CHECK_SIZEOF(unsigned int,       4)
794 AC_CHECK_SIZEOF(unsigned long,      4)
795 if test "$ac_cv_type_long_long" = yes; then
796 AC_CHECK_SIZEOF(unsigned long long, 8)
797 fi
798 AC_CHECK_SIZEOF(unsigned short,     2)
799 AC_CHECK_SIZEOF(void *,             4)
800
801 dnl for use in settings.in
802 WordSize=$ac_cv_sizeof_void_p
803 AC_SUBST(WordSize)
804
805 dnl ** what are alignment constraints on various types
806 FP_CHECK_ALIGNMENT(char)
807 FP_CHECK_ALIGNMENT(double)
808 FP_CHECK_ALIGNMENT(float)
809 FP_CHECK_ALIGNMENT(int)
810 FP_CHECK_ALIGNMENT(long)
811 if test "$ac_cv_type_long_long" = yes; then
812 FP_CHECK_ALIGNMENT(long long)
813 fi
814 FP_CHECK_ALIGNMENT(short)
815 FP_CHECK_ALIGNMENT(unsigned char)
816 FP_CHECK_ALIGNMENT(unsigned int)
817 FP_CHECK_ALIGNMENT(unsigned long)
818 if test "$ac_cv_type_long_long" = yes; then
819 FP_CHECK_ALIGNMENT(unsigned long long)
820 fi
821 FP_CHECK_ALIGNMENT(unsigned short)
822 FP_CHECK_ALIGNMENT(void *)
823
824 FP_CHECK_FUNC([WinExec],
825   [@%:@include <windows.h>], [WinExec("",0)])
826
827 FP_CHECK_FUNC([GetModuleFileName],
828   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
829
830 dnl ** check for more functions
831 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
832 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
833
834 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
835 dnl ** _POSIX_C_SOURCE is defined
836 AC_CHECK_DECLS([ctime_r], , ,
837 [#define _POSIX_SOURCE 1
838 #define _POSIX_C_SOURCE 199506L
839 #include <time.h>])
840
841 dnl ** check for mingwex library
842 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
843 AC_SUBST(HaveLibMingwEx)
844
845 if test $HaveLibMingwEx = YES ; then
846   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
847 fi
848
849 dnl ** check for math library
850 dnl    Keep that check as early as possible.
851 dnl    as we need to know whether we need libm
852 dnl    for math functions or not
853 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
854 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
855 if test $HaveLibM = YES
856 then
857   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
858 fi
859
860 FP_BFD_SUPPORT
861
862 dnl ################################################################
863 dnl Check for libraries
864 dnl ################################################################
865
866 # system libffi
867
868 AC_ARG_WITH([system-libffi],
869 [AC_HELP_STRING([--with-system-libffi],
870   [Use system provided libffi for RTS [default=no]])
871 ])
872
873 AS_IF([test "x$with_system_libffi" = "xyes"],
874   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
875 )
876
877
878 AC_SUBST(UseSystemLibFFI)
879
880 AC_ARG_WITH([ffi-includes],
881 [AC_HELP_STRING([--with-ffi-includes=ARG],
882   [Find includes for libffi in ARG [default=system default]])
883 ],
884 [
885  if test "x$UseSystemLibFFI" != "xYES"; then
886     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
887  else
888     FFIIncludeDir="$withval"
889     LIBFFI_CFLAGS="-I$withval"
890  fi
891 ])
892
893 AC_SUBST(FFIIncludeDir)
894
895 AC_ARG_WITH([ffi-libraries],
896 [AC_HELP_STRING([--with-ffi-libraries=ARG],
897   [Find libffi in ARG [default=system default]])
898 ],
899 [
900  if test "x$UseSystemLibFFI" != "xYES"; then
901     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
902  else
903     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
904  fi
905 ])
906
907 AC_SUBST(FFILibDir)
908
909 AS_IF([test "$UseSystemLibFFI" = "YES"], [
910  CFLAGS2="$CFLAGS"
911  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
912  LDFLAGS2="$LDFLAGS"
913  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
914  if test "$HostOS" = "openbsd";
915  then
916    # OpenBSD's libffi is not directly linked to the libpthread but
917    # still requires pthread functionality. This means that any client
918    # binary which links with libffi also needs to link with
919    # libpthread. If it does not, then linking fails with unresolved
920    # symbols.
921    LDFLAGS="$LDFLAGS -lpthread"
922  fi
923  AC_CHECK_LIB(ffi, ffi_call,
924   [AC_CHECK_HEADERS([ffi.h], [break], [])
925    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
926   [AC_MSG_ERROR([Cannot find system libffi])])
927  CFLAGS="$CFLAGS2"
928  LDFLAGS="$LDFLAGS2"
929 ])
930
931 dnl ** check whether we need -ldl to get dlopen()
932 AC_CHECK_LIB(dl, dlopen)
933
934 dnl --------------------------------------------------
935 dnl * Miscellaneous feature tests
936 dnl --------------------------------------------------
937
938 dnl ** can we get alloca?
939 AC_FUNC_ALLOCA
940
941 dnl ** working vfork?
942 AC_FUNC_FORK
943
944 dnl ** determine whether or not const works
945 AC_C_CONST
946
947 dnl ** are we big endian?
948 AC_C_BIGENDIAN
949 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
950
951 dnl ** check for leading underscores in symbol names
952 FP_LEADING_UNDERSCORE
953
954 FP_VISIBILITY_HIDDEN
955
956 dnl ** check for librt
957 AC_CHECK_LIB(rt, clock_gettime)
958 AC_CHECK_FUNCS(clock_gettime timer_settime)
959 FP_CHECK_TIMER_CREATE
960
961 dnl ** check for Apple's "interesting" long double compatibility scheme
962 AC_MSG_CHECKING(for printf\$LDBLStub)
963 AC_TRY_LINK_FUNC(printf\$LDBLStub,
964     [
965         AC_MSG_RESULT(yes)
966         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
967             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
968     ],
969     [
970         AC_MSG_RESULT(no)
971         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
972             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
973     ])
974
975 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
976 dnl    a different single-argument version.
977 AC_CHECK_LIB(pthread, pthread_setname_np)
978 AC_MSG_CHECKING(for pthread_setname_np)
979 AC_TRY_LINK(
980 [
981 #define _GNU_SOURCE
982 #include <pthread.h>
983 ],
984 [pthread_setname_np(pthread_self(), "name");],
985     AC_MSG_RESULT(yes)
986     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
987       [Define to 1 if you have the glibc version of pthread_setname_np]),
988     AC_MSG_RESULT(no)
989 )
990
991 dnl ** check for eventfd which is needed by the I/O manager
992 AC_CHECK_HEADERS([sys/eventfd.h])
993 AC_CHECK_FUNCS([eventfd])
994
995 dnl ** Check for __thread support in the compiler
996 AC_MSG_CHECKING(for __thread support)
997 AC_COMPILE_IFELSE(
998   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
999   [
1000    AC_MSG_RESULT(yes)
1001    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1002   ],
1003   [
1004    AC_MSG_RESULT(no)
1005    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1006   ])
1007
1008
1009 AC_CHECK_FUNCS(__mingw_vfprintf)
1010
1011 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
1012    HavePapi=YES
1013 else
1014    HavePapi=NO
1015 fi
1016 AC_SUBST(HavePapi)
1017
1018 dnl large address space support (see includes/rts/storage/MBlock.h)
1019 dnl
1020 dnl Darwin has vm_allocate/vm_protect
1021 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1022 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1023 dnl (They also have MADV_DONTNEED, but it means something else!)
1024 dnl
1025 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1026 dnl it counts page-table space as committed memory, and so quickly
1027 dnl runs out of paging file when we have multiple processes reserving
1028 dnl 1TB of address space, we get the following error:
1029 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1030 dnl
1031
1032 AC_ARG_ENABLE(large-address-space,
1033     [AC_HELP_STRING([--enable-large-address-space],
1034         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1035     EnableLargeAddressSpace=$enableval,
1036     EnableLargeAddressSpace=yes
1037 )
1038
1039 use_large_address_space=no
1040 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1041     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1042         if test "$ghc_host_os" = "darwin" ; then
1043             use_large_address_space=yes
1044         elif test "$ghc_host_os" = "openbsd" ; then
1045             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1046             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1047             # but is completely ignored by OS mmap
1048             use_large_address_space=no
1049         else
1050             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1051                 [
1052                 #include <unistd.h>
1053                 #include <sys/types.h>
1054                 #include <sys/mman.h>
1055                 #include <fcntl.h>
1056             ])
1057             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1058                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1059                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1060                     use_large_address_space=yes
1061             fi
1062         fi
1063     fi
1064 fi
1065 if test "$use_large_address_space" = "yes" ; then
1066    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1067 fi
1068
1069 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1070 AC_SUBST(HaveLibdw)
1071
1072 if test -n "$SPHINXBUILD"; then
1073     BUILD_MAN=YES
1074     BUILD_SPHINX_HTML=YES
1075     if test -n "$XELATEX"; then
1076         BUILD_SPHINX_PDF=YES
1077     else
1078         BUILD_SPHINX_PDF=NO
1079     fi
1080 else
1081     BUILD_MAN=NO
1082     BUILD_SPHINX_HTML=NO
1083     BUILD_SPHINX_PDF=NO
1084 fi
1085 AC_SUBST(BUILD_MAN)
1086 AC_SUBST(BUILD_SPHINX_HTML)
1087 AC_SUBST(BUILD_SPHINX_PDF)
1088
1089 LIBRARY_VERSION(base)
1090 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1091 LIBRARY_VERSION(ghc-prim)
1092 LIBRARY_ghc_VERSION="$ProjectVersion"
1093 AC_SUBST(LIBRARY_ghc_VERSION)
1094
1095 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1096    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1097 fi
1098
1099 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1100 AC_OUTPUT
1101
1102 # We got caught by
1103 #     http://savannah.gnu.org/bugs/index.php?1516
1104 #     $(eval ...) inside conditionals causes errors
1105 # with make 3.80, so warn the user if it looks like they're about to
1106 # try to use it.
1107 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1108 checkMake380() {
1109     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1110     then
1111         echo
1112         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1113         echo "This version cannot be used to build GHC."
1114         echo "Please use GNU make >= 3.81."
1115     fi
1116 }
1117
1118 checkMake380 make
1119 checkMake380 gmake
1120
1121 echo ["
1122 ----------------------------------------------------------------------
1123 Configure completed successfully.
1124
1125    Building GHC version  : $ProjectVersion
1126           Git commit id  : $ProjectGitCommitId
1127
1128    Build platform        : $BuildPlatform
1129    Host platform         : $HostPlatform
1130    Target platform       : $TargetPlatform
1131 "]
1132
1133 echo ["\
1134    Bootstrapping using   : $WithGhc
1135       which is version   : $GhcVersion
1136 "]
1137
1138 if test "x$CC_LLVM_BACKEND" = "x1"; then
1139     if test "x$CC_CLANG_BACKEND" = "x1"; then
1140         CompilerName="clang        "
1141     else
1142         CompilerName="llvm-gcc     "
1143     fi
1144 else
1145     CompilerName="gcc          "
1146 fi
1147
1148 echo ["\
1149    Using $CompilerName       : $WhatGccIsCalled
1150       which is version       : $GccVersion
1151    Building a cross compiler : $CrossCompiling
1152    hs-cpp       : $HaskellCPPCmd
1153    hs-cpp-flags : $HaskellCPPArgs
1154    ld           : $LdCmd
1155    Happy        : $HappyCmd ($HappyVersion)
1156    Alex         : $AlexCmd ($AlexVersion)
1157    Perl         : $PerlCmd
1158    sphinx-build : $SPHINXBUILD
1159    xelatex      : $XELATEX
1160
1161    Using LLVM tools
1162       llc   : $LlcCmd
1163       opt   : $OptCmd"]
1164
1165 if test "$HSCOLOUR" = ""; then
1166 echo ["
1167    HsColour was not found; documentation will not contain source links
1168 "]
1169 else
1170 echo ["\
1171    HsColour : $HSCOLOUR
1172 "]
1173 fi
1174
1175 echo ["\
1176    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1177    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1178
1179 echo ["----------------------------------------------------------------------
1180 "]
1181
1182 echo "\
1183 For a standard build of GHC (fully optimised with profiling), type (g)make.
1184
1185 To make changes to the default build configuration, copy the file
1186 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1187
1188 For more information on how to configure your GHC build, see
1189    http://ghc.haskell.org/trac/ghc/wiki/Building
1190 "