Merge commit 'c073f23aba6d88a9479a20ccb53bb98a338638db' into type-nats
[ghc.git] / compiler / parser / Parser.y.pp
1 --                                                              -*-haskell-*-
2 -- ---------------------------------------------------------------------------
3 -- (c) The University of Glasgow 1997-2003
4 ---
5 -- The GHC grammar.
6 --
7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
8 -- ---------------------------------------------------------------------------
9
10 {
11 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
12 {-# OPTIONS -Wwarn -w #-}
13 -- The above warning supression flag is a temporary kludge.
14 -- While working on this module you are encouraged to remove it and fix
15 -- any warnings in the module. See
16 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
17 -- for details
18
19 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
20 {-
21 Careful optimisation of the parser: we don't want to throw everything
22 at it, because that takes too long and doesn't buy much, but we do want
23 to inline certain key external functions, so we instruct GHC not to
24 throw away inlinings as it would normally do in -O0 mode.
25 -}
26
27 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
28                 parseHeader ) where
29
30 import HsSyn
31 import RdrHsSyn
32 import HscTypes         ( IsBootInterface, WarningTxt(..) )
33 import Lexer
34 import RdrName
35 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
36                           unboxedSingletonTyCon, unboxedSingletonDataCon,
37                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
38 import Type             ( funTyCon )
39 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
40                           CCallConv(..), CCallTarget(..), defaultCCallConv
41                         )
42 import OccName          ( varName, dataName, tcClsName, tvName )
43 import DataCon          ( DataCon, dataConName )
44 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
45                           SrcSpan, combineLocs, srcLocFile, 
46                           mkSrcLoc, mkSrcSpan, noSrcSpan )
47 import Module
48 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
49 import Type             ( Kind, liftedTypeKind, unliftedTypeKind )
50 import Coercion         ( mkArrowKind )
51 import Class            ( FunDep )
52 import BasicTypes
53 import DynFlags
54 import OrdList
55 import HaddockUtils
56
57 import FastString
58 import Maybes           ( orElse )
59 import Outputable
60
61 import Control.Monad    ( unless )
62 import GHC.Exts
63 import Data.Char
64 import Control.Monad    ( mplus )
65 }
66
67 {-
68 -----------------------------------------------------------------------------
69 24 Februar 2006
70
71 Conflicts: 33 shift/reduce
72            1 reduce/reduce
73
74 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
75 would think the two should never occur in the same context.
76
77   -=chak
78
79 -----------------------------------------------------------------------------
80 31 December 2006
81
82 Conflicts: 34 shift/reduce
83            1 reduce/reduce
84
85 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
86 would think the two should never occur in the same context.
87
88   -=chak
89
90 -----------------------------------------------------------------------------
91 6 December 2006
92
93 Conflicts: 32 shift/reduce
94            1 reduce/reduce
95
96 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
97 would think the two should never occur in the same context.
98
99   -=chak
100
101 -----------------------------------------------------------------------------
102 26 July 2006
103
104 Conflicts: 37 shift/reduce
105            1 reduce/reduce
106
107 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
108 would think the two should never occur in the same context.
109
110   -=chak
111
112 -----------------------------------------------------------------------------
113 Conflicts: 38 shift/reduce (1.25)
114
115 10 for abiguity in 'if x then y else z + 1'             [State 178]
116         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
117         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
118
119 1 for ambiguity in 'if x then y else z :: T'            [State 178]
120         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
121
122 4 for ambiguity in 'if x then y else z -< e'            [State 178]
123         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
124         There are four such operators: -<, >-, -<<, >>-
125
126
127 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
128         Which of these two is intended?
129           case v of
130             (x::T) -> T         -- Rhs is T
131     or
132           case v of
133             (x::T -> T) -> ..   -- Rhs is ...
134
135 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
136         (e::a) `b` c, or 
137         (e :: (a `b` c))
138     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
139     Same duplication between states 11 and 253 as the previous case
140
141 1 for ambiguity in 'let ?x ...'                         [State 329]
142         the parser can't tell whether the ?x is the lhs of a normal binding or
143         an implicit binding.  Fortunately resolving as shift gives it the only
144         sensible meaning, namely the lhs of an implicit binding.
145
146 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
147         we don't know whether the '[' starts the activation or not: it
148         might be the start of the declaration with the activation being
149         empty.  --SDM 1/4/2002
150
151 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
152         since 'forall' is a valid variable name, we don't know whether
153         to treat a forall on the input as the beginning of a quantifier
154         or the beginning of the rule itself.  Resolving to shift means
155         it's always treated as a quantifier, hence the above is disallowed.
156         This saves explicitly defining a grammar for the rule lhs that
157         doesn't include 'forall'.
158
159 1 for ambiguity when the source file starts with "-- | doc". We need another
160   token of lookahead to determine if a top declaration or the 'module' keyword
161   follows. Shift parses as if the 'module' keyword follows.   
162
163 -- ---------------------------------------------------------------------------
164 -- Adding location info
165
166 This is done in a stylised way using the three macros below, L0, L1
167 and LL.  Each of these macros can be thought of as having type
168
169    L0, L1, LL :: a -> Located a
170
171 They each add a SrcSpan to their argument.
172
173    L0   adds 'noSrcSpan', used for empty productions
174      -- This doesn't seem to work anymore -=chak
175
176    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
177         from that token.
178
179    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
180         the first and last tokens.
181
182 These suffice for the majority of cases.  However, we must be
183 especially careful with empty productions: LL won't work if the first
184 or last token on the lhs can represent an empty span.  In these cases,
185 we have to calculate the span using more of the tokens from the lhs, eg.
186
187         | 'newtype' tycl_hdr '=' newconstr deriving
188                 { L (comb3 $1 $4 $5)
189                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
190
191 We provide comb3 and comb4 functions which are useful in such cases.
192
193 Be careful: there's no checking that you actually got this right, the
194 only symptom will be that the SrcSpans of your syntax will be
195 incorrect.
196
197 /*
198  * We must expand these macros *before* running Happy, which is why this file is
199  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
200  */
201 #define L0   L noSrcSpan
202 #define L1   sL (getLoc $1)
203 #define LL   sL (comb2 $1 $>)
204
205 -- -----------------------------------------------------------------------------
206
207 -}
208
209 %token
210  '_'            { L _ ITunderscore }            -- Haskell keywords
211  'as'           { L _ ITas }
212  'case'         { L _ ITcase }          
213  'class'        { L _ ITclass } 
214  'data'         { L _ ITdata } 
215  'default'      { L _ ITdefault }
216  'deriving'     { L _ ITderiving }
217  'do'           { L _ ITdo }
218  'else'         { L _ ITelse }
219  'hiding'       { L _ IThiding }
220  'if'           { L _ ITif }
221  'import'       { L _ ITimport }
222  'in'           { L _ ITin }
223  'infix'        { L _ ITinfix }
224  'infixl'       { L _ ITinfixl }
225  'infixr'       { L _ ITinfixr }
226  'instance'     { L _ ITinstance }
227  'let'          { L _ ITlet }
228  'module'       { L _ ITmodule }
229  'newtype'      { L _ ITnewtype }
230  'of'           { L _ ITof }
231  'qualified'    { L _ ITqualified }
232  'then'         { L _ ITthen }
233  'type'         { L _ ITtype }
234  'where'        { L _ ITwhere }
235  '_scc_'        { L _ ITscc }         -- ToDo: remove
236
237  'forall'       { L _ ITforall }                -- GHC extension keywords
238  'foreign'      { L _ ITforeign }
239  'export'       { L _ ITexport }
240  'label'        { L _ ITlabel } 
241  'dynamic'      { L _ ITdynamic }
242  'safe'         { L _ ITsafe }
243  'threadsafe'   { L _ ITthreadsafe }  -- ToDo: remove deprecated alias
244  'interruptible' { L _ ITinterruptible }
245  'unsafe'       { L _ ITunsafe }
246  'mdo'          { L _ ITmdo }
247  'family'       { L _ ITfamily }
248  'stdcall'      { L _ ITstdcallconv }
249  'ccall'        { L _ ITccallconv }
250  'prim'         { L _ ITprimcallconv }
251  'proc'         { L _ ITproc }          -- for arrow notation extension
252  'rec'          { L _ ITrec }           -- for arrow notation extension
253  'group'    { L _ ITgroup }     -- for list transform extension
254  'by'       { L _ ITby }        -- for list transform extension
255  'using'    { L _ ITusing }     -- for list transform extension
256
257  '{-# INLINE'             { L _ (ITinline_prag _ _) }
258  '{-# SPECIALISE'         { L _ ITspec_prag }
259  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
260  '{-# SOURCE'      { L _ ITsource_prag }
261  '{-# RULES'       { L _ ITrules_prag }
262  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
263  '{-# SCC'         { L _ ITscc_prag }
264  '{-# GENERATED'   { L _ ITgenerated_prag }
265  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
266  '{-# WARNING'     { L _ ITwarning_prag }
267  '{-# UNPACK'      { L _ ITunpack_prag }
268  '{-# ANN'         { L _ ITann_prag }
269  '#-}'             { L _ ITclose_prag }
270
271  '..'           { L _ ITdotdot }                        -- reserved symbols
272  ':'            { L _ ITcolon }
273  '::'           { L _ ITdcolon }
274  '='            { L _ ITequal }
275  '\\'           { L _ ITlam }
276  '|'            { L _ ITvbar }
277  '<-'           { L _ ITlarrow }
278  '->'           { L _ ITrarrow }
279  '@'            { L _ ITat }
280  '~'            { L _ ITtilde }
281  '=>'           { L _ ITdarrow }
282  '-'            { L _ ITminus }
283  '!'            { L _ ITbang }
284  '*'            { L _ ITstar }
285  '-<'           { L _ ITlarrowtail }            -- for arrow notation
286  '>-'           { L _ ITrarrowtail }            -- for arrow notation
287  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
288  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
289  '.'            { L _ ITdot }
290
291  '{'            { L _ ITocurly }                        -- special symbols
292  '}'            { L _ ITccurly }
293  '{|'           { L _ ITocurlybar }
294  '|}'           { L _ ITccurlybar }
295  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
296  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
297  '['            { L _ ITobrack }
298  ']'            { L _ ITcbrack }
299  '[:'           { L _ ITopabrack }
300  ':]'           { L _ ITcpabrack }
301  '('            { L _ IToparen }
302  ')'            { L _ ITcparen }
303  '(#'           { L _ IToubxparen }
304  '#)'           { L _ ITcubxparen }
305  '(|'           { L _ IToparenbar }
306  '|)'           { L _ ITcparenbar }
307  ';'            { L _ ITsemi }
308  ','            { L _ ITcomma }
309  '`'            { L _ ITbackquote }
310
311  VARID          { L _ (ITvarid    _) }          -- identifiers
312  CONID          { L _ (ITconid    _) }
313  VARSYM         { L _ (ITvarsym   _) }
314  CONSYM         { L _ (ITconsym   _) }
315  QVARID         { L _ (ITqvarid   _) }
316  QCONID         { L _ (ITqconid   _) }
317  QVARSYM        { L _ (ITqvarsym  _) }
318  QCONSYM        { L _ (ITqconsym  _) }
319  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
320  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
321
322  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
323
324  CHAR           { L _ (ITchar     _) }
325  STRING         { L _ (ITstring   _) }
326  INTEGER        { L _ (ITinteger  _) }
327  RATIONAL       { L _ (ITrational _) }
328                     
329  PRIMCHAR       { L _ (ITprimchar   _) }
330  PRIMSTRING     { L _ (ITprimstring _) }
331  PRIMINTEGER    { L _ (ITprimint    _) }
332  PRIMWORD       { L _ (ITprimword  _) }
333  PRIMFLOAT      { L _ (ITprimfloat  _) }
334  PRIMDOUBLE     { L _ (ITprimdouble _) }
335
336  DOCNEXT        { L _ (ITdocCommentNext _) }
337  DOCPREV        { L _ (ITdocCommentPrev _) }
338  DOCNAMED       { L _ (ITdocCommentNamed _) }
339  DOCSECTION     { L _ (ITdocSection _ _) }
340
341 -- Template Haskell 
342 '[|'            { L _ ITopenExpQuote  }       
343 '[p|'           { L _ ITopenPatQuote  }      
344 '[t|'           { L _ ITopenTypQuote  }      
345 '[d|'           { L _ ITopenDecQuote  }      
346 '|]'            { L _ ITcloseQuote    }
347 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
348 '$('            { L _ ITparenEscape   }     -- $( exp )
349 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
350 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
351 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
352
353 %monad { P } { >>= } { return }
354 %lexer { lexer } { L _ ITeof }
355 %name parseModule module
356 %name parseStmt   maybe_stmt
357 %name parseIdentifier  identifier
358 %name parseType ctype
359 %partial parseHeader header
360 %tokentype { (Located Token) }
361 %%
362
363 -----------------------------------------------------------------------------
364 -- Identifiers; one of the entry points
365 identifier :: { Located RdrName }
366         : qvar                          { $1 }
367         | qcon                          { $1 }
368         | qvarop                        { $1 }
369         | qconop                        { $1 }
370     | '(' '->' ')'      { LL $ getRdrName funTyCon }
371
372 -----------------------------------------------------------------------------
373 -- Module Header
374
375 -- The place for module deprecation is really too restrictive, but if it
376 -- was allowed at its natural place just before 'module', we get an ugly
377 -- s/r conflict with the second alternative. Another solution would be the
378 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
379 -- either, and DEPRECATED is only expected to be used by people who really
380 -- know what they are doing. :-)
381
382 module  :: { Located (HsModule RdrName) }
383         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
384                 {% fileSrcSpan >>= \ loc ->
385                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
386                           ) )}
387         | body2
388                 {% fileSrcSpan >>= \ loc ->
389                    return (L loc (HsModule Nothing Nothing
390                           (fst $1) (snd $1) Nothing Nothing
391                           )) }
392
393 maybedocheader :: { Maybe LHsDocString }
394         : moduleheader            { $1 }
395         | {- empty -}             { Nothing }
396
397 missing_module_keyword :: { () }
398         : {- empty -}                           {% pushCurrentContext }
399
400 maybemodwarning :: { Maybe WarningTxt }
401     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
402     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
403     |  {- empty -}                  { Nothing }
404
405 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
406         :  '{'            top '}'               { $2 }
407         |      vocurly    top close             { $2 }
408
409 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
410         :  '{' top '}'                          { $2 }
411         |  missing_module_keyword top close     { $2 }
412
413 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
414         : importdecls                           { (reverse $1,[]) }
415         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
416         | cvtopdecls                            { ([],$1) }
417
418 cvtopdecls :: { [LHsDecl RdrName] }
419         : topdecls                              { cvTopDecls $1 }
420
421 -----------------------------------------------------------------------------
422 -- Module declaration & imports only
423
424 header  :: { Located (HsModule RdrName) }
425         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
426                 {% fileSrcSpan >>= \ loc ->
427                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
428                           ))}
429         | missing_module_keyword importdecls
430                 {% fileSrcSpan >>= \ loc ->
431                    return (L loc (HsModule Nothing Nothing $2 [] Nothing
432                           Nothing)) }
433
434 header_body :: { [LImportDecl RdrName] }
435         :  '{'            importdecls           { $2 }
436         |      vocurly    importdecls           { $2 }
437
438 -----------------------------------------------------------------------------
439 -- The Export List
440
441 maybeexports :: { Maybe [LIE RdrName] }
442         :  '(' exportlist ')'                   { Just $2 }
443         |  {- empty -}                          { Nothing }
444
445 exportlist :: { [LIE RdrName] }
446         : expdoclist ',' expdoclist             { $1 ++ $3 }
447         | exportlist1                           { $1 }
448
449 exportlist1 :: { [LIE RdrName] }
450         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 ++ $3) ++ $5 }
451         | expdoclist export expdoclist                 { $1 ++ ($2 ++ $3) }
452         | expdoclist                                   { $1 }
453
454 expdoclist :: { [LIE RdrName] }
455         : exp_doc expdoclist                           { $1 : $2 }
456         | {- empty -}                                  { [] }
457
458 exp_doc :: { LIE RdrName }                                                   
459         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
460         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
461         | docnext       { L1 (IEDoc (unLoc $1)) }       
462                        
463    -- NOTE 1: No longer allow things like [] and (,,,) to be exported
464    -- They are built in syntax, always available
465    -- NOTE 2: There is a lot of overlap between value and type names,
466    -- so, in the general case, we parse everything as values,
467    -- and post-process the declaration to determine what is being exported.
468 export  :: { [LIE RdrName] }
469         : qcname opt_subordinates { [L (comb3 $1 $1 $2)
470                                        (mkExportSpec (unLoc $1) (unLoc $2))] }
471         | 'type' oqtycons1        { map (fmap IEThingAbs) $2 }
472         | 'module' modid          { [LL (IEModuleContents (unLoc $2))] }
473
474 opt_subordinates :: { Located (Maybe Subordinates) }
475         : {- empty -}             { L0 Nothing }
476         | '(' '..' ')'            { LL (Just SubordinateAll) }
477         | '(' ')'                 { LL (Just (SubordinateList [])) }
478         | '(' qcnames ')'         { LL (Just (SubordinateList (reverse $2))) }
479
480 qcnames :: { [RdrName] }
481         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
482         |  qcname_ext                   { [unLoc $1]  }
483
484 qcname_ext :: { Located RdrName }       -- Variable or data constructor
485                                         -- or tagged type constructor
486         :  qcname                       { $1 }
487         |  'type' qcon                  { sL (comb2 $1 $2) 
488                                              (setRdrNameSpace (unLoc $2) 
489                                                               tcClsName)  }
490
491 -- Cannot pull into qcname_ext, as qcname is also used in expression.
492 qcname  :: { Located RdrName }  -- Variable or data constructor
493         :  qvar                         { $1 }
494         |  qcon                         { $1 }
495
496 -----------------------------------------------------------------------------
497 -- Import Declarations
498
499 -- import decls can be *empty*, or even just a string of semicolons
500 -- whereas topdecls must contain at least one topdecl.
501
502 importdecls :: { [LImportDecl RdrName] }
503         : importdecls ';' importdecl            { $3 : $1 }
504         | importdecls ';'                       { $1 }
505         | importdecl                            { [ $1 ] }
506         | {- empty -}                           { [] }
507
508 importdecl :: { LImportDecl RdrName }
509         : 'import' maybe_src optqualified maybe_pkg modid maybeas maybeimpspec 
510                 { L (comb4 $1 $5 $6 $7) (ImportDecl $5 $4 $2 $3 (unLoc $6) (unLoc $7)) }
511
512 maybe_src :: { IsBootInterface }
513         : '{-# SOURCE' '#-}'                    { True }
514         | {- empty -}                           { False }
515
516 maybe_pkg :: { Maybe FastString }
517         : STRING                                { Just (getSTRING $1) }
518         | {- empty -}                           { Nothing }
519
520 optqualified :: { Bool }
521         : 'qualified'                           { True  }
522         | {- empty -}                           { False }
523
524 maybeas :: { Located (Maybe ModuleName) }
525         : 'as' modid                            { LL (Just (unLoc $2)) }
526         | {- empty -}                           { noLoc Nothing }
527
528 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
529         : impspec                               { L1 (Just (unLoc $1)) }
530         | {- empty -}                           { noLoc Nothing }
531
532 impspec :: { Located (Bool, [LIE RdrName]) }
533         :  '(' exportlist ')'                   { LL (False, $2) }
534         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
535
536 -----------------------------------------------------------------------------
537 -- Fixity Declarations
538
539 prec    :: { Int }
540         : {- empty -}           { 9 }
541         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
542
543 infix   :: { Located FixityDirection }
544         : 'infix'                               { L1 InfixN  }
545         | 'infixl'                              { L1 InfixL  }
546         | 'infixr'                              { L1 InfixR }
547
548 ops     :: { Located [Located RdrName] }
549         : ops ',' op                            { LL ($3 : unLoc $1) }
550         | op                                    { L1 [$1] }
551
552 -----------------------------------------------------------------------------
553 -- Top-Level Declarations
554
555 topdecls :: { OrdList (LHsDecl RdrName) }
556         : topdecls ';' topdecl                  { $1 `appOL` $3 }
557         | topdecls ';'                          { $1 }
558         | topdecl                               { $1 }
559
560 topdecl :: { OrdList (LHsDecl RdrName) }
561         : cl_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
562         | ty_decl                       { unitOL (L1 (TyClD (unLoc $1))) }
563         | 'instance' inst_type where_inst
564             { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
565               in 
566               unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats)))}
567         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
568         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
569         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
570         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
571         | '{-# WARNING' warnings '#-}'          { $2 }
572         | '{-# RULES' rules '#-}'               { $2 }
573         | annotation { unitOL $1 }
574         | decl                                  { unLoc $1 }
575
576         -- Template Haskell Extension
577         -- The $(..) form is one possible form of infixexp
578         -- but we treat an arbitrary expression just as if 
579         -- it had a $(..) wrapped around it
580         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) } 
581
582 -- Type classes
583 --
584 cl_decl :: { LTyClDecl RdrName }
585         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
586
587 -- Type declarations (toplevel)
588 --
589 ty_decl :: { LTyClDecl RdrName }
590            -- ordinary type synonyms
591         : 'type' type '=' ctypedoc
592                 -- Note ctype, not sigtype, on the right of '='
593                 -- We allow an explicit for-all but we don't insert one
594                 -- in   type Foo a = (b,b)
595                 -- Instead we just say b is out of scope
596                 --
597                 -- Note the use of type for the head; this allows
598                 -- infix type constructors to be declared 
599                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
600
601            -- type family declarations
602         | 'type' 'family' type opt_kind_sig 
603                 -- Note the use of type for the head; this allows
604                 -- infix type constructors to be declared
605                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
606
607            -- type instance declarations
608         | 'type' 'instance' type '=' ctype
609                 -- Note the use of type for the head; this allows
610                 -- infix type constructors and type patterns
611                 {% mkTySynonym (comb2 $1 $5) True $3 $5 }
612
613           -- ordinary data type or newtype declaration
614         | data_or_newtype tycl_hdr constrs deriving
615                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) False $2 
616                             Nothing (reverse (unLoc $3)) (unLoc $4) }
617                                    -- We need the location on tycl_hdr in case 
618                                    -- constrs and deriving are both empty
619
620           -- ordinary GADT declaration
621         | data_or_newtype tycl_hdr opt_kind_sig 
622                  gadt_constrlist
623                  deriving
624                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) False $2 
625                             (unLoc $3) (unLoc $4) (unLoc $5) }
626                                    -- We need the location on tycl_hdr in case 
627                                    -- constrs and deriving are both empty
628
629           -- data/newtype family
630         | 'data' 'family' type opt_kind_sig
631                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
632
633           -- data/newtype instance declaration
634         | data_or_newtype 'instance' tycl_hdr constrs deriving
635                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $3
636                             Nothing (reverse (unLoc $4)) (unLoc $5) }
637
638           -- GADT instance declaration
639         | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
640                  gadt_constrlist
641                  deriving
642                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $3
643                             (unLoc $4) (unLoc $5) (unLoc $6) }
644
645 -- Associated type family declarations
646 --
647 -- * They have a different syntax than on the toplevel (no family special
648 --   identifier).
649 --
650 -- * They also need to be separate from instances; otherwise, data family
651 --   declarations without a kind signature cause parsing conflicts with empty
652 --   data declarations. 
653 --
654 at_decl_cls :: { LTyClDecl RdrName }
655            -- type family declarations
656         : 'type' type opt_kind_sig
657                 -- Note the use of type for the head; this allows
658                 -- infix type constructors to be declared
659                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
660
661            -- default type instance
662         | 'type' type '=' ctype
663                 -- Note the use of type for the head; this allows
664                 -- infix type constructors and type patterns
665                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
666
667           -- data/newtype family declaration
668         | 'data' type opt_kind_sig
669                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
670
671 -- Associated type instances
672 --
673 at_decl_inst :: { LTyClDecl RdrName }
674            -- type instance declarations
675         : 'type' type '=' ctype
676                 -- Note the use of type for the head; this allows
677                 -- infix type constructors and type patterns
678                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
679
680         -- data/newtype instance declaration
681         | data_or_newtype tycl_hdr constrs deriving
682                 {% mkTyData (comb4 $1 $2 $3 $4) (unLoc $1) True $2 
683                             Nothing (reverse (unLoc $3)) (unLoc $4) }
684
685         -- GADT instance declaration
686         | data_or_newtype tycl_hdr opt_kind_sig 
687                  gadt_constrlist
688                  deriving
689                 {% mkTyData (comb4 $1 $2 $4 $5) (unLoc $1) True $2 
690                             (unLoc $3) (unLoc $4) (unLoc $5) }
691
692 data_or_newtype :: { Located NewOrData }
693         : 'data'        { L1 DataType }
694         | 'newtype'     { L1 NewType }
695
696 opt_kind_sig :: { Located (Maybe Kind) }
697         :                               { noLoc Nothing }
698         | '::' kind                     { LL (Just (unLoc $2)) }
699
700 -- tycl_hdr parses the header of a class or data type decl,
701 -- which takes the form
702 --      T a b
703 --      Eq a => T a
704 --      (Eq a, Ord b) => T a b
705 --      T Int [a]                       -- for associated types
706 -- Rather a lot of inlining here, else we get reduce/reduce errors
707 tycl_hdr :: { Located (Maybe (LHsContext RdrName), LHsType RdrName) }
708         : context '=>' type             { LL (Just $1, $3) }
709         | type                          { L1 (Nothing, $1) }
710
711 -----------------------------------------------------------------------------
712 -- Stand-alone deriving
713
714 -- Glasgow extension: stand-alone deriving declarations
715 stand_alone_deriving :: { LDerivDecl RdrName }
716         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
717
718 -----------------------------------------------------------------------------
719 -- Nested declarations
720
721 -- Declaration in class bodies
722 --
723 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
724 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
725           | decl                        { $1 }
726
727 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
728           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
729           | decls_cls ';'               { LL (unLoc $1) }
730           | decl_cls                    { $1 }
731           | {- empty -}                 { noLoc nilOL }
732
733
734 decllist_cls
735         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
736         : '{'         decls_cls '}'     { LL (unLoc $2) }
737         |     vocurly decls_cls close   { $2 }
738
739 -- Class body
740 --
741 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
742                                 -- No implicit parameters
743                                 -- May have type declarations
744         : 'where' decllist_cls          { LL (unLoc $2) }
745         | {- empty -}                   { noLoc nilOL }
746
747 -- Declarations in instance bodies
748 --
749 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
750 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
751            | decl                       { $1 }
752
753 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
754            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
755            | decls_inst ';'             { LL (unLoc $1) }
756            | decl_inst                  { $1 }
757            | {- empty -}                { noLoc nilOL }
758
759 decllist_inst 
760         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
761         : '{'         decls_inst '}'    { LL (unLoc $2) }
762         |     vocurly decls_inst close  { $2 }
763
764 -- Instance body
765 --
766 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
767                                 -- No implicit parameters
768                                 -- May have type declarations
769         : 'where' decllist_inst         { LL (unLoc $2) }
770         | {- empty -}                   { noLoc nilOL }
771
772 -- Declarations in binding groups other than classes and instances
773 --
774 decls   :: { Located (OrdList (LHsDecl RdrName)) }      
775         : decls ';' decl                { let { this = unLoc $3;
776                                     rest = unLoc $1;
777                                     these = rest `appOL` this }
778                               in rest `seq` this `seq` these `seq`
779                                     LL these }
780         | decls ';'                     { LL (unLoc $1) }
781         | decl                          { $1 }
782         | {- empty -}                   { noLoc nilOL }
783
784 decllist :: { Located (OrdList (LHsDecl RdrName)) }
785         : '{'            decls '}'      { LL (unLoc $2) }
786         |     vocurly    decls close    { $2 }
787
788 -- Binding groups other than those of class and instance declarations
789 --
790 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
791                                                 -- No type declarations
792         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
793         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
794         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
795
796 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
797                                                 -- No type declarations
798         : 'where' binds                 { LL (unLoc $2) }
799         | {- empty -}                   { noLoc emptyLocalBinds }
800
801
802 -----------------------------------------------------------------------------
803 -- Transformation Rules
804
805 rules   :: { OrdList (LHsDecl RdrName) }
806         :  rules ';' rule                       { $1 `snocOL` $3 }
807         |  rules ';'                            { $1 }
808         |  rule                                 { unitOL $1 }
809         |  {- empty -}                          { nilOL }
810
811 rule    :: { LHsDecl RdrName }
812         : STRING activation rule_forall infixexp '=' exp
813              { LL $ RuleD (HsRule (getSTRING $1) 
814                                   ($2 `orElse` AlwaysActive) 
815                                   $3 $4 placeHolderNames $6 placeHolderNames) }
816
817 activation :: { Maybe Activation } 
818         : {- empty -}                           { Nothing }
819         | explicit_activation                   { Just $1 }
820
821 explicit_activation :: { Activation }  -- In brackets
822         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
823         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
824
825 rule_forall :: { [RuleBndr RdrName] }
826         : 'forall' rule_var_list '.'            { $2 }
827         | {- empty -}                           { [] }
828
829 rule_var_list :: { [RuleBndr RdrName] }
830         : rule_var                              { [$1] }
831         | rule_var rule_var_list                { $1 : $2 }
832
833 rule_var :: { RuleBndr RdrName }
834         : varid                                 { RuleBndr $1 }
835         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
836
837 -----------------------------------------------------------------------------
838 -- Warnings and deprecations (c.f. rules)
839
840 warnings :: { OrdList (LHsDecl RdrName) }
841         : warnings ';' warning          { $1 `appOL` $3 }
842         | warnings ';'                  { $1 }
843         | warning                               { $1 }
844         | {- empty -}                           { nilOL }
845
846 -- SUP: TEMPORARY HACK, not checking for `module Foo'
847 warning :: { OrdList (LHsDecl RdrName) }
848         : namelist strings
849                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
850                        | n <- unLoc $1 ] }
851
852 deprecations :: { OrdList (LHsDecl RdrName) }
853         : deprecations ';' deprecation          { $1 `appOL` $3 }
854         | deprecations ';'                      { $1 }
855         | deprecation                           { $1 }
856         | {- empty -}                           { nilOL }
857
858 -- SUP: TEMPORARY HACK, not checking for `module Foo'
859 deprecation :: { OrdList (LHsDecl RdrName) }
860         : namelist strings
861                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
862                        | n <- unLoc $1 ] }
863
864 strings :: { Located [FastString] }
865     : STRING { L1 [getSTRING $1] }
866     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
867
868 stringlist :: { Located (OrdList FastString) }
869     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
870     | STRING                { LL (unitOL (getSTRING $1)) }
871
872 -----------------------------------------------------------------------------
873 -- Annotations
874 annotation :: { LHsDecl RdrName }
875     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
876     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
877     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
878
879
880 -----------------------------------------------------------------------------
881 -- Foreign import and export declarations
882
883 fdecl :: { LHsDecl RdrName }
884 fdecl : 'import' callconv safety fspec
885                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
886       | 'import' callconv        fspec          
887                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
888                         return (LL d) } }
889       | 'export' callconv fspec
890                 {% mkExport $2 (unLoc $3) >>= return.LL }
891
892 callconv :: { CCallConv }
893           : 'stdcall'                   { StdCallConv }
894           | 'ccall'                     { CCallConv   }
895           | 'prim'                      { PrimCallConv}
896
897 safety :: { Safety }
898         : 'unsafe'                      { PlayRisky }
899         | 'safe'                        { PlaySafe  False }
900         | 'interruptible'               { PlayInterruptible }
901         | 'threadsafe'                  { PlaySafe  True } -- deprecated alias
902
903 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
904        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
905        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
906          -- if the entity string is missing, it defaults to the empty string;
907          -- the meaning of an empty entity string depends on the calling
908          -- convention
909
910 -----------------------------------------------------------------------------
911 -- Type signatures
912
913 opt_sig :: { Maybe (LHsType RdrName) }
914         : {- empty -}                   { Nothing }
915         | '::' sigtype                  { Just $2 }
916
917 opt_asig :: { Maybe (LHsType RdrName) }
918         : {- empty -}                   { Nothing }
919         | '::' atype                    { Just $2 }
920
921 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
922                                         -- to tell the renamer where to generalise
923         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
924         -- Wrap an Implicit forall if there isn't one there already
925
926 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
927         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
928         -- Wrap an Implicit forall if there isn't one there already
929
930 sig_vars :: { Located [Located RdrName] }
931          : sig_vars ',' var             { LL ($3 : unLoc $1) }
932          | var                          { L1 [$1] }
933
934 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
935         : sigtype                       { [ $1 ] }
936         | sigtype ',' sigtypes1         { $1 : $3 }
937
938 -----------------------------------------------------------------------------
939 -- Types
940
941 infixtype :: { LHsType RdrName }
942         : btype qtyconop type         { LL $ HsOpTy $1 $2 $3 }
943         | btype tyvarop  type    { LL $ HsOpTy $1 $2 $3 }
944
945 strict_mark :: { Located HsBang }
946         : '!'                           { L1 HsStrict }
947         | '{-# UNPACK' '#-}' '!'        { LL HsUnpack }
948
949 -- A ctype is a for-all type
950 ctype   :: { LHsType RdrName }
951         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
952         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
953         -- A type of form (context => type) is an *implicit* HsForAllTy
954         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
955         | type                          { $1 }
956
957 ----------------------
958 -- Notes for 'ctypedoc'
959 -- It would have been nice to simplify the grammar by unifying `ctype` and 
960 -- ctypedoc` into one production, allowing comments on types everywhere (and
961 -- rejecting them after parsing, where necessary).  This is however not possible
962 -- since it leads to ambiguity. The reason is the support for comments on record
963 -- fields: 
964 --         data R = R { field :: Int -- ^ comment on the field }
965 -- If we allow comments on types here, it's not clear if the comment applies
966 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
967
968 ctypedoc :: { LHsType RdrName }
969         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
970         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
971         -- A type of form (context => type) is an *implicit* HsForAllTy
972         | ipvar '::' type               { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
973         | typedoc                       { $1 }
974
975 ----------------------
976 -- Notes for 'context'
977 -- We parse a context as a btype so that we don't get reduce/reduce
978 -- errors in ctype.  The basic problem is that
979 --      (Eq a, Ord a)
980 -- looks so much like a tuple type.  We can't tell until we find the =>
981
982 -- We have the t1 ~ t2 form both in 'context' and in type, 
983 -- to permit an individual equational constraint without parenthesis.
984 -- Thus for some reason we allow    f :: a~b => blah
985 -- but not                          f :: ?x::Int => blah
986 context :: { LHsContext RdrName }
987         : btype '~'      btype          {% checkContext
988                                              (LL $ HsPredTy (HsEqualP $1 $3)) }
989         | btype                         {% checkContext $1 }
990
991 type :: { LHsType RdrName }
992         : btype                         { $1 }
993         | btype qtyconop type           { LL $ HsOpTy $1 $2 $3 }
994         | btype tyvarop  type           { LL $ HsOpTy $1 $2 $3 }
995         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
996         | btype '~'      btype          { LL $ HsPredTy (HsEqualP $1 $3) }
997
998 typedoc :: { LHsType RdrName }
999         : btype                          { $1 }
1000         | btype docprev                  { LL $ HsDocTy $1 $2 }
1001         | btype qtyconop type            { LL $ HsOpTy $1 $2 $3 }
1002         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
1003         | btype tyvarop  type            { LL $ HsOpTy $1 $2 $3 }
1004         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (HsOpTy $1 $2 $3)) $4 }
1005         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
1006         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
1007         | btype '~'      btype           { LL $ HsPredTy (HsEqualP $1 $3) }
1008
1009 btype :: { LHsType RdrName }
1010         : btype atype                   { LL $ HsAppTy $1 $2 }
1011         | atype                         { $1 }
1012
1013 atype :: { LHsType RdrName }
1014         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
1015         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
1016         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1017         | '{' fielddecls '}'            { LL $ HsRecTy $2 }              -- Constructor sigs only
1018         | '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
1019         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
1020         | '[' ctype ']'                 { LL $ HsListTy  $2 }
1021         | '[:' ctype ':]'               { LL $ HsPArrTy  $2 }
1022         | '(' ctype ')'                 { LL $ HsParTy   $2 }
1023         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 (unLoc $4) }
1024         | quasiquote                    { L1 (HsQuasiQuoteTy (unLoc $1)) }
1025         | '$(' exp ')'                  { LL $ mkHsSpliceTy $2 }
1026         | TH_ID_SPLICE                  { LL $ mkHsSpliceTy $ L1 $ HsVar $ 
1027                                           mkUnqual varName (getTH_ID_SPLICE $1) }
1028         | INTEGER                       {% mkNumberType (L1 (getINTEGER $1)) }
1029
1030 -- An inst_type is what occurs in the head of an instance decl
1031 --      e.g.  (Foo a, Gaz b) => Wibble a b
1032 -- It's kept as a single type, with a MonoDictTy at the right
1033 -- hand corner, for convenience.
1034 inst_type :: { LHsType RdrName }
1035         : sigtype                       {% checkInstType $1 }
1036
1037 inst_types1 :: { [LHsType RdrName] }
1038         : inst_type                     { [$1] }
1039         | inst_type ',' inst_types1     { $1 : $3 }
1040
1041 comma_types0  :: { [LHsType RdrName] }
1042         : comma_types1                  { $1 }
1043         | {- empty -}                   { [] }
1044
1045 comma_types1    :: { [LHsType RdrName] }
1046         : ctype                         { [$1] }
1047         | ctype  ',' comma_types1       { $1 : $3 }
1048
1049 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1050          : tv_bndr tv_bndrs             { $1 : $2 }
1051          | {- empty -}                  { [] }
1052
1053 tv_bndr :: { LHsTyVarBndr RdrName }
1054         : tyvar                         { L1 (UserTyVar (unLoc $1) placeHolderKind) }
1055         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) 
1056                                                           (unLoc $4)) }
1057
1058 fds :: { Located [Located (FunDep RdrName)] }
1059         : {- empty -}                   { noLoc [] }
1060         | '|' fds1                      { LL (reverse (unLoc $2)) }
1061
1062 fds1 :: { Located [Located (FunDep RdrName)] }
1063         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1064         | fd                            { L1 [$1] }
1065
1066 fd :: { Located (FunDep RdrName) }
1067         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1068                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1069
1070 varids0 :: { Located [RdrName] }
1071         : {- empty -}                   { noLoc [] }
1072         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1073
1074 -----------------------------------------------------------------------------
1075 -- Kinds
1076
1077 kind    :: { Located Kind }
1078         : akind                 { $1 }
1079         | akind '->' kind       { LL (mkArrowKind (unLoc $1) (unLoc $3)) }
1080
1081 akind   :: { Located Kind }
1082         : '*'                   { L1 liftedTypeKind }
1083         | '!'                   { L1 unliftedTypeKind }
1084         | tycon                 {% checkKindCon $1 }
1085         | '(' kind ')'          { LL (unLoc $2) }
1086
1087
1088 -----------------------------------------------------------------------------
1089 -- Datatype declarations
1090
1091 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1092         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1093         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1094         | {- empty -}                              { noLoc [] }
1095
1096 gadt_constrs :: { Located [LConDecl RdrName] }
1097         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1098         | gadt_constr                   { L (getLoc (head $1)) $1 }
1099         | {- empty -}                   { noLoc [] }
1100
1101 -- We allow the following forms:
1102 --      C :: Eq a => a -> T a
1103 --      C :: forall a. Eq a => !a -> T a
1104 --      D { x,y :: a } :: T a
1105 --      forall a. Eq a => D { x,y :: a } :: T a
1106
1107 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1108         : con_list '::' sigtype
1109                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) } 
1110
1111                 -- Deprecated syntax for GADT record declarations
1112         | oqtycon '{' fielddecls '}' '::' sigtype
1113                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1114                       ; return [cd] } }
1115
1116 constrs :: { Located [LConDecl RdrName] }
1117         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1118
1119 constrs1 :: { Located [LConDecl RdrName] }
1120         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1121         | constr                                          { L1 [$1] }
1122
1123 constr :: { LConDecl RdrName }
1124         : maybe_docnext forall context '=>' constr_stuff maybe_docprev  
1125                 { let (con,details) = unLoc $5 in 
1126                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1127                             ($1 `mplus` $6) }
1128         | maybe_docnext forall constr_stuff maybe_docprev
1129                 { let (con,details) = unLoc $3 in 
1130                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1131                             ($1 `mplus` $4) }
1132
1133 forall :: { Located [LHsTyVarBndr RdrName] }
1134         : 'forall' tv_bndrs '.'         { LL $2 }
1135         | {- empty -}                   { noLoc [] }
1136
1137 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1138 -- We parse the constructor declaration 
1139 --      C t1 t2
1140 -- as a btype (treating C as a type constructor) and then convert C to be
1141 -- a data constructor.  Reason: it might continue like this:
1142 --      C t1 t2 %: D Int
1143 -- in which case C really would be a type constructor.  We can't resolve this
1144 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1145         : btype                         {% splitCon $1 >>= return.LL }
1146         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1147
1148 fielddecls :: { [ConDeclField RdrName] }
1149         : {- empty -}     { [] }
1150         | fielddecls1     { $1 }
1151
1152 fielddecls1 :: { [ConDeclField RdrName] }
1153         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1154                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1155                              -- This adds the doc $4 to each field separately
1156         | fielddecl   { $1 }
1157
1158 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1159         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5) 
1160                                                                  | fld <- reverse (unLoc $2) ] }
1161
1162 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1163 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1164 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1165 -- We don't allow a context, but that's sorted out by the type checker.
1166 deriving :: { Located (Maybe [LHsType RdrName]) }
1167         : {- empty -}                           { noLoc Nothing }
1168         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
1169                                       ; p <- checkInstType (L loc (HsTyVar tv))
1170                                       ; return (LL (Just [p])) } }
1171         | 'deriving' '(' ')'                    { LL (Just []) }
1172         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1173              -- Glasgow extension: allow partial 
1174              -- applications in derivings
1175
1176 -----------------------------------------------------------------------------
1177 -- Value definitions
1178
1179 {- Note [Declaration/signature overlap]
1180 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1181 There's an awkward overlap with a type signature.  Consider
1182         f :: Int -> Int = ...rhs...
1183    Then we can't tell whether it's a type signature or a value
1184    definition with a result signature until we see the '='.
1185    So we have to inline enough to postpone reductions until we know.
1186 -}
1187
1188 {-
1189   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1190   instead of qvar, we get another shift/reduce-conflict. Consider the
1191   following programs:
1192   
1193      { (^^) :: Int->Int ; }          Type signature; only var allowed
1194
1195      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1196                                      qvar allowed (because of instance decls)
1197   
1198   We can't tell whether to reduce var to qvar until after we've read the signatures.
1199 -}
1200
1201 docdecl :: { LHsDecl RdrName }
1202         : docdecld { L1 (DocD (unLoc $1)) }
1203
1204 docdecld :: { LDocDecl }
1205         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1206         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1207         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1208         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1209
1210 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1211         : sigdecl               { $1 }
1212
1213         | '!' aexp rhs          {% do { let { e = LL (SectionR (LL (HsVar bang_RDR)) $2) };
1214                                         pat <- checkPattern e;
1215                                         return $ LL $ unitOL $ LL $ ValD $
1216                                                PatBind pat (unLoc $3)
1217                                                        placeHolderType placeHolderNames } }
1218                                 -- Turn it all into an expression so that
1219                                 -- checkPattern can check that bangs are enabled
1220
1221         | infixexp opt_sig rhs  {% do { r <- checkValDef $1 $2 $3;
1222                                         let { l = comb2 $1 $> };
1223                                         return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1224         | docdecl               { LL $ unitOL $1 }
1225
1226 rhs     :: { Located (GRHSs RdrName) }
1227         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1228         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1229
1230 gdrhs :: { Located [LGRHS RdrName] }
1231         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1232         | gdrh                  { L1 [$1] }
1233
1234 gdrh :: { LGRHS RdrName }
1235         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1236
1237 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1238         : infixexp '::' sigtypedoc      {% do s <- checkValSig $1 $3 
1239                                          ; return (LL $ unitOL (LL $ SigD s)) }
1240                 -- See Note [Declaration/signature overlap] for why we need infixexp here
1241         | var ',' sig_vars '::' sigtypedoc
1242                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1243         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1244                                              | n <- unLoc $3 ] }
1245         | '{-# INLINE'   activation qvar '#-}'        
1246                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma (getINLINE $1) $2))) }
1247         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1248                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlinePragma) 
1249                                             | t <- $4] }
1250         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1251                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma (getSPEC_INLINE $1) $2))
1252                                             | t <- $5] }
1253         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1254                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1255
1256 -----------------------------------------------------------------------------
1257 -- Expressions
1258
1259 quasiquote :: { Located (HsQuasiQuote RdrName) }
1260         : TH_QUASIQUOTE   { let { loc = getLoc $1
1261                                 ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1262                                 ; quoterId = mkUnqual varName quoter }
1263                             in L1 (mkHsQuasiQuote quoterId quoteSpan quote) }
1264
1265 exp   :: { LHsExpr RdrName }
1266         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1267         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1268         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1269         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1270         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1271         | infixexp                      { $1 }
1272
1273 infixexp :: { LHsExpr RdrName }
1274         : exp10                         { $1 }
1275         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1276
1277 exp10 :: { LHsExpr RdrName }
1278         : '\\' apat apats opt_asig '->' exp     
1279                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1280                                                                 (unguardedGRHSs $6)
1281                                                             ]) }
1282         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1283         | 'if' exp optSemi 'then' exp optSemi 'else' exp
1284                                         {% checkDoAndIfThenElse $2 $3 $5 $6 $8 >>
1285                                            return (LL $ mkHsIf $2 $5 $8) }
1286         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1287         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1288
1289         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1290                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1291                                            return (L loc (mkHsDo DoExpr stmts body)) }
1292         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1293                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1294                                            return (L loc (mkHsDo MDoExpr
1295                                                                  [L loc (mkRecStmt stmts)]
1296                                                                  body)) }
1297         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1298                                                         then HsSCC (unLoc $1) $2
1299                                                         else HsPar $2 }
1300         | hpc_annot exp                         { LL $ if opt_Hpc
1301                                                         then HsTickPragma (unLoc $1) $2
1302                                                         else HsPar $2 }
1303
1304         | 'proc' aexp '->' exp  
1305                         {% checkPattern $2 >>= \ p -> 
1306                            return (LL $ HsProc p (LL $ HsCmdTop $4 [] 
1307                                                    placeHolderType undefined)) }
1308                                                 -- TODO: is LL right here?
1309
1310         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1311                                                     -- hdaume: core annotation
1312         | fexp                                  { $1 }
1313
1314 optSemi :: { Bool }
1315         : ';'         { True }
1316         | {- empty -} { False }
1317
1318 scc_annot :: { Located FastString }
1319         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1320                                    ( do scc <- getSCC $2; return $ LL scc ) }
1321         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1322
1323 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1324         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1325                                                 { LL $ (getSTRING $2
1326                                                        ,( fromInteger $ getINTEGER $3
1327                                                         , fromInteger $ getINTEGER $5
1328                                                         )
1329                                                        ,( fromInteger $ getINTEGER $7
1330                                                         , fromInteger $ getINTEGER $9
1331                                                         )
1332                                                        )
1333                                                  }
1334
1335 fexp    :: { LHsExpr RdrName }
1336         : fexp aexp                             { LL $ HsApp $1 $2 }
1337         | aexp                                  { $1 }
1338
1339 aexp    :: { LHsExpr RdrName }
1340         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1341         | '~' aexp                      { LL $ ELazyPat $2 }
1342         | aexp1                 { $1 }
1343
1344 aexp1   :: { LHsExpr RdrName }
1345         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1346                                       ; return (LL r) }}
1347         | aexp2                 { $1 }
1348
1349 -- Here was the syntax for type applications that I was planning
1350 -- but there are difficulties (e.g. what order for type args)
1351 -- so it's not enabled yet.
1352 -- But this case *is* used for the left hand side of a generic definition,
1353 -- which is parsed as an expression before being munged into a pattern
1354         | qcname '{|' type '|}'         { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1355                                                      (sL (getLoc $3) (HsType $3)) }
1356
1357 aexp2   :: { LHsExpr RdrName }
1358         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1359         | qcname                        { L1 (HsVar   $! unLoc $1) }
1360         | literal                       { L1 (HsLit   $! unLoc $1) }
1361 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1362 -- into HsOverLit when -foverloaded-strings is on.
1363 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1364         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1365         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1366
1367         -- N.B.: sections get parsed by these next two productions.
1368         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't
1369         -- correct Haskell (you'd have to write '((+ 3), (4 -))')
1370         -- but the less cluttered version fell out of having texps.
1371         | '(' texp ')'                  { LL (HsPar $2) }
1372         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1373
1374         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1375         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1376
1377         | '[' list ']'                  { LL (unLoc $2) }
1378         | '[:' parr ':]'                { LL (unLoc $2) }
1379         | '_'                           { L1 EWildPat }
1380         
1381         -- Template Haskell Extension
1382         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice 
1383                                         (L1 $ HsVar (mkUnqual varName 
1384                                                         (getTH_ID_SPLICE $1)))) } 
1385         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               
1386
1387
1388         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1389         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1390         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1391         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1392         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }                       
1393         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }                       
1394         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1395                                         return (LL $ HsBracket (PatBr p)) }
1396         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBrL $2) }
1397         | quasiquote            { L1 (HsQuasiQuoteE (unLoc $1)) }
1398
1399         -- arrow notation extension
1400         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1401
1402 cmdargs :: { [LHsCmdTop RdrName] }
1403         : cmdargs acmd                  { $2 : $1 }
1404         | {- empty -}                   { [] }
1405
1406 acmd    :: { LHsCmdTop RdrName }
1407         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1408
1409 cvtopbody :: { [LHsDecl RdrName] }
1410         :  '{'            cvtopdecls0 '}'               { $2 }
1411         |      vocurly    cvtopdecls0 close             { $2 }
1412
1413 cvtopdecls0 :: { [LHsDecl RdrName] }
1414         : {- empty -}           { [] }
1415         | cvtopdecls            { $1 }
1416
1417 -----------------------------------------------------------------------------
1418 -- Tuple expressions
1419
1420 -- "texp" is short for tuple expressions: 
1421 -- things that can appear unparenthesized as long as they're
1422 -- inside parens or delimitted by commas
1423 texp :: { LHsExpr RdrName }
1424         : exp                           { $1 }
1425
1426         -- Note [Parsing sections]
1427         -- ~~~~~~~~~~~~~~~~~~~~~~~
1428         -- We include left and right sections here, which isn't
1429         -- technically right according to the Haskell standard.
1430         -- For example (3 +, True) isn't legal.
1431         -- However, we want to parse bang patterns like
1432         --      (!x, !y)
1433         -- and it's convenient to do so here as a section
1434         -- Then when converting expr to pattern we unravel it again
1435         -- Meanwhile, the renamer checks that real sections appear
1436         -- inside parens.
1437         | infixexp qop  { LL $ SectionL $1 $2 }
1438         | qopm infixexp       { LL $ SectionR $1 $2 }
1439
1440        -- View patterns get parenthesized above
1441         | exp '->' texp   { LL $ EViewPat $1 $3 }
1442
1443 -- Always at least one comma
1444 tup_exprs :: { [HsTupArg RdrName] }
1445            : texp commas_tup_tail  { Present $1 : $2 }
1446            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1447
1448 -- Always starts with commas; always follows an expr
1449 commas_tup_tail :: { [HsTupArg RdrName] }
1450 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1451
1452 -- Always follows a comma
1453 tup_tail :: { [HsTupArg RdrName] }
1454           : texp commas_tup_tail        { Present $1 : $2 }
1455           | texp                        { [Present $1] }
1456           | {- empty -}                 { [missingTupArg] }
1457
1458 -----------------------------------------------------------------------------
1459 -- List expressions
1460
1461 -- The rules below are little bit contorted to keep lexps left-recursive while
1462 -- avoiding another shift/reduce-conflict.
1463
1464 list :: { LHsExpr RdrName }
1465         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1466         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1467         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1468         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1469         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1470         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1471         | texp '|' flattenedpquals      { sL (comb2 $1 $>) $ mkHsDo ListComp (unLoc $3) $1 }
1472
1473 lexps :: { Located [LHsExpr RdrName] }
1474         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1475         | texp ',' texp                 { LL [$3,$1] }
1476
1477 -----------------------------------------------------------------------------
1478 -- List Comprehensions
1479
1480 flattenedpquals :: { Located [LStmt RdrName] }
1481     : pquals   { case (unLoc $1) of
1482                     [qs] -> L1 qs
1483                     -- We just had one thing in our "parallel" list so 
1484                     -- we simply return that thing directly
1485                     
1486                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss]]
1487                     -- We actually found some actual parallel lists so
1488                     -- we wrap them into as a ParStmt
1489                 }
1490
1491 pquals :: { Located [[LStmt RdrName]] }
1492     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1493     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1494
1495 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last 
1496                                         -- one can "grab" the earlier ones
1497     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1498     | squals ',' qual                        { LL ($3 : unLoc $1) }
1499     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1500     | qual                                   { L1 [$1] }
1501 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1502 --  | '{|' pquals '|}'                       { L1 [$2] }
1503
1504
1505 -- It is possible to enable bracketing (associating) qualifier lists by uncommenting the lines with {| |}
1506 -- above. Due to a lack of consensus on the syntax, this feature is not being used until we get user
1507 -- demand. Note that the {| |} symbols are reused from -XGenerics and hence if you want to compile
1508 -- a program that makes use of this temporary syntax you must supply that flag to GHC
1509
1510 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1511                         -- Function is applied to a list of stmts *in order*
1512     : 'then' exp                { LL $ \leftStmts -> (mkTransformStmt leftStmts $2) }
1513     -- >>>
1514     | 'then' exp 'by' exp       { LL $ \leftStmts -> (mkTransformByStmt leftStmts $2 $4) }
1515     | 'then' 'group' 'by' exp   { LL $ \leftStmts -> (mkGroupByStmt leftStmts $4) }
1516     -- <<<
1517     -- These two productions deliberately have a shift-reduce conflict. I have made 'group' into a special_id,
1518     -- which means you can enable TransformListComp while still using Data.List.group. However, this makes the two
1519     -- productions ambiguous. I've set things up so that Happy chooses to resolve the conflict in that case by
1520     -- choosing the "group by" variant, which is what we want.
1521     --
1522     -- This is rather dubious: the user might be confused as to how to parse this statement. However, it is a good
1523     -- practical choice. NB: Data.List.group :: [a] -> [[a]], so using the first production would not even type check
1524     -- if /that/ is the group function we conflict with.
1525     | 'then' 'group' 'using' exp           { LL $ \leftStmts -> (mkGroupUsingStmt leftStmts $4) }
1526     | 'then' 'group' 'by' exp 'using' exp  { LL $ \leftStmts -> (mkGroupByUsingStmt leftStmts $4 $6) }
1527
1528 -----------------------------------------------------------------------------
1529 -- Parallel array expressions
1530
1531 -- The rules below are little bit contorted; see the list case for details.
1532 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1533 -- Moreover, we allow explicit arrays with no element (represented by the nil
1534 -- constructor in the list case).
1535
1536 parr :: { LHsExpr RdrName }
1537         :                               { noLoc (ExplicitPArr placeHolderType []) }
1538         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1539         | lexps                         { L1 $ ExplicitPArr placeHolderType 
1540                                                        (reverse (unLoc $1)) }
1541         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1542         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1543         | texp '|' flattenedpquals      { LL $ mkHsDo PArrComp (unLoc $3) $1 }
1544
1545 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1546
1547 -----------------------------------------------------------------------------
1548 -- Guards
1549
1550 guardquals :: { Located [LStmt RdrName] }
1551     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1552
1553 guardquals1 :: { Located [LStmt RdrName] }
1554     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1555     | qual                  { L1 [$1] }
1556
1557 -----------------------------------------------------------------------------
1558 -- Case alternatives
1559
1560 altslist :: { Located [LMatch RdrName] }
1561         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1562         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1563
1564 alts    :: { Located [LMatch RdrName] }
1565         : alts1                         { L1 (unLoc $1) }
1566         | ';' alts                      { LL (unLoc $2) }
1567
1568 alts1   :: { Located [LMatch RdrName] }
1569         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1570         | alts1 ';'                     { LL (unLoc $1) }
1571         | alt                           { L1 [$1] }
1572
1573 alt     :: { LMatch RdrName }
1574         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1575
1576 alt_rhs :: { Located (GRHSs RdrName) }
1577         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1578
1579 ralt :: { Located [LGRHS RdrName] }
1580         : '->' exp                      { LL (unguardedRHS $2) }
1581         | gdpats                        { L1 (reverse (unLoc $1)) }
1582
1583 gdpats :: { Located [LGRHS RdrName] }
1584         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1585         | gdpat                         { L1 [$1] }
1586
1587 gdpat   :: { LGRHS RdrName }
1588         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1589
1590 -- 'pat' recognises a pattern, including one with a bang at the top
1591 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1592 -- Bangs inside are parsed as infix operator applications, so that
1593 -- we parse them right when bang-patterns are off
1594 pat     :: { LPat RdrName }
1595 pat     :  exp                  {% checkPattern $1 }
1596         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1597
1598 apat   :: { LPat RdrName }      
1599 apat    : aexp                  {% checkPattern $1 }
1600         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1601
1602 apats  :: { [LPat RdrName] }
1603         : apat apats            { $1 : $2 }
1604         | {- empty -}           { [] }
1605
1606 -----------------------------------------------------------------------------
1607 -- Statement sequences
1608
1609 stmtlist :: { Located [LStmt RdrName] }
1610         : '{'           stmts '}'       { LL (unLoc $2) }
1611         |     vocurly   stmts close     { $2 }
1612
1613 --      do { ;; s ; s ; ; s ;; }
1614 -- The last Stmt should be an expression, but that's hard to enforce
1615 -- here, because we need too much lookahead if we see do { e ; }
1616 -- So we use ExprStmts throughout, and switch the last one over
1617 -- in ParseUtils.checkDo instead
1618 stmts :: { Located [LStmt RdrName] }
1619         : stmt stmts_help               { LL ($1 : unLoc $2) }
1620         | ';' stmts                     { LL (unLoc $2) }
1621         | {- empty -}                   { noLoc [] }
1622
1623 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1624         : ';' stmts                     { LL (unLoc $2) }
1625         | {- empty -}                   { noLoc [] }
1626
1627 -- For typing stmts at the GHCi prompt, where 
1628 -- the input may consist of just comments.
1629 maybe_stmt :: { Maybe (LStmt RdrName) }
1630         : stmt                          { Just $1 }
1631         | {- nothing -}                 { Nothing }
1632
1633 stmt  :: { LStmt RdrName }
1634         : qual                              { $1 }
1635         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1636
1637 qual  :: { LStmt RdrName }
1638     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1639     | exp                                   { L1 $ mkExprStmt $1 }
1640     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1641
1642 -----------------------------------------------------------------------------
1643 -- Record Field Update/Construction
1644
1645 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1646         : fbinds1                       { $1 }
1647         | {- empty -}                   { ([], False) }
1648
1649 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1650         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) } 
1651         | fbind                         { ([$1], False) }
1652         | '..'                          { ([],   True) }
1653   
1654 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1655         : qvar '=' exp  { HsRecField $1 $3                False }
1656         | qvar          { HsRecField $1 placeHolderPunRhs True }
1657                         -- In the punning case, use a place-holder
1658                         -- The renamer fills in the final value
1659
1660 -----------------------------------------------------------------------------
1661 -- Implicit Parameter Bindings
1662
1663 dbinds  :: { Located [LIPBind RdrName] }
1664         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1665                               in rest `seq` this `seq` LL (this : rest) }
1666         | dbinds ';'                    { LL (unLoc $1) }
1667         | dbind                         { let this = $1 in this `seq` L1 [this] }
1668 --      | {- empty -}                   { [] }
1669
1670 dbind   :: { LIPBind RdrName }
1671 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1672
1673 ipvar   :: { Located (IPName RdrName) }
1674         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1675
1676 -----------------------------------------------------------------------------
1677 -- Warnings and deprecations
1678
1679 namelist :: { Located [RdrName] }
1680 namelist : name_var              { L1 [unLoc $1] }
1681          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1682
1683 name_var :: { Located RdrName }
1684 name_var : var { $1 }
1685          | con { $1 }
1686
1687 -----------------------------------------
1688 -- Data constructors
1689 qcon    :: { Located RdrName }
1690         : qconid                { $1 }
1691         | '(' qconsym ')'       { LL (unLoc $2) }
1692         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1693 -- The case of '[:' ':]' is part of the production `parr'
1694
1695 con     :: { Located RdrName }
1696         : conid                 { $1 }
1697         | '(' consym ')'        { LL (unLoc $2) }
1698         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1699
1700 con_list :: { Located [Located RdrName] }
1701 con_list : con                  { L1 [$1] }
1702          | con ',' con_list     { LL ($1 : unLoc $3) }
1703
1704 sysdcon :: { Located DataCon }  -- Wired in data constructors
1705         : '(' ')'               { LL unitDataCon }
1706         | '(' commas ')'        { LL $ tupleCon Boxed ($2 + 1) }
1707         | '(#' '#)'             { LL $ unboxedSingletonDataCon }
1708         | '(#' commas '#)'      { LL $ tupleCon Unboxed ($2 + 1) }
1709         | '[' ']'               { LL nilDataCon }
1710
1711 conop :: { Located RdrName }
1712         : consym                { $1 }  
1713         | '`' conid '`'         { LL (unLoc $2) }
1714
1715 qconop :: { Located RdrName }
1716         : qconsym               { $1 }
1717         | '`' qconid '`'        { LL (unLoc $2) }
1718
1719 -----------------------------------------------------------------------------
1720 -- Type constructors
1721
1722 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1723         : oqtycon                       { $1 }
1724         | '(' ')'                       { LL $ getRdrName unitTyCon }
1725         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed ($2 + 1)) }
1726         | '(#' '#)'                     { LL $ getRdrName unboxedSingletonTyCon }
1727         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon Unboxed ($2 + 1)) }
1728         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1729         | '[' ']'                       { LL $ listTyCon_RDR }
1730         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1731
1732 oqtycons1 :: { [Located RdrName] }
1733         : oqtycon                       { [$1] }
1734         | oqtycons1 oqtycon             { $2 : $1 }
1735
1736 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1737         : qtycon                        { $1 }
1738         | '(' qtyconsym ')'             { LL (unLoc $2) }
1739
1740 qtyconop :: { Located RdrName } -- Qualified or unqualified
1741         : qtyconsym                     { $1 }
1742         | '`' qtycon '`'                { LL (unLoc $2) }
1743
1744 qtycon :: { Located RdrName }   -- Qualified or unqualified
1745         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1746         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1747         | tycon                         { $1 }
1748
1749 tycon   :: { Located RdrName }  -- Unqualified
1750         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1751
1752 qtyconsym :: { Located RdrName }
1753         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1754         | tyconsym                      { $1 }
1755
1756 tyconsym :: { Located RdrName }
1757         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1758         -- Does not include "!", because that is used for strictness marks
1759         -- or ".", because that separates the quantified type vars from the rest
1760         -- or "*", because that's used for kinds  (XXX: Add this)
1761         | VARSYM                        { L1 $! mkUnqual tcClsName (getVARSYM $1) }
1762         | '*'                           { L1 $! mkUnqual tcClsName (fsLit "*") }
1763     
1764
1765
1766
1767
1768 -----------------------------------------------------------------------------
1769 -- Operators
1770
1771 op      :: { Located RdrName }   -- used in infix decls
1772         : varop                 { $1 }
1773         | conop                 { $1 }
1774
1775 varop   :: { Located RdrName }
1776         : varsym                { $1 }
1777         | '`' varid '`'         { LL (unLoc $2) }
1778
1779 qop     :: { LHsExpr RdrName }   -- used in sections
1780         : qvarop                { L1 $ HsVar (unLoc $1) }
1781         | qconop                { L1 $ HsVar (unLoc $1) }
1782
1783 qopm    :: { LHsExpr RdrName }   -- used in sections
1784         : qvaropm               { L1 $ HsVar (unLoc $1) }
1785         | qconop                { L1 $ HsVar (unLoc $1) }
1786
1787 qvarop :: { Located RdrName }
1788         : qvarsym               { $1 }
1789         | '`' qvarid '`'        { LL (unLoc $2) }
1790
1791 qvaropm :: { Located RdrName }
1792         : qvarsym_no_minus      { $1 }
1793         | '`' qvarid '`'        { LL (unLoc $2) }
1794
1795 -----------------------------------------------------------------------------
1796 -- Type variables
1797
1798 tyvar   :: { Located RdrName }
1799 tyvar   : tyvarid               { $1 }
1800
1801 tyvarop :: { Located RdrName }
1802 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1803         | '.'                   {% parseErrorSDoc (getLoc $1) 
1804                                       (vcat [ptext (sLit "Illegal symbol '.' in type"), 
1805                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1806                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1807                                 }
1808
1809 tyvarid :: { Located RdrName }
1810         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1811         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1812         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1813         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1814         | 'interruptible'       { L1 $! mkUnqual tvName (fsLit "interruptible") }
1815         | 'threadsafe'          { L1 $! mkUnqual tvName (fsLit "threadsafe") }
1816
1817 -----------------------------------------------------------------------------
1818 -- Variables 
1819
1820 var     :: { Located RdrName }
1821         : varid                 { $1 }
1822         | '(' varsym ')'        { LL (unLoc $2) }
1823
1824 qvar    :: { Located RdrName }
1825         : qvarid                { $1 }
1826         | '(' varsym ')'        { LL (unLoc $2) }
1827         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1828 -- We've inlined qvarsym here so that the decision about
1829 -- whether it's a qvar or a var can be postponed until
1830 -- *after* we see the close paren.
1831
1832 qvarid :: { Located RdrName }
1833         : varid                 { $1 }
1834         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1835         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1836
1837 varid :: { Located RdrName }
1838         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1839         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1840         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1841         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1842         | 'interruptible'       { L1 $! mkUnqual varName (fsLit "interruptible") }
1843         | 'threadsafe'          { L1 $! mkUnqual varName (fsLit "threadsafe") }
1844         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1845         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1846
1847 qvarsym :: { Located RdrName }
1848         : varsym                { $1 }
1849         | qvarsym1              { $1 }
1850
1851 qvarsym_no_minus :: { Located RdrName }
1852         : varsym_no_minus       { $1 }
1853         | qvarsym1              { $1 }
1854
1855 qvarsym1 :: { Located RdrName }
1856 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1857
1858 varsym :: { Located RdrName }
1859         : varsym_no_minus       { $1 }
1860         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1861
1862 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1863         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1864         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1865
1866
1867 -- These special_ids are treated as keywords in various places, 
1868 -- but as ordinary ids elsewhere.   'special_id' collects all these
1869 -- except 'unsafe', 'interruptible', 'forall', and 'family' whose treatment differs
1870 -- depending on context 
1871 special_id :: { Located FastString }
1872 special_id
1873         : 'as'                  { L1 (fsLit "as") }
1874         | 'qualified'           { L1 (fsLit "qualified") }
1875         | 'hiding'              { L1 (fsLit "hiding") }
1876         | 'export'              { L1 (fsLit "export") }
1877         | 'label'               { L1 (fsLit "label")  }
1878         | 'dynamic'             { L1 (fsLit "dynamic") }
1879         | 'stdcall'             { L1 (fsLit "stdcall") }
1880         | 'ccall'               { L1 (fsLit "ccall") }
1881         | 'prim'                { L1 (fsLit "prim") }
1882         | 'group'               { L1 (fsLit "group") }
1883
1884 special_sym :: { Located FastString }
1885 special_sym : '!'       { L1 (fsLit "!") }
1886             | '.'       { L1 (fsLit ".") }
1887             | '*'       { L1 (fsLit "*") }
1888
1889 -----------------------------------------------------------------------------
1890 -- Data constructors
1891
1892 qconid :: { Located RdrName }   -- Qualified or unqualified
1893         : conid                 { $1 }
1894         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1895         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1896
1897 conid   :: { Located RdrName }
1898         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1899
1900 qconsym :: { Located RdrName }  -- Qualified or unqualified
1901         : consym                { $1 }
1902         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1903
1904 consym :: { Located RdrName }
1905         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1906
1907         -- ':' means only list cons
1908         | ':'                   { L1 $ consDataCon_RDR }
1909
1910
1911 -----------------------------------------------------------------------------
1912 -- Literals
1913
1914 literal :: { Located HsLit }
1915         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1916         | STRING                { L1 $ HsString     $ getSTRING $1 }
1917         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1918         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1919         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1920         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1921         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1922         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1923
1924 -----------------------------------------------------------------------------
1925 -- Layout
1926
1927 close :: { () }
1928         : vccurly               { () } -- context popped in lexer.
1929         | error                 {% popContext }
1930
1931 -----------------------------------------------------------------------------
1932 -- Miscellaneous (mostly renamings)
1933
1934 modid   :: { Located ModuleName }
1935         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
1936         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1937                                   mkModuleNameFS
1938                                    (mkFastString
1939                                      (unpackFS mod ++ '.':unpackFS c))
1940                                 }
1941
1942 commas :: { Int }
1943         : commas ','                    { $1 + 1 }
1944         | ','                           { 1 }
1945
1946 -----------------------------------------------------------------------------
1947 -- Documentation comments
1948
1949 docnext :: { LHsDocString }
1950   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
1951
1952 docprev :: { LHsDocString }
1953   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
1954
1955 docnamed :: { Located (String, HsDocString) }
1956   : DOCNAMED {%
1957       let string = getDOCNAMED $1 
1958           (name, rest) = break isSpace string
1959       in return (L1 (name, HsDocString (mkFastString rest))) }
1960
1961 docsection :: { Located (Int, HsDocString) }
1962   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
1963         return (L1 (n, HsDocString (mkFastString doc))) }
1964
1965 moduleheader :: { Maybe LHsDocString }
1966         : DOCNEXT {% let string = getDOCNEXT $1 in
1967                      return (Just (L1 (HsDocString (mkFastString string)))) }
1968
1969 maybe_docprev :: { Maybe LHsDocString }
1970         : docprev                       { Just $1 }
1971         | {- empty -}                   { Nothing }
1972
1973 maybe_docnext :: { Maybe LHsDocString }
1974         : docnext                       { Just $1 }
1975         | {- empty -}                   { Nothing }
1976
1977 {
1978 happyError :: P a
1979 happyError = srcParseFail
1980
1981 getVARID        (L _ (ITvarid    x)) = x
1982 getCONID        (L _ (ITconid    x)) = x
1983 getVARSYM       (L _ (ITvarsym   x)) = x
1984 getCONSYM       (L _ (ITconsym   x)) = x
1985 getQVARID       (L _ (ITqvarid   x)) = x
1986 getQCONID       (L _ (ITqconid   x)) = x
1987 getQVARSYM      (L _ (ITqvarsym  x)) = x
1988 getQCONSYM      (L _ (ITqconsym  x)) = x
1989 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
1990 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
1991 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1992 getCHAR         (L _ (ITchar     x)) = x
1993 getSTRING       (L _ (ITstring   x)) = x
1994 getINTEGER      (L _ (ITinteger  x)) = x
1995 getRATIONAL     (L _ (ITrational x)) = x
1996 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1997 getPRIMSTRING   (L _ (ITprimstring x)) = x
1998 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1999 getPRIMWORD     (L _ (ITprimword x)) = x
2000 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
2001 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
2002 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
2003 getINLINE       (L _ (ITinline_prag inl conl)) = (inl,conl)
2004 getSPEC_INLINE  (L _ (ITspec_inline_prag True))  = (Inline,  FunLike)
2005 getSPEC_INLINE  (L _ (ITspec_inline_prag False)) = (NoInline,FunLike)
2006
2007 getDOCNEXT (L _ (ITdocCommentNext x)) = x
2008 getDOCPREV (L _ (ITdocCommentPrev x)) = x
2009 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
2010 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
2011
2012 getSCC :: Located Token -> P FastString
2013 getSCC lt = do let s = getSTRING lt
2014                    err = "Spaces are not allowed in SCCs"
2015                -- We probably actually want to be more restrictive than this
2016                if ' ' `elem` unpackFS s
2017                    then failSpanMsgP (getLoc lt) (text err)
2018                    else return s
2019
2020 -- Utilities for combining source spans
2021 comb2 :: Located a -> Located b -> SrcSpan
2022 comb2 a b = a `seq` b `seq` combineLocs a b
2023
2024 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2025 comb3 a b c = a `seq` b `seq` c `seq`
2026     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2027
2028 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2029 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2030     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2031                 combineSrcSpans (getLoc c) (getLoc d))
2032
2033 -- strict constructor version:
2034 {-# INLINE sL #-}
2035 sL :: SrcSpan -> a -> Located a
2036 sL span a = span `seq` a `seq` L span a
2037
2038 -- Make a source location for the file.  We're a bit lazy here and just
2039 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2040 -- try to find the span of the whole file (ToDo).
2041 fileSrcSpan :: P SrcSpan
2042 fileSrcSpan = do 
2043   l <- getSrcLoc; 
2044   let loc = mkSrcLoc (srcLocFile l) 1 1;
2045   return (mkSrcSpan loc loc)
2046 }