Pass LLVMTarget (identical to --target)
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         if test "${OSTYPE}" = "msys"
181         then
182             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
183         else
184             # Canonicalise to <drive>:/path/to/ghc
185             WithGhc=`cygpath -m "${WithGhc}"`
186         fi
187         echo "GHC path canonicalised to: ${WithGhc}"
188     fi
189 fi
190 AC_SUBST([WithGhc])
191
192 dnl ** Without optimization some INLINE trickery fails for GHCi
193 SRC_CC_OPTS="-O"
194
195 dnl--------------------------------------------------------------------
196 dnl * Choose host(/target/build) platform
197 dnl--------------------------------------------------------------------
198 dnl If we aren't explicitly told what values to use with configure flags,
199 dnl we ask the bootstrapping compiler what platform it is for
200
201 if test "${WithGhc}" != ""
202 then
203         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
204         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
205         if test "$bootstrap_host" != "$bootstrap_target"
206         then
207                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
208         fi
209 fi
210
211 # We have to run these unconditionally, but we may discard their
212 # results in the following code
213 AC_CANONICAL_BUILD
214 AC_CANONICAL_HOST
215 AC_CANONICAL_TARGET
216
217 FPTOOLS_SET_PLATFORM_VARS
218
219 # Verify that the installed (bootstrap) GHC is capable of generating
220 # code for the requested build platform.
221 if test "$BuildPlatform" != "$bootstrap_target"
222 then
223     echo "This GHC (${WithGhc}) does not generate code for the build platform"
224     echo "   GHC target platform    : $bootstrap_target"
225     echo "   Desired build platform : $BuildPlatform"
226     exit 1
227 fi
228
229 # Testing if we shall enable shared libs support on Solaris.
230 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
231
232 SOLARIS_BROKEN_SHLD=NO
233
234 case $host in
235      i386-*-solaris2)
236      # here we go with the test
237      MINOR=`uname -r|cut -d '.' -f 2-`
238      if test "$MINOR" -lt "11"; then
239          SOLARIS_BROKEN_SHLD=YES
240      fi
241      ;;
242 esac
243
244 AC_SUBST(SOLARIS_BROKEN_SHLD)
245
246 dnl ** Do an unregisterised build?
247 dnl --------------------------------------------------------------
248 case "$TargetArch" in
249     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
250         UnregisterisedDefault=NO
251         ;;
252     *)
253         UnregisterisedDefault=YES
254         ;;
255 esac
256 AC_ARG_ENABLE(unregisterised,
257 [AC_HELP_STRING([--enable-unregisterised],
258 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
259 [ if test x"$enableval" = x"yes"; then
260         Unregisterised=YES
261   else
262         Unregisterised=NO
263   fi
264 ],
265 [Unregisterised="$UnregisterisedDefault"]
266 )
267 AC_SUBST(Unregisterised)
268
269 dnl ** Does target have runtime linker support?
270 dnl --------------------------------------------------------------
271 case "$target" in
272     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
273         HaskellHaveRTSLinker=NO
274         ;;
275     *)
276         HaskellHaveRTSLinker=YES
277         ;;
278 esac
279 AC_SUBST(HaskellHaveRTSLinker)
280
281 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
282 FP_FIND_ROOT
283
284 fail() {
285     echo >&2
286     echo "$1" >&2
287     exit 1
288 }
289
290
291 if test "$HostOS" = "mingw32"
292 then
293     # Find the mingw-w64 7z file to extract.
294     # NB. If you update the tarballs to a new version of gcc, don't
295     # forget to tweak the paths in driver/gcc/gcc.c.
296     if test "$HostArch" = "i386"
297     then
298         mingw_arch="i686"
299         tarball_dest_dir="mingw-w64/x86"
300         tarball_mingw_dir="mingw32"
301     else
302         mingw_arch="x86_64"
303         tarball_dest_dir="mingw-w64/x86_64"
304         tarball_mingw_dir="mingw64"
305     fi
306 fi
307
308 set_up_tarballs() {
309     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
310     local action
311     if test "$TarballsAutodownload" = "NO"
312     then
313         action="verify"
314     else
315         action="download"
316     fi
317     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
318     case $? in
319         0)
320            rm missing-win32-tarballs
321            ;;
322         2)
323            echo
324            echo "Error:"
325            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
326            echo
327            echo "  * run configure with the --enable-tarballs-autodownload option"
328            echo
329            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
330            echo
331            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
332            echo "    them in the ghc-tarballs directory."
333            echo
334            exit 1
335            ;;
336         *)
337            echo
338            echo "Error fetching msys2 tarballs; see errors above."
339            exit 1
340            ;;
341     esac
342
343     # Extract all the tarballs in one go
344     if ! test -d inplace/mingw
345     then
346         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
347         rm -rf inplace/mingw
348         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
349         ( cd inplace &&
350         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
351         rm ".MTREE" &&
352         rm ".PKGINFO" &&
353         cd .. ) || fail "Error: Could not extract Windows toolchains."
354
355         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
356         touch inplace/mingw
357
358         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
359         # make a wrapper around it to give it the proper paths
360         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
361         PATH=`pwd`/inplace/mingw/bin:$PATH
362         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
363
364         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
365     fi
366 }
367
368 if test "$HostOS" = "mingw32"
369 then
370     test -d inplace || mkdir inplace
371
372     # NB. Download and extract the MingW-w64 distribution if required
373     set_up_tarballs
374
375     mingwbin="$hardtop/inplace/mingw/bin/"
376     CC="${mingwbin}gcc.exe"
377     LD="${mingwbin}ld.exe"
378     NM="${mingwbin}nm.exe"
379     RANLIB="${mingwbin}ranlib.exe"
380     OBJDUMP="${mingwbin}objdump.exe"
381     fp_prog_ar="${mingwbin}ar.exe"
382
383     # NB. Download the perl binaries if required
384     if ! test -d inplace/perl ||
385          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
386     then
387         AC_MSG_NOTICE([Making in-tree perl tree])
388         rm -rf inplace/perl
389         mkdir inplace/perl
390         (
391             cd inplace/perl &&
392             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
393         )
394         AC_MSG_NOTICE([In-tree perl tree created])
395     fi
396 fi
397
398 FP_ICONV
399 FP_GMP
400 FP_CURSES
401
402 XCODE_VERSION()
403
404
405 dnl ** Building a cross compiler?
406 dnl --------------------------------------------------------------
407 CrossCompiling=NO
408 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
409 if test "$TargetPlatform" != "$HostPlatform" ; then
410     CrossCompiling=YES
411     cross_compiling=yes   # This tells configure that it can accept just 'target',
412                           # otherwise you get
413                           #   configure: error: cannot run C compiled programs.
414                           #   If you meant to cross compile, use `--host'.
415 fi
416 if test "$BuildPlatform" != "$HostPlatform" ; then
417    AC_MSG_ERROR([
418 You've selected:
419
420   BUILD:  $BuildPlatform   (the architecture we're building on)
421   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
422   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
423
424 BUILD must equal HOST; that is, we do not support building GHC itself
425 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
426 1 will be a cross-compiler, and stage 2 will be the cross-compiled
427 GHC.
428 ])
429 fi
430 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
431 # in calls to subproject configure scripts and thus must be set to the autoconf
432 # triple, not the normalized GHC triple that TargetPlatform is set to.
433 #
434 # We use the non-canonicalized triple, target_alias, here since the subproject
435 # configure scripts will use this triple to construct the names of the toolchain
436 # executables. If we instead passed down the triple produced by
437 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
438 # name (this is a known problem in the case of the Android NDK, which has
439 # slightly odd triples).
440 #
441 # It may be better to just do away with the GHC triples altogether. This would
442 # all be taken care of for us if we configured the subprojects using
443 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
444 # configuration.
445 #
446 # We also use non-canonicalized triple when install stage1 crosscompiler
447 if test -z "${target_alias}"
448 then
449   # --target wasn't given; use result from AC_CANONICAL_TARGET
450   TargetPlatformFull="${target}"
451 else
452   TargetPlatformFull="${target_alias}"
453 fi
454 if test "$CrossCompiling" = "YES"
455 then
456   # Use value passed by user from --target=
457   CrossCompilePrefix="${TargetPlatformFull}-"
458 else
459   CrossCompilePrefix=""
460 fi
461 AC_SUBST(CrossCompiling)
462 AC_SUBST(CrossCompilePrefix)
463 AC_SUBST(TargetPlatformFull)
464
465 dnl ** Which gcc to use?
466 dnl --------------------------------------------------------------
467
468 AC_ARG_WITH([gcc],
469         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
470         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
471
472 AC_ARG_WITH([clang],
473         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
474         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
475
476 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
477 dnl later CC is copied to CC_STAGE{1,2,3}
478 AC_PROG_CC([gcc clang])
479
480 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
481
482 dnl make extensions visible to allow feature-tests to detect them lateron
483 AC_USE_SYSTEM_EXTENSIONS
484
485 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
486 AC_PROG_CPP
487
488 # --with-hs-cpp/--with-hs-cpp-flags
489 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
490 AC_SUBST([HaskellCPPCmd])
491 AC_SUBST([HaskellCPPArgs])
492
493 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
494 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
495 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
496 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
497
498 dnl ** Which ld to use?
499 dnl --------------------------------------------------------------
500 FIND_LD([$target],[LdCmd])
501 AC_SUBST([LdCmd])
502
503 dnl ** Which nm to use?
504 dnl --------------------------------------------------------------
505 if test "$HostOS" != "mingw32"; then
506     AC_CHECK_TARGET_TOOL([NM], [nm])
507     if test "$NM" = ":"; then
508         AC_MSG_ERROR([cannot find nm in your PATH])
509     fi
510 fi
511 NmCmd="$NM"
512 AC_SUBST([NmCmd])
513
514 if test "$TargetOS_CPP" = "darwin"
515 then
516     AC_MSG_CHECKING(whether nm program is broken)
517     # Some versions of XCode ship a broken version of `nm`. Detect and work
518     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
519     nmver=$(${NM} --version | grep version | sed 's/ //g')
520     case "$nmver" in
521         LLVMversion7.3.0|LLVMversion7.3.1)
522             AC_MSG_RESULT(yes)
523             echo "The detected nm program is broken."
524             echo
525             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
526             echo
527             echo "Try re-running configure with:"
528             echo
529             echo '   NM=$(xcrun --find nm-classic) ./configure'
530             echo
531             exit 1
532             ;;
533         *)
534             AC_MSG_RESULT(no)
535             ;;
536         esac
537 fi
538
539 dnl ** Which objdump to use?
540 dnl --------------------------------------------------------------
541 dnl Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
542 case $HostOS_CPP in
543   cygwin32|mingw32)
544     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
545     ;;
546 esac
547
548 ObjdumpCmd="$OBJDUMP"
549 AC_SUBST([ObjdumpCmd])
550
551 dnl ** Which ar to use?
552 dnl --------------------------------------------------------------
553 if test "$HostOS" != "mingw32"; then
554     AC_CHECK_TARGET_TOOL([AR], [ar])
555     if test "$AR" = ":"; then
556         AC_MSG_ERROR([cannot find ar in your PATH])
557     fi
558 fi
559 ArCmd="$AR"
560 fp_prog_ar="$AR"
561 AC_SUBST([ArCmd])
562
563 dnl ** Which ranlib to use?
564 dnl --------------------------------------------------------------
565 AC_PROG_RANLIB
566 if test "$RANLIB" = ":"; then
567     AC_MSG_ERROR([cannot find ranlib in your PATH])
568 fi
569 RanlibCmd="$RANLIB"
570 RANLIB="$RanlibCmd"
571
572
573 # Here is where we re-target which specific version of the LLVM
574 # tools we are looking for. In the past, GHC supported a number of
575 # versions of LLVM simultaneously, but that stopped working around
576 # 3.5/3.6 release of LLVM.
577 LlvmVersion=3.9
578 AC_SUBST([LlvmVersion])
579 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
580 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
581
582 dnl ** Which LLVM llc to use?
583 dnl --------------------------------------------------------------
584 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
585 LlcCmd="$LLC"
586 AC_SUBST([LlcCmd])
587
588 dnl ** Which LLVM opt to use?
589 dnl --------------------------------------------------------------
590 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
591 OptCmd="$OPT"
592 AC_SUBST([OptCmd])
593
594 dnl --------------------------------------------------------------
595 dnl End of configure script option section
596 dnl --------------------------------------------------------------
597
598
599 dnl --------------------------------------------------------------
600 dnl ** Can the unix package be built?
601 dnl --------------------------------------------------------------
602
603 if test "$TargetOS" = "mingw32"
604 then
605     GhcLibsWithUnix=NO
606 else
607     GhcLibsWithUnix=YES
608 fi
609 AC_SUBST([GhcLibsWithUnix])
610
611 dnl ** does #! work?
612 AC_SYS_INTERPRETER()
613
614 # Check for split-objs
615 SplitObjsBroken=NO
616 dnl ** look for `perl'
617 case $HostOS_CPP in
618 cygwin32|mingw32)
619   PerlCmd=$hardtop/inplace/perl/perl
620   ;;
621 *)
622     AC_PATH_PROG([PerlCmd],[perl])
623     if test -z "$PerlCmd"
624     then
625         AC_MSG_WARN([No Perl on PATH, disabling split object support])
626         SplitObjsBroken=YES
627     else
628         FPTOOLS_CHECK_PERL_VERSION
629     fi
630     ;;
631 esac
632 AC_SUBST([SplitObjsBroken])
633
634 dnl ** look for GCC and find out which version
635 dnl     Figure out which C compiler to use.  Gcc is preferred.
636 dnl     If gcc, make sure it's at least 3.0
637 dnl
638 FP_GCC_VERSION
639
640 dnl ** See whether gcc supports -no-pie
641 FP_GCC_SUPPORTS_NO_PIE
642
643 dnl ** look to see if we have a C compiler using an llvm back end.
644 dnl
645 FP_CC_LLVM_BACKEND
646
647 FP_PROG_LD_IS_GNU
648 FP_PROG_LD_BUILD_ID
649 FP_PROG_LD_NO_COMPACT_UNWIND
650 FP_PROG_LD_FILELIST
651
652
653 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
654 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
655 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
656 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
657 # Stage 3 won't be supported by cross-compilation
658
659 FP_GCC_EXTRA_FLAGS
660
661 # See rules/distdir-way-opts.mk for details.
662 # Flags passed to the C compiler
663 AC_SUBST(CONF_CC_OPTS_STAGE0)
664 AC_SUBST(CONF_CC_OPTS_STAGE1)
665 AC_SUBST(CONF_CC_OPTS_STAGE2)
666 # Flags passed to the C compiler when we ask it to link
667 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
668 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
669 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
670 # Flags passed to the linker when we ask it to link
671 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
672 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
673 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
674 # Flags passed to the C preprocessor
675 AC_SUBST(CONF_CPP_OPTS_STAGE0)
676 AC_SUBST(CONF_CPP_OPTS_STAGE1)
677 AC_SUBST(CONF_CPP_OPTS_STAGE2)
678 # Flags passed to the Haskell compiler
679 AC_SUBST(CONF_HC_OPTS_STAGE0)
680 AC_SUBST(CONF_HC_OPTS_STAGE1)
681 AC_SUBST(CONF_HC_OPTS_STAGE2)
682
683 dnl ** Set up the variables for the platform in the settings file.
684 dnl May need to use gcc to find platform details.
685 dnl --------------------------------------------------------------
686 FPTOOLS_SET_HASKELL_PLATFORM_VARS
687
688 dnl ** figure out how to do context diffs
689 FP_PROG_CONTEXT_DIFF
690
691 dnl Let's make sure install-sh is executable here.  If we got it from
692 dnl a darcs repo, it might not be (see bug #978).
693 chmod +x install-sh
694 dnl ** figure out how to do a BSD-ish install
695 AC_PROG_INSTALL
696
697 dnl ** how to invoke `ar' and `ranlib'
698 FP_PROG_AR_SUPPORTS_ATFILE
699 FP_PROG_AR_NEEDS_RANLIB
700
701 dnl ** Check to see whether ln -s works
702 AC_PROG_LN_S
703
704 FP_SETTINGS
705
706 dnl ** Find the path to sed
707 AC_PATH_PROGS(SedCmd,gsed sed,sed)
708
709
710 dnl ** check for time command
711 AC_PATH_PROG(TimeCmd,time)
712
713 dnl ** check for tar
714 dnl   if GNU tar is named gtar, look for it first.
715 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
716
717 dnl ** check for compressors
718 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
719 AC_PATH_PROGS(GzipCmd,gzip, gzip)
720 AC_PATH_PROGS(XzCmd,pxz xz, xz)
721
722 dnl ** check for patch
723 dnl if GNU patch is named gpatch, look for it first
724 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
725
726 dnl ** check for dtrace (currently only implemented for Mac OS X)
727 HaveDtrace=NO
728 AC_PATH_PROG(DtraceCmd,dtrace)
729 if test -n "$DtraceCmd"; then
730   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
731     HaveDtrace=YES
732   fi
733 fi
734 AC_SUBST(HaveDtrace)
735
736 AC_PATH_PROG(HSCOLOUR,HsColour)
737 # HsColour is passed to Cabal, so we need a native path
738 if test "$HostOS"      = "mingw32" && \
739    test "${OSTYPE}"   != "msys"    && \
740    test "${HSCOLOUR}" != ""
741 then
742     # Canonicalise to <drive>:/path/to/gcc
743     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
744 fi
745
746 dnl ** check for Sphinx toolchain
747 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
748 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
749 changequote(, )dnl
750 [if test -n "$SPHINXBUILD"; then
751   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
752 fi;
753 changequote([, ])dnl
754 ])
755 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
756     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
757
758 dnl ** check for xelatex
759 AC_PATH_PROG(XELATEX,xelatex)
760
761 dnl ** check for ghc-pkg command
762 FP_PROG_GHC_PKG
763
764 dnl ** check for installed happy binary + version
765 FPTOOLS_HAPPY
766
767 dnl ** check for installed alex binary + version
768 FPTOOLS_ALEX
769
770 dnl --------------------------------------------------
771 dnl ### program checking section ends here ###
772 dnl --------------------------------------------------
773
774 dnl --------------------------------------------------
775 dnl * Platform header file and syscall feature tests
776 dnl ### checking the state of the local header files and syscalls ###
777
778 dnl ** check for full ANSI header (.h) files
779 AC_HEADER_STDC
780
781 dnl ** Enable large file support.  NB. do this before testing the type of
782 dnl    off_t, because it will affect the result of that test.
783 AC_SYS_LARGEFILE
784
785 dnl ** check for specific header (.h) files that we are interested in
786 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
787
788 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
789 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
790 [[#if HAVE_SYS_PARAM_H
791 # include <sys/param.h>
792 #endif
793 ]])
794
795 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
796 AC_HEADER_TIME
797
798 dnl ** do we have long longs?
799 AC_CHECK_TYPES([long long])
800
801 dnl ** what are the sizes of various types
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
803 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
804 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
805 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
806 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
807 if test "$ac_cv_type_long_long" = yes; then
808 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
809 fi
810 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
811 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
812 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
813 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
814 if test "$ac_cv_type_long_long" = yes; then
815 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
816 fi
817 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
818 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
819
820 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
821 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
822 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
823 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
824 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
825 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
826 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
827 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
828
829
830 dnl for use in settings.in
831 WordSize=$ac_cv_sizeof_void_p
832 AC_SUBST(WordSize)
833 FP_CHECK_FUNC([WinExec],
834   [@%:@include <windows.h>], [WinExec("",0)])
835
836 FP_CHECK_FUNC([GetModuleFileName],
837   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
838
839 dnl ** check for more functions
840 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
841 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
842
843 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
844 dnl ** _POSIX_C_SOURCE is defined
845 AC_CHECK_DECLS([ctime_r], , ,
846 [#define _POSIX_SOURCE 1
847 #define _POSIX_C_SOURCE 199506L
848 #include <time.h>])
849
850 dnl ** check for mingwex library
851 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
852 AC_SUBST(HaveLibMingwEx)
853
854 if test $HaveLibMingwEx = YES ; then
855   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
856 fi
857
858 dnl ** check for math library
859 dnl    Keep that check as early as possible.
860 dnl    as we need to know whether we need libm
861 dnl    for math functions or not
862 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
863 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
864 if test $HaveLibM = YES
865 then
866   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
867 fi
868
869 FP_BFD_SUPPORT
870
871 dnl ################################################################
872 dnl Check for libraries
873 dnl ################################################################
874
875 # system libffi
876
877 AC_ARG_WITH([system-libffi],
878 [AC_HELP_STRING([--with-system-libffi],
879   [Use system provided libffi for RTS [default=no]])
880 ])
881
882 AS_IF([test "x$with_system_libffi" = "xyes"],
883   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
884 )
885
886
887 AC_SUBST(UseSystemLibFFI)
888
889 AC_ARG_WITH([ffi-includes],
890 [AC_HELP_STRING([--with-ffi-includes=ARG],
891   [Find includes for libffi in ARG [default=system default]])
892 ],
893 [
894  if test "x$UseSystemLibFFI" != "xYES"; then
895     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
896  else
897     FFIIncludeDir="$withval"
898     LIBFFI_CFLAGS="-I$withval"
899  fi
900 ])
901
902 AC_SUBST(FFIIncludeDir)
903
904 AC_ARG_WITH([ffi-libraries],
905 [AC_HELP_STRING([--with-ffi-libraries=ARG],
906   [Find libffi in ARG [default=system default]])
907 ],
908 [
909  if test "x$UseSystemLibFFI" != "xYES"; then
910     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
911  else
912     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
913  fi
914 ])
915
916 AC_SUBST(FFILibDir)
917
918 AS_IF([test "$UseSystemLibFFI" = "YES"], [
919  CFLAGS2="$CFLAGS"
920  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
921  LDFLAGS2="$LDFLAGS"
922  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
923  if test "$HostOS" = "openbsd";
924  then
925    # OpenBSD's libffi is not directly linked to the libpthread but
926    # still requires pthread functionality. This means that any client
927    # binary which links with libffi also needs to link with
928    # libpthread. If it does not, then linking fails with unresolved
929    # symbols.
930    LDFLAGS="$LDFLAGS -lpthread"
931  fi
932  AC_CHECK_LIB(ffi, ffi_call,
933   [AC_CHECK_HEADERS([ffi.h], [break], [])
934    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
935   [AC_MSG_ERROR([Cannot find system libffi])])
936  CFLAGS="$CFLAGS2"
937  LDFLAGS="$LDFLAGS2"
938 ])
939
940 dnl ** check whether we need -ldl to get dlopen()
941 AC_CHECK_LIB(dl, dlopen)
942
943 dnl --------------------------------------------------
944 dnl * Miscellaneous feature tests
945 dnl --------------------------------------------------
946
947 dnl ** can we get alloca?
948 AC_FUNC_ALLOCA
949
950 dnl ** working vfork?
951 AC_FUNC_FORK
952
953 dnl ** determine whether or not const works
954 AC_C_CONST
955
956 dnl ** are we big endian?
957 AC_C_BIGENDIAN
958 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
959
960 dnl ** check for leading underscores in symbol names
961 FP_LEADING_UNDERSCORE
962
963 FP_VISIBILITY_HIDDEN
964
965 dnl ** check for librt
966 AC_CHECK_LIB(rt, clock_gettime)
967 AC_CHECK_FUNCS(clock_gettime timer_settime)
968 FP_CHECK_TIMER_CREATE
969
970 dnl ** check for Apple's "interesting" long double compatibility scheme
971 AC_MSG_CHECKING(for printf\$LDBLStub)
972 AC_TRY_LINK_FUNC(printf\$LDBLStub,
973     [
974         AC_MSG_RESULT(yes)
975         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
976             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
977     ],
978     [
979         AC_MSG_RESULT(no)
980         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
981             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
982     ])
983
984 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
985 dnl without linking against libpthread. Check whether -lpthread is necessary
986 dnl to use pthreads.
987 dnl
988 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
989 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
990 AC_CHECK_FUNC(pthread_create,
991     [
992         AC_MSG_RESULT(no)
993         need_lpthread=0
994     ],
995     [
996         AC_CHECK_LIB(pthread, pthread_create,
997             [
998                 AC_MSG_RESULT(yes)
999                 need_lpthread=1
1000             ],
1001             [
1002                 AC_MSG_RESULT([no pthreads support found.])
1003                 need_lpthread=0
1004             ])
1005     ])
1006 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1007     [Define 1 if we need to link code using pthreads with -lpthread])
1008
1009 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1010 dnl    a different single-argument version.
1011 AC_CHECK_LIB(pthread, pthread_setname_np)
1012 AC_MSG_CHECKING(for pthread_setname_np)
1013 AC_TRY_LINK(
1014 [
1015 #define _GNU_SOURCE
1016 #include <pthread.h>
1017 ],
1018 [pthread_setname_np(pthread_self(), "name");],
1019     AC_MSG_RESULT(yes)
1020     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1021       [Define to 1 if you have the glibc version of pthread_setname_np]),
1022     AC_MSG_RESULT(no)
1023 )
1024
1025 dnl ** check for eventfd which is needed by the I/O manager
1026 AC_CHECK_HEADERS([sys/eventfd.h])
1027 AC_CHECK_FUNCS([eventfd])
1028
1029 dnl ** Check for __thread support in the compiler
1030 AC_MSG_CHECKING(for __thread support)
1031 AC_COMPILE_IFELSE(
1032   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1033   [
1034    AC_MSG_RESULT(yes)
1035    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1036   ],
1037   [
1038    AC_MSG_RESULT(no)
1039    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1040   ])
1041
1042 dnl large address space support (see includes/rts/storage/MBlock.h)
1043 dnl
1044 dnl Darwin has vm_allocate/vm_protect
1045 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1046 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1047 dnl (They also have MADV_DONTNEED, but it means something else!)
1048 dnl
1049 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1050 dnl it counts page-table space as committed memory, and so quickly
1051 dnl runs out of paging file when we have multiple processes reserving
1052 dnl 1TB of address space, we get the following error:
1053 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1054 dnl
1055
1056 AC_ARG_ENABLE(large-address-space,
1057     [AC_HELP_STRING([--enable-large-address-space],
1058         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1059     EnableLargeAddressSpace=$enableval,
1060     EnableLargeAddressSpace=yes
1061 )
1062
1063 use_large_address_space=no
1064 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1065     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1066         if test "$ghc_host_os" = "darwin" ; then
1067             use_large_address_space=yes
1068         elif test "$ghc_host_os" = "openbsd" ; then
1069             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1070             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1071             # but is completely ignored by OS mmap
1072             use_large_address_space=no
1073         else
1074             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1075                 [
1076                 #include <unistd.h>
1077                 #include <sys/types.h>
1078                 #include <sys/mman.h>
1079                 #include <fcntl.h>
1080             ])
1081             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1082                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1083                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1084                     use_large_address_space=yes
1085             fi
1086         fi
1087     fi
1088 fi
1089 if test "$use_large_address_space" = "yes" ; then
1090    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1091 fi
1092
1093 dnl ** Use MMAP in the runtime linker?
1094 dnl --------------------------------------------------------------
1095
1096 case ${TargetOS} in
1097     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1098         RtsLinkerUseMmap=1
1099         ;;
1100     darwin|ios)
1101         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1102         # reallocating. Reallocating is needed to allocate jump islands just
1103         # after each object image. Jumps to these jump islands use relative
1104         # branches which are limited to offsets that can be represented in
1105         # 24-bits.
1106         if test "$TargetArch" != "powerpc" ; then
1107             RtsLinkerUseMmap=1
1108         else
1109             RtsLinkerUseMmap=0
1110         fi
1111         ;;
1112     *)
1113         # Windows (which doesn't have mmap) and everything else.
1114         RtsLinkerUseMmap=0
1115         ;;
1116     esac
1117
1118 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1119                    [Use mmap in the runtime linker])
1120
1121 dnl ** Have libdw?
1122 dnl --------------------------------------------------------------
1123 UseLibdw=NO
1124 USE_LIBDW=0
1125 AC_ARG_ENABLE(dwarf-unwind,
1126     [AC_HELP_STRING([--enable-dwarf-unwind],
1127         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1128     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1129     [UseLibdw=NO]
1130 )
1131 AC_SUBST(UseLibdw)
1132 if test $UseLibdw = "YES" ; then
1133         USE_LIBDW=1
1134 fi
1135 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1136
1137 dnl ** Have libnuma?
1138 dnl --------------------------------------------------------------
1139 HaveLibNuma=0
1140 AC_CHECK_HEADERS([numa.h numaif.h])
1141
1142 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1143     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1144 fi
1145 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1146
1147 dnl ** Documentation
1148 dnl --------------------------------------------------------------
1149 if test -n "$SPHINXBUILD"; then
1150     BUILD_MAN=YES
1151     BUILD_SPHINX_HTML=YES
1152     if test -n "$XELATEX"; then
1153         BUILD_SPHINX_PDF=YES
1154     else
1155         BUILD_SPHINX_PDF=NO
1156     fi
1157 else
1158     BUILD_MAN=NO
1159     BUILD_SPHINX_HTML=NO
1160     BUILD_SPHINX_PDF=NO
1161 fi
1162 AC_SUBST(BUILD_MAN)
1163 AC_SUBST(BUILD_SPHINX_HTML)
1164 AC_SUBST(BUILD_SPHINX_PDF)
1165
1166 LIBRARY_VERSION(base)
1167 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1168 LIBRARY_VERSION(ghc-prim)
1169 LIBRARY_VERSION(ghc-compact)
1170 LIBRARY_ghc_VERSION="$ProjectVersion"
1171 AC_SUBST(LIBRARY_ghc_VERSION)
1172
1173 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1174    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1175 fi
1176
1177 # Create the configuration for the Hadrian build system if it is present
1178 if test -e hadrian/cfg/system.config.in; then
1179     AC_CONFIG_FILES([hadrian/cfg/system.config])
1180 fi
1181
1182 # We got caught by
1183 #     http://savannah.gnu.org/bugs/index.php?1516
1184 #     $(eval ...) inside conditionals causes errors
1185 # with make 3.80, so warn the user if it looks like they're about to
1186 # try to use it.
1187 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1188 print_make_warning=""
1189 checkMake380() {
1190     make_ver=`$1 --version 2>&1 | head -1`
1191     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1192     then
1193         print_make_warning="true"
1194     fi
1195     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1196     then
1197         MakeCmd=$1
1198         AC_SUBST(MakeCmd)
1199     fi
1200 }
1201
1202 checkMake380 make
1203 checkMake380 gmake
1204
1205 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1206 AC_OUTPUT
1207 [
1208 if test "$print_make_warning" = "true"; then
1209    echo
1210    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1211    echo "This version cannot be used to build GHC."
1212    echo "Please use GNU make >= 3.81."
1213 fi
1214
1215 echo "
1216 ----------------------------------------------------------------------
1217 Configure completed successfully.
1218
1219    Building GHC version  : $ProjectVersion
1220           Git commit id  : $ProjectGitCommitId
1221
1222    Build platform        : $BuildPlatform
1223    Host platform         : $HostPlatform
1224    Target platform       : $TargetPlatform
1225 "
1226
1227 echo "\
1228    Bootstrapping using   : $WithGhc
1229       which is version   : $GhcVersion
1230 "
1231
1232 if test "x$CC_LLVM_BACKEND" = "x1"; then
1233     if test "x$CC_CLANG_BACKEND" = "x1"; then
1234         CompilerName="clang        "
1235     else
1236         CompilerName="llvm-gcc     "
1237     fi
1238 else
1239     CompilerName="gcc          "
1240 fi
1241
1242 echo "\
1243    Using (for bootstrapping) : $CC_STAGE0
1244    Using $CompilerName       : $CC
1245       which is version       : $GccVersion
1246    Building a cross compiler : $CrossCompiling
1247    Unregisterised            : $Unregisterised
1248    hs-cpp       : $HaskellCPPCmd
1249    hs-cpp-flags : $HaskellCPPArgs
1250    ar           : $ArCmd
1251    ld           : $LdCmd
1252    nm           : $NmCmd
1253    objdump      : $ObjdumpCmd
1254    ranlib       : $RanlibCmd
1255    windres      : $Windres
1256    dllwrap      : $DllWrap
1257    Happy        : $HappyCmd ($HappyVersion)
1258    Alex         : $AlexCmd ($AlexVersion)
1259    Perl         : $PerlCmd
1260    sphinx-build : $SPHINXBUILD
1261    xelatex      : $XELATEX
1262
1263    Using LLVM tools
1264       llc   : $LlcCmd
1265       opt   : $OptCmd"
1266
1267 if test "$HSCOLOUR" = ""; then
1268 echo "
1269    HsColour was not found; documentation will not contain source links
1270 "
1271 else
1272 echo "\
1273    HsColour : $HSCOLOUR
1274 "
1275 fi
1276
1277 echo "\
1278    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1279    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1280
1281 echo "----------------------------------------------------------------------
1282 "
1283
1284 echo "\
1285 For a standard build of GHC (fully optimised with profiling), type (g)make.
1286
1287 To make changes to the default build configuration, copy the file
1288 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1289
1290 For more information on how to configure your GHC build, see
1291    http://ghc.haskell.org/trac/ghc/wiki/Building
1292 "]