Merge branch 'master' of darcs.haskell.org:/srv/darcs//ghc
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 --
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 module AsmCodeGen ( nativeCodeGen ) where
11
12 #include "HsVersions.h"
13 #include "nativeGen/NCG.h"
14
15
16 import qualified X86.CodeGen
17 import qualified X86.Regs
18 import qualified X86.Instr
19 import qualified X86.Ppr
20
21 import qualified SPARC.CodeGen
22 import qualified SPARC.Regs
23 import qualified SPARC.Instr
24 import qualified SPARC.Ppr
25 import qualified SPARC.ShortcutJump
26 import qualified SPARC.CodeGen.Expand
27
28 import qualified PPC.CodeGen
29 import qualified PPC.Cond
30 import qualified PPC.Regs
31 import qualified PPC.RegInfo
32 import qualified PPC.Instr
33 import qualified PPC.Ppr
34
35 import RegAlloc.Liveness
36 import qualified RegAlloc.Linear.Main           as Linear
37
38 import qualified GraphColor                     as Color
39 import qualified RegAlloc.Graph.Main            as Color
40 import qualified RegAlloc.Graph.Stats           as Color
41 import qualified RegAlloc.Graph.TrivColorable   as Color
42
43 import TargetReg
44 import Platform
45 import Config
46 import Instruction
47 import PIC
48 import Reg
49 import NCGMonad
50
51 import BlockId
52 import CgUtils          ( fixStgRegisters )
53 import OldCmm
54 import CmmOpt           ( cmmEliminateDeadBlocks, cmmMiniInline, cmmMachOpFold )
55 import OldPprCmm
56 import CLabel
57
58 import UniqFM
59 import Unique           ( Unique, getUnique )
60 import UniqSupply
61 import DynFlags
62 import StaticFlags
63 import Util
64
65 import BasicTypes       ( Alignment )
66 import Digraph
67 import qualified Pretty
68 import BufWrite
69 import Outputable
70 import FastString
71 import UniqSet
72 import ErrUtils
73 import Module
74
75 -- DEBUGGING ONLY
76 --import OrdList
77
78 import Data.List
79 import Data.Maybe
80 import Control.Monad
81 import System.IO
82
83 {-
84 The native-code generator has machine-independent and
85 machine-dependent modules.
86
87 This module ("AsmCodeGen") is the top-level machine-independent
88 module.  Before entering machine-dependent land, we do some
89 machine-independent optimisations (defined below) on the
90 'CmmStmts's.
91
92 We convert to the machine-specific 'Instr' datatype with
93 'cmmCodeGen', assuming an infinite supply of registers.  We then use
94 a machine-independent register allocator ('regAlloc') to rejoin
95 reality.  Obviously, 'regAlloc' has machine-specific helper
96 functions (see about "RegAllocInfo" below).
97
98 Finally, we order the basic blocks of the function so as to minimise
99 the number of jumps between blocks, by utilising fallthrough wherever
100 possible.
101
102 The machine-dependent bits break down as follows:
103
104   * ["MachRegs"]  Everything about the target platform's machine
105     registers (and immediate operands, and addresses, which tend to
106     intermingle/interact with registers).
107
108   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
109     have a module of its own), plus a miscellany of other things
110     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
111
112   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
113     machine instructions.
114
115   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
116     a 'SDoc').
117
118   * ["RegAllocInfo"] In the register allocator, we manipulate
119     'MRegsState's, which are 'BitSet's, one bit per machine register.
120     When we want to say something about a specific machine register
121     (e.g., ``it gets clobbered by this instruction''), we set/unset
122     its bit.  Obviously, we do this 'BitSet' thing for efficiency
123     reasons.
124
125     The 'RegAllocInfo' module collects together the machine-specific
126     info needed to do register allocation.
127
128    * ["RegisterAlloc"] The (machine-independent) register allocator.
129 -}
130
131 -- -----------------------------------------------------------------------------
132 -- Top-level of the native codegen
133
134 data NcgImpl statics instr jumpDest = NcgImpl {
135     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
136     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
137     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
138     canShortcut               :: instr -> Maybe jumpDest,
139     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
140     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
141     pprNatCmmDecl              :: Platform -> NatCmmDecl statics instr -> SDoc,
142     maxSpillSlots             :: Int,
143     allocatableRegs           :: [RealReg],
144     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
145     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
146     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
147     }
148
149 --------------------
150 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
151 nativeCodeGen dflags h us cmms
152  = let platform = targetPlatform dflags
153        nCG' :: (Outputable statics, Outputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
154        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
155        x86NcgImpl = NcgImpl {
156                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
157                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr
158                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
159                         ,canShortcut               = X86.Instr.canShortcut
160                         ,shortcutStatics           = X86.Instr.shortcutStatics
161                         ,shortcutJump              = X86.Instr.shortcutJump
162                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
163                         ,maxSpillSlots             = X86.Instr.maxSpillSlots (target32Bit platform)
164                         ,allocatableRegs           = X86.Regs.allocatableRegs
165                         ,ncg_x86fp_kludge          = id
166                         ,ncgExpandTop              = id
167                         ,ncgMakeFarBranches        = id
168                     }
169    in case platformArch platform of
170                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
171                  ArchX86_64 -> nCG' x86NcgImpl
172                  ArchPPC ->
173                      nCG' $ NcgImpl {
174                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
175                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr
176                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
177                          ,canShortcut               = PPC.RegInfo.canShortcut
178                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
179                          ,shortcutJump              = PPC.RegInfo.shortcutJump
180                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
181                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots
182                          ,allocatableRegs           = PPC.Regs.allocatableRegs
183                          ,ncg_x86fp_kludge          = id
184                          ,ncgExpandTop              = id
185                          ,ncgMakeFarBranches        = makeFarBranches
186                      }
187                  ArchSPARC ->
188                      nCG' $ NcgImpl {
189                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
190                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr
191                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
192                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
193                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
194                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
195                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
196                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots
197                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
198                          ,ncg_x86fp_kludge          = id
199                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
200                          ,ncgMakeFarBranches        = id
201                      }
202                  ArchARM _ _ _ ->
203                      panic "nativeCodeGen: No NCG for ARM"
204                  ArchPPC_64 ->
205                      panic "nativeCodeGen: No NCG for PPC 64"
206                  ArchUnknown ->
207                      panic "nativeCodeGen: No NCG for unknown arch"
208
209 nativeCodeGen' :: (Outputable statics, Outputable instr, Instruction instr)
210                => DynFlags
211                -> NcgImpl statics instr jumpDest
212                -> Handle -> UniqSupply -> [RawCmmGroup] -> IO ()
213 nativeCodeGen' dflags ncgImpl h us cmms
214  = do
215         let platform = targetPlatform dflags
216             split_cmms  = concat $ map add_split cmms
217         -- BufHandle is a performance hack.  We could hide it inside
218         -- Pretty if it weren't for the fact that we do lots of little
219         -- printDocs here (in order to do codegen in constant space).
220         bufh <- newBufHandle h
221         (imports, prof) <- cmmNativeGens dflags ncgImpl bufh us split_cmms [] [] 0
222         bFlush bufh
223
224         let (native, colorStats, linearStats)
225                 = unzip3 prof
226
227         -- dump native code
228         dumpIfSet_dyn dflags
229                 Opt_D_dump_asm "Asm code"
230                 (vcat $ map (pprNatCmmDecl ncgImpl platform) $ concat native)
231
232         -- dump global NCG stats for graph coloring allocator
233         (case concat $ catMaybes colorStats of
234           []    -> return ()
235           stats -> do
236                 -- build the global register conflict graph
237                 let graphGlobal
238                         = foldl Color.union Color.initGraph
239                         $ [ Color.raGraph stat
240                                 | stat@Color.RegAllocStatsStart{} <- stats]
241
242                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
243                         $ Color.pprStats stats graphGlobal
244
245                 dumpIfSet_dyn dflags
246                         Opt_D_dump_asm_conflicts "Register conflict graph"
247                         $ Color.dotGraph
248                                 (targetRegDotColor platform)
249                                 (Color.trivColorable platform
250                                         (targetVirtualRegSqueeze platform)
251                                         (targetRealRegSqueeze platform))
252                         $ graphGlobal)
253
254
255         -- dump global NCG stats for linear allocator
256         (case concat $ catMaybes linearStats of
257                 []      -> return ()
258                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
259                                 $ Linear.pprStats (concat native) stats)
260
261         -- write out the imports
262         Pretty.printDoc Pretty.LeftMode h
263                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
264                 $ makeImportsDoc dflags (concat imports)
265
266         return  ()
267
268  where  add_split tops
269                 | dopt Opt_SplitObjs dflags = split_marker : tops
270                 | otherwise                 = tops
271
272         split_marker = CmmProc Nothing mkSplitMarkerLabel (ListGraph [])
273
274
275 -- | Do native code generation on all these cmms.
276 --
277 cmmNativeGens :: (Outputable statics, Outputable instr, Instruction instr)
278               => DynFlags
279               -> NcgImpl statics instr jumpDest
280               -> BufHandle
281               -> UniqSupply
282               -> [RawCmmDecl]
283               -> [[CLabel]]
284               -> [ ([NatCmmDecl statics instr],
285                    Maybe [Color.RegAllocStats statics instr],
286                    Maybe [Linear.RegAllocStats]) ]
287               -> Int
288               -> IO ( [[CLabel]],
289                       [([NatCmmDecl statics instr],
290                       Maybe [Color.RegAllocStats statics instr],
291                       Maybe [Linear.RegAllocStats])] )
292
293 cmmNativeGens _ _ _ _ [] impAcc profAcc _
294         = return (reverse impAcc, reverse profAcc)
295
296 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
297  = do
298         let platform = targetPlatform dflags
299
300         (us', native, imports, colorStats, linearStats)
301                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
302
303         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
304                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
305                 $ vcat $ map (pprNatCmmDecl ncgImpl platform) native
306
307            -- carefully evaluate this strictly.  Binding it with 'let'
308            -- and then using 'seq' doesn't work, because the let
309            -- apparently gets inlined first.
310         lsPprNative <- return $!
311                 if  dopt Opt_D_dump_asm       dflags
312                  || dopt Opt_D_dump_asm_stats dflags
313                         then native
314                         else []
315
316         count' <- return $! count + 1;
317
318         -- force evaulation all this stuff to avoid space leaks
319         {-# SCC "seqString" #-} seqString (showSDoc dflags $ vcat $ map ppr imports) `seq` return ()
320
321         cmmNativeGens dflags ncgImpl
322             h us' cmms
323                         (imports : impAcc)
324                         ((lsPprNative, colorStats, linearStats) : profAcc)
325                         count'
326
327  where  seqString []            = ()
328         seqString (x:xs)        = x `seq` seqString xs `seq` ()
329
330
331 -- | Complete native code generation phase for a single top-level chunk of Cmm.
332 --      Dumping the output of each stage along the way.
333 --      Global conflict graph and NGC stats
334 cmmNativeGen
335         :: (Outputable statics, Outputable instr, Instruction instr)
336     => DynFlags
337     -> NcgImpl statics instr jumpDest
338         -> UniqSupply
339         -> RawCmmDecl                                   -- ^ the cmm to generate code for
340         -> Int                                          -- ^ sequence number of this top thing
341         -> IO   ( UniqSupply
342                 , [NatCmmDecl statics instr]                -- native code
343                 , [CLabel]                                  -- things imported by this cmm
344                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
345                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
346
347 cmmNativeGen dflags ncgImpl us cmm count
348  = do
349         let platform = targetPlatform dflags
350
351         -- rewrite assignments to global regs
352         let fixed_cmm =
353                 {-# SCC "fixStgRegisters" #-}
354                 fixStgRegisters cmm
355
356         -- cmm to cmm optimisations
357         let (opt_cmm, imports) =
358                 {-# SCC "cmmToCmm" #-}
359                 cmmToCmm dflags fixed_cmm
360
361         dumpIfSet_dyn dflags
362                 Opt_D_dump_opt_cmm "Optimised Cmm"
363                 (pprCmmGroup platform [opt_cmm])
364
365         -- generate native code from cmm
366         let ((native, lastMinuteImports), usGen) =
367                 {-# SCC "genMachCode" #-}
368                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
369
370         dumpIfSet_dyn dflags
371                 Opt_D_dump_asm_native "Native code"
372                 (vcat $ map (pprNatCmmDecl ncgImpl platform) native)
373
374         -- tag instructions with register liveness information
375         let (withLiveness, usLive) =
376                 {-# SCC "regLiveness" #-}
377                 initUs usGen
378                         $ mapM regLiveness
379                         $ map natCmmTopToLive native
380
381         dumpIfSet_dyn dflags
382                 Opt_D_dump_asm_liveness "Liveness annotations added"
383                 (vcat $ map ppr withLiveness)
384
385         -- allocate registers
386         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
387          if ( dopt Opt_RegsGraph dflags
388            || dopt Opt_RegsIterative dflags)
389           then do
390                 -- the regs usable for allocation
391                 let (alloc_regs :: UniqFM (UniqSet RealReg))
392                         = foldr (\r -> plusUFM_C unionUniqSets
393                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
394                                 emptyUFM
395                         $ allocatableRegs ncgImpl
396
397                 -- do the graph coloring register allocation
398                 let ((alloced, regAllocStats), usAlloc)
399                         = {-# SCC "RegAlloc" #-}
400                           initUs usLive
401                           $ Color.regAlloc
402                                 dflags
403                                 alloc_regs
404                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
405                                 withLiveness
406
407                 -- dump out what happened during register allocation
408                 dumpIfSet_dyn dflags
409                         Opt_D_dump_asm_regalloc "Registers allocated"
410                         (vcat $ map (pprNatCmmDecl ncgImpl platform) alloced)
411
412                 dumpIfSet_dyn dflags
413                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
414                         (vcat   $ map (\(stage, stats)
415                                         -> text "# --------------------------"
416                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
417                                         $$ ppr stats)
418                                 $ zip [0..] regAllocStats)
419
420                 let mPprStats =
421                         if dopt Opt_D_dump_asm_stats dflags
422                          then Just regAllocStats else Nothing
423
424                 -- force evaluation of the Maybe to avoid space leak
425                 mPprStats `seq` return ()
426
427                 return  ( alloced, usAlloc
428                         , mPprStats
429                         , Nothing)
430
431           else do
432                 -- do linear register allocation
433                 let ((alloced, regAllocStats), usAlloc)
434                         = {-# SCC "RegAlloc" #-}
435                           initUs usLive
436                           $ liftM unzip
437                           $ mapM (Linear.regAlloc dflags) withLiveness
438
439                 dumpIfSet_dyn dflags
440                         Opt_D_dump_asm_regalloc "Registers allocated"
441                         (vcat $ map (pprNatCmmDecl ncgImpl platform) alloced)
442
443                 let mPprStats =
444                         if dopt Opt_D_dump_asm_stats dflags
445                          then Just (catMaybes regAllocStats) else Nothing
446
447                 -- force evaluation of the Maybe to avoid space leak
448                 mPprStats `seq` return ()
449
450                 return  ( alloced, usAlloc
451                         , Nothing
452                         , mPprStats)
453
454         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
455         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
456         ---- is clear, and library functions can return odd results if it
457         ---- isn't.
458         ----
459         ---- NB. must happen before shortcutBranches, because that
460         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
461         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
462
463         ---- generate jump tables
464         let tabled      =
465                 {-# SCC "generateJumpTables" #-}
466                 generateJumpTables ncgImpl kludged
467
468         ---- shortcut branches
469         let shorted     =
470                 {-# SCC "shortcutBranches" #-}
471                 shortcutBranches dflags ncgImpl tabled
472
473         ---- sequence blocks
474         let sequenced   =
475                 {-# SCC "sequenceBlocks" #-}
476                 map (sequenceTop ncgImpl) shorted
477
478         ---- expansion of SPARC synthetic instrs
479         let expanded =
480                 {-# SCC "sparc_expand" #-}
481                 ncgExpandTop ncgImpl sequenced
482
483         dumpIfSet_dyn dflags
484                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
485                 (vcat $ map (pprNatCmmDecl ncgImpl platform) expanded)
486
487         return  ( usAlloc
488                 , expanded
489                 , lastMinuteImports ++ imports
490                 , ppr_raStatsColor
491                 , ppr_raStatsLinear)
492
493
494 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
495 x86fp_kludge top@(CmmData _ _) = top
496 x86fp_kludge (CmmProc info lbl (ListGraph code)) =
497         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
498
499
500 -- | Build a doc for all the imports.
501 --
502 makeImportsDoc :: DynFlags -> [CLabel] -> SDoc
503 makeImportsDoc dflags imports
504  = dyld_stubs imports
505             $$
506             -- On recent versions of Darwin, the linker supports
507             -- dead-stripping of code and data on a per-symbol basis.
508             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
509             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
510              then text ".subsections_via_symbols"
511              else empty)
512             $$
513                 -- On recent GNU ELF systems one can mark an object file
514                 -- as not requiring an executable stack. If all objects
515                 -- linked into a program have this note then the program
516                 -- will not use an executable stack, which is good for
517                 -- security. GHC generated code does not need an executable
518                 -- stack so add the note in:
519             (if platformHasGnuNonexecStack (targetPlatform dflags)
520              then text ".section .note.GNU-stack,\"\",@progbits"
521              else empty)
522             $$
523                 -- And just because every other compiler does, lets stick in
524                 -- an identifier directive: .ident "GHC x.y.z"
525             (if platformHasIdentDirective (targetPlatform dflags)
526              then let compilerIdent = text "GHC" <+> text cProjectVersion
527                    in text ".ident" <+> doubleQuotes compilerIdent
528              else empty)
529
530  where
531         -- Generate "symbol stubs" for all external symbols that might
532         -- come from a dynamic library.
533         dyld_stubs :: [CLabel] -> SDoc
534 {-      dyld_stubs imps = vcat $ map pprDyldSymbolStub $
535                                     map head $ group $ sort imps-}
536
537         platform = targetPlatform dflags
538         arch = platformArch platform
539         os   = platformOS   platform
540
541         -- (Hack) sometimes two Labels pretty-print the same, but have
542         -- different uniques; so we compare their text versions...
543         dyld_stubs imps
544                 | needImportedSymbols arch os
545                 = vcat $
546                         (pprGotDeclaration arch os :) $
547                         map ( pprImportedSymbol platform . fst . head) $
548                         groupBy (\(_,a) (_,b) -> a == b) $
549                         sortBy (\(_,a) (_,b) -> compare a b) $
550                         map doPpr $
551                         imps
552                 | otherwise
553                 = empty
554
555         doPpr lbl = (lbl, renderWithStyle dflags (pprCLabel platform lbl) astyle)
556         astyle = mkCodeStyle AsmStyle
557
558
559 -- -----------------------------------------------------------------------------
560 -- Sequencing the basic blocks
561
562 -- Cmm BasicBlocks are self-contained entities: they always end in a
563 -- jump, either non-local or to another basic block in the same proc.
564 -- In this phase, we attempt to place the basic blocks in a sequence
565 -- such that as many of the local jumps as possible turn into
566 -- fallthroughs.
567
568 sequenceTop
569         :: Instruction instr
570     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
571
572 sequenceTop _       top@(CmmData _ _) = top
573 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) =
574   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks blocks)
575
576 -- The algorithm is very simple (and stupid): we make a graph out of
577 -- the blocks where there is an edge from one block to another iff the
578 -- first block ends by jumping to the second.  Then we topologically
579 -- sort this graph.  Then traverse the list: for each block, we first
580 -- output the block, then if it has an out edge, we move the
581 -- destination of the out edge to the front of the list, and continue.
582
583 -- FYI, the classic layout for basic blocks uses postorder DFS; this
584 -- algorithm is implemented in Hoopl.
585
586 sequenceBlocks
587         :: Instruction instr
588         => [NatBasicBlock instr]
589         -> [NatBasicBlock instr]
590
591 sequenceBlocks [] = []
592 sequenceBlocks (entry:blocks) =
593   seqBlocks (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
594   -- the first block is the entry point ==> it must remain at the start.
595
596
597 sccBlocks
598         :: Instruction instr
599         => [NatBasicBlock instr]
600         -> [SCC ( NatBasicBlock instr
601                 , Unique
602                 , [Unique])]
603
604 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
605
606 -- we're only interested in the last instruction of
607 -- the block, and only if it has a single destination.
608 getOutEdges
609         :: Instruction instr
610         => [instr] -> [Unique]
611
612 getOutEdges instrs
613         = case jumpDestsOfInstr (last instrs) of
614                 [one] -> [getUnique one]
615                 _many -> []
616
617 mkNode :: (Instruction t)
618        => GenBasicBlock t
619        -> (GenBasicBlock t, Unique, [Unique])
620 mkNode block@(BasicBlock id instrs) = (block, getUnique id, getOutEdges instrs)
621
622 seqBlocks :: (Eq t) => [(GenBasicBlock t1, t, [t])] -> [GenBasicBlock t1]
623 seqBlocks [] = []
624 seqBlocks ((block,_,[]) : rest)
625   = block : seqBlocks rest
626 seqBlocks ((block@(BasicBlock id instrs),_,[next]) : rest)
627   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks rest'
628   | otherwise       = block : seqBlocks rest'
629   where
630         (can_fallthrough, rest') = reorder next [] rest
631           -- TODO: we should do a better job for cycles; try to maximise the
632           -- fallthroughs within a loop.
633 seqBlocks _ = panic "AsmCodegen:seqBlocks"
634
635 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
636 reorder  _ accum [] = (False, reverse accum)
637 reorder id accum (b@(block,id',out) : rest)
638   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
639   | otherwise  = reorder id (b:accum) rest
640
641
642 -- -----------------------------------------------------------------------------
643 -- Making far branches
644
645 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
646 -- big, we have to work around this limitation.
647
648 makeFarBranches
649         :: [NatBasicBlock PPC.Instr.Instr]
650         -> [NatBasicBlock PPC.Instr.Instr]
651 makeFarBranches blocks
652     | last blockAddresses < nearLimit = blocks
653     | otherwise = zipWith handleBlock blockAddresses blocks
654     where
655         blockAddresses = scanl (+) 0 $ map blockLen blocks
656         blockLen (BasicBlock _ instrs) = length instrs
657
658         handleBlock addr (BasicBlock id instrs)
659                 = BasicBlock id (zipWith makeFar [addr..] instrs)
660
661         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
662         makeFar addr (PPC.Instr.BCC cond tgt)
663             | abs (addr - targetAddr) >= nearLimit
664             = PPC.Instr.BCCFAR cond tgt
665             | otherwise
666             = PPC.Instr.BCC cond tgt
667             where Just targetAddr = lookupUFM blockAddressMap tgt
668         makeFar _ other            = other
669
670         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
671                          -- distance, as we have a few pseudo-insns that are
672                          -- pretty-printed as multiple instructions,
673                          -- and it's just not worth the effort to calculate
674                          -- things exactly
675
676         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
677
678 -- -----------------------------------------------------------------------------
679 -- Generate jump tables
680
681 -- Analyzes all native code and generates data sections for all jump
682 -- table instructions.
683 generateJumpTables
684         :: NcgImpl statics instr jumpDest
685     -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
686 generateJumpTables ncgImpl xs = concatMap f xs
687     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
688           f p = [p]
689           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
690
691 -- -----------------------------------------------------------------------------
692 -- Shortcut branches
693
694 shortcutBranches
695         :: DynFlags
696     -> NcgImpl statics instr jumpDest
697         -> [NatCmmDecl statics instr]
698         -> [NatCmmDecl statics instr]
699
700 shortcutBranches dflags ncgImpl tops
701   | optLevel dflags < 1 = tops    -- only with -O or higher
702   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
703   where
704     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
705     mapping = foldr plusUFM emptyUFM mappings
706
707 build_mapping :: NcgImpl statics instr jumpDest
708               -> GenCmmDecl d t (ListGraph instr)
709               -> (GenCmmDecl d t (ListGraph instr), UniqFM jumpDest)
710 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
711 build_mapping _ (CmmProc info lbl (ListGraph []))
712   = (CmmProc info lbl (ListGraph []), emptyUFM)
713 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
714   = (CmmProc info lbl (ListGraph (head:others)), mapping)
715         -- drop the shorted blocks, but don't ever drop the first one,
716         -- because it is pointed to by a global label.
717   where
718     -- find all the blocks that just consist of a jump that can be
719     -- shorted.
720     -- Don't completely eliminate loops here -- that can leave a dangling jump!
721     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
722     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
723         | Just jd <- canShortcut ncgImpl insn,
724           Just dest <- getJumpDestBlockId ncgImpl jd,
725           (setMember dest s) || dest == id -- loop checks
726         = (s, shortcut_blocks, b : others)
727     split (s, shortcut_blocks, others) (BasicBlock id [insn])
728         | Just dest <- canShortcut ncgImpl insn
729         = (setInsert id s, (id,dest) : shortcut_blocks, others)
730     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
731
732
733     -- build a mapping from BlockId to JumpDest for shorting branches
734     mapping = foldl add emptyUFM shortcut_blocks
735     add ufm (id,dest) = addToUFM ufm id dest
736
737 apply_mapping :: NcgImpl statics instr jumpDest
738               -> UniqFM jumpDest
739               -> GenCmmDecl statics h (ListGraph instr)
740               -> GenCmmDecl statics h (ListGraph instr)
741 apply_mapping ncgImpl ufm (CmmData sec statics)
742   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
743 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
744   = CmmProc info lbl (ListGraph $ map short_bb blocks)
745   where
746     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
747     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
748                  -- shortcutJump should apply the mapping repeatedly,
749                  -- just in case we can short multiple branches.
750
751 -- -----------------------------------------------------------------------------
752 -- Instruction selection
753
754 -- Native code instruction selection for a chunk of stix code.  For
755 -- this part of the computation, we switch from the UniqSM monad to
756 -- the NatM monad.  The latter carries not only a Unique, but also an
757 -- Int denoting the current C stack pointer offset in the generated
758 -- code; this is needed for creating correct spill offsets on
759 -- architectures which don't offer, or for which it would be
760 -- prohibitively expensive to employ, a frame pointer register.  Viz,
761 -- x86.
762
763 -- The offset is measured in bytes, and indicates the difference
764 -- between the current (simulated) C stack-ptr and the value it was at
765 -- the beginning of the block.  For stacks which grow down, this value
766 -- should be either zero or negative.
767
768 -- Switching between the two monads whilst carrying along the same
769 -- Unique supply breaks abstraction.  Is that bad?
770
771 genMachCode
772         :: DynFlags
773         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
774         -> RawCmmDecl
775         -> UniqSM
776                 ( [NatCmmDecl statics instr]
777                 , [CLabel])
778
779 genMachCode dflags cmmTopCodeGen cmm_top
780   = do  { initial_us <- getUs
781         ; let initial_st           = mkNatM_State initial_us 0 dflags
782               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
783               final_delta          = natm_delta final_st
784               final_imports        = natm_imports final_st
785         ; if   final_delta == 0
786           then return (new_tops, final_imports)
787           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
788     }
789
790 -- -----------------------------------------------------------------------------
791 -- Generic Cmm optimiser
792
793 {-
794 Here we do:
795
796   (a) Constant folding
797   (b) Simple inlining: a temporary which is assigned to and then
798       used, once, can be shorted.
799   (c) Position independent code and dynamic linking
800         (i)  introduce the appropriate indirections
801              and position independent refs
802         (ii) compile a list of imported symbols
803   (d) Some arch-specific optimizations
804
805 (a) and (b) will be moving to the new Hoopl pipeline, however, (c) and
806 (d) are only needed by the native backend and will continue to live
807 here.
808
809 Ideas for other things we could do (put these in Hoopl please!):
810
811   - shortcut jumps-to-jumps
812   - simple CSE: if an expr is assigned to a temp, then replace later occs of
813     that expr with the temp, until the expr is no longer valid (can push through
814     temp assignments, and certain assigns to mem...)
815 -}
816
817 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
818 cmmToCmm _ top@(CmmData _ _) = (top, [])
819 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
820   blocks' <- mapM cmmBlockConFold (cmmMiniInline dflags (cmmEliminateDeadBlocks blocks))
821   return $ CmmProc info lbl (ListGraph blocks')
822
823 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
824
825 instance Monad CmmOptM where
826   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
827   (CmmOptM f) >>= g =
828     CmmOptM $ \(imports, dflags) ->
829                 case f (imports, dflags) of
830                   (# x, imports' #) ->
831                     case g x of
832                       CmmOptM g' -> g' (imports', dflags)
833
834 addImportCmmOpt :: CLabel -> CmmOptM ()
835 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
836
837 instance HasDynFlags CmmOptM where
838     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
839
840 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
841 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
842                         (# result, imports #) -> (result, imports)
843
844 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
845 cmmBlockConFold (BasicBlock id stmts) = do
846   stmts' <- mapM cmmStmtConFold stmts
847   return $ BasicBlock id stmts'
848
849 -- This does three optimizations, but they're very quick to check, so we don't
850 -- bother turning them off even when the Hoopl code is active.  Since
851 -- this is on the old Cmm representation, we can't reuse the code either:
852 --  * reg = reg      --> nop
853 --  * if 0 then jump --> nop
854 --  * if 1 then jump --> jump
855 -- We might be tempted to skip this step entirely of not opt_PIC, but
856 -- there is some PowerPC code for the non-PIC case, which would also
857 -- have to be separated.
858 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
859 cmmStmtConFold stmt
860    = case stmt of
861         CmmAssign reg src
862            -> do src' <- cmmExprConFold DataReference src
863                  return $ case src' of
864                    CmmReg reg' | reg == reg' -> CmmNop
865                    new_src -> CmmAssign reg new_src
866
867         CmmStore addr src
868            -> do addr' <- cmmExprConFold DataReference addr
869                  src'  <- cmmExprConFold DataReference src
870                  return $ CmmStore addr' src'
871
872         CmmJump addr live
873            -> do addr' <- cmmExprConFold JumpReference addr
874                  return $ CmmJump addr' live
875
876         CmmCall target regs args returns
877            -> do target' <- case target of
878                               CmmCallee e conv -> do
879                                 e' <- cmmExprConFold CallReference e
880                                 return $ CmmCallee e' conv
881                               op@(CmmPrim _ Nothing) ->
882                                 return op
883                               CmmPrim op (Just stmts) ->
884                                 do stmts' <- mapM cmmStmtConFold stmts
885                                    return $ CmmPrim op (Just stmts')
886                  args' <- mapM (\(CmmHinted arg hint) -> do
887                                   arg' <- cmmExprConFold DataReference arg
888                                   return (CmmHinted arg' hint)) args
889                  return $ CmmCall target' regs args' returns
890
891         CmmCondBranch test dest
892            -> do test' <- cmmExprConFold DataReference test
893                  dflags <- getDynFlags
894                  let platform = targetPlatform dflags
895                  return $ case test' of
896                    CmmLit (CmmInt 0 _) ->
897                      CmmComment (mkFastString ("deleted: " ++
898                                         showSDoc dflags (pprStmt platform stmt)))
899
900                    CmmLit (CmmInt _ _) -> CmmBranch dest
901                    _other -> CmmCondBranch test' dest
902
903         CmmSwitch expr ids
904            -> do expr' <- cmmExprConFold DataReference expr
905                  return $ CmmSwitch expr' ids
906
907         other
908            -> return other
909
910 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
911 cmmExprConFold referenceKind expr = do
912     dflags <- getDynFlags
913     -- Skip constant folding if new code generator is running
914     -- (this optimization is done in Hoopl)
915     let expr' = if dopt Opt_TryNewCodeGen dflags
916                     then expr
917                     else cmmExprCon (targetPlatform dflags) expr
918     cmmExprNative referenceKind expr'
919
920 cmmExprCon :: Platform -> CmmExpr -> CmmExpr
921 cmmExprCon platform (CmmLoad addr rep) = CmmLoad (cmmExprCon platform addr) rep
922 cmmExprCon platform (CmmMachOp mop args)
923     = cmmMachOpFold platform mop (map (cmmExprCon platform) args)
924 cmmExprCon _ other = other
925
926 -- handles both PIC and non-PIC cases... a very strange mixture
927 -- of things to do.
928 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
929 cmmExprNative referenceKind expr = do
930      dflags <- getDynFlags
931      let platform = targetPlatform dflags
932          arch = platformArch platform
933      case expr of
934         CmmLoad addr rep
935            -> do addr' <- cmmExprNative DataReference addr
936                  return $ CmmLoad addr' rep
937
938         CmmMachOp mop args
939            -> do args' <- mapM (cmmExprNative DataReference) args
940                  return $ CmmMachOp mop args'
941
942         CmmLit (CmmLabel lbl)
943            -> do
944                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
945         CmmLit (CmmLabelOff lbl off)
946            -> do
947                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
948                  -- need to optimize here, since it's late
949                  return $ cmmMachOpFold platform (MO_Add wordWidth) [
950                      dynRef,
951                      (CmmLit $ CmmInt (fromIntegral off) wordWidth)
952                    ]
953
954         -- On powerpc (non-PIC), it's easier to jump directly to a label than
955         -- to use the register table, so we replace these registers
956         -- with the corresponding labels:
957         CmmReg (CmmGlobal EagerBlackholeInfo)
958           | arch == ArchPPC && not opt_PIC
959           -> cmmExprNative referenceKind $
960              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
961         CmmReg (CmmGlobal GCEnter1)
962           | arch == ArchPPC && not opt_PIC
963           -> cmmExprNative referenceKind $
964              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
965         CmmReg (CmmGlobal GCFun)
966           | arch == ArchPPC && not opt_PIC
967           -> cmmExprNative referenceKind $
968              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
969
970         other
971            -> return other
972
973 \end{code}
974