Comment only
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 {-# OPTIONS -fno-warn-tabs #-}
8 -- The above warning supression flag is a temporary kludge.
9 -- While working on this module you are encouraged to remove it and
10 -- detab the module (please do the detabbing in a separate patch). See
11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
12 -- for details
13
14 module Simplify ( simplTopBinds, simplExpr ) where
15
16 #include "HsVersions.h"
17
18 import DynFlags
19 import SimplMonad
20 import Type hiding      ( substTy, extendTvSubst, substTyVar )
21 import SimplEnv
22 import SimplUtils
23 import FamInstEnv       ( FamInstEnv )
24 import Literal          ( litIsLifted )
25 import Id
26 import MkId             ( seqId, realWorldPrimId )
27 import MkCore           ( mkImpossibleExpr )
28 import IdInfo
29 import Name             ( mkSystemVarName, isExternalName )
30 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
31 import OptCoercion      ( optCoercion )
32 import FamInstEnv       ( topNormaliseType )
33 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness )
34 import CoreMonad        ( Tick(..), SimplifierMode(..) )
35 import CoreSyn
36 import Demand           ( isStrictDmd, StrictSig(..), dmdTypeDepth )
37 import PprCore          ( pprParendExpr, pprCoreExpr )
38 import CoreUnfold 
39 import CoreUtils
40 import qualified CoreSubst
41 import CoreArity
42 import Rules            ( lookupRule, getRules )
43 import BasicTypes       ( isMarkedStrict, Arity )
44 import TysPrim          ( realWorldStatePrimTy )
45 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
46 import MonadUtils       ( foldlM, mapAccumLM )
47 import Maybes           ( orElse, isNothing )
48 import Data.List        ( mapAccumL )
49 import Outputable
50 import FastString
51 import Pair
52 \end{code}
53
54
55 The guts of the simplifier is in this module, but the driver loop for
56 the simplifier is in SimplCore.lhs.
57
58
59 -----------------------------------------
60         *** IMPORTANT NOTE ***
61 -----------------------------------------
62 The simplifier used to guarantee that the output had no shadowing, but
63 it does not do so any more.   (Actually, it never did!)  The reason is
64 documented with simplifyArgs.
65
66
67 -----------------------------------------
68         *** IMPORTANT NOTE ***
69 -----------------------------------------
70 Many parts of the simplifier return a bunch of "floats" as well as an
71 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
72
73 All "floats" are let-binds, not case-binds, but some non-rec lets may
74 be unlifted (with RHS ok-for-speculation).
75
76
77
78 -----------------------------------------
79         ORGANISATION OF FUNCTIONS
80 -----------------------------------------
81 simplTopBinds
82   - simplify all top-level binders
83   - for NonRec, call simplRecOrTopPair
84   - for Rec,    call simplRecBind
85
86
87         ------------------------------
88 simplExpr (applied lambda)      ==> simplNonRecBind
89 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
90 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
91
92         ------------------------------
93 simplRecBind    [binders already simplfied]
94   - use simplRecOrTopPair on each pair in turn
95
96 simplRecOrTopPair [binder already simplified]
97   Used for: recursive bindings (top level and nested)
98             top-level non-recursive bindings
99   Returns:
100   - check for PreInlineUnconditionally
101   - simplLazyBind
102
103 simplNonRecBind
104   Used for: non-top-level non-recursive bindings
105             beta reductions (which amount to the same thing)
106   Because it can deal with strict arts, it takes a
107         "thing-inside" and returns an expression
108
109   - check for PreInlineUnconditionally
110   - simplify binder, including its IdInfo
111   - if strict binding
112         simplStrictArg
113         mkAtomicArgs
114         completeNonRecX
115     else
116         simplLazyBind
117         addFloats
118
119 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
120   Used for: binding case-binder and constr args in a known-constructor case
121   - check for PreInLineUnconditionally
122   - simplify binder
123   - completeNonRecX
124
125         ------------------------------
126 simplLazyBind:  [binder already simplified, RHS not]
127   Used for: recursive bindings (top level and nested)
128             top-level non-recursive bindings
129             non-top-level, but *lazy* non-recursive bindings
130         [must not be strict or unboxed]
131   Returns floats + an augmented environment, not an expression
132   - substituteIdInfo and add result to in-scope
133         [so that rules are available in rec rhs]
134   - simplify rhs
135   - mkAtomicArgs
136   - float if exposes constructor or PAP
137   - completeBind
138
139
140 completeNonRecX:        [binder and rhs both simplified]
141   - if the the thing needs case binding (unlifted and not ok-for-spec)
142         build a Case
143    else
144         completeBind
145         addFloats
146
147 completeBind:   [given a simplified RHS]
148         [used for both rec and non-rec bindings, top level and not]
149   - try PostInlineUnconditionally
150   - add unfolding [this is the only place we add an unfolding]
151   - add arity
152
153
154
155 Right hand sides and arguments
156 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
157 In many ways we want to treat
158         (a) the right hand side of a let(rec), and
159         (b) a function argument
160 in the same way.  But not always!  In particular, we would
161 like to leave these arguments exactly as they are, so they
162 will match a RULE more easily.
163
164         f (g x, h x)
165         g (+ x)
166
167 It's harder to make the rule match if we ANF-ise the constructor,
168 or eta-expand the PAP:
169
170         f (let { a = g x; b = h x } in (a,b))
171         g (\y. + x y)
172
173 On the other hand if we see the let-defns
174
175         p = (g x, h x)
176         q = + x
177
178 then we *do* want to ANF-ise and eta-expand, so that p and q
179 can be safely inlined.
180
181 Even floating lets out is a bit dubious.  For let RHS's we float lets
182 out if that exposes a value, so that the value can be inlined more vigorously.
183 For example
184
185         r = let x = e in (x,x)
186
187 Here, if we float the let out we'll expose a nice constructor. We did experiments
188 that showed this to be a generally good thing.  But it was a bad thing to float
189 lets out unconditionally, because that meant they got allocated more often.
190
191 For function arguments, there's less reason to expose a constructor (it won't
192 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
193 So for the moment we don't float lets out of function arguments either.
194
195
196 Eta expansion
197 ~~~~~~~~~~~~~~
198 For eta expansion, we want to catch things like
199
200         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
201
202 If the \x was on the RHS of a let, we'd eta expand to bring the two
203 lambdas together.  And in general that's a good thing to do.  Perhaps
204 we should eta expand wherever we find a (value) lambda?  Then the eta
205 expansion at a let RHS can concentrate solely on the PAP case.
206
207
208 %************************************************************************
209 %*                                                                      *
210 \subsection{Bindings}
211 %*                                                                      *
212 %************************************************************************
213
214 \begin{code}
215 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
216
217 simplTopBinds env0 binds0
218   = do  {       -- Put all the top-level binders into scope at the start
219                 -- so that if a transformation rule has unexpectedly brought
220                 -- anything into scope, then we don't get a complaint about that.
221                 -- It's rather as if the top-level binders were imported.
222                 -- See note [Glomming] in OccurAnal.
223         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
224         ; dflags <- getDOptsSmpl
225         ; let dump_flag = dopt Opt_D_verbose_core2core dflags
226         ; env2 <- simpl_binds dump_flag env1 binds0
227         ; freeTick SimplifierDone
228         ; return env2 }
229   where
230         -- We need to track the zapped top-level binders, because
231         -- they should have their fragile IdInfo zapped (notably occurrence info)
232         -- That's why we run down binds and bndrs' simultaneously.
233         --
234         -- The dump-flag emits a trace for each top-level binding, which
235         -- helps to locate the tracing for inlining and rule firing
236     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
237     simpl_binds _    env []           = return env
238     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
239                                                      simpl_bind env bind
240                                            ; simpl_binds dump env' binds }
241
242     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
243     trace_bind False _    = \x -> x
244
245     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
246     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
247         where
248           (env', b') = addBndrRules env b (lookupRecBndr env b)
249 \end{code}
250
251
252 %************************************************************************
253 %*                                                                      *
254 \subsection{Lazy bindings}
255 %*                                                                      *
256 %************************************************************************
257
258 simplRecBind is used for
259         * recursive bindings only
260
261 \begin{code}
262 simplRecBind :: SimplEnv -> TopLevelFlag
263              -> [(InId, InExpr)]
264              -> SimplM SimplEnv
265 simplRecBind env0 top_lvl pairs0
266   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
267         ; env1 <- go (zapFloats env_with_info) triples
268         ; return (env0 `addRecFloats` env1) }
269         -- addFloats adds the floats from env1,
270         -- _and_ updates env0 with the in-scope set from env1
271   where
272     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
273         -- Add the (substituted) rules to the binder
274     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
275         where
276           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
277
278     go env [] = return env
279
280     go env ((old_bndr, new_bndr, rhs) : pairs)
281         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
282              ; go env' pairs }
283 \end{code}
284
285 simplOrTopPair is used for
286         * recursive bindings (whether top level or not)
287         * top-level non-recursive bindings
288
289 It assumes the binder has already been simplified, but not its IdInfo.
290
291 \begin{code}
292 simplRecOrTopPair :: SimplEnv
293                   -> TopLevelFlag -> RecFlag
294                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
295                   -> SimplM SimplEnv    -- Returns an env that includes the binding
296
297 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
298   | preInlineUnconditionally env top_lvl old_bndr rhs   -- Check for unconditional inline
299   = do  { tick (PreInlineUnconditionally old_bndr)
300         ; return (extendIdSubst env old_bndr (mkContEx env rhs)) }
301
302   | otherwise
303   = simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env
304 \end{code}
305
306
307 simplLazyBind is used for
308   * [simplRecOrTopPair] recursive bindings (whether top level or not)
309   * [simplRecOrTopPair] top-level non-recursive bindings
310   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
311
312 Nota bene:
313     1. It assumes that the binder is *already* simplified,
314        and is in scope, and its IdInfo too, except unfolding
315
316     2. It assumes that the binder type is lifted.
317
318     3. It does not check for pre-inline-unconditionallly;
319        that should have been done already.
320
321 \begin{code}
322 simplLazyBind :: SimplEnv
323               -> TopLevelFlag -> RecFlag
324               -> InId -> OutId          -- Binder, both pre-and post simpl
325                                         -- The OutId has IdInfo, except arity, unfolding
326               -> InExpr -> SimplEnv     -- The RHS and its environment
327               -> SimplM SimplEnv
328
329 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
330   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
331     do  { let   rhs_env     = rhs_se `setInScope` env
332                 (tvs, body) = case collectTyBinders rhs of
333                                 (tvs, body) | not_lam body -> (tvs,body)
334                                             | otherwise    -> ([], rhs)
335                 not_lam (Lam _ _) = False
336                 not_lam _         = True
337                         -- Do not do the "abstract tyyvar" thing if there's
338                         -- a lambda inside, becuase it defeats eta-reduction
339                         --    f = /\a. \x. g a x  
340                         -- should eta-reduce
341
342         ; (body_env, tvs') <- simplBinders rhs_env tvs
343                 -- See Note [Floating and type abstraction] in SimplUtils
344
345         -- Simplify the RHS
346         ; (body_env1, body1) <- simplExprF body_env body mkRhsStop
347         -- ANF-ise a constructor or PAP rhs
348         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
349
350         ; (env', rhs')
351             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
352                 then                            -- No floating, revert to body1
353                      do { rhs' <- mkLam env tvs' (wrapFloats body_env1 body1)
354                         ; return (env, rhs') }
355
356                 else if null tvs then           -- Simple floating
357                      do { tick LetFloatFromLet
358                         ; return (addFloats env body_env2, body2) }
359
360                 else                            -- Do type-abstraction first
361                      do { tick LetFloatFromLet
362                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
363                         ; rhs' <- mkLam env tvs' body3
364                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
365                         ; return (env', rhs') }
366
367         ; completeBind env' top_lvl bndr bndr1 rhs' }
368 \end{code}
369
370 A specialised variant of simplNonRec used when the RHS is already simplified,
371 notably in knownCon.  It uses case-binding where necessary.
372
373 \begin{code}
374 simplNonRecX :: SimplEnv
375              -> InId            -- Old binder
376              -> OutExpr         -- Simplified RHS
377              -> SimplM SimplEnv
378
379 simplNonRecX env bndr new_rhs
380   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
381   = return env          --               Here c is dead, and we avoid creating
382                         --               the binding c = (a,b)
383   | Coercion co <- new_rhs    
384   = return (extendCvSubst env bndr co)
385   | otherwise           --               the binding b = (a,b)
386   = do  { (env', bndr') <- simplBinder env bndr
387         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
388                 -- simplNonRecX is only used for NotTopLevel things
389
390 completeNonRecX :: TopLevelFlag -> SimplEnv
391                 -> Bool
392                 -> InId                 -- Old binder
393                 -> OutId                -- New binder
394                 -> OutExpr              -- Simplified RHS
395                 -> SimplM SimplEnv
396
397 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
398   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
399         ; (env2, rhs2) <- 
400                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
401                 then do { tick LetFloatFromLet
402                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
403                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
404         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
405 \end{code}
406
407 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
408    Doing so risks exponential behaviour, because new_rhs has been simplified once already
409    In the cases described by the folowing commment, postInlineUnconditionally will
410    catch many of the relevant cases.
411         -- This happens; for example, the case_bndr during case of
412         -- known constructor:  case (a,b) of x { (p,q) -> ... }
413         -- Here x isn't mentioned in the RHS, so we don't want to
414         -- create the (dead) let-binding  let x = (a,b) in ...
415         --
416         -- Similarly, single occurrences can be inlined vigourously
417         -- e.g.  case (f x, g y) of (a,b) -> ....
418         -- If a,b occur once we can avoid constructing the let binding for them.
419
420    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
421         -- Consider     case I# (quotInt# x y) of
422         --                I# v -> let w = J# v in ...
423         -- If we gaily inline (quotInt# x y) for v, we end up building an
424         -- extra thunk:
425         --                let w = J# (quotInt# x y) in ...
426         -- because quotInt# can fail.
427
428   | preInlineUnconditionally env NotTopLevel bndr new_rhs
429   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
430 -}
431
432 ----------------------------------
433 prepareRhs takes a putative RHS, checks whether it's a PAP or
434 constructor application and, if so, converts it to ANF, so that the
435 resulting thing can be inlined more easily.  Thus
436         x = (f a, g b)
437 becomes
438         t1 = f a
439         t2 = g b
440         x = (t1,t2)
441
442 We also want to deal well cases like this
443         v = (f e1 `cast` co) e2
444 Here we want to make e1,e2 trivial and get
445         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
446 That's what the 'go' loop in prepareRhs does
447
448 \begin{code}
449 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
450 -- Adds new floats to the env iff that allows us to return a good RHS
451 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
452   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
453   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
454   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
455         ; return (env', Cast rhs' co) }
456   where
457     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
458                                    `setDemandInfo`     demandInfo info
459     info = idInfo id
460
461 prepareRhs top_lvl env0 _ rhs0
462   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
463         ; return (env1, rhs1) }
464   where
465     go n_val_args env (Cast rhs co)
466         = do { (is_exp, env', rhs') <- go n_val_args env rhs
467              ; return (is_exp, env', Cast rhs' co) }
468     go n_val_args env (App fun (Type ty))
469         = do { (is_exp, env', rhs') <- go n_val_args env fun
470              ; return (is_exp, env', App rhs' (Type ty)) }
471     go n_val_args env (App fun arg)
472         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
473              ; case is_exp of
474                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
475                            ; return (True, env'', App fun' arg') }
476                 False -> return (False, env, App fun arg) }
477     go n_val_args env (Var fun)
478         = return (is_exp, env, Var fun)
479         where
480           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
481                         -- See Note [CONLIKE pragma] in BasicTypes
482                         -- The definition of is_exp should match that in
483                         -- OccurAnal.occAnalApp
484
485     go _ env other
486         = return (False, env, other)
487 \end{code}
488
489
490 Note [Float coercions]
491 ~~~~~~~~~~~~~~~~~~~~~~
492 When we find the binding
493         x = e `cast` co
494 we'd like to transform it to
495         x' = e
496         x = x `cast` co         -- A trivial binding
497 There's a chance that e will be a constructor application or function, or something
498 like that, so moving the coerion to the usage site may well cancel the coersions
499 and lead to further optimisation.  Example:
500
501      data family T a :: *
502      data instance T Int = T Int
503
504      foo :: Int -> Int -> Int
505      foo m n = ...
506         where
507           x = T m
508           go 0 = 0
509           go n = case x of { T m -> go (n-m) }
510                 -- This case should optimise
511
512 Note [Preserve strictness when floating coercions]
513 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
514 In the Note [Float coercions] transformation, keep the strictness info.
515 Eg
516         f = e `cast` co    -- f has strictness SSL
517 When we transform to
518         f' = e             -- f' also has strictness SSL
519         f = f' `cast` co   -- f still has strictness SSL
520
521 Its not wrong to drop it on the floor, but better to keep it.
522
523 Note [Float coercions (unlifted)]
524 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
525 BUT don't do [Float coercions] if 'e' has an unlifted type.
526 This *can* happen:
527
528      foo :: Int = (error (# Int,Int #) "urk")
529                   `cast` CoUnsafe (# Int,Int #) Int
530
531 If do the makeTrivial thing to the error call, we'll get
532     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
533 But 'v' isn't in scope!
534
535 These strange casts can happen as a result of case-of-case
536         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
537                 (# p,q #) -> p+q
538
539
540 \begin{code}
541 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
542 -- Binds the expression to a variable, if it's not trivial, returning the variable
543 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
544
545 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo 
546                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
547 -- Propagate strictness and demand info to the new binder
548 -- Note [Preserve strictness when floating coercions]
549 -- Returned SimplEnv has same substitution as incoming one
550 makeTrivialWithInfo top_lvl env info expr
551   | exprIsTrivial expr                          -- Already trivial
552   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
553                                                 --   See Note [Cannot trivialise]
554   = return (env, expr)
555   | otherwise           -- See Note [Take care] below
556   = do  { uniq <- getUniqueM
557         ; let name = mkSystemVarName uniq (fsLit "a")
558               var = mkLocalIdWithInfo name expr_ty info
559         ; env'  <- completeNonRecX top_lvl env False var var expr
560         ; expr' <- simplVar env' var
561         ; return (env', expr') }
562         -- The simplVar is needed becase we're constructing a new binding
563         --     a = rhs
564         -- And if rhs is of form (rhs1 |> co), then we might get
565         --     a1 = rhs1
566         --     a = a1 |> co
567         -- and now a's RHS is trivial and can be substituted out, and that
568         -- is what completeNonRecX will do
569         -- To put it another way, it's as if we'd simplified
570         --    let var = e in var
571   where
572     expr_ty = exprType expr
573
574 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
575 -- True iff we can have a binding of this expression at this level
576 -- Precondition: the type is the type of the expression
577 bindingOk top_lvl _ expr_ty
578   | isTopLevel top_lvl = not (isUnLiftedType expr_ty) 
579   | otherwise          = True
580 \end{code}
581
582 Note [Cannot trivialise]
583 ~~~~~~~~~~~~~~~~~~~~~~~~
584 Consider tih
585    f :: Int -> Addr#
586    
587    foo :: Bar
588    foo = Bar (f 3)
589
590 Then we can't ANF-ise foo, even though we'd like to, because
591 we can't make a top-level binding for the Addr# (f 3). And if
592 so we don't want to turn it into
593    foo = let x = f 3 in Bar x
594 because we'll just end up inlining x back, and that makes the
595 simplifier loop.  Better not to ANF-ise it at all.
596
597 A case in point is literal strings (a MachStr is not regarded as
598 trivial):
599
600    foo = Ptr "blob"#
601
602 We don't want to ANF-ise this.
603
604 %************************************************************************
605 %*                                                                      *
606 \subsection{Completing a lazy binding}
607 %*                                                                      *
608 %************************************************************************
609
610 completeBind
611   * deals only with Ids, not TyVars
612   * takes an already-simplified binder and RHS
613   * is used for both recursive and non-recursive bindings
614   * is used for both top-level and non-top-level bindings
615
616 It does the following:
617   - tries discarding a dead binding
618   - tries PostInlineUnconditionally
619   - add unfolding [this is the only place we add an unfolding]
620   - add arity
621
622 It does *not* attempt to do let-to-case.  Why?  Because it is used for
623   - top-level bindings (when let-to-case is impossible)
624   - many situations where the "rhs" is known to be a WHNF
625                 (so let-to-case is inappropriate).
626
627 Nor does it do the atomic-argument thing
628
629 \begin{code}
630 completeBind :: SimplEnv
631              -> TopLevelFlag            -- Flag stuck into unfolding
632              -> InId                    -- Old binder
633              -> OutId -> OutExpr        -- New binder and RHS
634              -> SimplM SimplEnv
635 -- completeBind may choose to do its work
636 --      * by extending the substitution (e.g. let x = y in ...)
637 --      * or by adding to the floats in the envt
638
639 completeBind env top_lvl old_bndr new_bndr new_rhs
640  | isCoVar old_bndr
641  = case new_rhs of
642      Coercion co -> return (extendCvSubst env old_bndr co)
643      _           -> return (addNonRec env new_bndr new_rhs)
644
645  | otherwise
646  = ASSERT( isId new_bndr )
647    do { let old_info = idInfo old_bndr
648             old_unf  = unfoldingInfo old_info
649             occ_info = occInfo old_info
650
651         -- Do eta-expansion on the RHS of the binding
652         -- See Note [Eta-expanding at let bindings] in SimplUtils
653       ; (new_arity, final_rhs) <- tryEtaExpand env new_bndr new_rhs
654
655         -- Simplify the unfolding
656       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
657
658       ; if postInlineUnconditionally env top_lvl new_bndr occ_info
659                                      final_rhs new_unfolding
660
661                         -- Inline and discard the binding
662         then do  { tick (PostInlineUnconditionally old_bndr)
663                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
664                 -- Use the substitution to make quite, quite sure that the
665                 -- substitution will happen, since we are going to discard the binding
666         else
667    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
668         
669               -- Unfolding info: Note [Setting the new unfolding]
670             info2 = info1 `setUnfoldingInfo` new_unfolding
671
672               -- Demand info: Note [Setting the demand info]
673               --
674               -- We also have to nuke demand info if for some reason
675               -- eta-expansion *reduces* the arity of the binding to less
676               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
677             info3 | isEvaldUnfolding new_unfolding
678                     || (case strictnessInfo info2 of
679                           Just (StrictSig dmd_ty) -> new_arity < dmdTypeDepth dmd_ty
680                           Nothing                 -> False)
681                   = zapDemandInfo info2 `orElse` info2
682                   | otherwise
683                   = info2
684
685             final_id = new_bndr `setIdInfo` info3
686
687       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
688         return (addNonRec env final_id final_rhs) } }
689                 -- The addNonRec adds it to the in-scope set too
690
691 ------------------------------
692 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
693 -- Add a new binding to the environment, complete with its unfolding
694 -- but *do not* do postInlineUnconditionally, because we have already
695 -- processed some of the scope of the binding
696 -- We still want the unfolding though.  Consider
697 --      let 
698 --            x = /\a. let y = ... in Just y
699 --      in body
700 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
701 -- but 'x' may well then be inlined in 'body' in which case we'd like the 
702 -- opportunity to inline 'y' too.
703 --
704 -- INVARIANT: the arity is correct on the incoming binders
705
706 addPolyBind top_lvl env (NonRec poly_id rhs)
707   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
708                         -- Assumes that poly_id did not have an INLINE prag
709                         -- which is perhaps wrong.  ToDo: think about this
710         ; let final_id = setIdInfo poly_id $
711                          idInfo poly_id `setUnfoldingInfo` unfolding
712
713         ; return (addNonRec env final_id rhs) }
714
715 addPolyBind _ env bind@(Rec _) 
716   = return (extendFloats env bind)
717         -- Hack: letrecs are more awkward, so we extend "by steam"
718         -- without adding unfoldings etc.  At worst this leads to
719         -- more simplifier iterations
720
721 ------------------------------
722 simplUnfolding :: SimplEnv-> TopLevelFlag
723                -> InId
724                -> OutExpr
725                -> Unfolding -> SimplM Unfolding
726 -- Note [Setting the new unfolding]
727 simplUnfolding env _ _ _ (DFunUnfolding ar con ops)
728   = return (DFunUnfolding ar con ops')
729   where
730     ops' = map (substExpr (text "simplUnfolding") env) ops
731
732 simplUnfolding env top_lvl id _
733     (CoreUnfolding { uf_tmpl = expr, uf_arity = arity
734                    , uf_src = src, uf_guidance = guide })
735   | isStableSource src
736   = do { expr' <- simplExpr rule_env expr
737        ; let src' = CoreSubst.substUnfoldingSource (mkCoreSubst (text "inline-unf") env) src
738              is_top_lvl = isTopLevel top_lvl
739        ; case guide of
740            UnfWhen sat_ok _    -- Happens for INLINE things
741               -> let guide' = UnfWhen sat_ok (inlineBoringOk expr')
742                      -- Refresh the boring-ok flag, in case expr'
743                      -- has got small. This happens, notably in the inlinings
744                      -- for dfuns for single-method classes; see
745                      -- Note [Single-method classes] in TcInstDcls.
746                      -- A test case is Trac #4138
747                  in return (mkCoreUnfolding src' is_top_lvl expr' arity guide')
748                  -- See Note [Top-level flag on inline rules] in CoreUnfold
749
750            _other              -- Happens for INLINABLE things
751               -> let bottoming = isBottomingId id
752                  in bottoming `seq` -- See Note [Force bottoming field]
753                     return (mkUnfolding src' is_top_lvl bottoming expr')
754                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
755                 -- unfolding, and we need to make sure the guidance is kept up
756                 -- to date with respect to any changes in the unfolding.
757        }
758   where
759     act      = idInlineActivation id
760     rule_env = updMode (updModeForInlineRules act) env
761                -- See Note [Simplifying inside InlineRules] in SimplUtils
762
763 simplUnfolding _ top_lvl id new_rhs _
764   = let bottoming = isBottomingId id
765     in bottoming `seq`  -- See Note [Force bottoming field]
766        return (mkUnfolding InlineRhs (isTopLevel top_lvl) bottoming new_rhs)
767           -- We make an  unfolding *even for loop-breakers*.
768           -- Reason: (a) It might be useful to know that they are WHNF
769           --         (b) In TidyPgm we currently assume that, if we want to
770           --             expose the unfolding then indeed we *have* an unfolding
771           --             to expose.  (We could instead use the RHS, but currently
772           --             we don't.)  The simple thing is always to have one.
773 \end{code}
774
775 Note [Force bottoming field]
776 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
777 We need to force bottoming, or the new unfolding holds
778 on to the old unfolding (which is part of the id).
779
780 Note [Arity decrease]
781 ~~~~~~~~~~~~~~~~~~~~~
782 Generally speaking the arity of a binding should not decrease.  But it *can* 
783 legitimately happen becuase of RULES.  Eg
784         f = g Int
785 where g has arity 2, will have arity 2.  But if there's a rewrite rule
786         g Int --> h
787 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
788 which is in the output of Specialise:
789
790      Rec {
791         $dm {Arity 2} = \d.\x. op d
792         {-# RULES forall d. $dm Int d = $s$dm #-}
793         
794         dInt = MkD .... opInt ...
795         opInt {Arity 1} = $dm dInt
796
797         $s$dm {Arity 0} = \x. op dInt }
798
799 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
800 That's why Specialise goes to a little trouble to pin the right arity
801 on specialised functions too.
802
803 Note [Setting the new unfolding]
804 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
805 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
806   should do nothing at all, but simplifying gently might get rid of 
807   more crap.
808
809 * If not, we make an unfolding from the new RHS.  But *only* for
810   non-loop-breakers. Making loop breakers not have an unfolding at all
811   means that we can avoid tests in exprIsConApp, for example.  This is
812   important: if exprIsConApp says 'yes' for a recursive thing, then we
813   can get into an infinite loop
814
815 If there's an InlineRule on a loop breaker, we hang on to the inlining.
816 It's pretty dodgy, but the user did say 'INLINE'.  May need to revisit
817 this choice.
818
819 Note [Setting the demand info]
820 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
821 If the unfolding is a value, the demand info may
822 go pear-shaped, so we nuke it.  Example:
823      let x = (a,b) in
824      case x of (p,q) -> h p q x
825 Here x is certainly demanded. But after we've nuked
826 the case, we'll get just
827      let x = (a,b) in h a b x
828 and now x is not demanded (I'm assuming h is lazy)
829 This really happens.  Similarly
830      let f = \x -> e in ...f..f...
831 After inlining f at some of its call sites the original binding may
832 (for example) be no longer strictly demanded.
833 The solution here is a bit ad hoc...
834
835
836 %************************************************************************
837 %*                                                                      *
838 \subsection[Simplify-simplExpr]{The main function: simplExpr}
839 %*                                                                      *
840 %************************************************************************
841
842 The reason for this OutExprStuff stuff is that we want to float *after*
843 simplifying a RHS, not before.  If we do so naively we get quadratic
844 behaviour as things float out.
845
846 To see why it's important to do it after, consider this (real) example:
847
848         let t = f x
849         in fst t
850 ==>
851         let t = let a = e1
852                     b = e2
853                 in (a,b)
854         in fst t
855 ==>
856         let a = e1
857             b = e2
858             t = (a,b)
859         in
860         a       -- Can't inline a this round, cos it appears twice
861 ==>
862         e1
863
864 Each of the ==> steps is a round of simplification.  We'd save a
865 whole round if we float first.  This can cascade.  Consider
866
867         let f = g d
868         in \x -> ...f...
869 ==>
870         let f = let d1 = ..d.. in \y -> e
871         in \x -> ...f...
872 ==>
873         let d1 = ..d..
874         in \x -> ...(\y ->e)...
875
876 Only in this second round can the \y be applied, and it
877 might do the same again.
878
879
880 \begin{code}
881 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
882 simplExpr env expr = simplExprC env expr mkBoringStop
883
884 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
885         -- Simplify an expression, given a continuation
886 simplExprC env expr cont
887   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
888     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
889         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
890           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
891           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
892           return (wrapFloats env' expr') }
893
894 --------------------------------------------------
895 simplExprF :: SimplEnv -> InExpr -> SimplCont
896            -> SimplM (SimplEnv, OutExpr)
897
898 simplExprF env e cont
899   = {- pprTrace "simplExprF" (vcat 
900       [ ppr e
901       , text "cont =" <+> ppr cont
902       , text "inscope =" <+> ppr (seInScope env)
903       , text "tvsubst =" <+> ppr (seTvSubst env)
904       , text "idsubst =" <+> ppr (seIdSubst env)
905       , text "cvsubst =" <+> ppr (seCvSubst env)
906       {- , ppr (seFloats env) -} 
907       ]) $ -}
908     simplExprF1 env e cont
909
910 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
911             -> SimplM (SimplEnv, OutExpr)
912 simplExprF1 env (Var v)        cont = simplIdF env v cont
913 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
914 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
915 simplExprF1 env (Cast body co) cont = simplCast env body co cont
916 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
917 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
918                                       rebuild env (Type (substTy env ty)) cont
919 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
920                                       ApplyTo NoDup arg env cont
921
922 simplExprF1 env expr@(Lam {}) cont
923   = simplLam env zapped_bndrs body cont
924         -- The main issue here is under-saturated lambdas
925         --   (\x1. \x2. e) arg1
926         -- Here x1 might have "occurs-once" occ-info, because occ-info
927         -- is computed assuming that a group of lambdas is applied
928         -- all at once.  If there are too few args, we must zap the
929         -- occ-info, UNLESS the remaining binders are one-shot
930   where
931     (bndrs, body) = collectBinders expr
932     zapped_bndrs | need_to_zap = map zap bndrs
933                  | otherwise   = bndrs
934
935     need_to_zap = any zappable_bndr (drop n_args bndrs)
936     n_args = countArgs cont
937         -- NB: countArgs counts all the args (incl type args)
938         -- and likewise drop counts all binders (incl type lambdas)
939
940     zappable_bndr b = isId b && not (isOneShotBndr b)
941     zap b | isTyVar b = b
942           | otherwise = zapLamIdInfo b
943
944 simplExprF1 env (Case scrut bndr _ alts) cont
945   | sm_case_case (getMode env)
946   =     -- Simplify the scrutinee with a Select continuation
947     simplExprF env scrut (Select NoDup bndr alts env cont)
948
949   | otherwise
950   =     -- If case-of-case is off, simply simplify the case expression
951         -- in a vanilla Stop context, and rebuild the result around it
952     do  { case_expr' <- simplExprC env scrut
953                              (Select NoDup bndr alts env mkBoringStop)
954         ; rebuild env case_expr' cont }
955
956 simplExprF1 env (Let (Rec pairs) body) cont
957   = do  { env' <- simplRecBndrs env (map fst pairs)
958                 -- NB: bndrs' don't have unfoldings or rules
959                 -- We add them as we go down
960
961         ; env'' <- simplRecBind env' NotTopLevel pairs
962         ; simplExprF env'' body cont }
963
964 simplExprF1 env (Let (NonRec bndr rhs) body) cont
965   = simplNonRecE env bndr (rhs, env) ([], body) cont
966
967 ---------------------------------
968 simplType :: SimplEnv -> InType -> SimplM OutType
969         -- Kept monadic just so we can do the seqType
970 simplType env ty
971   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
972     seqType new_ty `seq` return new_ty
973   where
974     new_ty = substTy env ty
975
976 ---------------------------------
977 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
978                -> SimplM (SimplEnv, OutExpr)
979 -- We are simplifying a term of form (Coercion co)
980 -- Simplify the InCoercion, and then try to combine with the 
981 -- context, to implememt the rule
982 --     (Coercion co) |> g
983 --  =  Coercion (syn (nth 0 g) ; co ; nth 1 g) 
984 simplCoercionF env co cont 
985   = do { co' <- simplCoercion env co
986        ; simpl_co co' cont }
987   where
988     simpl_co co (CoerceIt g cont)
989        = simpl_co new_co cont
990      where
991        -- g :: (s1 ~# s2) ~# (t1 ~#  t2)
992        -- g1 :: s1 ~# t1
993        -- g2 :: s2 ~# t2
994        new_co = mkSymCo g1 `mkTransCo` co `mkTransCo` g2
995        [_reflk, g1, g2] = decomposeCo 3 g
996             -- Remember, (~#) :: forall k. k -> k -> *
997             -- so it takes *three* arguments, not two
998
999     simpl_co co cont
1000        = seqCo co `seq` rebuild env (Coercion co) cont
1001
1002 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
1003 simplCoercion env co
1004   = let opt_co = optCoercion (getCvSubst env) co
1005     in opt_co `seq` return opt_co
1006
1007 -----------------------------------
1008 -- | Push a TickIt context outwards past applications and cases, as
1009 -- long as this is a non-scoping tick, to let case and application
1010 -- optimisations apply.
1011
1012 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1013           -> SimplM (SimplEnv, OutExpr)
1014 simplTick env tickish expr cont
1015   -- A scoped tick turns into a continuation, so that we can spot
1016   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1017   -- it this way, then it would take two passes of the simplifier to
1018   -- reduce ((scc t (\x . e)) e').
1019   -- NB, don't do this with counting ticks, because if the expr is
1020   -- bottom, then rebuildCall will discard the continuation.
1021
1022 -- XXX: we cannot do this, because the simplifier assumes that
1023 -- the context can be pushed into a case with a single branch. e.g.
1024 --    scc<f>  case expensive of p -> e
1025 -- becomes
1026 --    case expensive of p -> scc<f> e
1027 --
1028 -- So I'm disabling this for now.  It just means we will do more
1029 -- simplifier iterations that necessary in some cases.
1030
1031 --  | tickishScoped tickish && not (tickishCounts tickish)
1032 --  = simplExprF env expr (TickIt tickish cont)
1033
1034   -- For non-scoped ticks, we push the continuation inside the
1035   -- tick.  This has the effect of moving the tick to the outside of a
1036   -- case or application context, allowing the normal case and
1037   -- application optimisations to fire.
1038   | not (tickishScoped tickish)
1039   = do { (env', expr') <- simplExprF env expr cont
1040        ; return (env', mkTick tickish expr')
1041        }
1042
1043   -- the last case handles scoped/counting ticks, where all we
1044   -- can do is simplify the inner expression and then rebuild.
1045   --
1046   -- NB. float handling here is tricky.  We have some floats already
1047   -- in the env, and there may be floats arising from the inner
1048   -- expression.  We must be careful to wrap any floats arising from
1049   -- the inner expression with a non-counting tick, but not those from
1050   -- the env passed in.
1051   --
1052
1053   -- For breakpoints, we cannot do any floating of bindings around the
1054   -- tick, because breakpoints cannot be split into tick/scope pairs.
1055   | Breakpoint{} <- tickish
1056   = do { let (inc,outc) = splitCont cont
1057        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1058        ; let tickish' = simplTickish env tickish
1059        ; (env'', expr'') <- rebuild (zapFloats env') (wrapFloats env' expr') (TickIt tickish' outc)
1060        ; return (env'', wrapFloats env expr'')
1061        }
1062
1063   | Just expr' <- want_to_push_tick_inside
1064     -- see Note [case-of-scc-of-case]
1065   = simplExprF env expr' cont
1066
1067   | otherwise
1068   = do { let (inc,outc) = splitCont cont
1069        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1070        ; let tickish' = simplTickish env tickish
1071        ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1072                                    mkTick (mkNoTick tickish') rhs)
1073               -- when wrapping a float with mkTick, we better zap the Id's
1074               -- strictness info and arity, because it might be wrong now.
1075        ; let env'' = addFloats env (mapFloats env' wrap_float)
1076        ; rebuild env'' expr' (TickIt tickish' outc)
1077        }
1078  where
1079   want_to_push_tick_inside
1080      | not interesting_cont = Nothing
1081      | otherwise
1082        = case expr of
1083            Case scrut bndr ty alts
1084               -> Just (Case (mkTick tickish scrut) bndr ty alts')
1085              where t_scope = mkNoTick tickish -- drop the tick on the dup'd ones
1086                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1087            _other -> Nothing
1088
1089   interesting_cont = case cont of
1090                           Select _ _ _ _ _ -> True
1091                           _ -> False
1092
1093
1094   simplTickish env tickish
1095     | Breakpoint n ids <- tickish
1096           = Breakpoint n (map (getDoneId . substId env) ids)
1097     | otherwise = tickish
1098
1099   -- push type application and coercion inside a tick
1100   splitCont :: SimplCont -> (SimplCont, SimplCont)
1101   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1102     where (inc,outc) = splitCont c
1103   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1104     where (inc,outc) = splitCont c
1105   splitCont other = (mkBoringStop, other)
1106
1107   getDoneId (DoneId id) = id
1108   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1109   getDoneId other = pprPanic "getDoneId" (ppr other)
1110
1111 -- Note [case-of-scc-of-case]
1112 -- It's pretty important to be able to transform case-of-case when
1113 -- there's an SCC in the way.  For example, the following comes up
1114 -- in nofib/real/compress/Encode.hs:
1115 --
1116 --        case scctick<code_string.r1>
1117 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1118 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1119 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1120 --             }
1121 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1122 --        tick<code_string.f1>
1123 --        (ww_s12Y,
1124 --         ww1_s12Z,
1125 --         PTTrees.PT
1126 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1127 --        }
1128 --  
1129 -- We really want this case-of-case to fire, because then the 3-tuple
1130 -- will go away (indeed, the CPR optimisation is relying on this
1131 -- happening).  But the scctick is in the way - we need to push it
1132 -- inside to expose the case-of-case.  So we perform this
1133 -- transformation on the inner case:
1134 --
1135 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1136 --    ==>
1137 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1138 --
1139 -- So we've moved a constant amount of work out of the scc to expose
1140 -- the case.  We only do this when the continuation is interesting: in
1141 -- for now, it has to be another Case (maybe generalise this later).
1142 \end{code}
1143
1144
1145 %************************************************************************
1146 %*                                                                      *
1147 \subsection{The main rebuilder}
1148 %*                                                                      *
1149 %************************************************************************
1150
1151 \begin{code}
1152 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1153 -- At this point the substitution in the SimplEnv should be irrelevant
1154 -- only the in-scope set and floats should matter
1155 rebuild env expr cont
1156   = case cont of
1157       Stop {}                      -> return (env, expr)
1158       CoerceIt co cont             -> rebuild env (Cast expr co) cont
1159       Select _ bndr alts se cont   -> rebuildCase (se `setFloats` env) expr bndr alts cont
1160       StrictArg info _ cont        -> rebuildCall env (info `addArgTo` expr) cont
1161       StrictBind b bs body se cont -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1162                                          ; simplLam env' bs body cont }
1163       ApplyTo dup_flag arg se cont -- See Note [Avoid redundant simplification]
1164         | isSimplified dup_flag    -> rebuild env (App expr arg) cont
1165         | otherwise                -> do { arg' <- simplExpr (se `setInScope` env) arg
1166                                          ; rebuild env (App expr arg') cont }
1167       TickIt t cont                -> rebuild env (mkTick t expr) cont
1168 \end{code}
1169
1170
1171 %************************************************************************
1172 %*                                                                      *
1173 \subsection{Lambdas}
1174 %*                                                                      *
1175 %************************************************************************
1176
1177 \begin{code}
1178 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1179           -> SimplM (SimplEnv, OutExpr)
1180 simplCast env body co0 cont0
1181   = do  { co1 <- simplCoercion env co0
1182         ; -- pprTrace "simplCast" (ppr co1) $
1183           simplExprF env body (addCoerce co1 cont0) }
1184   where
1185        addCoerce co cont = add_coerce co (coercionKind co) cont
1186
1187        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1188          | s1 `eqType` k1 = cont    -- is a no-op
1189
1190        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1191          | (Pair _l1 t1) <- coercionKind co2
1192                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1193                 -- ==>
1194                 --      e,                       if S1=T1
1195                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1196                 --
1197                 -- For example, in the initial form of a worker
1198                 -- we may find  (coerce T (coerce S (\x.e))) y
1199                 -- and we'd like it to simplify to e[y/x] in one round
1200                 -- of simplification
1201          , s1 `eqType` t1  = cont            -- The coerces cancel out
1202          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1203
1204        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1205                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1206                 -- This implements the PushT rule from the paper
1207          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1208          = ASSERT( isTyVar tyvar )
1209            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1210          where
1211            new_cast = mkInstCo co arg_ty'
1212            arg_ty' | isSimplified dup = arg_ty
1213                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1214
1215        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1216          | isFunTy s1s2   -- This implements the Push rule from the paper
1217          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1218                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1219                 -- ===>
1220                 --      (e (f |> (arg g :: t1~s1))
1221                 --      |> (res g :: s2->t2)
1222                 --
1223                 -- t1t2 must be a function type, t1->t2, because it's applied
1224                 -- to something but s1s2 might conceivably not be
1225                 --
1226                 -- When we build the ApplyTo we can't mix the out-types
1227                 -- with the InExpr in the argument, so we simply substitute
1228                 -- to make it all consistent.  It's a bit messy.
1229                 -- But it isn't a common case.
1230                 --
1231                 -- Example of use: Trac #995
1232          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1233          where
1234            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1235            -- t2 ~ s2 with left and right on the curried form:
1236            --    (->) t1 t2 ~ (->) s1 s2
1237            [co1, co2] = decomposeCo 2 co
1238            new_arg    = mkCoerce (mkSymCo co1) arg'
1239            arg'       = substExpr (text "move-cast") arg_se' arg
1240            arg_se'    = arg_se `setInScope` env
1241
1242        add_coerce co _ cont = CoerceIt co cont
1243 \end{code}
1244
1245
1246 %************************************************************************
1247 %*                                                                      *
1248 \subsection{Lambdas}
1249 %*                                                                      *
1250 %************************************************************************
1251
1252 Note [Zap unfolding when beta-reducing]
1253 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1254 Lambda-bound variables can have stable unfoldings, such as
1255    $j = \x. \b{Unf=Just x}. e
1256 See Note [Case binders and join points] below; the unfolding for lets
1257 us optimise e better.  However when we beta-reduce it we want to
1258 revert to using the actual value, otherwise we can end up in the
1259 stupid situation of
1260           let x = blah in
1261           let b{Unf=Just x} = y
1262           in ...b...
1263 Here it'd be far better to drop the unfolding and use the actual RHS.
1264
1265 \begin{code}
1266 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1267          -> SimplM (SimplEnv, OutExpr)
1268
1269 simplLam env [] body cont = simplExprF env body cont
1270
1271         -- Beta reduction
1272 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1273   = do  { tick (BetaReduction bndr)
1274         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1275   where
1276     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1277       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1278       = setIdUnfolding bndr NoUnfolding
1279       | otherwise = bndr
1280
1281       -- discard a non-counting tick on a lambda.  This may change the
1282       -- cost attribution slightly (moving the allocation of the
1283       -- lambda elsewhere), but we don't care: optimisation changes
1284       -- cost attribution all the time.
1285 simplLam env bndrs body (TickIt tickish cont)
1286   | not (tickishCounts tickish)
1287   = simplLam env bndrs body cont
1288
1289         -- Not enough args, so there are real lambdas left to put in the result
1290 simplLam env bndrs body cont
1291   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1292         ; body' <- simplExpr env' body
1293         ; new_lam <- mkLam env' bndrs' body'
1294         ; rebuild env' new_lam cont }
1295
1296 ------------------
1297 simplNonRecE :: SimplEnv
1298              -> InBndr                  -- The binder
1299              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1300              -> ([InBndr], InExpr)      -- Body of the let/lambda
1301                                         --      \xs.e
1302              -> SimplCont
1303              -> SimplM (SimplEnv, OutExpr)
1304
1305 -- simplNonRecE is used for
1306 --  * non-top-level non-recursive lets in expressions
1307 --  * beta reduction
1308 --
1309 -- It deals with strict bindings, via the StrictBind continuation,
1310 -- which may abort the whole process
1311 --
1312 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1313 -- representing a lambda; so we recurse back to simplLam
1314 -- Why?  Because of the binder-occ-info-zapping done before
1315 --       the call to simplLam in simplExprF (Lam ...)
1316
1317         -- First deal with type applications and type lets
1318         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1319 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1320   = ASSERT( isTyVar bndr )
1321     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1322         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1323
1324 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1325   | preInlineUnconditionally env NotTopLevel bndr rhs
1326   = do  { tick (PreInlineUnconditionally bndr)
1327         ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1328           simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1329
1330   | isStrictId bndr              -- Includes coercions
1331   = do  { simplExprF (rhs_se `setFloats` env) rhs
1332                      (StrictBind bndr bndrs body env cont) }
1333
1334   | otherwise
1335   = ASSERT( not (isTyVar bndr) )
1336     do  { (env1, bndr1) <- simplNonRecBndr env bndr
1337         ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1338         ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1339         ; simplLam env3 bndrs body cont }
1340 \end{code}
1341
1342 %************************************************************************
1343 %*                                                                      *
1344                      Variables
1345 %*                                                                      *
1346 %************************************************************************
1347
1348 \begin{code}
1349 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1350 -- Look up an InVar in the environment
1351 simplVar env var
1352   | isTyVar var = return (Type (substTyVar env var))
1353   | isCoVar var = return (Coercion (substCoVar env var))
1354   | otherwise
1355   = case substId env var of
1356         DoneId var1          -> return (Var var1)
1357         DoneEx e             -> return e
1358         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1359
1360 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1361 simplIdF env var cont
1362   = case substId env var of
1363         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1364         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1365         DoneId var1          -> completeCall env var1 cont
1366                 -- Note [zapSubstEnv]
1367                 -- The template is already simplified, so don't re-substitute.
1368                 -- This is VITAL.  Consider
1369                 --      let x = e in
1370                 --      let y = \z -> ...x... in
1371                 --      \ x -> ...y...
1372                 -- We'll clone the inner \x, adding x->x' in the id_subst
1373                 -- Then when we inline y, we must *not* replace x by x' in
1374                 -- the inlined copy!!
1375
1376 ---------------------------------------------------------
1377 --      Dealing with a call site
1378
1379 completeCall :: SimplEnv -> Id -> SimplCont -> SimplM (SimplEnv, OutExpr)
1380 completeCall env var cont
1381   = do  {   ------------- Try inlining ----------------
1382           dflags <- getDOptsSmpl
1383         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1384                 -- The args are OutExprs, obtained by *lazily* substituting
1385                 -- in the args found in cont.  These args are only examined
1386                 -- to limited depth (unless a rule fires).  But we must do
1387                 -- the substitution; rule matching on un-simplified args would
1388                 -- be bogus
1389
1390                n_val_args = length arg_infos
1391                interesting_cont = interestingCallContext call_cont
1392                unfolding    = activeUnfolding env var
1393                maybe_inline = callSiteInline dflags var unfolding
1394                                              lone_variable arg_infos interesting_cont
1395         ; case maybe_inline of {
1396             Just expr      -- There is an inlining!
1397               ->  do { checkedTick (UnfoldingDone var)
1398                      ; trace_inline dflags expr cont $
1399                        simplExprF (zapSubstEnv env) expr cont }
1400
1401             ; Nothing -> do               -- No inlining!
1402
1403         { rule_base <- getSimplRules
1404         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1405         ; rebuildCall env info cont
1406     }}}
1407   where
1408     trace_inline dflags unfolding cont stuff
1409       | not (dopt Opt_D_dump_inlinings dflags) = stuff
1410       | not (dopt Opt_D_verbose_core2core dflags) 
1411       = if isExternalName (idName var) then 
1412           pprDefiniteTrace "Inlining done:" (ppr var) stuff
1413         else stuff
1414       | otherwise
1415       = pprDefiniteTrace ("Inlining done: " ++ showSDoc (ppr var))
1416            (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1417                   text "Cont:  " <+> ppr cont])
1418            stuff
1419
1420 rebuildCall :: SimplEnv
1421             -> ArgInfo
1422             -> SimplCont
1423             -> SimplM (SimplEnv, OutExpr)
1424 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1425   -- When we run out of strictness args, it means
1426   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1427   -- Then we want to discard the entire strict continuation.  E.g.
1428   --    * case (error "hello") of { ... }
1429   --    * (error "Hello") arg
1430   --    * f (error "Hello") where f is strict
1431   --    etc
1432   -- Then, especially in the first of these cases, we'd like to discard
1433   -- the continuation, leaving just the bottoming expression.  But the
1434   -- type might not be right, so we may have to add a coerce.
1435   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1436   = return (env, mk_coerce res)  -- contination to discard, else we do it
1437   where                          -- again and again!
1438     res     = mkApps (Var fun) (reverse rev_args)
1439     res_ty  = exprType res
1440     cont_ty = contResultType env res_ty cont
1441     co      = mkUnsafeCo res_ty cont_ty
1442     mk_coerce expr | cont_ty `eqType` res_ty = expr
1443                    | otherwise = mkCoerce co expr
1444
1445 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1446   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1447                     else simplType (se `setInScope` env) arg_ty
1448        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1449
1450 rebuildCall env info@(ArgInfo { ai_encl = encl_rules
1451                               , ai_strs = str:strs, ai_discs = disc:discs })
1452             (ApplyTo dup_flag arg arg_se cont)
1453   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1454   = rebuildCall env (addArgTo info' arg) cont
1455
1456   | str                 -- Strict argument
1457   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1458     simplExprF (arg_se `setFloats` env) arg
1459                (StrictArg info' cci cont)
1460                 -- Note [Shadowing]
1461
1462   | otherwise                           -- Lazy argument
1463         -- DO NOT float anything outside, hence simplExprC
1464         -- There is no benefit (unlike in a let-binding), and we'd
1465         -- have to be very careful about bogus strictness through
1466         -- floating a demanded let.
1467   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1468                              (mkLazyArgStop cci)
1469         ; rebuildCall env (addArgTo info' arg') cont }
1470   where
1471     info' = info { ai_strs = strs, ai_discs = discs }
1472     cci | encl_rules || disc > 0 = ArgCtxt encl_rules  -- Be keener here
1473         | otherwise              = BoringCtxt          -- Nothing interesting
1474
1475 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1476   = do {  -- We've accumulated a simplified call in <fun,rev_args> 
1477           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1478           -- See also Note [Rules for recursive functions]
1479         ; let args = reverse rev_args
1480               env' = zapSubstEnv env
1481         ; mb_rule <- tryRules env rules fun args cont
1482         ; case mb_rule of {
1483              Just (n_args, rule_rhs) -> simplExprF env' rule_rhs $
1484                                         pushSimplifiedArgs env' (drop n_args args) cont ;
1485                  -- n_args says how many args the rule consumed
1486            ; Nothing -> rebuild env (mkApps (Var fun) args) cont      -- No rules
1487     } }
1488 \end{code}
1489
1490 Note [RULES apply to simplified arguments]
1491 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1492 It's very desirable to try RULES once the arguments have been simplified, because
1493 doing so ensures that rule cascades work in one pass.  Consider
1494    {-# RULES g (h x) = k x
1495              f (k x) = x #-}
1496    ...f (g (h x))...
1497 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1498 we match f's rules against the un-simplified RHS, it won't match.  This 
1499 makes a particularly big difference when superclass selectors are involved:
1500         op ($p1 ($p2 (df d)))
1501 We want all this to unravel in one sweeep.
1502
1503 Note [Avoid redundant simplification]
1504 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1505 Because RULES apply to simplified arguments, there's a danger of repeatedly
1506 simplifying already-simplified arguments.  An important example is that of
1507             (>>=) d e1 e2
1508 Here e1, e2 are simplified before the rule is applied, but don't really
1509 participate in the rule firing. So we mark them as Simplified to avoid
1510 re-simplifying them.
1511
1512 Note [Shadowing]
1513 ~~~~~~~~~~~~~~~~
1514 This part of the simplifier may break the no-shadowing invariant
1515 Consider
1516         f (...(\a -> e)...) (case y of (a,b) -> e')
1517 where f is strict in its second arg
1518 If we simplify the innermost one first we get (...(\a -> e)...)
1519 Simplifying the second arg makes us float the case out, so we end up with
1520         case y of (a,b) -> f (...(\a -> e)...) e'
1521 So the output does not have the no-shadowing invariant.  However, there is
1522 no danger of getting name-capture, because when the first arg was simplified
1523 we used an in-scope set that at least mentioned all the variables free in its
1524 static environment, and that is enough.
1525
1526 We can't just do innermost first, or we'd end up with a dual problem:
1527         case x of (a,b) -> f e (...(\a -> e')...)
1528
1529 I spent hours trying to recover the no-shadowing invariant, but I just could
1530 not think of an elegant way to do it.  The simplifier is already knee-deep in
1531 continuations.  We have to keep the right in-scope set around; AND we have
1532 to get the effect that finding (error "foo") in a strict arg position will
1533 discard the entire application and replace it with (error "foo").  Getting
1534 all this at once is TOO HARD!
1535
1536
1537 %************************************************************************
1538 %*                                                                      *
1539                 Rewrite rules
1540 %*                                                                      *
1541 %************************************************************************
1542
1543 \begin{code}
1544 tryRules :: SimplEnv -> [CoreRule]
1545          -> Id -> [OutExpr] -> SimplCont 
1546          -> SimplM (Maybe (Arity, CoreExpr))         -- The arity is the number of
1547                                                      -- args consumed by the rule
1548 tryRules env rules fn args call_cont
1549   | null rules
1550   = return Nothing
1551   | otherwise
1552   = do { case lookupRule (activeRule env) (getUnfoldingInRuleMatch env) 
1553                          (getInScope env) fn args rules of {
1554            Nothing               -> return Nothing ;   -- No rule matches
1555            Just (rule, rule_rhs) ->
1556
1557              do { checkedTick (RuleFired (ru_name rule))
1558                 ; dflags <- getDOptsSmpl
1559                 ; trace_dump dflags rule rule_rhs $
1560                   return (Just (ruleArity rule, rule_rhs)) }}}
1561   where
1562     trace_dump dflags rule rule_rhs stuff
1563       | not (dopt Opt_D_dump_rule_firings dflags)
1564       , not (dopt Opt_D_dump_rule_rewrites dflags) = stuff
1565
1566       | not (dopt Opt_D_dump_rule_rewrites dflags)
1567       = pprDefiniteTrace "Rule fired:" (ftext (ru_name rule)) stuff
1568
1569       | otherwise
1570       = pprDefiniteTrace "Rule fired"
1571            (vcat [text "Rule:" <+> ftext (ru_name rule),
1572                   text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args)),
1573                   text "After: " <+> pprCoreExpr rule_rhs,
1574                   text "Cont:  " <+> ppr call_cont])
1575            stuff
1576 \end{code}
1577
1578 Note [Rules for recursive functions]
1579 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1580 You might think that we shouldn't apply rules for a loop breaker:
1581 doing so might give rise to an infinite loop, because a RULE is
1582 rather like an extra equation for the function:
1583      RULE:           f (g x) y = x+y
1584      Eqn:            f a     y = a-y
1585
1586 But it's too drastic to disable rules for loop breakers.
1587 Even the foldr/build rule would be disabled, because foldr
1588 is recursive, and hence a loop breaker:
1589      foldr k z (build g) = g k z
1590 So it's up to the programmer: rules can cause divergence
1591
1592
1593 %************************************************************************
1594 %*                                                                      *
1595                 Rebuilding a case expression
1596 %*                                                                      *
1597 %************************************************************************
1598
1599 Note [Case elimination]
1600 ~~~~~~~~~~~~~~~~~~~~~~~
1601 The case-elimination transformation discards redundant case expressions.
1602 Start with a simple situation:
1603
1604         case x# of      ===>   let y# = x# in e
1605           y# -> e
1606
1607 (when x#, y# are of primitive type, of course).  We can't (in general)
1608 do this for algebraic cases, because we might turn bottom into
1609 non-bottom!
1610
1611 The code in SimplUtils.prepareAlts has the effect of generalise this
1612 idea to look for a case where we're scrutinising a variable, and we
1613 know that only the default case can match.  For example:
1614
1615         case x of
1616           0#      -> ...
1617           DEFAULT -> ...(case x of
1618                          0#      -> ...
1619                          DEFAULT -> ...) ...
1620
1621 Here the inner case is first trimmed to have only one alternative, the
1622 DEFAULT, after which it's an instance of the previous case.  This
1623 really only shows up in eliminating error-checking code.
1624
1625 Note that SimplUtils.mkCase combines identical RHSs.  So
1626
1627         case e of       ===> case e of DEFAULT -> r
1628            True  -> r
1629            False -> r
1630
1631 Now again the case may be elminated by the CaseElim transformation.
1632 This includes things like (==# a# b#)::Bool so that we simplify
1633       case ==# a# b# of { True -> x; False -> x }
1634 to just
1635       x
1636 This particular example shows up in default methods for
1637 comparision operations (e.g. in (>=) for Int.Int32)
1638
1639 Note [Case elimination: lifted case]
1640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1641 We also make sure that we deal with this very common case,
1642 where x has a lifted type:
1643
1644         case e of
1645           x -> ...x...
1646
1647 Here we are using the case as a strict let; if x is used only once
1648 then we want to inline it.  We have to be careful that this doesn't
1649 make the program terminate when it would have diverged before, so we
1650 check that
1651         (a) 'e' is already evaluated (it may so if e is a variable)
1652             Specifically we check (exprIsHNF e)
1653 or
1654         (b) the scrutinee is a variable and 'x' is used strictly
1655 or
1656         (c) 'x' is not used at all and e is ok-for-speculation
1657
1658 For the (c), consider
1659    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1660      r -> blah
1661 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1662 not want to transform to
1663    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1664    in blah
1665 because that builds an unnecessary thunk.
1666
1667
1668 Further notes about case elimination
1669 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1670 Consider:       test :: Integer -> IO ()
1671                 test = print
1672
1673 Turns out that this compiles to:
1674     Print.test
1675       = \ eta :: Integer
1676           eta1 :: State# RealWorld ->
1677           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1678           case hPutStr stdout
1679                  (PrelNum.jtos eta ($w[] @ Char))
1680                  eta1
1681           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1682
1683 Notice the strange '<' which has no effect at all. This is a funny one.
1684 It started like this:
1685
1686 f x y = if x < 0 then jtos x
1687           else if y==0 then "" else jtos x
1688
1689 At a particular call site we have (f v 1).  So we inline to get
1690
1691         if v < 0 then jtos x
1692         else if 1==0 then "" else jtos x
1693
1694 Now simplify the 1==0 conditional:
1695
1696         if v<0 then jtos v else jtos v
1697
1698 Now common-up the two branches of the case:
1699
1700         case (v<0) of DEFAULT -> jtos v
1701
1702 Why don't we drop the case?  Because it's strict in v.  It's technically
1703 wrong to drop even unnecessary evaluations, and in practice they
1704 may be a result of 'seq' so we *definitely* don't want to drop those.
1705 I don't really know how to improve this situation.
1706
1707 \begin{code}
1708 ---------------------------------------------------------
1709 --      Eliminate the case if possible
1710
1711 rebuildCase, reallyRebuildCase
1712    :: SimplEnv
1713    -> OutExpr          -- Scrutinee
1714    -> InId             -- Case binder
1715    -> [InAlt]          -- Alternatives (inceasing order)
1716    -> SimplCont
1717    -> SimplM (SimplEnv, OutExpr)
1718
1719 --------------------------------------------------
1720 --      1. Eliminate the case if there's a known constructor
1721 --------------------------------------------------
1722
1723 rebuildCase env scrut case_bndr alts cont
1724   | Lit lit <- scrut    -- No need for same treatment as constructors
1725                         -- because literals are inlined more vigorously
1726   , not (litIsLifted lit)
1727   = do  { tick (KnownBranch case_bndr)
1728         ; case findAlt (LitAlt lit) alts of
1729             Nothing           -> missingAlt env case_bndr alts cont
1730             Just (_, bs, rhs) -> simple_rhs bs rhs }
1731
1732   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1733         -- Works when the scrutinee is a variable with a known unfolding
1734         -- as well as when it's an explicit constructor application
1735   = do  { tick (KnownBranch case_bndr)
1736         ; case findAlt (DataAlt con) alts of
1737             Nothing  -> missingAlt env case_bndr alts cont
1738             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1739             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args 
1740                                                 case_bndr bs rhs cont
1741         }
1742   where
1743     simple_rhs bs rhs = ASSERT( null bs ) 
1744                         do { env' <- simplNonRecX env case_bndr scrut
1745                            ; simplExprF env' rhs cont }
1746
1747
1748 --------------------------------------------------
1749 --      2. Eliminate the case if scrutinee is evaluated
1750 --------------------------------------------------
1751
1752 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1753   -- See if we can get rid of the case altogether
1754   -- See Note [Case elimination] 
1755   -- mkCase made sure that if all the alternatives are equal,
1756   -- then there is now only one (DEFAULT) rhs
1757  | all isDeadBinder bndrs       -- bndrs are [InId]
1758
1759  , if isUnLiftedType (idType case_bndr)
1760    then ok_for_spec         -- Satisfy the let-binding invariant
1761    else elim_lifted
1762   = do  { tick (CaseElim case_bndr)
1763         ; env' <- simplNonRecX env case_bndr scrut
1764           -- If case_bndr is deads, simplNonRecX will discard
1765         ; simplExprF env' rhs cont }
1766   where
1767     elim_lifted   -- See Note [Case elimination: lifted case]
1768       = exprIsHNF scrut
1769      || (strict_case_bndr && scrut_is_var scrut) 
1770               -- The case binder is going to be evaluated later,
1771               -- and the scrutinee is a simple variable
1772
1773      || (is_plain_seq && ok_for_spec)
1774               -- Note: not the same as exprIsHNF
1775
1776     ok_for_spec      = exprOkForSpeculation scrut
1777     is_plain_seq     = isDeadBinder case_bndr   -- Evaluation *only* for effect
1778     strict_case_bndr = isStrictDmd (idDemandInfo case_bndr)
1779
1780     scrut_is_var (Cast s _) = scrut_is_var s
1781     scrut_is_var (Var _)    = True
1782     scrut_is_var _          = False
1783
1784
1785 --------------------------------------------------
1786 --      3. Try seq rules; see Note [User-defined RULES for seq] in MkId
1787 --------------------------------------------------
1788
1789 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1790   | all isDeadBinder (case_bndr : bndrs)  -- So this is just 'seq'
1791   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1792              out_args = [Type (substTy env (idType case_bndr)), 
1793                          Type (exprType rhs'), scrut, rhs']
1794                       -- Lazily evaluated, so we don't do most of this
1795
1796        ; rule_base <- getSimplRules
1797        ; mb_rule <- tryRules env (getRules rule_base seqId) seqId out_args cont
1798        ; case mb_rule of 
1799            Just (n_args, res) -> simplExprF (zapSubstEnv env) 
1800                                             (mkApps res (drop n_args out_args))
1801                                             cont
1802            Nothing -> reallyRebuildCase env scrut case_bndr alts cont }
1803
1804 rebuildCase env scrut case_bndr alts cont
1805   = reallyRebuildCase env scrut case_bndr alts cont
1806
1807 --------------------------------------------------
1808 --      3. Catch-all case
1809 --------------------------------------------------
1810
1811 reallyRebuildCase env scrut case_bndr alts cont
1812   = do  {       -- Prepare the continuation;
1813                 -- The new subst_env is in place
1814           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1815
1816         -- Simplify the alternatives
1817         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1818
1819         -- Check for empty alternatives
1820         ; if null alts' then missingAlt env case_bndr alts cont
1821           else do
1822         { dflags <- getDOptsSmpl
1823         ; case_expr <- mkCase dflags scrut' case_bndr' alts'
1824
1825         -- Notice that rebuild gets the in-scope set from env', not alt_env
1826         -- (which in any case is only build in simplAlts)
1827         -- The case binder *not* scope over the whole returned case-expression
1828         ; rebuild env' case_expr nodup_cont } }
1829 \end{code}
1830
1831 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1832 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1833 way, there's a chance that v will now only be used once, and hence
1834 inlined.
1835
1836 Historical note: we use to do the "case binder swap" in the Simplifier
1837 so there were additional complications if the scrutinee was a variable.
1838 Now the binder-swap stuff is done in the occurrence analyer; see
1839 OccurAnal Note [Binder swap].
1840
1841 Note [zapOccInfo]
1842 ~~~~~~~~~~~~~~~~~
1843 If the case binder is not dead, then neither are the pattern bound
1844 variables:  
1845         case <any> of x { (a,b) ->
1846         case x of { (p,q) -> p } }
1847 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1848 The point is that we bring into the envt a binding
1849         let x = (a,b)
1850 after the outer case, and that makes (a,b) alive.  At least we do unless
1851 the case binder is guaranteed dead.
1852
1853 In practice, the scrutinee is almost always a variable, so we pretty
1854 much always zap the OccInfo of the binders.  It doesn't matter much though.
1855
1856 Note [Improving seq]
1857 ~~~~~~~~~~~~~~~~~~~
1858 Consider
1859         type family F :: * -> *
1860         type instance F Int = Int
1861
1862         ... case e of x { DEFAULT -> rhs } ...
1863
1864 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1865
1866         case e `cast` co of x'::Int
1867            I# x# -> let x = x' `cast` sym co
1868                     in rhs
1869
1870 so that 'rhs' can take advantage of the form of x'.  
1871
1872 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result. 
1873
1874 Nota Bene: We only do the [Improving seq] transformation if the 
1875 case binder 'x' is actually used in the rhs; that is, if the case 
1876 is *not* a *pure* seq.  
1877   a) There is no point in adding the cast to a pure seq.
1878   b) There is a good reason not to: doing so would interfere 
1879      with seq rules (Note [Built-in RULES for seq] in MkId).
1880      In particular, this [Improving seq] thing *adds* a cast
1881      while [Built-in RULES for seq] *removes* one, so they
1882      just flip-flop.
1883
1884 You might worry about 
1885    case v of x { __DEFAULT ->
1886       ... case (v `cast` co) of y { I# -> ... }}
1887 This is a pure seq (since x is unused), so [Improving seq] won't happen.
1888 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
1889    case v of x { __DEFAULT ->
1890       ... case (x `cast` co) of y { I# -> ... }}
1891 Now the outer case is not a pure seq, so [Improving seq] will happen,
1892 and then the inner case will disappear.
1893
1894 The need for [Improving seq] showed up in Roman's experiments.  Example:
1895   foo :: F Int -> Int -> Int
1896   foo t n = t `seq` bar n
1897      where
1898        bar 0 = 0
1899        bar n = bar (n - case t of TI i -> i)
1900 Here we'd like to avoid repeated evaluating t inside the loop, by
1901 taking advantage of the `seq`.
1902
1903 At one point I did transformation in LiberateCase, but it's more
1904 robust here.  (Otherwise, there's a danger that we'll simply drop the
1905 'seq' altogether, before LiberateCase gets to see it.)
1906
1907 \begin{code}
1908 simplAlts :: SimplEnv
1909           -> OutExpr
1910           -> InId                       -- Case binder
1911           -> [InAlt]                    -- Non-empty
1912           -> SimplCont
1913           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
1914 -- Like simplExpr, this just returns the simplified alternatives;
1915 -- it does not return an environment
1916
1917 simplAlts env scrut case_bndr alts cont'
1918   = -- pprTrace "simplAlts" (ppr alts $$ ppr (seTvSubst env)) $
1919     do  { let env0 = zapFloats env
1920
1921         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
1922
1923         ; fam_envs <- getFamEnvs
1924         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut 
1925                                                        case_bndr case_bndr1 alts
1926
1927         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
1928
1929         ; let mb_var_scrut = case scrut' of { Var v -> Just v; _ -> Nothing }
1930         ; alts' <- mapM (simplAlt alt_env' mb_var_scrut
1931                              imposs_deflt_cons case_bndr' cont') in_alts
1932         ; return (scrut', case_bndr', alts') }
1933
1934
1935 ------------------------------------
1936 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
1937            -> OutExpr -> InId -> OutId -> [InAlt]
1938            -> SimplM (SimplEnv, OutExpr, OutId)
1939 -- Note [Improving seq]
1940 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
1941   | not (isDeadBinder case_bndr)        -- Not a pure seq!  See Note [Improving seq]
1942   , Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
1943   = do { case_bndr2 <- newId (fsLit "nt") ty2
1944         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
1945               env2 = extendIdSubst env case_bndr rhs
1946         ; return (env2, scrut `Cast` co, case_bndr2) }
1947
1948 improveSeq _ env scrut _ case_bndr1 _
1949   = return (env, scrut, case_bndr1)
1950
1951
1952 ------------------------------------
1953 simplAlt :: SimplEnv
1954          -> Maybe OutId    -- Scrutinee
1955          -> [AltCon]       -- These constructors can't be present when
1956                            -- matching the DEFAULT alternative
1957          -> OutId          -- The case binder
1958          -> SimplCont
1959          -> InAlt
1960          -> SimplM OutAlt
1961
1962 simplAlt env scrut imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1963   = ASSERT( null bndrs )
1964     do  { let env' = addBinderUnfolding env scrut case_bndr' 
1965                                         (mkOtherCon imposs_deflt_cons)
1966                 -- Record the constructors that the case-binder *can't* be.
1967         ; rhs' <- simplExprC env' rhs cont'
1968         ; return (DEFAULT, [], rhs') }
1969
1970 simplAlt env scrut _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
1971   = ASSERT( null bndrs )
1972     do  { let env' = addBinderUnfolding env scrut case_bndr' 
1973                                         (mkSimpleUnfolding (Lit lit))
1974         ; rhs' <- simplExprC env' rhs cont'
1975         ; return (LitAlt lit, [], rhs') }
1976
1977 simplAlt env scrut _ case_bndr' cont' (DataAlt con, vs, rhs)
1978   = do  {       -- Deal with the pattern-bound variables
1979                 -- Mark the ones that are in ! positions in the
1980                 -- data constructor as certainly-evaluated.
1981                 -- NB: simplLamBinders preserves this eval info
1982           let vs_with_evals = add_evals (dataConRepStrictness con)
1983         ; (env', vs') <- simplLamBndrs env vs_with_evals
1984
1985                 -- Bind the case-binder to (con args)
1986         ; let inst_tys' = tyConAppArgs (idType case_bndr')
1987               con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
1988               unf       = mkSimpleUnfolding (mkConApp con con_args)
1989               env''     = addBinderUnfolding env' scrut case_bndr' unf
1990
1991         ; rhs' <- simplExprC env'' rhs cont'
1992         ; return (DataAlt con, vs', rhs') }
1993   where
1994         -- add_evals records the evaluated-ness of the bound variables of
1995         -- a case pattern.  This is *important*.  Consider
1996         --      data T = T !Int !Int
1997         --
1998         --      case x of { T a b -> T (a+1) b }
1999         --
2000         -- We really must record that b is already evaluated so that we don't
2001         -- go and re-evaluate it when constructing the result.
2002         -- See Note [Data-con worker strictness] in MkId.lhs
2003     add_evals the_strs
2004         = go vs the_strs
2005         where
2006           go [] [] = []
2007           go (v:vs') strs | isTyVar v = v : go vs' strs
2008           go (v:vs') (str:strs)
2009             | isMarkedStrict str = evald_v  : go vs' strs
2010             | otherwise          = zapped_v : go vs' strs
2011             where
2012               zapped_v = zapBndrOccInfo keep_occ_info v
2013               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2014           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2015
2016         -- See Note [zapOccInfo]
2017         -- zap_occ_info: if the case binder is alive, then we add the unfolding
2018         --      case_bndr = C vs
2019         -- to the envt; so vs are now very much alive
2020         -- Note [Aug06] I can't see why this actually matters, but it's neater
2021         --        case e of t { (a,b) -> ...(case t of (p,q) -> p)... }
2022         --   ==>  case e of t { (a,b) -> ...(a)... }
2023         -- Look, Ma, a is alive now.
2024     keep_occ_info = isDeadBinder case_bndr' && isNothing scrut
2025
2026 addBinderUnfolding :: SimplEnv -> Maybe OutId -> Id -> Unfolding -> SimplEnv
2027 addBinderUnfolding env scrut bndr unf
2028   = case scrut of
2029        Just v -> modifyInScope env1 (v `setIdUnfolding` unf)
2030        _      -> env1
2031   where
2032     env1 = modifyInScope env bndr_w_unf
2033     bndr_w_unf = bndr `setIdUnfolding` unf
2034
2035 zapBndrOccInfo :: Bool -> Id -> Id
2036 -- Consider  case e of b { (a,b) -> ... }
2037 -- Then if we bind b to (a,b) in "...", and b is not dead,
2038 -- then we must zap the deadness info on a,b
2039 zapBndrOccInfo keep_occ_info pat_id
2040   | keep_occ_info = pat_id
2041   | otherwise     = zapIdOccInfo pat_id
2042 \end{code}
2043
2044 Note [Add unfolding for scrutinee]
2045 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2046 In general it's unlikely that a variable scrutinee will appear 
2047 in the case alternatives   case x of { ...x unlikely to appear... }
2048 because the binder-swap in OccAnal has got rid of all such occcurrences
2049 See Note [Binder swap] in OccAnal.
2050
2051 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2052 variable scrutinee, in simplAlt.  Here's why
2053    case x of y
2054      (a,b) -> case b of c
2055                 I# v -> ...(f y)...
2056 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2057 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2058     RULE f (p, I# q) = ...
2059 we want that rule to match, so we must extend the in-scope env with a
2060 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2061 it's also good for case-elimintation -- suppose that 'f' was inlined
2062 and did multi-level case analysis, then we'd solve it in one
2063 simplifier sweep instead of two.
2064
2065 Exactly the same issue arises in SpecConstr; 
2066 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2067
2068 %************************************************************************
2069 %*                                                                      *
2070 \subsection{Known constructor}
2071 %*                                                                      *
2072 %************************************************************************
2073
2074 We are a bit careful with occurrence info.  Here's an example
2075
2076         (\x* -> case x of (a*, b) -> f a) (h v, e)
2077
2078 where the * means "occurs once".  This effectively becomes
2079         case (h v, e) of (a*, b) -> f a)
2080 and then
2081         let a* = h v; b = e in f a
2082 and then
2083         f (h v)
2084
2085 All this should happen in one sweep.
2086
2087 \begin{code}
2088 knownCon :: SimplEnv            
2089          -> OutExpr                             -- The scrutinee
2090          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2091          -> InId -> [InBndr] -> InExpr          -- The alternative
2092          -> SimplCont
2093          -> SimplM (SimplEnv, OutExpr)
2094
2095 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2096   = do  { env'  <- bind_args env bs dc_args
2097         ; env'' <- bind_case_bndr env'
2098         ; simplExprF env'' rhs cont }
2099   where
2100     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2101
2102                   -- Ugh!
2103     bind_args env' [] _  = return env'
2104
2105     bind_args env' (b:bs') (Type ty : args)
2106       = ASSERT( isTyVar b )
2107         bind_args (extendTvSubst env' b ty) bs' args
2108
2109     bind_args env' (b:bs') (arg : args)
2110       = ASSERT( isId b )
2111         do { let b' = zap_occ b
2112              -- Note that the binder might be "dead", because it doesn't
2113              -- occur in the RHS; and simplNonRecX may therefore discard
2114              -- it via postInlineUnconditionally.
2115              -- Nevertheless we must keep it if the case-binder is alive,
2116              -- because it may be used in the con_app.  See Note [zapOccInfo]
2117            ; env'' <- simplNonRecX env' b' arg
2118            ; bind_args env'' bs' args }
2119
2120     bind_args _ _ _ =
2121       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2122                              text "scrut:" <+> ppr scrut
2123
2124        -- It's useful to bind bndr to scrut, rather than to a fresh
2125        -- binding      x = Con arg1 .. argn
2126        -- because very often the scrut is a variable, so we avoid
2127        -- creating, and then subsequently eliminating, a let-binding
2128        -- BUT, if scrut is a not a variable, we must be careful
2129        -- about duplicating the arg redexes; in that case, make
2130        -- a new con-app from the args
2131     bind_case_bndr env
2132       | isDeadBinder bndr   = return env
2133       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2134       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2135                                          -- dc_ty_args are aready OutTypes, 
2136                                          -- but bs are InBndrs
2137                                  ; let con_app = Var (dataConWorkId dc) 
2138                                                  `mkTyApps` dc_ty_args      
2139                                                  `mkApps`   dc_args
2140                                  ; simplNonRecX env bndr con_app }
2141   
2142 -------------------
2143 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2144                 -- This isn't strictly an error, although it is unusual. 
2145                 -- It's possible that the simplifer might "see" that 
2146                 -- an inner case has no accessible alternatives before 
2147                 -- it "sees" that the entire branch of an outer case is 
2148                 -- inaccessible.  So we simply put an error case here instead.
2149 missingAlt env case_bndr alts cont
2150   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2151     return (env, mkImpossibleExpr res_ty)
2152   where
2153     res_ty = contResultType env (substTy env (coreAltsType alts)) cont
2154 \end{code}
2155
2156
2157 %************************************************************************
2158 %*                                                                      *
2159 \subsection{Duplicating continuations}
2160 %*                                                                      *
2161 %************************************************************************
2162
2163 \begin{code}
2164 prepareCaseCont :: SimplEnv
2165                 -> [InAlt] -> SimplCont
2166                 -> SimplM (SimplEnv, SimplCont, SimplCont)
2167 -- We are considering
2168 --     K[case _ of { p1 -> r1; ...; pn -> rn }] 
2169 -- where K is some enclosing continuation for the case
2170 -- Goal: split K into two pieces Kdup,Knodup so that
2171 --       a) Kdup can be duplicated
2172 --       b) Knodup[Kdup[e]] = K[e]
2173 -- The idea is that we'll transform thus:
2174 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2175 --
2176 -- We also return some extra bindings in SimplEnv (that scope over 
2177 -- the entire continuation)
2178
2179 prepareCaseCont env alts cont 
2180   | many_alts alts = mkDupableCont env cont 
2181   | otherwise      = return (env, cont, mkBoringStop)
2182   where
2183     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2184     many_alts []  = False         -- See Note [Bottom alternatives]
2185     many_alts [_] = False
2186     many_alts (alt:alts) 
2187       | is_bot_alt alt = many_alts alts   
2188       | otherwise      = not (all is_bot_alt alts)
2189   
2190     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2191 \end{code}
2192
2193 Note [Bottom alternatives]
2194 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2195 When we have
2196      case (case x of { A -> error .. ; B -> e; C -> error ..) 
2197        of alts
2198 then we can just duplicate those alts because the A and C cases
2199 will disappear immediately.  This is more direct than creating
2200 join points and inlining them away; and in some cases we would
2201 not even create the join points (see Note [Single-alternative case])
2202 and we would keep the case-of-case which is silly.  See Trac #4930.
2203
2204 \begin{code}
2205 mkDupableCont :: SimplEnv -> SimplCont
2206               -> SimplM (SimplEnv, SimplCont, SimplCont)
2207
2208 mkDupableCont env cont
2209   | contIsDupable cont
2210   = return (env, cont, mkBoringStop)
2211
2212 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2213
2214 mkDupableCont env (CoerceIt ty cont)
2215   = do  { (env', dup, nodup) <- mkDupableCont env cont
2216         ; return (env', CoerceIt ty dup, nodup) }
2217
2218 -- Duplicating ticks for now, not sure if this is good or not
2219 mkDupableCont env cont@(TickIt{})
2220   = return (env, mkBoringStop, cont)
2221
2222 mkDupableCont env cont@(StrictBind {})
2223   =  return (env, mkBoringStop, cont)
2224         -- See Note [Duplicating StrictBind]
2225
2226 mkDupableCont env (StrictArg info cci cont)
2227         -- See Note [Duplicating StrictArg]
2228   = do { (env', dup, nodup) <- mkDupableCont env cont
2229        ; (env'', args')     <- mapAccumLM (makeTrivial NotTopLevel) env' (ai_args info)
2230        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2231
2232 mkDupableCont env (ApplyTo _ arg se cont)
2233   =     -- e.g.         [...hole...] (...arg...)
2234         --      ==>
2235         --              let a = ...arg...
2236         --              in [...hole...] a
2237     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2238         ; arg' <- simplExpr (se `setInScope` env') arg
2239         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2240         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2241         ; return (env'', app_cont, nodup_cont) }
2242
2243 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2244 --  See Note [Single-alternative case]
2245 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2246 --  | not (isDeadBinder case_bndr)
2247   | all isDeadBinder bs  -- InIds
2248     && not (isUnLiftedType (idType case_bndr))
2249     -- Note [Single-alternative-unlifted]
2250   = return (env, mkBoringStop, cont)
2251
2252 mkDupableCont env (Select _ case_bndr alts se cont)
2253   =     -- e.g.         (case [...hole...] of { pi -> ei })
2254         --      ===>
2255         --              let ji = \xij -> ei
2256         --              in case [...hole...] of { pi -> ji xij }
2257     do  { tick (CaseOfCase case_bndr)
2258         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2259                 -- NB: We call prepareCaseCont here.  If there is only one
2260                 -- alternative, then dup_cont may be big, but that's ok
2261                 -- becuase we push it into the single alternative, and then
2262                 -- use mkDupableAlt to turn that simplified alternative into
2263                 -- a join point if it's too big to duplicate.
2264                 -- And this is important: see Note [Fusing case continuations]
2265
2266         ; let alt_env = se `setInScope` env'
2267         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2268         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2269         -- Safe to say that there are no handled-cons for the DEFAULT case
2270                 -- NB: simplBinder does not zap deadness occ-info, so
2271                 -- a dead case_bndr' will still advertise its deadness
2272                 -- This is really important because in
2273                 --      case e of b { (# p,q #) -> ... }
2274                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2275                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2276                 -- In the new alts we build, we have the new case binder, so it must retain
2277                 -- its deadness.
2278         -- NB: we don't use alt_env further; it has the substEnv for
2279         --     the alternatives, and we don't want that
2280
2281         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2282         ; return (env'',  -- Note [Duplicated env]
2283                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'') mkBoringStop,
2284                   nodup_cont) }
2285
2286
2287 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2288               -> SimplM (SimplEnv, [InAlt])
2289 -- Absorbs the continuation into the new alternatives
2290
2291 mkDupableAlts env case_bndr' the_alts
2292   = go env the_alts
2293   where
2294     go env0 [] = return (env0, [])
2295     go env0 (alt:alts)
2296         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2297              ; (env2, alts') <- go env1 alts
2298              ; return (env2, alt' : alts' ) }
2299
2300 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2301               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2302 mkDupableAlt env case_bndr (con, bndrs', rhs')
2303   | exprIsDupable rhs'  -- Note [Small alternative rhs]
2304   = return (env, (con, bndrs', rhs'))
2305   | otherwise
2306   = do  { let rhs_ty'  = exprType rhs'
2307               scrut_ty = idType case_bndr
2308               case_bndr_w_unf   
2309                 = case con of 
2310                       DEFAULT    -> case_bndr                                   
2311                       DataAlt dc -> setIdUnfolding case_bndr unf
2312                           where
2313                                  -- See Note [Case binders and join points]
2314                              unf = mkInlineUnfolding Nothing rhs
2315                              rhs = mkConApp dc (map Type (tyConAppArgs scrut_ty)
2316                                                 ++ varsToCoreExprs bndrs')
2317
2318                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2319                                                 <+> ppr case_bndr <+> ppr con )
2320                                    case_bndr
2321                            -- The case binder is alive but trivial, so why has 
2322                            -- it not been substituted away?
2323
2324               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2325                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2326               
2327               abstract_over bndr
2328                   | isTyVar bndr = True -- Abstract over all type variables just in case
2329                   | otherwise    = not (isDeadBinder bndr)
2330                         -- The deadness info on the new Ids is preserved by simplBinders
2331
2332         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2333                 <- if (any isId used_bndrs')
2334                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2335                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
2336                             ; return ([rw_id], [Var realWorldPrimId]) }
2337
2338         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2339                 -- Note [Funky mkPiTypes]
2340
2341         ; let   -- We make the lambdas into one-shot-lambdas.  The
2342                 -- join point is sure to be applied at most once, and doing so
2343                 -- prevents the body of the join point being floated out by
2344                 -- the full laziness pass
2345                 really_final_bndrs     = map one_shot final_bndrs'
2346                 one_shot v | isId v    = setOneShotLambda v
2347                            | otherwise = v
2348                 join_rhs   = mkLams really_final_bndrs rhs'
2349                 join_arity = exprArity join_rhs
2350                 join_call  = mkApps (Var join_bndr) final_args
2351
2352         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2353         ; return (env', (con, bndrs', join_call)) }
2354                 -- See Note [Duplicated env]
2355 \end{code}
2356
2357 Note [Fusing case continuations]
2358 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2359 It's important to fuse two successive case continuations when the
2360 first has one alternative.  That's why we call prepareCaseCont here.
2361 Consider this, which arises from thunk splitting (see Note [Thunk
2362 splitting] in WorkWrap):
2363
2364       let
2365         x* = case (case v of {pn -> rn}) of 
2366                I# a -> I# a
2367       in body
2368
2369 The simplifier will find
2370     (Var v) with continuation  
2371             Select (pn -> rn) (
2372             Select [I# a -> I# a] (
2373             StrictBind body Stop
2374
2375 So we'll call mkDupableCont on 
2376    Select [I# a -> I# a] (StrictBind body Stop)
2377 There is just one alternative in the first Select, so we want to
2378 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2379 Supposing that body is big, we end up with
2380           let $j a = <let x = I# a in body> 
2381           in case v of { pn -> case rn of 
2382                                  I# a -> $j a }
2383 This is just what we want because the rn produces a box that
2384 the case rn cancels with.  
2385
2386 See Trac #4957 a fuller example.
2387
2388 Note [Case binders and join points]
2389 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2390 Consider this 
2391    case (case .. ) of c {
2392      I# c# -> ....c....
2393
2394 If we make a join point with c but not c# we get
2395   $j = \c -> ....c....
2396
2397 But if later inlining scrutines the c, thus
2398
2399   $j = \c -> ... case c of { I# y -> ... } ...
2400
2401 we won't see that 'c' has already been scrutinised.  This actually
2402 happens in the 'tabulate' function in wave4main, and makes a significant
2403 difference to allocation.
2404
2405 An alternative plan is this:
2406
2407    $j = \c# -> let c = I# c# in ...c....
2408
2409 but that is bad if 'c' is *not* later scrutinised.  
2410
2411 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2412 (an InlineRule) that it's really I# c#, thus
2413    
2414    $j = \c# -> \c[=I# c#] -> ...c....
2415
2416 Absence analysis may later discard 'c'.
2417
2418 NB: take great care when doing strictness analysis; 
2419     see Note [Lamba-bound unfoldings] in DmdAnal.
2420
2421 Also note that we can still end up passing stuff that isn't used.  Before
2422 strictness analysis we have
2423    let $j x y c{=(x,y)} = (h c, ...)
2424    in ...
2425 After strictness analysis we see that h is strict, we end up with
2426    let $j x y c{=(x,y)} = ($wh x y, ...)
2427 and c is unused.
2428    
2429 Note [Duplicated env]
2430 ~~~~~~~~~~~~~~~~~~~~~
2431 Some of the alternatives are simplified, but have not been turned into a join point
2432 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2433 bind the join point, because it might to do PostInlineUnconditionally, and
2434 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2435 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2436 at worst delays the join-point inlining.
2437
2438 Note [Small alternative rhs]
2439 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2440 It is worth checking for a small RHS because otherwise we
2441 get extra let bindings that may cause an extra iteration of the simplifier to
2442 inline back in place.  Quite often the rhs is just a variable or constructor.
2443 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2444 iterations because the version with the let bindings looked big, and so wasn't
2445 inlined, but after the join points had been inlined it looked smaller, and so
2446 was inlined.
2447
2448 NB: we have to check the size of rhs', not rhs.
2449 Duplicating a small InAlt might invalidate occurrence information
2450 However, if it *is* dupable, we return the *un* simplified alternative,
2451 because otherwise we'd need to pair it up with an empty subst-env....
2452 but we only have one env shared between all the alts.
2453 (Remember we must zap the subst-env before re-simplifying something).
2454 Rather than do this we simply agree to re-simplify the original (small) thing later.
2455
2456 Note [Funky mkPiTypes]
2457 ~~~~~~~~~~~~~~~~~~~~~~
2458 Notice the funky mkPiTypes.  If the contructor has existentials
2459 it's possible that the join point will be abstracted over
2460 type varaibles as well as term variables.
2461  Example:  Suppose we have
2462         data T = forall t.  C [t]
2463  Then faced with
2464         case (case e of ...) of
2465             C t xs::[t] -> rhs
2466  We get the join point
2467         let j :: forall t. [t] -> ...
2468             j = /\t \xs::[t] -> rhs
2469         in
2470         case (case e of ...) of
2471             C t xs::[t] -> j t xs
2472
2473 Note [Join point abstaction]
2474 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2475 If we try to lift a primitive-typed something out
2476 for let-binding-purposes, we will *caseify* it (!),
2477 with potentially-disastrous strictness results.  So
2478 instead we turn it into a function: \v -> e
2479 where v::State# RealWorld#.  The value passed to this function
2480 is realworld#, which generates (almost) no code.
2481
2482 There's a slight infelicity here: we pass the overall
2483 case_bndr to all the join points if it's used in *any* RHS,
2484 because we don't know its usage in each RHS separately
2485
2486 We used to say "&& isUnLiftedType rhs_ty'" here, but now
2487 we make the join point into a function whenever used_bndrs'
2488 is empty.  This makes the join-point more CPR friendly.
2489 Consider:       let j = if .. then I# 3 else I# 4
2490                 in case .. of { A -> j; B -> j; C -> ... }
2491
2492 Now CPR doesn't w/w j because it's a thunk, so
2493 that means that the enclosing function can't w/w either,
2494 which is a lose.  Here's the example that happened in practice:
2495         kgmod :: Int -> Int -> Int
2496         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2497                     then 78
2498                     else 5
2499
2500 I have seen a case alternative like this:
2501         True -> \v -> ...
2502 It's a bit silly to add the realWorld dummy arg in this case, making
2503         $j = \s v -> ...
2504            True -> $j s
2505 (the \v alone is enough to make CPR happy) but I think it's rare
2506
2507 Note [Duplicating StrictArg]
2508 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2509 The original plan had (where E is a big argument)
2510 e.g.    f E [..hole..]
2511         ==>     let $j = \a -> f E a
2512                 in $j [..hole..]
2513
2514 But this is terrible! Here's an example:
2515         && E (case x of { T -> F; F -> T })
2516 Now, && is strict so we end up simplifying the case with
2517 an ArgOf continuation.  If we let-bind it, we get
2518         let $j = \v -> && E v
2519         in simplExpr (case x of { T -> F; F -> T })
2520                      (ArgOf (\r -> $j r)
2521 And after simplifying more we get
2522         let $j = \v -> && E v
2523         in case x of { T -> $j F; F -> $j T }
2524 Which is a Very Bad Thing
2525
2526 What we do now is this
2527         f E [..hole..]
2528         ==>     let a = E
2529                 in f a [..hole..]
2530 Now if the thing in the hole is a case expression (which is when
2531 we'll call mkDupableCont), we'll push the function call into the
2532 branches, which is what we want.  Now RULES for f may fire, and
2533 call-pattern specialisation.  Here's an example from Trac #3116
2534      go (n+1) (case l of
2535                  1  -> bs'
2536                  _  -> Chunk p fpc (o+1) (l-1) bs')
2537 If we can push the call for 'go' inside the case, we get
2538 call-pattern specialisation for 'go', which is *crucial* for 
2539 this program.
2540
2541 Here is the (&&) example: 
2542         && E (case x of { T -> F; F -> T })
2543   ==>   let a = E in 
2544         case x of { T -> && a F; F -> && a T }
2545 Much better!
2546
2547 Notice that 
2548   * Arguments to f *after* the strict one are handled by 
2549     the ApplyTo case of mkDupableCont.  Eg
2550         f [..hole..] E
2551
2552   * We can only do the let-binding of E because the function
2553     part of a StrictArg continuation is an explicit syntax
2554     tree.  In earlier versions we represented it as a function
2555     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2556
2557 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2558 nothing by propagating them into the expressions, and we do lose a
2559 lot.  
2560
2561 The desire not to duplicate is the entire reason that
2562 mkDupableCont returns a pair of continuations.
2563
2564 Note [Duplicating StrictBind]
2565 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2566 Unlike StrictArg, there doesn't seem anything to gain from
2567 duplicating a StrictBind continuation, so we don't.
2568
2569
2570 Note [Single-alternative cases]
2571 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2572 This case is just like the ArgOf case.  Here's an example:
2573         data T a = MkT !a
2574         ...(MkT (abs x))...
2575 Then we get
2576         case (case x of I# x' ->
2577               case x' <# 0# of
2578                 True  -> I# (negate# x')
2579                 False -> I# x') of y {
2580           DEFAULT -> MkT y
2581 Because the (case x) has only one alternative, we'll transform to
2582         case x of I# x' ->
2583         case (case x' <# 0# of
2584                 True  -> I# (negate# x')
2585                 False -> I# x') of y {
2586           DEFAULT -> MkT y
2587 But now we do *NOT* want to make a join point etc, giving
2588         case x of I# x' ->
2589         let $j = \y -> MkT y
2590         in case x' <# 0# of
2591                 True  -> $j (I# (negate# x'))
2592                 False -> $j (I# x')
2593 In this case the $j will inline again, but suppose there was a big
2594 strict computation enclosing the orginal call to MkT.  Then, it won't
2595 "see" the MkT any more, because it's big and won't get duplicated.
2596 And, what is worse, nothing was gained by the case-of-case transform.
2597
2598 So, in circumstances like these, we don't want to build join points
2599 and push the outer case into the branches of the inner one. Instead,
2600 don't duplicate the continuation. 
2601
2602 When should we use this strategy?  We should not use it on *every*
2603 single-alternative case:
2604   e.g.  case (case ....) of (a,b) -> (# a,b #)
2605 Here we must push the outer case into the inner one!
2606 Other choices:
2607
2608    * Match [(DEFAULT,_,_)], but in the common case of Int,
2609      the alternative-filling-in code turned the outer case into
2610                 case (...) of y { I# _ -> MkT y }
2611
2612    * Match on single alternative plus (not (isDeadBinder case_bndr))
2613      Rationale: pushing the case inwards won't eliminate the construction.
2614      But there's a risk of
2615                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2616      Now y looks dead, but it'll come alive again.  Still, this
2617      seems like the best option at the moment.
2618
2619    * Match on single alternative plus (all (isDeadBinder bndrs))
2620      Rationale: this is essentially  seq.
2621
2622    * Match when the rhs is *not* duplicable, and hence would lead to a
2623      join point.  This catches the disaster-case above.  We can test
2624      the *un-simplified* rhs, which is fine.  It might get bigger or
2625      smaller after simplification; if it gets smaller, this case might
2626      fire next time round.  NB also that we must test contIsDupable
2627      case_cont *too, because case_cont might be big!
2628
2629      HOWEVER: I found that this version doesn't work well, because
2630      we can get         let x = case (...) of { small } in ...case x...
2631      When x is inlined into its full context, we find that it was a bad
2632      idea to have pushed the outer case inside the (...) case.
2633
2634 Note [Single-alternative-unlifted]
2635 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2636 Here's another single-alternative where we really want to do case-of-case:
2637
2638 data Mk1 = Mk1 Int# | Mk2 Int#
2639
2640 M1.f =
2641     \r [x_s74 y_s6X]
2642         case
2643             case y_s6X of tpl_s7m {
2644               M1.Mk1 ipv_s70 -> ipv_s70;
2645               M1.Mk2 ipv_s72 -> ipv_s72;
2646             }
2647         of
2648         wild_s7c
2649         { __DEFAULT ->
2650               case
2651                   case x_s74 of tpl_s7n {
2652                     M1.Mk1 ipv_s77 -> ipv_s77;
2653                     M1.Mk2 ipv_s79 -> ipv_s79;
2654                   }
2655               of
2656               wild1_s7b
2657               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2658               };
2659         };
2660
2661 So the outer case is doing *nothing at all*, other than serving as a
2662 join-point.  In this case we really want to do case-of-case and decide
2663 whether to use a real join point or just duplicate the continuation:
2664
2665     let $j s7c = case x of
2666                    Mk1 ipv77 -> (==) s7c ipv77
2667                    Mk1 ipv79 -> (==) s7c ipv79
2668     in
2669     case y of 
2670       Mk1 ipv70 -> $j ipv70
2671       Mk2 ipv72 -> $j ipv72
2672
2673 Hence: check whether the case binder's type is unlifted, because then
2674 the outer case is *not* a seq.