Merge remote-tracking branch 'laptop/newcg' into newcg
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 -- 
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 {-# OPTIONS -fno-warn-tabs #-}
11 -- The above warning supression flag is a temporary kludge.
12 -- While working on this module you are encouraged to remove it and
13 -- detab the module (please do the detabbing in a separate patch). See
14 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
15 -- for details
16
17 module AsmCodeGen ( nativeCodeGen ) where
18
19 #include "HsVersions.h"
20 #include "nativeGen/NCG.h"
21
22
23 import qualified X86.CodeGen
24 import qualified X86.Regs
25 import qualified X86.Instr
26 import qualified X86.Ppr
27
28 import qualified SPARC.CodeGen
29 import qualified SPARC.Regs
30 import qualified SPARC.Instr
31 import qualified SPARC.Ppr
32 import qualified SPARC.ShortcutJump
33 import qualified SPARC.CodeGen.Expand
34
35 import qualified PPC.CodeGen
36 import qualified PPC.Cond
37 import qualified PPC.Regs
38 import qualified PPC.RegInfo
39 import qualified PPC.Instr
40 import qualified PPC.Ppr
41
42 import RegAlloc.Liveness
43 import qualified RegAlloc.Linear.Main           as Linear
44
45 import qualified GraphColor                     as Color
46 import qualified RegAlloc.Graph.Main            as Color
47 import qualified RegAlloc.Graph.Stats           as Color
48 import qualified RegAlloc.Graph.TrivColorable   as Color
49
50 import TargetReg
51 import Platform
52 import Config
53 import Instruction
54 import PIC
55 import Reg
56 import NCGMonad
57
58 import BlockId
59 import CgUtils          ( fixStgRegisters )
60 import OldCmm
61 import CmmOpt           ( cmmEliminateDeadBlocks, cmmMiniInline, cmmMachOpFold )
62 import OldPprCmm
63 import CLabel
64
65 import UniqFM
66 import Unique           ( Unique, getUnique )
67 import UniqSupply
68 import DynFlags
69 import StaticFlags
70 import Util
71
72 import BasicTypes       ( Alignment )
73 import Digraph
74 import Pretty (Doc)
75 import qualified Pretty
76 import BufWrite
77 import Outputable
78 import FastString
79 import UniqSet
80 import ErrUtils
81 import Module
82 import Stream (Stream)
83 import qualified Stream
84
85 -- DEBUGGING ONLY
86 --import OrdList
87
88 import Data.List
89 import Data.Maybe
90 import Control.Monad
91 import System.IO
92
93 {-
94 The native-code generator has machine-independent and
95 machine-dependent modules.
96
97 This module ("AsmCodeGen") is the top-level machine-independent
98 module.  Before entering machine-dependent land, we do some
99 machine-independent optimisations (defined below) on the
100 'CmmStmts's.
101
102 We convert to the machine-specific 'Instr' datatype with
103 'cmmCodeGen', assuming an infinite supply of registers.  We then use
104 a machine-independent register allocator ('regAlloc') to rejoin
105 reality.  Obviously, 'regAlloc' has machine-specific helper
106 functions (see about "RegAllocInfo" below).
107
108 Finally, we order the basic blocks of the function so as to minimise
109 the number of jumps between blocks, by utilising fallthrough wherever
110 possible.
111
112 The machine-dependent bits break down as follows:
113
114   * ["MachRegs"]  Everything about the target platform's machine
115     registers (and immediate operands, and addresses, which tend to
116     intermingle/interact with registers).
117
118   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
119     have a module of its own), plus a miscellany of other things
120     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
121
122   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
123     machine instructions.
124
125   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
126     a 'Doc').
127
128   * ["RegAllocInfo"] In the register allocator, we manipulate
129     'MRegsState's, which are 'BitSet's, one bit per machine register.
130     When we want to say something about a specific machine register
131     (e.g., ``it gets clobbered by this instruction''), we set/unset
132     its bit.  Obviously, we do this 'BitSet' thing for efficiency
133     reasons.
134
135     The 'RegAllocInfo' module collects together the machine-specific
136     info needed to do register allocation.
137
138    * ["RegisterAlloc"] The (machine-independent) register allocator.
139 -}
140
141 -- -----------------------------------------------------------------------------
142 -- Top-level of the native codegen
143
144 data NcgImpl statics instr jumpDest = NcgImpl {
145     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
146     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
147     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
148     canShortcut               :: instr -> Maybe jumpDest,
149     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
150     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
151     pprNatCmmDecl              :: Platform -> NatCmmDecl statics instr -> Doc,
152     maxSpillSlots             :: Int,
153     allocatableRegs           :: [RealReg],
154     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
155     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
156     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
157     }
158
159 --------------------
160 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
161 nativeCodeGen dflags h us cmms
162  = let platform = targetPlatform dflags
163        nCG' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
164        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
165        x86NcgImpl = NcgImpl {
166                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
167                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr
168                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
169                         ,canShortcut               = X86.Instr.canShortcut
170                         ,shortcutStatics           = X86.Instr.shortcutStatics
171                         ,shortcutJump              = X86.Instr.shortcutJump
172                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
173                         ,maxSpillSlots             = X86.Instr.maxSpillSlots (target32Bit platform)
174                         ,allocatableRegs           = X86.Regs.allocatableRegs
175                         ,ncg_x86fp_kludge          = id
176                         ,ncgExpandTop              = id
177                         ,ncgMakeFarBranches        = id
178                     }
179    in case platformArch platform of
180                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
181                  ArchX86_64 -> nCG' x86NcgImpl
182                  ArchPPC ->
183                      nCG' $ NcgImpl {
184                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
185                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr
186                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
187                          ,canShortcut               = PPC.RegInfo.canShortcut
188                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
189                          ,shortcutJump              = PPC.RegInfo.shortcutJump
190                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
191                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots
192                          ,allocatableRegs           = PPC.Regs.allocatableRegs
193                          ,ncg_x86fp_kludge          = id
194                          ,ncgExpandTop              = id
195                          ,ncgMakeFarBranches        = makeFarBranches
196                      }
197                  ArchSPARC ->
198                      nCG' $ NcgImpl {
199                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
200                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr
201                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
202                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
203                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
204                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
205                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
206                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots
207                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
208                          ,ncg_x86fp_kludge          = id
209                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
210                          ,ncgMakeFarBranches        = id
211                      }
212                  ArchARM _ _ ->
213                      panic "nativeCodeGen: No NCG for ARM"
214                  ArchPPC_64 ->
215                      panic "nativeCodeGen: No NCG for PPC 64"
216                  ArchUnknown ->
217                      panic "nativeCodeGen: No NCG for unknown arch"
218
219 nativeCodeGen' :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
220                => DynFlags
221                -> NcgImpl statics instr jumpDest
222                -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
223 nativeCodeGen' dflags ncgImpl h us cmms
224  = do
225         let platform = targetPlatform dflags
226             split_cmms  = Stream.map add_split cmms
227         -- BufHandle is a performance hack.  We could hide it inside
228         -- Pretty if it weren't for the fact that we do lots of little
229         -- printDocs here (in order to do codegen in constant space).
230         bufh <- newBufHandle h
231         (imports, prof) <- cmmNativeGenStream dflags ncgImpl bufh us split_cmms [] [] 0
232         bFlush bufh
233
234         let (native, colorStats, linearStats)
235                 = unzip3 prof
236
237         -- dump native code
238         dumpIfSet_dyn dflags
239                 Opt_D_dump_asm "Asm code"
240                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) $ concat native)
241
242         -- dump global NCG stats for graph coloring allocator
243         (case concat $ catMaybes colorStats of
244           []    -> return ()
245           stats -> do   
246                 -- build the global register conflict graph
247                 let graphGlobal 
248                         = foldl Color.union Color.initGraph
249                         $ [ Color.raGraph stat
250                                 | stat@Color.RegAllocStatsStart{} <- stats]
251            
252                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
253                         $ Color.pprStats stats graphGlobal
254
255                 dumpIfSet_dyn dflags
256                         Opt_D_dump_asm_conflicts "Register conflict graph"
257                         $ Color.dotGraph 
258                                 (targetRegDotColor platform)
259                                 (Color.trivColorable platform
260                                         (targetVirtualRegSqueeze platform)
261                                         (targetRealRegSqueeze platform))
262                         $ graphGlobal)
263
264
265         -- dump global NCG stats for linear allocator
266         (case concat $ catMaybes linearStats of
267                 []      -> return ()
268                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
269                                 $ Linear.pprStats (concat native) stats)
270
271         -- write out the imports
272         Pretty.printDoc Pretty.LeftMode h
273                 $ makeImportsDoc dflags (concat imports)
274
275         return  ()
276
277  where  add_split tops
278                 | dopt Opt_SplitObjs dflags = split_marker : tops
279                 | otherwise                 = tops
280
281         split_marker = CmmProc Nothing mkSplitMarkerLabel (ListGraph [])
282
283
284 cmmNativeGenStream :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
285               => DynFlags
286               -> NcgImpl statics instr jumpDest
287               -> BufHandle
288               -> UniqSupply
289               -> Stream IO RawCmmGroup ()
290               -> [[CLabel]]
291               -> [ ([NatCmmDecl statics instr],
292                    Maybe [Color.RegAllocStats statics instr],
293                    Maybe [Linear.RegAllocStats]) ]
294               -> Int
295               -> IO ( [[CLabel]],
296                       [([NatCmmDecl statics instr],
297                       Maybe [Color.RegAllocStats statics instr],
298                       Maybe [Linear.RegAllocStats])] )
299
300 cmmNativeGenStream dflags ncgImpl h us cmm_stream impAcc profAcc count
301  = do
302         r <- Stream.runStream cmm_stream
303         case r of
304           Left () -> return (reverse impAcc, reverse profAcc)
305           Right (cmms, cmm_stream') -> do
306             (impAcc,profAcc,us') <- cmmNativeGens dflags ncgImpl h us cmms
307                                               impAcc profAcc count
308             cmmNativeGenStream dflags ncgImpl h us' cmm_stream'
309                                               impAcc profAcc count
310
311
312 -- | Do native code generation on all these cmms.
313 --
314 cmmNativeGens :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
315               => DynFlags
316               -> NcgImpl statics instr jumpDest
317               -> BufHandle
318               -> UniqSupply
319               -> [RawCmmDecl]
320               -> [[CLabel]]
321               -> [ ([NatCmmDecl statics instr],
322                    Maybe [Color.RegAllocStats statics instr],
323                    Maybe [Linear.RegAllocStats]) ]
324               -> Int
325               -> IO ( [[CLabel]],
326                       [([NatCmmDecl statics instr],
327                        Maybe [Color.RegAllocStats statics instr],
328                        Maybe [Linear.RegAllocStats])],
329                       UniqSupply )
330
331 cmmNativeGens _ _ _ us [] impAcc profAcc _
332         = return (impAcc,profAcc,us)
333
334 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
335  = do
336         let platform = targetPlatform dflags
337
338         (us', native, imports, colorStats, linearStats)
339                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
340
341         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
342                 $ Pretty.vcat $ map (pprNatCmmDecl ncgImpl platform) native
343
344            -- carefully evaluate this strictly.  Binding it with 'let'
345            -- and then using 'seq' doesn't work, because the let
346            -- apparently gets inlined first.
347         lsPprNative <- return $!
348                 if  dopt Opt_D_dump_asm       dflags
349                  || dopt Opt_D_dump_asm_stats dflags
350                         then native
351                         else []
352
353         count' <- return $! count + 1;
354
355         -- force evaulation all this stuff to avoid space leaks
356         {-# SCC "seqString" #-} seqString (showSDoc $ vcat $ map (pprPlatform platform) imports) `seq` return ()
357
358         cmmNativeGens dflags ncgImpl
359             h us' cmms
360                         (imports : impAcc)
361                         ((lsPprNative, colorStats, linearStats) : profAcc)
362                         count'
363
364  where  seqString []            = ()
365         seqString (x:xs)        = x `seq` seqString xs `seq` ()
366
367
368 -- | Complete native code generation phase for a single top-level chunk of Cmm.
369 --      Dumping the output of each stage along the way.
370 --      Global conflict graph and NGC stats
371 cmmNativeGen
372         :: (PlatformOutputable statics, PlatformOutputable instr, Instruction instr)
373     => DynFlags
374     -> NcgImpl statics instr jumpDest
375         -> UniqSupply
376         -> RawCmmDecl                                   -- ^ the cmm to generate code for
377         -> Int                                          -- ^ sequence number of this top thing
378         -> IO   ( UniqSupply
379                 , [NatCmmDecl statics instr]                -- native code
380                 , [CLabel]                                  -- things imported by this cmm
381                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
382                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
383
384 cmmNativeGen dflags ncgImpl us cmm count
385  = do
386         let platform = targetPlatform dflags
387
388         -- rewrite assignments to global regs
389         let fixed_cmm =
390                 {-# SCC "fixStgRegisters" #-}
391                 fixStgRegisters cmm
392
393         -- cmm to cmm optimisations
394         let (opt_cmm, imports) =
395                 {-# SCC "cmmToCmm" #-}
396                 cmmToCmm dflags fixed_cmm
397
398         dumpIfSet_dyn dflags
399                 Opt_D_dump_opt_cmm "Optimised Cmm"
400                 (pprCmmGroup platform [opt_cmm])
401
402         -- generate native code from cmm
403         let ((native, lastMinuteImports), usGen) =
404                 {-# SCC "genMachCode" #-}
405                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
406
407         dumpIfSet_dyn dflags
408                 Opt_D_dump_asm_native "Native code"
409                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) native)
410
411         -- tag instructions with register liveness information
412         let (withLiveness, usLive) =
413                 {-# SCC "regLiveness" #-}
414                 initUs usGen 
415                         $ mapUs (regLiveness platform)
416                         $ map natCmmTopToLive native
417
418         dumpIfSet_dyn dflags
419                 Opt_D_dump_asm_liveness "Liveness annotations added"
420                 (vcat $ map (pprPlatform platform) withLiveness)
421                 
422         -- allocate registers
423         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
424          if ( dopt Opt_RegsGraph dflags
425            || dopt Opt_RegsIterative dflags)
426           then do
427                 -- the regs usable for allocation
428                 let (alloc_regs :: UniqFM (UniqSet RealReg))
429                         = foldr (\r -> plusUFM_C unionUniqSets
430                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
431                                 emptyUFM
432                         $ allocatableRegs ncgImpl
433
434                 -- do the graph coloring register allocation
435                 let ((alloced, regAllocStats), usAlloc)
436                         = {-# SCC "RegAlloc" #-}
437                           initUs usLive
438                           $ Color.regAlloc
439                                 dflags
440                                 alloc_regs
441                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
442                                 withLiveness
443
444                 -- dump out what happened during register allocation
445                 dumpIfSet_dyn dflags
446                         Opt_D_dump_asm_regalloc "Registers allocated"
447                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
448
449                 dumpIfSet_dyn dflags
450                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
451                         (vcat   $ map (\(stage, stats)
452                                         -> text "# --------------------------"
453                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
454                                         $$ pprPlatform platform stats)
455                                 $ zip [0..] regAllocStats)
456
457                 let mPprStats =
458                         if dopt Opt_D_dump_asm_stats dflags
459                          then Just regAllocStats else Nothing
460
461                 -- force evaluation of the Maybe to avoid space leak
462                 mPprStats `seq` return ()
463
464                 return  ( alloced, usAlloc
465                         , mPprStats
466                         , Nothing)
467
468           else do
469                 -- do linear register allocation
470                 let ((alloced, regAllocStats), usAlloc) 
471                         = {-# SCC "RegAlloc" #-}
472                           initUs usLive
473                           $ liftM unzip
474                           $ mapUs (Linear.regAlloc dflags) withLiveness
475
476                 dumpIfSet_dyn dflags
477                         Opt_D_dump_asm_regalloc "Registers allocated"
478                         (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) alloced)
479
480                 let mPprStats =
481                         if dopt Opt_D_dump_asm_stats dflags
482                          then Just (catMaybes regAllocStats) else Nothing
483
484                 -- force evaluation of the Maybe to avoid space leak
485                 mPprStats `seq` return ()
486
487                 return  ( alloced, usAlloc
488                         , Nothing
489                         , mPprStats)
490
491         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
492         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
493         ---- is clear, and library functions can return odd results if it
494         ---- isn't.
495         ----
496         ---- NB. must happen before shortcutBranches, because that
497         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
498         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
499
500         ---- generate jump tables
501         let tabled      =
502                 {-# SCC "generateJumpTables" #-}
503                 generateJumpTables ncgImpl kludged
504
505         ---- shortcut branches
506         let shorted     =
507                 {-# SCC "shortcutBranches" #-}
508                 shortcutBranches dflags ncgImpl tabled
509
510         ---- sequence blocks
511         let sequenced   =
512                 {-# SCC "sequenceBlocks" #-}
513                 map (sequenceTop ncgImpl) shorted
514
515         ---- expansion of SPARC synthetic instrs
516         let expanded = 
517                 {-# SCC "sparc_expand" #-}
518                 ncgExpandTop ncgImpl sequenced
519
520         dumpIfSet_dyn dflags
521                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
522                 (vcat $ map (docToSDoc . pprNatCmmDecl ncgImpl platform) expanded)
523
524         return  ( usAlloc
525                 , expanded
526                 , lastMinuteImports ++ imports
527                 , ppr_raStatsColor
528                 , ppr_raStatsLinear)
529
530
531 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
532 x86fp_kludge top@(CmmData _ _) = top
533 x86fp_kludge (CmmProc info lbl (ListGraph code)) = 
534         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
535
536
537 -- | Build a doc for all the imports.
538 --
539 makeImportsDoc :: DynFlags -> [CLabel] -> Pretty.Doc
540 makeImportsDoc dflags imports
541  = dyld_stubs imports
542             Pretty.$$
543             -- On recent versions of Darwin, the linker supports
544             -- dead-stripping of code and data on a per-symbol basis.
545             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
546             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
547              then Pretty.text ".subsections_via_symbols"
548              else Pretty.empty)
549             Pretty.$$ 
550                 -- On recent GNU ELF systems one can mark an object file
551                 -- as not requiring an executable stack. If all objects
552                 -- linked into a program have this note then the program
553                 -- will not use an executable stack, which is good for
554                 -- security. GHC generated code does not need an executable
555                 -- stack so add the note in:
556             (if platformHasGnuNonexecStack (targetPlatform dflags)
557              then Pretty.text ".section .note.GNU-stack,\"\",@progbits"
558              else Pretty.empty)
559             Pretty.$$
560                 -- And just because every other compiler does, lets stick in
561                 -- an identifier directive: .ident "GHC x.y.z"
562             (if platformHasIdentDirective (targetPlatform dflags)
563              then let compilerIdent = Pretty.text "GHC" Pretty.<+>
564                                       Pretty.text cProjectVersion
565                    in Pretty.text ".ident" Pretty.<+>
566                       Pretty.doubleQuotes compilerIdent
567              else Pretty.empty)
568
569  where
570         -- Generate "symbol stubs" for all external symbols that might
571         -- come from a dynamic library.
572         dyld_stubs :: [CLabel] -> Pretty.Doc
573 {-      dyld_stubs imps = Pretty.vcat $ map pprDyldSymbolStub $
574                                     map head $ group $ sort imps-}
575
576         platform = targetPlatform dflags
577         arch = platformArch platform
578         os   = platformOS   platform
579         
580         -- (Hack) sometimes two Labels pretty-print the same, but have
581         -- different uniques; so we compare their text versions...
582         dyld_stubs imps
583                 | needImportedSymbols arch os
584                 = Pretty.vcat $
585                         (pprGotDeclaration arch os :) $
586                         map ( pprImportedSymbol platform . fst . head) $
587                         groupBy (\(_,a) (_,b) -> a == b) $
588                         sortBy (\(_,a) (_,b) -> compare a b) $
589                         map doPpr $
590                         imps
591                 | otherwise
592                 = Pretty.empty
593
594         doPpr lbl = (lbl, renderWithStyle (pprCLabel platform lbl) astyle)
595         astyle = mkCodeStyle AsmStyle
596
597
598 -- -----------------------------------------------------------------------------
599 -- Sequencing the basic blocks
600
601 -- Cmm BasicBlocks are self-contained entities: they always end in a
602 -- jump, either non-local or to another basic block in the same proc.
603 -- In this phase, we attempt to place the basic blocks in a sequence
604 -- such that as many of the local jumps as possible turn into
605 -- fallthroughs.
606
607 sequenceTop 
608         :: Instruction instr
609     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
610
611 sequenceTop _       top@(CmmData _ _) = top
612 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) = 
613   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks blocks)
614
615 -- The algorithm is very simple (and stupid): we make a graph out of
616 -- the blocks where there is an edge from one block to another iff the
617 -- first block ends by jumping to the second.  Then we topologically
618 -- sort this graph.  Then traverse the list: for each block, we first
619 -- output the block, then if it has an out edge, we move the
620 -- destination of the out edge to the front of the list, and continue.
621
622 -- FYI, the classic layout for basic blocks uses postorder DFS; this
623 -- algorithm is implemented in Hoopl.
624
625 sequenceBlocks 
626         :: Instruction instr
627         => [NatBasicBlock instr] 
628         -> [NatBasicBlock instr]
629
630 sequenceBlocks [] = []
631 sequenceBlocks (entry:blocks) = 
632   seqBlocks (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
633   -- the first block is the entry point ==> it must remain at the start.
634
635
636 sccBlocks 
637         :: Instruction instr
638         => [NatBasicBlock instr] 
639         -> [SCC ( NatBasicBlock instr
640                 , Unique
641                 , [Unique])]
642
643 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
644
645 -- we're only interested in the last instruction of
646 -- the block, and only if it has a single destination.
647 getOutEdges 
648         :: Instruction instr
649         => [instr] -> [Unique]
650
651 getOutEdges instrs 
652         = case jumpDestsOfInstr (last instrs) of
653                 [one] -> [getUnique one]
654                 _many -> []
655
656 mkNode :: (Instruction t)
657        => GenBasicBlock t
658        -> (GenBasicBlock t, Unique, [Unique])
659 mkNode block@(BasicBlock id instrs) = (block, getUnique id, getOutEdges instrs)
660
661 seqBlocks :: (Eq t) => [(GenBasicBlock t1, t, [t])] -> [GenBasicBlock t1]
662 seqBlocks [] = []
663 seqBlocks ((block,_,[]) : rest)
664   = block : seqBlocks rest
665 seqBlocks ((block@(BasicBlock id instrs),_,[next]) : rest)
666   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks rest'
667   | otherwise       = block : seqBlocks rest'
668   where
669         (can_fallthrough, rest') = reorder next [] rest
670           -- TODO: we should do a better job for cycles; try to maximise the
671           -- fallthroughs within a loop.
672 seqBlocks _ = panic "AsmCodegen:seqBlocks"
673
674 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
675 reorder  _ accum [] = (False, reverse accum)
676 reorder id accum (b@(block,id',out) : rest)
677   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
678   | otherwise  = reorder id (b:accum) rest
679
680
681 -- -----------------------------------------------------------------------------
682 -- Making far branches
683
684 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
685 -- big, we have to work around this limitation.
686
687 makeFarBranches
688         :: [NatBasicBlock PPC.Instr.Instr] 
689         -> [NatBasicBlock PPC.Instr.Instr]
690 makeFarBranches blocks
691     | last blockAddresses < nearLimit = blocks
692     | otherwise = zipWith handleBlock blockAddresses blocks
693     where
694         blockAddresses = scanl (+) 0 $ map blockLen blocks
695         blockLen (BasicBlock _ instrs) = length instrs
696         
697         handleBlock addr (BasicBlock id instrs)
698                 = BasicBlock id (zipWith makeFar [addr..] instrs)
699         
700         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
701         makeFar addr (PPC.Instr.BCC cond tgt)
702             | abs (addr - targetAddr) >= nearLimit
703             = PPC.Instr.BCCFAR cond tgt
704             | otherwise
705             = PPC.Instr.BCC cond tgt
706             where Just targetAddr = lookupUFM blockAddressMap tgt
707         makeFar _ other            = other
708         
709         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
710                          -- distance, as we have a few pseudo-insns that are
711                          -- pretty-printed as multiple instructions,
712                          -- and it's just not worth the effort to calculate
713                          -- things exactly
714         
715         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
716
717 -- -----------------------------------------------------------------------------
718 -- Generate jump tables
719
720 -- Analyzes all native code and generates data sections for all jump
721 -- table instructions.
722 generateJumpTables
723         :: NcgImpl statics instr jumpDest
724     -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
725 generateJumpTables ncgImpl xs = concatMap f xs
726     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
727           f p = [p]
728           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
729
730 -- -----------------------------------------------------------------------------
731 -- Shortcut branches
732
733 shortcutBranches
734         :: DynFlags
735     -> NcgImpl statics instr jumpDest
736         -> [NatCmmDecl statics instr] 
737         -> [NatCmmDecl statics instr]
738
739 shortcutBranches dflags ncgImpl tops
740   | optLevel dflags < 1 = tops    -- only with -O or higher
741   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
742   where
743     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
744     mapping = foldr plusUFM emptyUFM mappings
745
746 build_mapping :: NcgImpl statics instr jumpDest
747               -> GenCmmDecl d t (ListGraph instr)
748               -> (GenCmmDecl d t (ListGraph instr), UniqFM jumpDest)
749 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
750 build_mapping _ (CmmProc info lbl (ListGraph []))
751   = (CmmProc info lbl (ListGraph []), emptyUFM)
752 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
753   = (CmmProc info lbl (ListGraph (head:others)), mapping)
754         -- drop the shorted blocks, but don't ever drop the first one,
755         -- because it is pointed to by a global label.
756   where
757     -- find all the blocks that just consist of a jump that can be
758     -- shorted.
759     -- Don't completely eliminate loops here -- that can leave a dangling jump!
760     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
761     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
762         | Just jd <- canShortcut ncgImpl insn,
763           Just dest <- getJumpDestBlockId ncgImpl jd,
764           (setMember dest s) || dest == id -- loop checks
765         = (s, shortcut_blocks, b : others)
766     split (s, shortcut_blocks, others) (BasicBlock id [insn])
767         | Just dest <- canShortcut ncgImpl insn
768         = (setInsert id s, (id,dest) : shortcut_blocks, others)
769     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
770
771
772     -- build a mapping from BlockId to JumpDest for shorting branches
773     mapping = foldl add emptyUFM shortcut_blocks
774     add ufm (id,dest) = addToUFM ufm id dest
775     
776 apply_mapping :: NcgImpl statics instr jumpDest
777               -> UniqFM jumpDest
778               -> GenCmmDecl statics h (ListGraph instr)
779               -> GenCmmDecl statics h (ListGraph instr)
780 apply_mapping ncgImpl ufm (CmmData sec statics)
781   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
782 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
783   = CmmProc info lbl (ListGraph $ map short_bb blocks)
784   where
785     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
786     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
787                  -- shortcutJump should apply the mapping repeatedly,
788                  -- just in case we can short multiple branches.
789
790 -- -----------------------------------------------------------------------------
791 -- Instruction selection
792
793 -- Native code instruction selection for a chunk of stix code.  For
794 -- this part of the computation, we switch from the UniqSM monad to
795 -- the NatM monad.  The latter carries not only a Unique, but also an
796 -- Int denoting the current C stack pointer offset in the generated
797 -- code; this is needed for creating correct spill offsets on
798 -- architectures which don't offer, or for which it would be
799 -- prohibitively expensive to employ, a frame pointer register.  Viz,
800 -- x86.
801
802 -- The offset is measured in bytes, and indicates the difference
803 -- between the current (simulated) C stack-ptr and the value it was at
804 -- the beginning of the block.  For stacks which grow down, this value
805 -- should be either zero or negative.
806
807 -- Switching between the two monads whilst carrying along the same
808 -- Unique supply breaks abstraction.  Is that bad?
809
810 genMachCode 
811         :: DynFlags 
812         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
813         -> RawCmmDecl 
814         -> UniqSM 
815                 ( [NatCmmDecl statics instr]
816                 , [CLabel])
817
818 genMachCode dflags cmmTopCodeGen cmm_top
819   = do  { initial_us <- getUs
820         ; let initial_st           = mkNatM_State initial_us 0 dflags
821               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
822               final_delta          = natm_delta final_st
823               final_imports        = natm_imports final_st
824         ; if   final_delta == 0
825           then return (new_tops, final_imports)
826           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
827     }
828
829 -- -----------------------------------------------------------------------------
830 -- Generic Cmm optimiser
831
832 {-
833 Here we do:
834
835   (a) Constant folding
836   (b) Simple inlining: a temporary which is assigned to and then
837       used, once, can be shorted.
838   (c) Position independent code and dynamic linking
839         (i)  introduce the appropriate indirections
840              and position independent refs
841         (ii) compile a list of imported symbols
842   (d) Some arch-specific optimizations
843
844 (a) and (b) will be moving to the new Hoopl pipeline, however, (c) and
845 (d) are only needed by the native backend and will continue to live
846 here.
847
848 Ideas for other things we could do (put these in Hoopl please!):
849
850   - shortcut jumps-to-jumps
851   - simple CSE: if an expr is assigned to a temp, then replace later occs of
852     that expr with the temp, until the expr is no longer valid (can push through
853     temp assignments, and certain assigns to mem...)
854 -}
855
856 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
857 cmmToCmm _ top@(CmmData _ _) = (top, [])
858 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
859   let platform = targetPlatform dflags
860   blocks' <- mapM cmmBlockConFold (cmmMiniInline platform (cmmEliminateDeadBlocks blocks))
861   return $ CmmProc info lbl (ListGraph blocks')
862
863 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
864
865 instance Monad CmmOptM where
866   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
867   (CmmOptM f) >>= g =
868     CmmOptM $ \(imports, dflags) ->
869                 case f (imports, dflags) of
870                   (# x, imports' #) ->
871                     case g x of
872                       CmmOptM g' -> g' (imports', dflags)
873
874 addImportCmmOpt :: CLabel -> CmmOptM ()
875 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
876
877 instance HasDynFlags CmmOptM where
878     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
879
880 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
881 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
882                         (# result, imports #) -> (result, imports)
883
884 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
885 cmmBlockConFold (BasicBlock id stmts) = do
886   stmts' <- mapM cmmStmtConFold stmts
887   return $ BasicBlock id stmts'
888
889 -- This does three optimizations, but they're very quick to check, so we don't
890 -- bother turning them off even when the Hoopl code is active.  Since
891 -- this is on the old Cmm representation, we can't reuse the code either:
892 --  * reg = reg      --> nop
893 --  * if 0 then jump --> nop
894 --  * if 1 then jump --> jump
895 -- We might be tempted to skip this step entirely of not opt_PIC, but
896 -- there is some PowerPC code for the non-PIC case, which would also
897 -- have to be separated.
898 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
899 cmmStmtConFold stmt
900    = case stmt of
901         CmmAssign reg src
902            -> do src' <- cmmExprConFold DataReference src
903                  return $ case src' of
904                    CmmReg reg' | reg == reg' -> CmmNop
905                    new_src -> CmmAssign reg new_src
906
907         CmmStore addr src
908            -> do addr' <- cmmExprConFold DataReference addr
909                  src'  <- cmmExprConFold DataReference src
910                  return $ CmmStore addr' src'
911
912         CmmJump addr live
913            -> do addr' <- cmmExprConFold JumpReference addr
914                  return $ CmmJump addr' live
915
916         CmmCall target regs args returns
917            -> do target' <- case target of
918                               CmmCallee e conv -> do
919                                 e' <- cmmExprConFold CallReference e
920                                 return $ CmmCallee e' conv
921                               other -> return other
922                  args' <- mapM (\(CmmHinted arg hint) -> do
923                                   arg' <- cmmExprConFold DataReference arg
924                                   return (CmmHinted arg' hint)) args
925                  return $ CmmCall target' regs args' returns
926
927         CmmCondBranch test dest
928            -> do test' <- cmmExprConFold DataReference test
929                  dflags <- getDynFlags
930                  let platform = targetPlatform dflags
931                  return $ case test' of
932                    CmmLit (CmmInt 0 _) -> 
933                      CmmComment (mkFastString ("deleted: " ++ 
934                                         showSDoc (pprStmt platform stmt)))
935
936                    CmmLit (CmmInt _ _) -> CmmBranch dest
937                    _other -> CmmCondBranch test' dest
938
939         CmmSwitch expr ids
940            -> do expr' <- cmmExprConFold DataReference expr
941                  return $ CmmSwitch expr' ids
942
943         other
944            -> return other
945
946 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
947 cmmExprConFold referenceKind expr = do
948     dflags <- getDynFlags
949     -- Skip constant folding if new code generator is running
950     -- (this optimization is done in Hoopl)
951     let expr' = if dopt Opt_TryNewCodeGen dflags
952                     then expr
953                     else cmmExprCon (targetPlatform dflags) expr
954     cmmExprNative referenceKind expr'
955
956 cmmExprCon :: Platform -> CmmExpr -> CmmExpr
957 cmmExprCon platform (CmmLoad addr rep) = CmmLoad (cmmExprCon platform addr) rep
958 cmmExprCon platform (CmmMachOp mop args)
959     = cmmMachOpFold platform mop (map (cmmExprCon platform) args)
960 cmmExprCon _ other = other
961
962 -- handles both PIC and non-PIC cases... a very strange mixture
963 -- of things to do.
964 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
965 cmmExprNative referenceKind expr = do
966      dflags <- getDynFlags
967      let platform = targetPlatform dflags
968          arch = platformArch platform
969      case expr of
970         CmmLoad addr rep
971            -> do addr' <- cmmExprNative DataReference addr
972                  return $ CmmLoad addr' rep
973
974         CmmMachOp mop args
975            -> do args' <- mapM (cmmExprNative DataReference) args
976                  return $ CmmMachOp mop args'
977
978         CmmLit (CmmLabel lbl)
979            -> do
980                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
981         CmmLit (CmmLabelOff lbl off)
982            -> do
983                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
984                  -- need to optimize here, since it's late
985                  return $ cmmMachOpFold platform (MO_Add wordWidth) [
986                      dynRef,
987                      (CmmLit $ CmmInt (fromIntegral off) wordWidth)
988                    ]
989
990         -- On powerpc (non-PIC), it's easier to jump directly to a label than
991         -- to use the register table, so we replace these registers
992         -- with the corresponding labels:
993         CmmReg (CmmGlobal EagerBlackholeInfo)
994           | arch == ArchPPC && not opt_PIC
995           -> cmmExprNative referenceKind $
996              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
997         CmmReg (CmmGlobal GCEnter1)
998           | arch == ArchPPC && not opt_PIC
999           -> cmmExprNative referenceKind $
1000              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1"))) 
1001         CmmReg (CmmGlobal GCFun)
1002           | arch == ArchPPC && not opt_PIC
1003           -> cmmExprNative referenceKind $
1004              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
1005
1006         other
1007            -> return other
1008
1009 \end{code}
1010